+=head2 _koha_notify_reserve
+
+ _koha_notify_reserve( $itemnumber, $borrowernumber, $biblionumber );
+
+Sends a notification to the patron that their hold has been filled (through
+ModReserveAffect, _not_ ModReserveFill)
+
+=cut
+
+sub _koha_notify_reserve {
+ my ($itemnumber, $borrowernumber, $biblionumber) = @_;
+
+ my $dbh = C4::Context->dbh;
+ my $borrower = C4::Members::GetMember(borrowernumber => $borrowernumber);
+ my $letter_code;
+ my $print_mode = 0;
+ my $messagingprefs;
+ if ( $borrower->{'email'} || $borrower->{'smsalertnumber'} ) {
+ $messagingprefs = C4::Members::Messaging::GetMessagingPreferences( { borrowernumber => $borrowernumber, message_name => 'Hold Filled' } );
+
+ return if ( !defined( $messagingprefs->{'letter_code'} ) );
+ $letter_code = $messagingprefs->{'letter_code'};
+ } else {
+ $letter_code = 'HOLD_PRINT';
+ $print_mode = 1;
+ }
+
+ my $sth = $dbh->prepare("
+ SELECT *
+ FROM reserves
+ WHERE borrowernumber = ?
+ AND biblionumber = ?
+ ");
+ $sth->execute( $borrowernumber, $biblionumber );
+ my $reserve = $sth->fetchrow_hashref;
+ my $branch_details = GetBranchDetail( $reserve->{'branchcode'} );
+
+ my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
+
+ my $letter = getletter( 'reserves', $letter_code );
+ die "Could not find a letter called '$letter_code' in the 'reserves' module" unless( $letter );
+
+ C4::Letters::parseletter( $letter, 'branches', $reserve->{'branchcode'} );
+ C4::Letters::parseletter( $letter, 'borrowers', $borrowernumber );
+ C4::Letters::parseletter( $letter, 'biblio', $biblionumber );
+ C4::Letters::parseletter( $letter, 'reserves', $borrowernumber, $biblionumber );
+
+ if ( $reserve->{'itemnumber'} ) {
+ C4::Letters::parseletter( $letter, 'items', $reserve->{'itemnumber'} );
+ }
+ my $today = C4::Dates->new()->output();
+ $letter->{'title'} =~ s/<<today>>/$today/g;
+ $letter->{'content'} =~ s/<<today>>/$today/g;
+ $letter->{'content'} =~ s/<<[a-z0-9_]+\.[a-z0-9]+>>//g; #remove any stragglers
+
+ if ( $print_mode ) {
+ C4::Letters::EnqueueLetter( {
+ letter => $letter,
+ borrowernumber => $borrowernumber,
+ message_transport_type => 'print',
+ } );
+
+ return;
+ }
+
+ if ( grep { $_ eq 'email' } @{$messagingprefs->{transports}} ) {
+ # aka, 'email' in ->{'transports'}
+ C4::Letters::EnqueueLetter(
+ { letter => $letter,
+ borrowernumber => $borrowernumber,
+ message_transport_type => 'email',
+ from_address => $admin_email_address,
+ }
+ );
+ }
+
+ if ( grep { $_ eq 'sms' } @{$messagingprefs->{transports}} ) {
+ C4::Letters::EnqueueLetter(
+ { letter => $letter,
+ borrowernumber => $borrowernumber,
+ message_transport_type => 'sms',
+ }
+ );
+ }
+}
+
+=head2 _ShiftPriorityByDateAndPriority
+
+ $new_priority = _ShiftPriorityByDateAndPriority( $biblionumber, $reservedate, $priority );
+
+This increments the priority of all reserves after the one
+with either the lowest date after C<$reservedate>
+or the lowest priority after C<$priority>.
+
+It effectively makes room for a new reserve to be inserted with a certain
+priority, which is returned.
+
+This is most useful when the reservedate can be set by the user. It allows
+the new reserve to be placed before other reserves that have a later
+reservedate. Since priority also is set by the form in reserves/request.pl
+the sub accounts for that too.
+
+=cut
+
+sub _ShiftPriorityByDateAndPriority {
+ my ( $biblio, $resdate, $new_priority ) = @_;
+
+ my $dbh = C4::Context->dbh;
+ my $query = "SELECT priority FROM reserves WHERE biblionumber = ? AND ( reservedate > ? OR priority > ? ) ORDER BY priority ASC LIMIT 1";
+ my $sth = $dbh->prepare( $query );
+ $sth->execute( $biblio, $resdate, $new_priority );
+ my $min_priority = $sth->fetchrow;
+ # if no such matches are found, $new_priority remains as original value
+ $new_priority = $min_priority if ( $min_priority );
+
+ # Shift the priority up by one; works in conjunction with the next SQL statement
+ $query = "UPDATE reserves
+ SET priority = priority+1
+ WHERE biblionumber = ?
+ AND borrowernumber = ?
+ AND reservedate = ?
+ AND found IS NULL";
+ my $sth_update = $dbh->prepare( $query );
+
+ # Select all reserves for the biblio with priority greater than $new_priority, and order greatest to least
+ $query = "SELECT borrowernumber, reservedate FROM reserves WHERE priority >= ? AND biblionumber = ? ORDER BY priority DESC";
+ $sth = $dbh->prepare( $query );
+ $sth->execute( $new_priority, $biblio );
+ while ( my $row = $sth->fetchrow_hashref ) {
+ $sth_update->execute( $biblio, $row->{borrowernumber}, $row->{reservedate} );
+ }
+
+ return $new_priority; # so the caller knows what priority they wind up receiving
+}