svc/holds

   1 #!/usr/bin/perl
   2
   3 # Copyright 2014 ByWater Solutions
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI;
  23 use JSON qw(to_json);
  24
  25 use C4::Auth qw(check_cookie_auth);
  26 use C4::Charset;
  27 use C4::Context;
  28
  29 use Koha::DateUtils qw( dt_from_string output_pref );
  30 use Koha::Holds;
  31 use Koha::ItemTypes;
  32 use Koha::Libraries;
  33
  34 my $input = CGI->new;
  35
  36 my ( $auth_status ) =
  37   check_cookie_auth( $input->cookie('CGISESSID'),
  38     { circulate => 'circulate_remaining_permissions' } );
  39
  40 if ( $auth_status ne "ok" ) {
  41     exit 0;
  42 }
  43
  44 my $branch = C4::Context->userenv->{'branch'};
  45
  46 my $schema = Koha::Database->new()->schema();
  47
  48 my @sort_columns =
  49   qw/reservedate title itemcallnumber barcode expirationdate priority/;
  50
  51 my $borrowernumber    = $input->param('borrowernumber');
  52 my $offset            = $input->param('iDisplayStart');
  53 my $results_per_page  = $input->param('iDisplayLength');
  54 my $sorting_direction = $input->param('sSortDir_0') || 'desc';
  55 my $iSortCol          = $input->param('iSortCol_0') // 0;
  56 my $sorting_column    = $sort_columns[$iSortCol] // 'reservedate';
  57
  58 binmode STDOUT, ":encoding(UTF-8)";
  59 print $input->header( -type => 'text/plain', -charset => 'UTF-8' );
  60
  61 my $holds_rs = Koha::Holds->search(
  62     { borrowernumber => $borrowernumber },
  63     {
  64         order_by => { "-$sorting_direction" => $sorting_column }
  65     }
  66 );
  67
  68 my @holds;
  69 while ( my $h = $holds_rs->next() ) {
  70     my $item = $h->item();
  71     my $item_group = $h->item_group();
  72
  73     my $biblionumber = $h->biblio()->biblionumber();
  74
  75     my $desk_id = $h->desk_id;
  76     my $desk_name = '';
  77     if ($desk_id) {
  78         $desk_name = $h->desk()->desk_name();
  79     }
  80
  81     my $itemtype_limit;
  82     if ( $h->itemtype ) {
  83         my $itemtype = Koha::ItemTypes->find( $h->itemtype );
  84         $itemtype_limit = $itemtype->translated_description;
  85     }
  86
  87     my $libraries = Koha::Libraries->search({}, { order_by => ['branchname'] })->unblessed;
  88     for my $library ( @$libraries ) {
  89         $library->{selected} = 1 if $library->{branchcode} eq $h->branchcode();
  90     }
  91
  92     my $biblio = $h->biblio();
  93     my @subtitles = split(/ \| /, $biblio->subtitle() // '');
  94     my $hold = {
  95         DT_RowId       => $h->reserve_id(),
  96         biblionumber   => $biblionumber,
  97         title          => $biblio->title(),
  98         subtitle       => \@subtitles,
  99         medium         => $biblio->medium() // '',
 100         part_number    => $biblio->part_number() // '',
 101         part_name      => $biblio->part_name() // '',
 102         author         => $biblio->author(),
 103         reserve_id     => $h->reserve_id(),
 104         branchcode     => $h->branch()->branchname(),
 105         branches       => $libraries,
 106         desk_name      => $desk_name,
 107         reservedate    => $h->reservedate(),
 108         expirationdate => $h->expirationdate(),
 109         suspend        => $h->suspend(),
 110         suspend_until  => $h->suspend_until(),
 111         found          => $h->found(),
 112         waiting        => $h->is_waiting(),
 113         waiting_at     => $h->branch()->branchname(),
 114         waiting_here   => $h->branch()->branchcode() eq $branch,
 115         priority       => $h->priority(),
 116         itemtype_limit => $itemtype_limit,
 117         reservedate_formatted => $h->reservedate() ? output_pref(
 118             { dt => dt_from_string( $h->reservedate() ), dateonly => 1 }
 119           )
 120         : q{},
 121         suspend_until_formatted => $h->suspend_until() ? output_pref(
 122             { dt => dt_from_string( $h->suspend_until() ), dateonly => 1 }
 123           )
 124         : q{},
 125         expirationdate_formatted => $h->expirationdate() ? output_pref(
 126             { dt => dt_from_string( $h->expirationdate() ), dateonly => 1 }
 127           )
 128         : q{},
 129     };
 130
 131     $hold->{transfered}     = 0;
 132     $hold->{not_transfered} = 0;
 133
 134     if ($item) {
 135         $hold->{itemnumber}     = $item->itemnumber();
 136         $hold->{barcode}        = $item->barcode();
 137         $hold->{itemtype}       = $item->effective_itemtype();
 138         $hold->{itemtype_description} = $item->itemtype->description;
 139         $hold->{enumchron}      = $item->enumchron();
 140         $hold->{itemcallnumber} = $item->itemcallnumber() || q{};
 141
 142         my $transfer = $item->get_transfer;
 143         if ( $transfer && $transfer->in_transit ) {
 144             $hold->{color}       = 'transferred';
 145             $hold->{transferred} = 1;
 146             $hold->{date_sent} = output_pref({ dt => dt_from_string($transfer->datesent) });
 147             $hold->{from_branch} = Koha::Libraries->find($transfer->frombranch)->branchname;
 148         }
 149         elsif ( $item->holding_branch() && $item->holding_branch()->branchcode() ne
 150             $h->branch()->branchcode() )
 151         {
 152             $hold->{not_transferred}    = 1;
 153             $hold->{not_transferred_by} = $h->item()->holding_branch()->branchname();
 154         }
 155     }
 156
 157     if ($item_group) {
 158         $hold->{item_group_id}          = $item_group->id;
 159         $hold->{item_group_description} = $item_group->description;
 160     }
 161
 162     push( @holds, $hold );
 163 }
 164
 165 my $data;
 166 $data->{'iTotalRecords'}        = scalar @holds;
 167 $data->{'iTotalDisplayRecords'} = scalar @holds;
 168 $data->{'sEcho'}                = $input->param('sEcho') || undef;
 169 $data->{'aaData'}               = \@holds;
 170
 171 print to_json($data);