koha-dev.rot13.org Git - srvgit/blob - t/db_dependent/Reports/Guided.t

   1 # Copyright 2012 Catalyst IT Ltd.
   2 # Copyright 2015 Koha Development team
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20
  21 use Test::More tests => 11;
  22 use Test::Warn;
  23
  24 use t::lib::TestBuilder;
  25 use C4::Context;
  26 use Koha::Database;
  27 use Koha::Items;
  28 use Koha::Reports;
  29 use Koha::Notice::Messages;
  30
  31 use_ok('C4::Reports::Guided', qw( execute_query save_report delete_report strip_limit GetReservedAuthorisedValues IsAuthorisedValueValid GetParametersFromSQL ValidateSQLParameters get_saved_reports update_sql get_report_areas convert_sql EmailReport nb_rows ));
  32 can_ok(
  33     'C4::Reports::Guided',
  34     qw(save_report delete_report execute_query)
  35 );
  36
  37 my $schema = Koha::Database->new->schema;
  38 $schema->storage->txn_begin;
  39 my $builder = t::lib::TestBuilder->new;
  40
  41 subtest 'strip_limit' => sub {
  42     # This is the query I found that triggered bug 8594.
  43     my $sql = "SELECT aqorders.ordernumber, biblio.title, biblio.biblionumber, items.homebranch,
  44         aqorders.entrydate, aqorders.datereceived,
  45         (SELECT DATE(datetime) FROM statistics
  46             WHERE itemnumber=items.itemnumber AND
  47                 (type='return' OR type='issue') LIMIT 1)
  48         AS shelvedate,
  49         DATEDIFF(COALESCE(
  50             (SELECT DATE(datetime) FROM statistics
  51                 WHERE itemnumber=items.itemnumber AND
  52                 (type='return' OR type='issue') LIMIT 1),
  53         aqorders.datereceived), aqorders.entrydate) AS totaldays
  54     FROM aqorders
  55     LEFT JOIN biblio USING (biblionumber)
  56     LEFT JOIN items ON (items.biblionumber = biblio.biblionumber
  57         AND dateaccessioned=aqorders.datereceived)
  58     WHERE (entrydate >= '2011-01-01' AND (datereceived < '2011-02-01' OR datereceived IS NULL))
  59         AND items.homebranch LIKE 'INFO'
  60     ORDER BY title";
  61
  62     my ($res_sql, $res_lim1, $res_lim2) = C4::Reports::Guided::strip_limit($sql);
  63     is($res_sql, $sql, "Not breaking subqueries");
  64     is($res_lim1, 0, "Returns correct default offset");
  65     is($res_lim2, undef, "Returns correct default LIMIT");
  66
  67     # Now the same thing, but we want it to remove the LIMIT from the end
  68
  69     my $test_sql = $res_sql . " LIMIT 242";
  70     ($res_sql, $res_lim1, $res_lim2) = C4::Reports::Guided::strip_limit($test_sql);
  71     # The replacement drops a ' ' where the limit was
  72     is(trim($res_sql), $sql, "Correctly removes only final LIMIT");
  73     is($res_lim1, 0, "Returns correct default offset");
  74     is($res_lim2, 242, "Returns correct extracted LIMIT");
  75
  76     $test_sql = $res_sql . " LIMIT 13,242";
  77     ($res_sql, $res_lim1, $res_lim2) = C4::Reports::Guided::strip_limit($test_sql);
  78     # The replacement drops a ' ' where the limit was
  79     is(trim($res_sql), $sql, "Correctly removes only final LIMIT (with offset)");
  80     is($res_lim1, 13, "Returns correct extracted offset");
  81     is($res_lim2, 242, "Returns correct extracted LIMIT");
  82
  83     # After here is the simpler case, where there isn't a WHERE clause to worry
  84     # about.
  85
  86     # First case with nothing to change
  87     $sql = "SELECT * FROM items";
  88     ($res_sql, $res_lim1, $res_lim2) = C4::Reports::Guided::strip_limit($sql);
  89     is($res_sql, $sql, "Not breaking simple queries");
  90     is($res_lim1, 0, "Returns correct default offset");
  91     is($res_lim2, undef, "Returns correct default LIMIT");
  92
  93     $test_sql = $sql . " LIMIT 242";
  94     ($res_sql, $res_lim1, $res_lim2) = C4::Reports::Guided::strip_limit($test_sql);
  95     is(trim($res_sql), $sql, "Correctly removes LIMIT in simple case");
  96     is($res_lim1, 0, "Returns correct default offset");
  97     is($res_lim2, 242, "Returns correct extracted LIMIT");
  98
  99     $test_sql = $sql . " LIMIT 13,242";
 100     ($res_sql, $res_lim1, $res_lim2) = C4::Reports::Guided::strip_limit($test_sql);
 101     is(trim($res_sql), $sql, "Correctly removes LIMIT in simple case (with offset)");
 102     is($res_lim1, 13, "Returns correct extracted offset");
 103     is($res_lim2, 242, "Returns correct extracted LIMIT");
 104 };
 105
 106 $_->delete for Koha::AuthorisedValues->search({ category => 'XXX' });
 107 Koha::AuthorisedValue->new({category => 'LOC'})->store;
 108
 109 subtest 'GetReservedAuthorisedValues' => sub {
 110     plan tests => 1;
 111     # This one will catch new reserved words not added
 112     # to GetReservedAuthorisedValues
 113     my %test_authval = (
 114         'date' => 1,
 115         'branches' => 1,
 116         'itemtypes' => 1,
 117         'cn_source' => 1,
 118         'categorycode' => 1,
 119         'biblio_framework' => 1,
 120         'list' => 1,
 121     );
 122
 123     my $reserved_authorised_values = GetReservedAuthorisedValues();
 124     is_deeply(\%test_authval, $reserved_authorised_values,
 125                 'GetReservedAuthorisedValues returns a fixed list');
 126 };
 127
 128 subtest 'IsAuthorisedValueValid' => sub {
 129     plan tests => 9;
 130     ok( IsAuthorisedValueValid('LOC'),
 131         'User defined authorised value category is valid');
 132
 133     ok( ! IsAuthorisedValueValid('XXX'),
 134         'Not defined authorised value category is invalid');
 135
 136     # Loop through the reserved authorised values
 137     foreach my $authorised_value ( keys %{GetReservedAuthorisedValues()} ) {
 138         ok( IsAuthorisedValueValid($authorised_value),
 139             '\''.$authorised_value.'\' is a reserved word, and thus a valid authorised value');
 140     }
 141 };
 142
 143 subtest 'GetParametersFromSQL+ValidateSQLParameters' => sub  {
 144     plan tests => 3;
 145     my $test_query_1 = "
 146         SELECT date_due
 147         FROM old_issues
 148         WHERE YEAR(timestamp) = <<Year|custom_list>> AND
 149               branchcode = <<Branch|branches>> AND
 150               borrowernumber = <<Borrower>> AND
 151               itemtype = <<Item type|itemtypes:all>>
 152     ";
 153
 154     my @test_parameters_with_custom_list = (
 155         { 'name' => 'Year', 'authval' => 'custom_list' },
 156         { 'name' => 'Branch', 'authval' => 'branches' },
 157         { 'name' => 'Borrower', 'authval' => undef },
 158         { 'name' => 'Item type', 'authval' => 'itemtypes' }
 159     );
 160
 161     is_deeply( GetParametersFromSQL($test_query_1), \@test_parameters_with_custom_list,
 162         'SQL params are correctly parsed');
 163
 164     my @problematic_parameters = ();
 165     push @problematic_parameters, { 'name' => 'Year', 'authval' => 'custom_list' };
 166     is_deeply( ValidateSQLParameters( $test_query_1 ),
 167                \@problematic_parameters,
 168                '\'custom_list\' not a valid category' );
 169
 170     my $test_query_2 = "
 171         SELECT date_due
 172         FROM old_issues
 173         WHERE YEAR(timestamp) = <<Year|date>> AND
 174               branchcode = <<Branch|branches>> AND
 175               borrowernumber = <<Borrower|LOC>>
 176     ";
 177
 178     is_deeply( ValidateSQLParameters( $test_query_2 ),
 179         [],
 180         'All parameters valid, empty problematic authvals list'
 181     );
 182 };
 183
 184 subtest 'get_saved_reports' => sub {
 185     plan tests => 17;
 186     my $dbh = C4::Context->dbh;
 187     $dbh->do(q|DELETE FROM saved_sql|);
 188     $dbh->do(q|DELETE FROM saved_reports|);
 189
 190     #Test save_report
 191     my $count = scalar @{ get_saved_reports() };
 192     is( $count, 0, "There is no report" );
 193
 194     my @report_ids;
 195     foreach my $ii ( 1..3 ) {
 196         my $id = $builder->build({ source => 'Borrower' })->{ borrowernumber };
 197         push @report_ids, save_report({
 198             borrowernumber => $id,
 199             sql            => "SQL$id",
 200             name           => "Name$id",
 201             area           => "area$ii", # ii vs id area is varchar(6)
 202             group          => "group$id",
 203             subgroup       => "subgroup$id",
 204             type           => "type$id",
 205             notes          => "note$id",
 206             cache_expiry   => undef,
 207             public         => 0,
 208         });
 209         $count++;
 210     }
 211     like( $report_ids[0], '/^\d+$/', "Save_report returns an id for first" );
 212     like( $report_ids[1], '/^\d+$/', "Save_report returns an id for second" );
 213     like( $report_ids[2], '/^\d+$/', "Save_report returns an id for third" );
 214
 215     is( scalar @{ get_saved_reports() },
 216         $count, "$count reports have been added" );
 217
 218     ok( 0 < scalar @{ get_saved_reports( $report_ids[0] ) }, "filter takes report id" );
 219
 220     my $r1 = Koha::Reports->find($report_ids[0]);
 221     $r1 = update_sql($r1->id, { %{$r1->unblessed}, borrowernumber => $r1->borrowernumber, name => 'Just another report' });
 222     is( $r1->cache_expiry, 300, 'cache_expiry has the correct default value, from DBMS' );
 223
 224     #Test delete_report
 225     is (delete_report(),undef, "Without id delete_report returns undef");
 226
 227     is( delete_report( $report_ids[0] ), 1, "report 1 is deleted" );
 228     $count--;
 229
 230     is( scalar @{ get_saved_reports() }, $count, "Report1 has been deleted" );
 231
 232     is( delete_report( $report_ids[1], $report_ids[2] ), 2, "report 2 and 3 are deleted" );
 233     $count -= 2;
 234
 235     is( scalar @{ get_saved_reports() },
 236         $count, "Report2 and report3 have been deleted" );
 237
 238     my $sth = execute_query('SELECT COUNT(*) FROM systempreferences', 0, 10);
 239     my $results = $sth->fetchall_arrayref;
 240     is(scalar @$results, 1, 'running a query returned a result');
 241
 242     my $version = C4::Context->preference('Version');
 243     $sth = execute_query(
 244         'SELECT value FROM systempreferences WHERE variable = ?',
 245         0,
 246         10,
 247         [ 'Version' ],
 248     );
 249     $results = $sth->fetchall_arrayref;
 250     is_deeply(
 251         $results,
 252         [ [ $version ] ],
 253         'running a query with a parameter returned the expected result'
 254     );
 255
 256     # for next test, we want to let execute_query capture any SQL errors
 257     my $errors;
 258     warning_like {local $dbh->{RaiseError} = 0; ($sth, $errors) = execute_query(
 259             'SELECT surname FRM borrowers',  # error in the query is intentional
 260             0, 10 ) }
 261             qr/DBD::mysql::st execute failed: You have an error in your SQL syntax;/,
 262             "Wrong SQL syntax raises warning";
 263     ok(
 264         defined($errors) && exists($errors->{queryerr}),
 265         'attempting to run a report with an SQL syntax error returns error message (Bug 12214)'
 266     );
 267
 268     is_deeply( get_report_areas(), [ 'CIRC', 'CAT', 'PAT', 'ACQ', 'ACC', 'SER' ],
 269         "get_report_areas returns the correct array of report areas");
 270 };
 271
 272 subtest 'Ensure last_run is populated' => sub {
 273     plan tests => 3;
 274
 275     my $rs = Koha::Database->new()->schema()->resultset('SavedSql');
 276
 277     my $report = $rs->new(
 278         {
 279             report_name => 'Test Report',
 280             savedsql    => 'SELECT * FROM branches',
 281             notes       => undef,
 282         }
 283     )->insert();
 284
 285     is( $report->last_run, undef, 'Newly created report has null last_run ' );
 286
 287     execute_query( $report->savedsql, undef, undef, undef, $report->id );
 288     $report->discard_changes();
 289
 290     isnt( $report->last_run, undef, 'First run of report populates last_run' );
 291
 292     my $previous_last_run = $report->last_run;
 293     sleep(1); # last_run is stored to the second, so we need to ensure at least one second has passed between runs
 294     execute_query( $report->savedsql, undef, undef, undef, $report->id );
 295     $report->discard_changes();
 296
 297     isnt( $report->last_run, $previous_last_run, 'Second run of report updates last_run' );
 298 };
 299
 300 subtest 'convert_sql' => sub {
 301     plan tests => 4;
 302
 303     my $sql = q|
 304     SELECT biblionumber, ExtractValue(marcxml,
 305 'count(//datafield[@tag="505"])') AS count505
 306     FROM biblioitems
 307     HAVING count505 > 1|;
 308     my $expected_converted_sql = q|
 309     SELECT biblionumber, ExtractValue(metadata,
 310 'count(//datafield[@tag="505"])') AS count505
 311     FROM biblio_metadata
 312     HAVING count505 > 1|;
 313
 314     is( C4::Reports::Guided::convert_sql( $sql ), $expected_converted_sql, "Simple query should have been correctly converted");
 315
 316     $sql = q|
 317     SELECT biblionumber, substring(
 318 ExtractValue(marcxml,'//controlfield[@tag="008"]'), 8,4 ) AS 'PUB DATE',
 319 title
 320     FROM biblioitems
 321     INNER JOIN biblio USING (biblionumber)
 322     WHERE biblionumber = 14|;
 323
 324     $expected_converted_sql = q|
 325     SELECT biblionumber, substring(
 326 ExtractValue(metadata,'//controlfield[@tag="008"]'), 8,4 ) AS 'PUB DATE',
 327 title
 328     FROM biblio_metadata
 329     INNER JOIN biblio USING (biblionumber)
 330     WHERE biblionumber = 14|;
 331     is( C4::Reports::Guided::convert_sql( $sql ), $expected_converted_sql, "Query with biblio info should have been correctly converted");
 332
 333     $sql = q|
 334     SELECT concat(b.title, ' ', ExtractValue(m.marcxml,
 335 '//datafield[@tag="245"]/subfield[@code="b"]')) AS title, b.author,
 336 count(h.reservedate) AS 'holds'
 337     FROM biblio b
 338     LEFT JOIN biblioitems m USING (biblionumber)
 339     LEFT JOIN reserves h ON (b.biblionumber=h.biblionumber)
 340     GROUP BY b.biblionumber
 341     HAVING count(h.reservedate) >= 42|;
 342
 343     $expected_converted_sql = q|
 344     SELECT concat(b.title, ' ', ExtractValue(m.metadata,
 345 '//datafield[@tag="245"]/subfield[@code="b"]')) AS title, b.author,
 346 count(h.reservedate) AS 'holds'
 347     FROM biblio b
 348     LEFT JOIN biblio_metadata m USING (biblionumber)
 349     LEFT JOIN reserves h ON (b.biblionumber=h.biblionumber)
 350     GROUP BY b.biblionumber
 351     HAVING count(h.reservedate) >= 42|;
 352     is( C4::Reports::Guided::convert_sql( $sql ), $expected_converted_sql, "Query with 2 joins should have been correctly converted");
 353
 354     $sql = q|
 355     SELECT t1.marcxml AS first, t2.marcxml AS second,
 356     FROM biblioitems t1
 357     LEFT JOIN biblioitems t2 USING ( biblionumber )|;
 358
 359     $expected_converted_sql = q|
 360     SELECT t1.metadata AS first, t2.metadata AS second,
 361     FROM biblio_metadata t1
 362     LEFT JOIN biblio_metadata t2 USING ( biblionumber )|;
 363     is( C4::Reports::Guided::convert_sql( $sql ), $expected_converted_sql, "Query with multiple instances of marcxml and biblioitems should have them all replaced");
 364 };
 365
 366 subtest 'Email report test' => sub {
 367
 368     plan tests => 12;
 369     my $dbh = C4::Context->dbh;
 370
 371     my $id1 = $builder->build({ source => 'Borrower',value => { surname => 'mailer', email => 'a@b.com', emailpro => 'b@c.com' } })->{ borrowernumber };
 372     my $id2 = $builder->build({ source => 'Borrower',value => { surname => 'nomailer', email => undef, emailpro => 'd@e.com' } })->{ borrowernumber };
 373     my $id3 = $builder->build({ source => 'Borrower',value => { surname => 'norman', email => 'a@b.com', emailpro => undef } })->{ borrowernumber };
 374     my $report1 = $builder->build({ source => 'SavedSql', value => { savedsql => "SELECT surname,borrowernumber,email,emailpro FROM borrowers WHERE borrowernumber IN ($id1,$id2,$id3)" } })->{ id };
 375     my $report2 = $builder->build({ source => 'SavedSql', value => { savedsql => "SELECT potato FROM mashed" } })->{ id };
 376
 377     my $letter1 = $builder->build({
 378             source => 'Letter',
 379             value => {
 380                 content => "[% surname %]",
 381                 branchcode => "",
 382                 message_transport_type => 'email'
 383             }
 384         });
 385     my $letter2 = $builder->build({
 386             source => 'Letter',
 387             value => {
 388                 content => "[% firstname %]",
 389                 branchcode => "",
 390                 message_transport_type => 'email'
 391             }
 392         });
 393
 394     my $message_count = Koha::Notice::Messages->search({})->count;
 395
 396     my ( $emails, $errors ) = C4::Reports::Guided::EmailReport();
 397     is( $errors->[0]{FATAL}, 'MISSING_PARAMS', "Need to enter required params");
 398
 399     ($emails, $errors ) = C4::Reports::Guided::EmailReport({report_id => $report1, module => $letter1->{module}, code => $letter2->{code}});
 400     is( $errors->[0]{FATAL}, 'NO_LETTER', "Must have a letter that exists");
 401
 402     # for next test, we want to let execute_query capture any SQL errors
 403     warning_like { local $dbh->{RaiseError} = 0; ($emails, $errors ) = C4::Reports::Guided::EmailReport({report_id => $report2, module => $letter1->{module} , code => $letter1->{code} }) }
 404         qr/DBD::mysql::st execute failed/,
 405         'Error from bad report';
 406     is( $errors->[0]{FATAL}, 'REPORT_FAIL', "Bad report returns failure");
 407
 408     ($emails, $errors ) = C4::Reports::Guided::EmailReport({report_id => $report1, module => $letter1->{module} , code => $letter1->{code} });
 409     is( $errors->[0]{NO_FROM_COL} == 1 && $errors->[1]{NO_EMAIL_COL} == 2  && $errors->[2]{NO_FROM_COL} == 2, 1, "Correct warnings from the routine");
 410
 411     ($emails, $errors ) = C4::Reports::Guided::EmailReport({report_id => $report1, module => $letter1->{module} , code => $letter1->{code}, from => 'the@future.ooh' });
 412     is( $errors->[0]{NO_EMAIL_COL}, 2, "Warning only for patron with no email");
 413
 414     is( $message_count,  Koha::Notice::Messages->search({})->count, "Messages not added without commit");
 415
 416     ($emails, $errors ) = C4::Reports::Guided::EmailReport({report_id => $report1, module => $letter1->{module} , code => $letter1->{code}, from => 'the@future.ooh' });
 417     is( $emails->[0]{letter}->{content}, "mailer", "Message has expected content");
 418     is( $emails->[1]{letter}->{content}, "norman", "Message has expected content");
 419
 420     ($emails, $errors ) = C4::Reports::Guided::EmailReport({report_id => $report1, module => $letter1->{module} , code => $letter1->{code}, from => 'the@future.ooh', email => 'emailpro' });
 421     is_deeply( $errors, [{'NO_EMAIL_COL'=>3}],"We report missing email in emailpro column");
 422     is( $emails->[0]->{to_address}, 'b@c.com', "Message uses correct email");
 423     is( $emails->[1]->{to_address}, 'd@e.com', "Message uses correct email");
 424
 425 };
 426
 427 $schema->storage->txn_rollback;
 428
 429 subtest 'nb_rows() tests' => sub {
 430
 431     plan tests => 3;
 432
 433     my $dbh = C4::Context->dbh;
 434     $schema->storage->txn_begin;
 435
 436     my $items_count = Koha::Items->search->count;
 437     $builder->build_object({ class => 'Koha::Items' });
 438     $builder->build_object({ class => 'Koha::Items' });
 439     $items_count += 2;
 440
 441     my $query = q{
 442         SELECT * FROM items xxx
 443     };
 444
 445     my $nb_rows = nb_rows( $query );
 446
 447     is( $nb_rows, $items_count, 'nb_rows returns the right value' );
 448
 449     my $bad_query = q{
 450         SELECT * items xxx
 451     };
 452
 453     # for next test, we want to let execute_query capture any SQL errors
 454
 455     warning_like
 456         { $nb_rows = nb_rows( $bad_query ) }
 457         qr/DBD::mysql::st execute failed:/,
 458         'Bad queries raise a warning';
 459
 460     is( $nb_rows, 0, 'nb_rows returns 0 on bad queries' );
 461
 462     $schema->storage->txn_rollback;
 463 };
 464
 465 sub trim {
 466     my ($s) = @_;
 467     $s =~ s/^\s*(.*?)\s*$/$1/s;
 468     return $s;
 469 }