t/lib/QA/TemplateFilters.pm

   1 package t::lib::QA::TemplateFilters;
   2
   3 use Modern::Perl;
   4
   5 our @tt_directives = (
   6     qr{^\s*INCLUDE},
   7     qr{^\s*USE},
   8     qr{^\s*IF},
   9     qr{^\s*UNLESS},
  10     qr{^\s*ELSE},
  11     qr{^\s*ELSIF},
  12     qr{^\s*END},
  13     qr{^\s*SET},
  14     qr{^\s*FOR},
  15     qr{^\s*FOREACH},
  16     qr{^\s*MACRO},
  17     qr{^\s*SWITCH},
  18     qr{^\s*CASE},
  19     qr{^\s*PROCESS},
  20     qr{^\s*DEFAULT},
  21     qr{^\s*TRY},
  22     qr{^\s*CATCH},
  23     qr{^\s*BLOCK},
  24     qr{^\s*FILTER},
  25     qr{^\s*STOP},
  26     qr{^\s*NEXT},
  27 );
  28
  29 sub missing_filters {
  30     my ($content) = @_;
  31     my ( $use_raw, $has_use_raw );
  32     my @errors;
  33     my $line_number;
  34     for my $line ( split "\n", $content ) {
  35         $line_number++;
  36         if ( $line =~ m{\[%[^%]+%\]} ) {
  37
  38             # handle exceptions first
  39             $use_raw = 1
  40               if $line =~ m{|\s*\$raw};    # Is the file use the raw filter?
  41
  42             # Do we have Asset without the raw filter?
  43             if ( $line =~ m{^\s*\[% Asset} ) {
  44                 push @errors, { error => 'asset_must_be_raw', line => $line, line_number => $line_number }
  45                   and next
  46                   unless $line =~ m{\|\s*\$raw};
  47             }
  48
  49             $has_use_raw++
  50               if $line =~ m{\[% USE raw %\]};    # Does [% Use raw %] exist?
  51
  52             # Loop on TT blocks
  53             while (
  54                 $line =~ m{
  55                     \[%
  56                     (?<pre_chomp>(\s|\-|~)*)
  57                     (?<tt_block>[^%\-~]+)
  58                     (?<post_chomp>(\s|\-|~)*)
  59                     %\]}gmxs
  60               )
  61             {
  62                 my $tt_block = $+{tt_block};
  63
  64                 # It's a TT directive, no filters needed
  65                 next if grep { $tt_block =~ $_ } @tt_directives;
  66
  67                 next
  68                   if   $tt_block =~ m{\s?\|\s?\$KohaDates\s?$}
  69                     or $tt_block =~ m{\s?\|\s?\$Price\s?$}
  70                   ;    # We could escape it but should be safe
  71                 next if $tt_block =~ m{^\#};    # Is a comment, skip it
  72
  73                 push @errors, { error => 'missing_filter', line => $line, line_number => $line_number }
  74                   if $tt_block !~ m{\|\s?\$raw}   # already escaped correctly with raw
  75                   && $tt_block !~ m{=}            # assignment, maybe we should require to use SET (?)
  76                   && $tt_block !~ m{\|\s?ur(l|i)} # already has url or uri filter
  77                   && $tt_block !~ m{\|\s?html}    # already has html filter
  78                   && $tt_block !~ m{^(?<before>\S+)\s+UNLESS\s+(?<after>\S+)} # Specific for [% foo UNLESS bar %]
  79                 ;
  80             }
  81         }
  82     }
  83
  84     return @errors;
  85 }
  86
  87 1;
  88
  89 =head1 NAME
  90
  91 t::lib::QA::TemplateFilters - Module used by tests and QA script to catch missing filters in template files
  92
  93 =head1 SYNOPSIS
  94
  95     my $content = read_file($filename);
  96     my @e = t::lib::QA::TemplateFilters::missing_filters($content);
  97
  98 =head1 DESCRIPTION
  99
 100 The goal of this module is to make the subroutine reusable from the QA scripts
 101 and to not duplicate the code.
 102
 103 =head1 METHODS
 104
 105 =head2 missing_filters
 106
 107     Take a template content file in parameter and return an array of errors.
 108     An error is a hashref with 2 keys, error and line.
 109     * error can be:
 110     asset_must_be_raw - When Asset is called without using raw
 111     missing_filter    - When a TT variable is displayed without filter
 112
 113     * line is the line where the error has been found.
 114
 115 =head1 AUTHORS
 116
 117 Jonathan Druart <jonathan.druart@bugs.koha-community.org>
 118
 119 =head1 COPYRIGHT
 120
 121 Copyright 2017 - Koha Development Team
 122
 123 =head1 LICENSE
 124
 125 This file is part of Koha.
 126
 127 Koha is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by
 128 the Free Software Foundation; either version 3 of the License, or (at your option) any later version.
 129
 130 Koha is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details.
 131
 132 You should have received a copy of the GNU General Public License along with Koha; if not, see <http://www.gnu.org/licenses>.
 133
 134 =cut
 135
 136 1;