koha-dev.rot13.org Git - koha_fer/blob - svc/checkouts.pl

   1 #!/usr/bin/perl
   2
   3 # This software is placed under the gnu General Public License, v2 (http://www.gnu.org/licenses/gpl.html)
   4
   5 # Copyright 2014 ByWater Solutions
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it under the
  10 # terms of the GNU General Public License as published by the Free Software
  11 # Foundation; either version 3 of the License, or (at your option) any later
  12 # version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  15 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  16 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License along
  19 # with Koha; if not, write to the Free Software Foundation, Inc.,
  20 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  21
  22 use strict;
  23 use warnings;
  24
  25 use CGI;
  26 use JSON qw(to_json);
  27
  28 use C4::Auth qw(check_cookie_auth);
  29 use C4::Biblio qw(GetMarcBiblio GetFrameworkCode GetRecordValue );
  30 use C4::Circulation qw(GetIssuingCharges CanBookBeRenewed GetRenewCount);
  31 use C4::Context;
  32
  33 use Koha::DateUtils;
  34
  35 my $input = new CGI;
  36
  37 my ( $auth_status, $sessionID ) =
  38   check_cookie_auth( $input->cookie('CGISESSID'),
  39     { circulate => 'circulate_remaining_permissions' } );
  40
  41 if ( $auth_status ne "ok" ) {
  42     exit 0;
  43 }
  44
  45 my @sort_columns = qw/date_due title itype issuedate branchcode itemcallnumber/;
  46
  47 my @borrowernumber   = $input->param('borrowernumber');
  48 my $offset           = $input->param('iDisplayStart');
  49 my $results_per_page = $input->param('iDisplayLength') || -1;
  50 my $sorting_column   = $sort_columns[ $input->param('iSortCol_0') ]
  51   || 'issuedate';
  52 my $sorting_direction = $input->param('sSortDir_0') eq 'asc' ? 'asc' : 'desc';
  53
  54 $results_per_page = undef if ( $results_per_page == -1 );
  55
  56 binmode STDOUT, ":encoding(UTF-8)";
  57 print $input->header( -type => 'text/plain', -charset => 'UTF-8' );
  58
  59 my @parameters;
  60 my $sql = '
  61     SELECT
  62         issuedate,
  63         date_due,
  64
  65         biblionumber,
  66         biblio.title,
  67         author,
  68
  69         itemnumber,
  70         barcode,
  71         itemnotes,
  72         itemcallnumber,
  73         replacementprice,
  74
  75         issues.branchcode,
  76         branchname,
  77
  78         itype,
  79         itemtype,
  80
  81         borrowernumber,
  82         surname,
  83         firstname,
  84         cardnumber
  85     FROM issues
  86         LEFT JOIN items USING ( itemnumber )
  87         LEFT JOIN biblio USING ( biblionumber )
  88         LEFT JOIN biblioitems USING ( biblionumber )
  89         LEFT JOIN borrowers USING ( borrowernumber )
  90         LEFT JOIN branches ON ( issues.branchcode = branches.branchcode )
  91     WHERE borrowernumber
  92 ';
  93
  94 if ( @borrowernumber == 1 ) {
  95     $sql .= '= ?';
  96 }
  97 else {
  98     $sql = ' IN (' . join( ',', ('?') x @borrowernumber ) . ') ';
  99 }
 100 push( @parameters, @borrowernumber );
 101
 102 $sql .= " ORDER BY $sorting_column $sorting_direction ";
 103
 104 my $dbh = C4::Context->dbh();
 105 my $sth = $dbh->prepare($sql);
 106 $sth->execute( @parameters );
 107
 108 my $item_level_itypes = C4::Context->preference('item-level_itypes');
 109
 110 my @checkouts;
 111 while ( my $c = $sth->fetchrow_hashref() ) {
 112     my ($charge) = GetIssuingCharges( $c->{itemnumber}, $c->{borrowernumber} );
 113
 114     my ( $can_renew, $can_renew_error ) =
 115       CanBookBeRenewed( $c->{borrowernumber}, $c->{itemnumber} );
 116
 117     my ( $renewals_count, $renewals_allowed, $renewals_remaining ) =
 118       GetRenewCount( $c->{borrowernumber}, $c->{itemnumber} );
 119     push(
 120         @checkouts,
 121         {
 122             DT_RowId   => $c->{itemnumber} . '-' . $c->{borrowernumber},
 123             title      => $c->{title},
 124             author     => $c->{author},
 125             barcode    => $c->{barcode},
 126             itemtype   => $item_level_itypes ? $c->{itype} : $c->{itemtype},
 127             itemnotes  => $c->{itemnotes},
 128             branchcode => $c->{branchcode},
 129             branchname => $c->{branchname},
 130             itemcallnumber => $c->{itemcallnumber}   || q{},
 131             charge         => $charge,
 132             price          => $c->{replacementprice} || q{},
 133             can_renew      => $can_renew,
 134             can_renew_error    => $can_renew_error,
 135             itemnumber         => $c->{itemnumber},
 136             borrowernumber     => $c->{borrowernumber},
 137             biblionumber       => $c->{biblionumber},
 138             issuedate          => $c->{issuedate},
 139             date_due           => $c->{date_due},
 140             renewals_count     => $renewals_count,
 141             renewals_allowed   => $renewals_allowed,
 142             renewals_remaining => $renewals_remaining,
 143             issuedate_formatted =>
 144               output_pref( dt_from_string( $c->{issuedate} ) ),
 145             date_due_formatted =>
 146               output_pref_due( dt_from_string( $c->{date_due} ) ),
 147             subtitle => GetRecordValue(
 148                 'subtitle',
 149                 GetMarcBiblio( $c->{biblionumber} ),
 150                 GetFrameworkCode( $c->{biblionumber} )
 151             ),
 152             borrower => {
 153                 surname    => $c->{surname},
 154                 firstname  => $c->{firstname},
 155                 cardnumber => $c->{cardnumber},
 156             }
 157         }
 158     );
 159 }
 160
 161 my $data;
 162 $data->{'iTotalRecords'}        = scalar @checkouts;                 #FIXME
 163 $data->{'iTotalDisplayRecords'} = scalar @checkouts;
 164 $data->{'sEcho'}                = $input->param('sEcho') || undef;
 165 $data->{'aaData'}               = \@checkouts;
 166
 167 print to_json($data);