koha-dev.rot13.org Git - srvgit/blob - t/db_dependent/Members.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Test::More tests => 56;
  21 use Test::MockModule;
  22 use Data::Dumper;
  23 use C4::Context;
  24 use Koha::Database;
  25
  26 use t::lib::TestBuilder;
  27
  28 BEGIN {
  29         use_ok('C4::Members');
  30 }
  31
  32 my $schema = Koha::Database->schema;
  33 $schema->storage->txn_begin;
  34 my $builder = t::lib::TestBuilder->new;
  35 my $dbh = C4::Context->dbh;
  36 $dbh->{RaiseError} = 1;
  37
  38 my $library1 = $builder->build({
  39     source => 'Branch',
  40 });
  41 my $library2 = $builder->build({
  42     source => 'Branch',
  43 });
  44 my $CARDNUMBER   = 'TESTCARD01';
  45 my $FIRSTNAME    = 'Marie';
  46 my $SURNAME      = 'Mcknight';
  47 my $CATEGORYCODE = 'S';
  48 my $BRANCHCODE   = $library1->{branchcode};
  49
  50 my $CHANGED_FIRSTNAME = "Marry Ann";
  51 my $EMAIL             = "Marie\@email.com";
  52 my $EMAILPRO          = "Marie\@work.com";
  53 my $PHONE             = "555-12123";
  54
  55 # XXX should be randomised and checked against the database
  56 my $IMPOSSIBLE_CARDNUMBER = "XYZZZ999";
  57
  58 #my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter)= @_;
  59 my @USERENV = (
  60     1,
  61     'test',
  62     'MASTERTEST',
  63     'Test',
  64     'Test',
  65     't',
  66     'Test',
  67     0,
  68 );
  69 my $BRANCH_IDX = 5;
  70
  71 C4::Context->_new_userenv ('DUMMY_SESSION_ID');
  72 C4::Context->set_userenv ( @USERENV );
  73
  74 my $userenv = C4::Context->userenv
  75   or BAIL_OUT("No userenv");
  76
  77 # Make a borrower for testing
  78 my %data = (
  79     cardnumber => $CARDNUMBER,
  80     firstname =>  $FIRSTNAME,
  81     surname => $SURNAME,
  82     categorycode => $CATEGORYCODE,
  83     branchcode => $BRANCHCODE,
  84     dateofbirth => '',
  85     dateexpiry => '9999-12-31',
  86     userid => 'tomasito'
  87 );
  88
  89 testAgeAccessors(\%data); #Age accessor tests don't touch the db so it is safe to run them with just the object.
  90
  91 my $addmem=AddMember(%data);
  92 ok($addmem, "AddMember()");
  93
  94 # It's not really a Move, it's a Copy.
  95 my $result = MoveMemberToDeleted($addmem);
  96 ok($result,"MoveMemberToDeleted()");
  97
  98 my $sth = $dbh->prepare("SELECT * from borrowers WHERE borrowernumber=?");
  99 $sth->execute($addmem);
 100 my $MemberAdded = $sth->fetchrow_hashref;
 101
 102 $sth = $dbh->prepare("SELECT * from deletedborrowers WHERE borrowernumber=?");
 103 $sth->execute($addmem);
 104 my $MemberMoved = $sth->fetchrow_hashref;
 105
 106 is_deeply($MemberMoved,$MemberAdded,"Confirm MoveMemberToDeleted.");
 107
 108 my $member=GetMemberDetails("",$CARDNUMBER)
 109   or BAIL_OUT("Cannot read member with card $CARDNUMBER");
 110
 111 ok ( $member->{firstname}    eq $FIRSTNAME    &&
 112      $member->{surname}      eq $SURNAME      &&
 113      $member->{categorycode} eq $CATEGORYCODE &&
 114      $member->{branchcode}   eq $BRANCHCODE
 115      , "Got member")
 116   or diag("Mismatching member details: ".Dumper(\%data, $member));
 117
 118 is($member->{dateofbirth}, undef, "Empty dates handled correctly");
 119
 120 $member->{firstname} = $CHANGED_FIRSTNAME;
 121 $member->{email}     = $EMAIL;
 122 $member->{phone}     = $PHONE;
 123 $member->{emailpro}  = $EMAILPRO;
 124 ModMember(%$member);
 125 my $changedmember=GetMemberDetails("",$CARDNUMBER);
 126 ok ( $changedmember->{firstname} eq $CHANGED_FIRSTNAME &&
 127      $changedmember->{email}     eq $EMAIL             &&
 128      $changedmember->{phone}     eq $PHONE             &&
 129      $changedmember->{emailpro}  eq $EMAILPRO
 130      , "Member Changed")
 131   or diag("Mismatching member details: ".Dumper($member, $changedmember));
 132
 133 C4::Context->set_preference( 'CardnumberLength', '' );
 134 C4::Context->clear_syspref_cache();
 135
 136 my $checkcardnum=C4::Members::checkcardnumber($CARDNUMBER, "");
 137 is ($checkcardnum, "1", "Card No. in use");
 138
 139 $checkcardnum=C4::Members::checkcardnumber($IMPOSSIBLE_CARDNUMBER, "");
 140 is ($checkcardnum, "0", "Card No. not used");
 141
 142 C4::Context->set_preference( 'CardnumberLength', '4' );
 143 C4::Context->clear_syspref_cache();
 144
 145 $checkcardnum=C4::Members::checkcardnumber($IMPOSSIBLE_CARDNUMBER, "");
 146 is ($checkcardnum, "2", "Card number is too long");
 147
 148
 149
 150 C4::Context->set_preference( 'AutoEmailPrimaryAddress', 'OFF' );
 151 C4::Context->clear_syspref_cache();
 152
 153 my $notice_email = GetNoticeEmailAddress($member->{'borrowernumber'});
 154 is ($notice_email, $EMAIL, "GetNoticeEmailAddress returns correct value when AutoEmailPrimaryAddress is off");
 155
 156 C4::Context->set_preference( 'AutoEmailPrimaryAddress', 'emailpro' );
 157 C4::Context->clear_syspref_cache();
 158
 159 $notice_email = GetNoticeEmailAddress($member->{'borrowernumber'});
 160 is ($notice_email, $EMAILPRO, "GetNoticeEmailAddress returns correct value when AutoEmailPrimaryAddress is emailpro");
 161
 162 ok(!$member->{is_expired}, "GetMemberDetails() indicates that patron is not expired");
 163 ModMember(borrowernumber => $member->{'borrowernumber'}, dateexpiry => '2001-01-1');
 164 $member = GetMemberDetails($member->{'borrowernumber'});
 165 ok($member->{is_expired}, "GetMemberDetails() indicates that patron is expired");
 166
 167 # clean up
 168 DelMember($member->{borrowernumber});
 169 my $borrower = GetMember( cardnumber => $CARDNUMBER );
 170 is( $borrower, undef, 'DelMember should remove the patron' );
 171
 172 # Check_Userid tests
 173 %data = (
 174     cardnumber   => "123456789",
 175     firstname    => "Tomasito",
 176     surname      => "None",
 177     categorycode => "S",
 178     branchcode   => $library2->{branchcode},
 179     dateofbirth  => '',
 180     debarred     => '',
 181     dateexpiry   => '',
 182     dateenrolled => '',
 183 );
 184 # Add a new borrower
 185 my $borrowernumber = AddMember( %data );
 186 is( Check_Userid( 'tomasito.non', $borrowernumber ), 1,
 187     'recently created userid -> unique (borrowernumber passed)' );
 188 is( Check_Userid( 'tomasitoxxx', $borrowernumber ), 1,
 189     'non-existent userid -> unique (borrowernumber passed)' );
 190 is( Check_Userid( 'tomasito.none', '' ), 0,
 191     'userid exists (blank borrowernumber)' );
 192 is( Check_Userid( 'tomasitoxxx', '' ), 1,
 193     'non-existent userid -> unique (blank borrowernumber)' );
 194
 195 $borrower = GetMember( borrowernumber => $borrowernumber );
 196 is( $borrower->{dateofbirth}, undef, 'AddMember should undef dateofbirth if empty string is given');
 197 is( $borrower->{debarred}, undef, 'AddMember should undef debarred if empty string is given');
 198 isnt( $borrower->{dateexpiry}, '0000-00-00', 'AddMember should not set dateexpiry to 0000-00-00 if empty string is given');
 199 isnt( $borrower->{dateenrolled}, '0000-00-00', 'AddMember should not set dateenrolled to 0000-00-00 if empty string is given');
 200
 201 ModMember( borrowernumber => $borrowernumber, dateofbirth => '', debarred => '', dateexpiry => '', dateenrolled => '' );
 202 $borrower = GetMember( borrowernumber => $borrowernumber );
 203 is( $borrower->{dateofbirth}, undef, 'ModMember should undef dateofbirth if empty string is given');
 204 is( $borrower->{debarred}, undef, 'ModMember should undef debarred if empty string is given');
 205 isnt( $borrower->{dateexpiry}, '0000-00-00', 'ModMember should not set dateexpiry to 0000-00-00 if empty string is given');
 206 isnt( $borrower->{dateenrolled}, '0000-00-00', 'ModMember should not set dateenrolled to 0000-00-00 if empty string is given');
 207
 208 ModMember( borrowernumber => $borrowernumber, dateofbirth => '1970-01-01', debarred => '2042-01-01', dateexpiry => '9999-12-31', dateenrolled => '2015-09-06' );
 209 $borrower = GetMember( borrowernumber => $borrowernumber );
 210 is( $borrower->{dateofbirth}, '1970-01-01', 'ModMember should correctly set dateofbirth if a valid date is given');
 211 is( $borrower->{debarred}, '2042-01-01', 'ModMember should correctly set debarred if a valid date is given');
 212 is( $borrower->{dateexpiry}, '9999-12-31', 'ModMember should correctly set dateexpiry if a valid date is given');
 213 is( $borrower->{dateenrolled}, '2015-09-06', 'ModMember should correctly set dateenrolled if a valid date is given');
 214
 215 # Add a new borrower with the same userid but different cardnumber
 216 $data{ cardnumber } = "987654321";
 217 my $new_borrowernumber = AddMember( %data );
 218 is( Check_Userid( 'tomasito.none', '' ), 0,
 219     'userid not unique (blank borrowernumber)' );
 220 is( Check_Userid( 'tomasito.none', $new_borrowernumber ), 0,
 221     'userid not unique (second borrowernumber passed)' );
 222 $borrower = GetMember( borrowernumber => $new_borrowernumber );
 223 ok( $borrower->{userid} ne 'tomasito', "Borrower with duplicate userid has new userid generated" );
 224
 225 $data{ cardnumber } = "234567890";
 226 $data{userid} = 'a_user_id';
 227 $borrowernumber = AddMember( %data );
 228 $borrower = GetMember( borrowernumber => $borrowernumber );
 229 is( $borrower->{userid}, $data{userid}, 'AddMember should insert the given userid' );
 230
 231 # Regression tests for BZ13502
 232 ## Remove all entries with userid='' (should be only 1 max)
 233 $dbh->do(q|DELETE FROM borrowers WHERE userid = ''|);
 234 ## And create a patron with a userid=''
 235 $borrowernumber = AddMember( categorycode => 'S', branchcode => $library2->{branchcode} );
 236 $dbh->do(q|UPDATE borrowers SET userid = '' WHERE borrowernumber = ?|, undef, $borrowernumber);
 237 # Create another patron and verify the userid has been generated
 238 $borrowernumber = AddMember( categorycode => 'S', branchcode => $library2->{branchcode} );
 239 ok( $borrowernumber > 0, 'AddMember should have inserted the patron even if no userid is given' );
 240 $borrower = GetMember( borrowernumber => $borrowernumber );
 241 ok( $borrower->{userid},  'A userid should have been generated correctly' );
 242
 243 # Regression tests for BZ12226
 244 is( Check_Userid( C4::Context->config('user'), '' ), 0,
 245     'Check_Userid should return 0 for the DB user (Bug 12226)');
 246
 247 subtest 'GetMemberAccountBalance' => sub {
 248
 249     plan tests => 10;
 250
 251     my $members_mock = new Test::MockModule('C4::Members');
 252     $members_mock->mock( 'GetMemberAccountRecords', sub {
 253         my ($borrowernumber) = @_;
 254         if ($borrowernumber) {
 255             my @accountlines = (
 256             { amountoutstanding => '7', accounttype => 'Rent' },
 257             { amountoutstanding => '5', accounttype => 'Res' },
 258             { amountoutstanding => '3', accounttype => 'Pay' } );
 259             return ( 15, \@accountlines );
 260         }
 261         else {
 262             my @accountlines;
 263             return ( 0, \@accountlines );
 264         }
 265     });
 266
 267     my $person = GetMemberDetails(undef,undef);
 268     ok( !$person , 'Expected no member details from undef,undef' );
 269     $person = GetMemberDetails(undef,'987654321');
 270     is( $person->{amountoutstanding}, 15,
 271         'Expected 15 outstanding for cardnumber.');
 272     $borrowernumber = $person->{borrowernumber};
 273     $person = GetMemberDetails($borrowernumber,undef);
 274     is( $person->{amountoutstanding}, 15,
 275         'Expected 15 outstanding for borrowernumber.');
 276     $person = GetMemberDetails($borrowernumber,'987654321');
 277     is( $person->{amountoutstanding}, 15,
 278         'Expected 15 outstanding for both borrowernumber and cardnumber.');
 279
 280     # do not count holds charges
 281     C4::Context->set_preference( 'HoldsInNoissuesCharge', '1' );
 282     C4::Context->set_preference( 'ManInvInNoissuesCharge', '0' );
 283     my ($total, $total_minus_charges,
 284         $other_charges) = C4::Members::GetMemberAccountBalance(123);
 285     is( $total, 15 , "Total calculated correctly");
 286     is( $total_minus_charges, 15, "Holds charges are not count if HoldsInNoissuesCharge=1");
 287     is( $other_charges, 0, "Holds charges are not considered if HoldsInNoissuesCharge=1");
 288
 289     C4::Context->set_preference( 'HoldsInNoissuesCharge', '0' );
 290     ($total, $total_minus_charges,
 291         $other_charges) = C4::Members::GetMemberAccountBalance(123);
 292     is( $total, 15 , "Total calculated correctly");
 293     is( $total_minus_charges, 10, "Holds charges are count if HoldsInNoissuesCharge=0");
 294     is( $other_charges, 5, "Holds charges are considered if HoldsInNoissuesCharge=1");
 295 };
 296
 297 subtest 'purgeSelfRegistration' => sub {
 298     plan tests => 2;
 299
 300     #purge unverified
 301     my $d=360;
 302     C4::Members::DeleteUnverifiedOpacRegistrations($d);
 303     foreach(1..3) {
 304         $dbh->do("INSERT INTO borrower_modifications (timestamp, borrowernumber, verification_token) VALUES ('2014-01-01 01:02:03',0,?)", undef, (scalar localtime)."_$_");
 305     }
 306     is( C4::Members::DeleteUnverifiedOpacRegistrations($d), 3, 'Test for DeleteUnverifiedOpacRegistrations' );
 307
 308     #purge members in temporary category
 309     my $c= 'XYZ';
 310     $dbh->do("INSERT IGNORE INTO categories (categorycode) VALUES ('$c')");
 311     C4::Context->set_preference('PatronSelfRegistrationDefaultCategory', $c );
 312     C4::Context->set_preference('PatronSelfRegistrationExpireTemporaryAccountsDelay', 360);
 313     C4::Members::DeleteExpiredOpacRegistrations();
 314     $dbh->do("INSERT INTO borrowers (surname, address, city, branchcode, categorycode, dateenrolled) VALUES ('Testaabbcc', 'Street 1', 'CITY', ?, '$c', '2014-01-01 01:02:03')", undef, $library1->{branchcode});
 315     is( C4::Members::DeleteExpiredOpacRegistrations(), 1, 'Test for DeleteExpiredOpacRegistrations');
 316 };
 317
 318 sub _find_member {
 319     my ($resultset) = @_;
 320     my $found = $resultset && grep( { $_->{cardnumber} && $_->{cardnumber} eq $CARDNUMBER } @$resultset );
 321     return $found;
 322 }
 323
 324 # Regression tests for BZ15343
 325 my $password="";
 326 ( $borrowernumber, $password ) = AddMember_Opac(surname=>"Dick",firstname=>'Philip',branchcode => $library2->{branchcode});
 327 is( $password =~ /^[a-zA-Z]{10}$/ , 1, 'Test for autogenerated password if none submitted');
 328 ( $borrowernumber, $password ) = AddMember_Opac(surname=>"Deckard",firstname=>"Rick",password=>"Nexus-6",branchcode => $library2->{branchcode});
 329 is( $password eq "Nexus-6", 1, 'Test password used if submitted');
 330 $borrower = GetMember(borrowernumber => $borrowernumber);
 331 my $hashed_up =  Koha::AuthUtils::hash_password("Nexus-6", $borrower->{password});
 332 is( $borrower->{password} eq $hashed_up, 1, 'Check password hash equals hash of submitted password' );
 333
 334
 335
 336 ### ------------------------------------- ###
 337 ### Testing GetAge() / SetAge() functions ###
 338 ### ------------------------------------- ###
 339 #USES the package $member-variable to mock a koha.borrowers-object
 340 sub testAgeAccessors {
 341     my ($member) = @_;
 342     my $original_dateofbirth = $member->{dateofbirth};
 343
 344     ##Testing GetAge()
 345     my $age=GetAge("1992-08-14", "2011-01-19");
 346     is ($age, "18", "Age correct");
 347
 348     $age=GetAge("2011-01-19", "1992-01-19");
 349     is ($age, "-19", "Birthday In the Future");
 350
 351     ##Testing SetAge() for now()
 352     my $dt_now = DateTime->now();
 353     $age = DateTime::Duration->new(years => 12, months => 6, days => 1);
 354     C4::Members::SetAge( $member, $age );
 355     $age = C4::Members::GetAge( $member->{dateofbirth} );
 356     is ($age, '12', "SetAge 12 years");
 357
 358     $age = DateTime::Duration->new(years => 18, months => 12, days => 31);
 359     C4::Members::SetAge( $member, $age );
 360     $age = C4::Members::GetAge( $member->{dateofbirth} );
 361     is ($age, '19', "SetAge 18+1 years"); #This is a special case, where months=>12 and days=>31 constitute one full year, hence we get age 19 instead of 18.
 362
 363     $age = DateTime::Duration->new(years => 18, months => 12, days => 30);
 364     C4::Members::SetAge( $member, $age );
 365     $age = C4::Members::GetAge( $member->{dateofbirth} );
 366     is ($age, '19', "SetAge 18 years");
 367
 368     $age = DateTime::Duration->new(years => 0, months => 1, days => 1);
 369     C4::Members::SetAge( $member, $age );
 370     $age = C4::Members::GetAge( $member->{dateofbirth} );
 371     is ($age, '0', "SetAge 0 years");
 372
 373     $age = '0018-12-31';
 374     C4::Members::SetAge( $member, $age );
 375     $age = C4::Members::GetAge( $member->{dateofbirth} );
 376     is ($age, '19', "SetAge ISO_Date 18+1 years"); #This is a special case, where months=>12 and days=>31 constitute one full year, hence we get age 19 instead of 18.
 377
 378     $age = '0018-12-30';
 379     C4::Members::SetAge( $member, $age );
 380     $age = C4::Members::GetAge( $member->{dateofbirth} );
 381     is ($age, '19', "SetAge ISO_Date 18 years");
 382
 383     $age = '18-1-1';
 384     eval { C4::Members::SetAge( $member, $age ); };
 385     is ((length $@ > 1), '1', "SetAge ISO_Date $age years FAILS");
 386
 387     $age = '0018-01-01';
 388     eval { C4::Members::SetAge( $member, $age ); };
 389     is ((length $@ == 0), '1', "SetAge ISO_Date $age years succeeds");
 390
 391     ##Testing SetAge() for relative_date
 392     my $relative_date = DateTime->new(year => 3010, month => 3, day => 15);
 393
 394     $age = DateTime::Duration->new(years => 10, months => 3);
 395     C4::Members::SetAge( $member, $age, $relative_date );
 396     $age = C4::Members::GetAge( $member->{dateofbirth}, $relative_date->ymd() );
 397     is ($age, '10', "SetAge, 10 years and 3 months old person was born on ".$member->{dateofbirth}." if todays is ".$relative_date->ymd());
 398
 399     $age = DateTime::Duration->new(years => 112, months => 1, days => 1);
 400     C4::Members::SetAge( $member, $age, $relative_date );
 401     $age = C4::Members::GetAge( $member->{dateofbirth}, $relative_date->ymd() );
 402     is ($age, '112', "SetAge, 112 years, 1 months and 1 days old person was born on ".$member->{dateofbirth}." if today is ".$relative_date->ymd());
 403
 404     $age = '0112-01-01';
 405     C4::Members::SetAge( $member, $age, $relative_date );
 406     $age = C4::Members::GetAge( $member->{dateofbirth}, $relative_date->ymd() );
 407     is ($age, '112', "SetAge ISO_Date, 112 years, 1 months and 1 days old person was born on ".$member->{dateofbirth}." if today is ".$relative_date->ymd());
 408
 409     $member->{dateofbirth} = $original_dateofbirth; #It is polite to revert made changes in the unit tests.
 410 } #sub testAgeAccessors
 411
 412 1;