koha-dev.rot13.org Git - srvgit/blob - virtualshelves/sendshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode;
  24 use Carp qw( carp );
  25 use Try::Tiny qw( catch try );
  26
  27 use C4::Auth qw( get_template_and_user );
  28 use C4::Biblio qw(
  29     GetMarcISBN
  30     GetMarcSubjects
  31 );
  32 use C4::Output qw(
  33     output_html_with_http_headers
  34     output_and_exit
  35 );
  36
  37 use Koha::Biblios;
  38 use Koha::Email;
  39 use Koha::Virtualshelves;
  40
  41 my $query = CGI->new;
  42
  43 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  44     {
  45         template_name   => "virtualshelves/sendshelfform.tt",
  46         query           => $query,
  47         type            => "intranet",
  48         flagsrequired   => { catalogue => 1 },
  49     }
  50 );
  51
  52 my $shelfid    = $query->param('shelfid');
  53 my $to_address = $query->param('email');
  54
  55 my $shelf = Koha::Virtualshelves->find( $shelfid );
  56
  57 output_and_exit( $query, $cookie, $template, 'insufficient_permission' )
  58     if $shelf && !$shelf->can_be_viewed( $loggedinuser );
  59
  60 if ($to_address) {
  61     my $comment = $query->param('comment');
  62
  63     my ( $template2, $borrowernumber, $cookie ) = get_template_and_user(
  64         {
  65         template_name   => "virtualshelves/sendshelf.tt",
  66         query           => $query,
  67         type            => "intranet",
  68         flagsrequired   => { catalogue => 1 },
  69         }
  70     );
  71
  72     my $contents = $shelf->get_contents;
  73     my $marcflavour = C4::Context->preference('marcflavour');
  74     my $iso2709;
  75     my @results;
  76
  77     while ( my $content = $contents->next ) {
  78         my $biblionumber     = $content->biblionumber;
  79         my $biblio           = Koha::Biblios->find( $biblionumber ) or next;
  80         my $dat              = $biblio->unblessed;
  81         my $record           = $biblio->metadata->record({ embed_items => 1 });
  82         my $marcauthorsarray = $biblio->get_marc_contributors;
  83         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  84
  85         my $items = $biblio->items->search_ordered;
  86
  87         $dat->{ISBN}           = GetMarcISBN($record, $marcflavour);
  88         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
  89         $dat->{MARCAUTHORS}    = $marcauthorsarray;
  90         $dat->{'biblionumber'} = $biblionumber;
  91         $dat->{ITEM_RESULTS}   = $items;
  92         $dat->{HASAUTHORS}     = $dat->{'author'} || @$marcauthorsarray;
  93         my ( $host, $relatedparts ) = $biblio->get_marc_host;
  94         $dat->{HOSTITEMENTRIES} = $host;
  95         $dat->{RELATEDPARTS} = $relatedparts;
  96
  97         $iso2709 .= $record->as_usmarc();
  98
  99         push( @results, $dat );
 100     }
 101
 102     $template2->param(
 103         BIBLIO_RESULTS => \@results,
 104         comment        => $comment,
 105         shelfname      => $shelf->shelfname,
 106     );
 107
 108     # Getting template result
 109     my $template_res = $template2->output();
 110     my $body;
 111
 112     my $subject;
 113     # Analysing information and getting mail properties
 114     if ( $template_res =~ /<SUBJECT>(?<subject>.*)<END_SUBJECT>/s ) {
 115         $subject = $+{subject};
 116         $subject =~ s|\n?(.*)\n?|$1|;
 117     }
 118     else {
 119         $subject = "no subject";
 120     }
 121
 122     my $email_header = "";
 123     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 124         $email_header = $1;
 125         $email_header =~ s|\n?(.*)\n?|$1|;
 126     }
 127
 128     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 129         $body = $1;
 130         $body =~ s|\n?(.*)\n?|$1|;
 131     }
 132
 133     my $THE_body = <<END_OF_BODY;
 134 $email_header
 135 $body
 136 END_OF_BODY
 137
 138     try {
 139         my $email = Koha::Email->create(
 140             {
 141                 to      => $to_address,
 142                 subject => $subject,
 143             }
 144         );
 145         $email->text_body( $THE_body );
 146         $email->attach(
 147             Encode::encode("UTF-8", $iso2709),
 148             content_type => 'application/octet-stream',
 149             name         => 'shelf.iso2709',
 150             disposition  => 'attachment',
 151         );
 152
 153         my $library = Koha::Patrons->find( $borrowernumber )->library;
 154         $email->send_or_die({ transport => $library->smtp_server->transport });
 155         $template->param( SENT => "1" );
 156     }
 157     catch {
 158         carp "Error sending mail: $_";
 159         $template->param( error => 1 );
 160     };
 161
 162     $template->param( email => $to_address );
 163     output_html_with_http_headers $query, $cookie, $template->output;
 164
 165 }
 166 else {
 167     $template->param(
 168         shelfid => $shelfid,
 169         url     => "/cgi-bin/koha/virtualshelves/sendshelf.pl",
 170     );
 171     output_html_with_http_headers $query, $cookie, $template->output;
 172 }