koha-dev.rot13.org Git - srvgit/blob - reserve/request.pl

   1 #!/usr/bin/perl
   2
   3
   4 #written 2/1/00 by chris@katipo.oc.nz
   5 # Copyright 2000-2002 Katipo Communications
   6 # Parts Copyright 2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 request.pl
  24
  25 script to place reserves/requests
  26
  27 =cut
  28
  29 use Modern::Perl;
  30
  31 use CGI qw ( -utf8 );
  32 use List::MoreUtils qw( uniq );
  33 use Date::Calc qw( Date_to_Days );
  34 use C4::Output qw( output_html_with_http_headers );
  35 use C4::Auth qw( get_template_and_user );
  36 use C4::Reserves qw( RevertWaitingStatus AlterPriority ToggleLowestPriority ToggleSuspend CanBookBeReserved GetMaxPatronHoldsForRecord ItemsAnyAvailableAndNotRestricted CanItemBeReserved IsAvailableForItemLevelRequest );
  37 use C4::Items qw( get_hostitemnumbers_of );
  38 use C4::Koha qw( getitemtypeimagelocation );
  39 use C4::Serials qw( CountSubscriptionFromBiblionumber );
  40 use C4::Circulation qw( GetTransfers _GetCircControlBranch GetBranchItemRule );
  41 use Koha::DateUtils qw( dt_from_string output_pref );
  42 use C4::Utils::DataTables::Members;
  43 use C4::Search qw( enabled_staff_search_views );
  44
  45 use Koha::Biblios;
  46 use Koha::DateUtils qw( dt_from_string output_pref );
  47 use Koha::Checkouts;
  48 use Koha::Holds;
  49 use Koha::CirculationRules;
  50 use Koha::Items;
  51 use Koha::ItemTypes;
  52 use Koha::Libraries;
  53 use Koha::Patrons;
  54 use Koha::Clubs;
  55
  56 my $dbh = C4::Context->dbh;
  57 my $input = CGI->new;
  58 my ( $template, $borrowernumber, $cookie, $flags ) = get_template_and_user(
  59     {
  60         template_name   => "reserve/request.tt",
  61         query           => $input,
  62         type            => "intranet",
  63         flagsrequired   => { reserveforothers => 'place_holds' },
  64     }
  65 );
  66
  67 my $showallitems = $input->param('showallitems');
  68 my $pickup = $input->param('pickup');
  69
  70 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
  71
  72 # Select borrowers infos
  73 my $findborrower = $input->param('findborrower');
  74 $findborrower = '' unless defined $findborrower;
  75 $findborrower =~ s|,| |g;
  76 my $findclub = $input->param('findclub');
  77 $findclub = '' unless defined $findclub && !$findborrower;
  78 my $borrowernumber_hold = $input->param('borrowernumber') || '';
  79 my $club_hold = $input->param('club')||'';
  80 my $messageborrower;
  81 my $messageclub;
  82 my $warnings;
  83 my $messages;
  84 my $exceeded_maxreserves;
  85 my $exceeded_holds_per_record;
  86
  87 my $date = output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 });
  88 my $action = $input->param('action');
  89 $action ||= q{};
  90
  91 if ( $action eq 'move' ) {
  92   my $where           = $input->param('where');
  93   my $reserve_id      = $input->param('reserve_id');
  94   my $prev_priority   = $input->param('prev_priority');
  95   my $next_priority   = $input->param('next_priority');
  96   my $first_priority  = $input->param('first_priority');
  97   my $last_priority   = $input->param('last_priority');
  98   my $hold_itemnumber = $input->param('itemnumber');
  99   if ( $prev_priority == 0 && $next_priority == 1 ){
 100       C4::Reserves::RevertWaitingStatus({ itemnumber => $hold_itemnumber });
 101   } else {
 102       AlterPriority( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority );
 103   }
 104 } elsif ( $action eq 'cancel' ) {
 105   my $reserve_id = $input->param('reserve_id');
 106   my $cancellation_reason = $input->param("cancellation-reason");
 107   my $hold = Koha::Holds->find( $reserve_id );
 108   $hold->cancel({ cancellation_reason => $cancellation_reason }) if $hold;
 109 } elsif ( $action eq 'setLowestPriority' ) {
 110   my $reserve_id = $input->param('reserve_id');
 111   ToggleLowestPriority( $reserve_id );
 112 } elsif ( $action eq 'toggleSuspend' ) {
 113   my $reserve_id = $input->param('reserve_id');
 114   my $suspend_until  = $input->param('suspend_until');
 115   ToggleSuspend( $reserve_id, $suspend_until );
 116 }
 117
 118 if ($findborrower) {
 119     my $patron = Koha::Patrons->find( { cardnumber => $findborrower } );
 120     if ( $patron ) {
 121         $borrowernumber_hold = $patron->borrowernumber;
 122     } else {
 123         my $dt_params = { iDisplayLength => -1 };
 124         my $results = C4::Utils::DataTables::Members::search(
 125             {
 126                 searchmember => $findborrower,
 127                 dt_params => $dt_params,
 128             }
 129         );
 130         my $borrowers = $results->{patrons};
 131         if ( scalar @$borrowers == 1 ) {
 132             $borrowernumber_hold = $borrowers->[0]->{borrowernumber};
 133         } elsif ( @$borrowers ) {
 134             $template->param( borrowers => $borrowers );
 135         } else {
 136             $messageborrower = "'$findborrower'";
 137         }
 138     }
 139 }
 140
 141 if($findclub) {
 142     my $club = Koha::Clubs->find( { name => $findclub } );
 143     if( $club ) {
 144         $club_hold = $club->id;
 145     } else {
 146         my @clubs = Koha::Clubs->search( [
 147             { name => { like => '%'.$findclub.'%' } },
 148             { description => { like => '%'.$findclub.'%' } }
 149         ] );
 150         if( scalar @clubs == 1 ) {
 151             $club_hold = $clubs[0]->id;
 152         } elsif ( @clubs ) {
 153             $template->param( clubs => \@clubs );
 154         } else {
 155             $messageclub = "'$findclub'";
 156         }
 157     }
 158 }
 159
 160 my @biblionumbers = ();
 161 my $biblionumber = $input->param('biblionumber');
 162 my $biblionumbers = $input->param('biblionumbers');
 163 if ( $biblionumbers ) {
 164     @biblionumbers = split '/', $biblionumbers;
 165 } else {
 166     push @biblionumbers, $input->multi_param('biblionumber');
 167 }
 168
 169 my $multi_hold = @biblionumbers > 1;
 170 $template->param(
 171     multi_hold => $multi_hold,
 172 );
 173
 174 # If we have the borrowernumber because we've performed an action, then we
 175 # don't want to try to place another reserve.
 176 if ($borrowernumber_hold && !$action) {
 177     my $patron = Koha::Patrons->find( $borrowernumber_hold );
 178     my $diffbranch;
 179
 180     # we check the reserves of the user, and if they can reserve a document
 181     # FIXME At this time we have a simple count of reservs, but, later, we could improve the infos "title" ...
 182
 183     my $reserves_count = $patron->holds->count;
 184
 185     my $new_reserves_count = scalar( @biblionumbers );
 186
 187     my $maxreserves = C4::Context->preference('maxreserves');
 188     $template->param( maxreserves => $maxreserves );
 189
 190     if ( $maxreserves
 191         && ( $reserves_count + $new_reserves_count > $maxreserves ) )
 192     {
 193         my $new_reserves_allowed =
 194             $maxreserves - $reserves_count > 0
 195           ? $maxreserves - $reserves_count
 196           : 0;
 197         $warnings             = 1;
 198         $exceeded_maxreserves = 1;
 199         $template->param(
 200             new_reserves_allowed => $new_reserves_allowed,
 201             new_reserves_count   => $new_reserves_count,
 202             reserves_count       => $reserves_count,
 203             maxreserves          => $maxreserves,
 204         );
 205     }
 206
 207     # we check the date expiry of the borrower (only if there is an expiry date, otherwise, set to 1 (warn)
 208     my $expiry_date = $patron->dateexpiry;
 209     my $expiry = 0; # flag set if patron account has expired
 210     if ($expiry_date and
 211         Date_to_Days(split /-/,$date) > Date_to_Days(split /-/,$expiry_date)) {
 212         $expiry = 1;
 213     }
 214
 215     # check if the borrower make the reserv in a different branch
 216     if ( $patron->branchcode ne C4::Context->userenv->{'branch'} ) {
 217         $diffbranch = 1;
 218     }
 219
 220     my $amount_outstanding = $patron->account->balance;
 221     $template->param(
 222                 patron              => $patron,
 223                 expiry              => $expiry,
 224                 diffbranch          => $diffbranch,
 225                 messages            => $messages,
 226                 warnings            => $warnings,
 227                 amount_outstanding  => $amount_outstanding,
 228     );
 229 }
 230
 231 if ($club_hold && !$borrowernumber_hold && !$action) {
 232     my $club = Koha::Clubs->find($club_hold);
 233
 234     my $enrollments = $club->club_enrollments;
 235
 236     my $maxreserves = C4::Context->preference('maxreserves');
 237     my $new_reserves_count = scalar( @biblionumbers );
 238
 239     my @members;
 240
 241     while(my $enrollment = $enrollments->next) {
 242         next if $enrollment->is_canceled;
 243         my $member = { patron => $enrollment->patron->unblessed };
 244         my $reserves_count = $enrollment->patron->holds->count;
 245         if ( $maxreserves
 246             && ( $reserves_count + $new_reserves_count > $maxreserves ) )
 247         {
 248             $member->{new_reserves_allowed} = $maxreserves - $reserves_count > 0
 249                 ? $maxreserves - $reserves_count
 250                 : 0;
 251             $member->{exceeded_maxreserves} = 1;
 252         }
 253         my $expiry_date = $enrollment->patron->dateexpiry;
 254         $member->{expiry} = 0; # flag set if patron account has expired
 255         if ($expiry_date and
 256             Date_to_Days(split /-/,$date) > Date_to_Days(split /-/,$expiry_date)) {
 257             $member->{expiry} = 1;
 258         }
 259         $member->{amount_outstanding} = $enrollment->patron->account->balance;
 260         if ( $enrollment->patron->branchcode ne C4::Context->userenv->{'branch'} ) {
 261             $member->{diffbranch} = 1;
 262         }
 263
 264         push @members, $member;
 265     }
 266
 267     $template->param(
 268         club                => $club,
 269         members             => \@members,
 270         maxreserves         => $maxreserves,
 271         new_reserves_count  => $new_reserves_count
 272     );
 273 }
 274
 275 unless ( $club_hold or $borrowernumber_hold ) {
 276     $template->param( clubcount => Koha::Clubs->search->count );
 277 }
 278
 279 $template->param(
 280     messageborrower => $messageborrower,
 281     messageclub     => $messageclub
 282 );
 283
 284 # FIXME launch another time GetMember perhaps until (Joubu: Why?)
 285 my $patron = Koha::Patrons->find( $borrowernumber_hold );
 286
 287 if ( $patron && $multi_hold ) {
 288     my @multi_pickup_locations =
 289       Koha::Biblios->search( { biblionumber => \@biblionumbers } )
 290       ->pickup_locations( { patron => $patron } );
 291     $template->param( multi_pickup_locations => \@multi_pickup_locations );
 292 }
 293
 294 my $logged_in_patron = Koha::Patrons->find( $borrowernumber );
 295
 296 my $wants_check;
 297 if ($patron) {
 298     $wants_check = $patron->wants_check_for_previous_checkout;
 299 }
 300 my $itemdata_enumchron = 0;
 301 my $itemdata_ccode = 0;
 302 my @biblioloop = ();
 303 my $no_reserves_allowed = 0;
 304 foreach my $biblionumber (@biblionumbers) {
 305     next unless $biblionumber =~ m|^\d+$|;
 306
 307     my %biblioloopiter = ();
 308
 309     my $biblio = Koha::Biblios->find( $biblionumber );
 310
 311     my $force_hold_level;
 312     if ( $patron ) {
 313         { # CanBookBeReserved
 314             my $canReserve = CanBookBeReserved( $patron->borrowernumber, $biblionumber );
 315             if ( $canReserve->{status} eq 'OK' ) {
 316
 317                 #All is OK and we can continue
 318             }
 319             elsif ( $canReserve->{status} eq 'noReservesAllowed' || $canReserve->{status} eq 'notReservable' ) {
 320                 $no_reserves_allowed = 1;
 321             }
 322             elsif ( $canReserve->{status} eq 'tooManyReserves' ) {
 323                 $exceeded_maxreserves = 1;
 324                 $template->param( maxreserves => $canReserve->{limit} );
 325             }
 326             elsif ( $canReserve->{status} eq 'tooManyHoldsForThisRecord' ) {
 327                 $exceeded_holds_per_record = 1;
 328                 $biblioloopiter{ $canReserve->{status} } = 1;
 329             }
 330             elsif ( $canReserve->{status} eq 'ageRestricted' ) {
 331                 $template->param( $canReserve->{status} => 1 );
 332                 $biblioloopiter{ $canReserve->{status} } = 1;
 333             }
 334             elsif ( $canReserve->{status} eq 'alreadypossession' ) {
 335                 $template->param( $canReserve->{status} => 1);
 336                 $biblioloopiter{ $canReserve->{status} } = 1;
 337             }
 338             else {
 339                 $biblioloopiter{ $canReserve->{status} } = 1;
 340             }
 341         }
 342
 343         # For multiple holds per record, if a patron has previously placed a hold,
 344         # the patron can only place more holds of the same type. That is, if the
 345         # patron placed a record level hold, all the holds the patron places must
 346         # be record level. If the patron placed an item level hold, all holds
 347         # the patron places must be item level
 348         my $holds = Koha::Holds->search(
 349             {
 350                 borrowernumber => $patron->borrowernumber,
 351                 biblionumber   => $biblionumber,
 352                 found          => undef,
 353             }
 354         );
 355         $force_hold_level = $holds->forced_hold_level();
 356         $biblioloopiter{force_hold_level} = $force_hold_level;
 357         $template->param( force_hold_level => $force_hold_level );
 358
 359         # For a librarian to be able to place multiple record holds for a patron for a record,
 360         # we must find out what the maximum number of holds they can place for the patron is
 361         my $max_holds_for_record = GetMaxPatronHoldsForRecord( $patron->borrowernumber, $biblionumber );
 362         my $remaining_holds_for_record = $max_holds_for_record - $holds->count();
 363         $biblioloopiter{remaining_holds_for_record} = $max_holds_for_record;
 364         $template->param( max_holds_for_record => $max_holds_for_record );
 365         $template->param( remaining_holds_for_record => $remaining_holds_for_record );
 366     }
 367
 368
 369     my $count = Koha::Holds->search( { biblionumber => $biblionumber } )->count();
 370     my $totalcount = $count;
 371
 372     # FIXME think @optionloop, is maybe obsolete, or  must be switchable by a systeme preference fixed rank or not
 373     # make priorities options
 374
 375     my @optionloop;
 376     for ( 1 .. $count + 1 ) {
 377         push(
 378              @optionloop,
 379              {
 380               num      => $_,
 381               selected => ( $_ == $count + 1 ),
 382              }
 383             );
 384     }
 385     # adding a fixed value for priority options
 386     my $fixedRank = $count+1;
 387
 388     my %itemnumbers_of_biblioitem;
 389
 390     my @hostitems = get_hostitemnumbers_of($biblionumber);
 391     my @itemnumbers;
 392     if (@hostitems){
 393         $template->param('hostitemsflag' => 1);
 394         push(@itemnumbers, @hostitems);
 395     }
 396
 397     my $items = Koha::Items->search({ -or => { biblionumber => $biblionumber, itemnumber => { in => \@itemnumbers } } });
 398
 399     unless ( $items->count ) {
 400         # FIXME Then why do we continue?
 401         $template->param('noitems' => 1);
 402         $biblioloopiter{noitems} = 1;
 403     }
 404
 405     ## Here we go backwards again to create hash of biblioitemnumber to itemnumbers,
 406     ## when by definition all of the itemnumber have the same biblioitemnumber
 407     my ( $iteminfos_of );
 408     while ( my $item = $items->next ) {
 409         $item = $item->unblessed;
 410         my $biblioitemnumber = $item->{biblioitemnumber};
 411         my $itemnumber = $item->{itemnumber};
 412         push( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} }, $itemnumber );
 413         $iteminfos_of->{$itemnumber} = $item;
 414     }
 415
 416     ## Should be same as biblionumber
 417     my @biblioitemnumbers = keys %itemnumbers_of_biblioitem;
 418
 419     my $biblioiteminfos_of = {
 420         map {
 421             my $biblioitem = $_;
 422             ( $biblioitem->{biblioitemnumber} => $biblioitem )
 423           } @{ Koha::Biblioitems->search(
 424                 { biblioitemnumber => { -in => \@biblioitemnumbers } },
 425                 { select => ['biblioitemnumber', 'publicationyear', 'itemtype']}
 426             )->unblessed
 427           }
 428     };
 429
 430     my @bibitemloop;
 431
 432     my @available_itemtypes;
 433     foreach my $biblioitemnumber (@biblioitemnumbers) {
 434         my $biblioitem = $biblioiteminfos_of->{$biblioitemnumber};
 435         my $num_available = 0;
 436         my $num_override  = 0;
 437         my $hiddencount   = 0;
 438         my $num_alreadyheld = 0;
 439
 440         $biblioitem->{force_hold_level} = $force_hold_level;
 441
 442         if ( $biblioitem->{biblioitemnumber} ne $biblionumber ) {
 443             $biblioitem->{hostitemsflag} = 1;
 444         }
 445
 446         $biblioloopiter{description} = $biblioitem->{description};
 447         $biblioloopiter{itypename}   = $biblioitem->{description};
 448         if ( $biblioitem->{itemtype} ) {
 449
 450             $biblioitem->{description} =
 451               $itemtypes->{ $biblioitem->{itemtype} }{description};
 452
 453             $biblioloopiter{imageurl} =
 454               getitemtypeimagelocation( 'intranet',
 455                 $itemtypes->{ $biblioitem->{itemtype} }{imageurl} );
 456         }
 457
 458         # iterating through all items first to check if any of them available
 459         # to pass this value further inside down to IsAvailableForItemLevelRequest to
 460         # it's complicated logic to analyse.
 461         # (before this loop was inside that sub loop so it was O(n^2) )
 462         my $items_any_available;
 463
 464         $items_any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $biblioitemnumber, patron => $patron })
 465             if $patron;
 466
 467         foreach my $itemnumber ( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} } )    {
 468             my $item = $iteminfos_of->{$itemnumber};
 469             my $do_check;
 470             if ( $patron ) {
 471                 $do_check = $patron->do_check_for_previous_checkout($item) if $wants_check;
 472                 if ( $do_check && $wants_check ) {
 473                     $item->{checked_previously} = $do_check;
 474                     if ( $multi_hold ) {
 475                         $biblioloopiter{checked_previously} = $do_check;
 476                     } else {
 477                         $template->param( checked_previously => $do_check );
 478                     }
 479                 }
 480             }
 481             $item->{force_hold_level} = $force_hold_level;
 482
 483             unless (C4::Context->preference('item-level_itypes')) {
 484                 $item->{itype} = $biblioitem->{itemtype};
 485             }
 486
 487             $item->{itypename} = $itemtypes->{ $item->{itype} }{description};
 488             $item->{imageurl} = getitemtypeimagelocation( 'intranet', $itemtypes->{ $item->{itype} }{imageurl} );
 489             $item->{homebranch} = $item->{homebranch};
 490
 491             # if the holdingbranch is different than the homebranch, we show the
 492             # holdingbranch of the document too
 493             if ( $item->{homebranch} ne $item->{holdingbranch} ) {
 494                 $item->{holdingbranch} = $item->{holdingbranch};
 495             }
 496
 497             if($item->{biblionumber} ne $biblionumber){
 498                 $item->{hostitemsflag} = 1;
 499                 $item->{hosttitle} = Koha::Biblios->find( $item->{biblionumber} )->title;
 500             }
 501
 502             # if the item is currently on loan, we display its return date and
 503             # change the background color
 504             my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } );
 505             if ( $issue ) {
 506                 $item->{date_due} = $issue->date_due;
 507                 $item->{backgroundcolor} = 'onloan';
 508             }
 509
 510             # checking reserve
 511             my $item_object = Koha::Items->find( $itemnumber );
 512             my $holds = $item_object->current_holds;
 513             if ( my $first_hold = $holds->next ) {
 514                 my $p = Koha::Patrons->find( $first_hold->borrowernumber );
 515
 516                 $item->{backgroundcolor} = 'reserved';
 517                 $item->{reservedate}     = output_pref({ dt => dt_from_string( $first_hold->reservedate ), dateonly => 1 }); # FIXME Should be formatted in the template
 518                 $item->{ReservedFor}     = $p;
 519                 $item->{ExpectedAtLibrary}     = $first_hold->branchcode;
 520                 $item->{waitingdate} = $first_hold->waitingdate;
 521             }
 522
 523             # Management of the notforloan document
 524             if ( $item->{notforloan} ) {
 525                 $item->{backgroundcolor} = 'other';
 526             }
 527
 528             # Management of lost or long overdue items
 529             if ( $item->{itemlost} ) {
 530                 $item->{backgroundcolor} = 'other';
 531                 if ($logged_in_patron->category->hidelostitems && !$showallitems) {
 532                     $item->{hide} = 1;
 533                     $hiddencount++;
 534                 }
 535             }
 536
 537             # Check the transit status
 538             my ( $transfertwhen, $transfertfrom, $transfertto ) =
 539               GetTransfers($itemnumber);
 540
 541             if ( defined $transfertwhen && $transfertwhen ne '' ) {
 542                 $item->{transfertwhen} = output_pref({ dt => dt_from_string( $transfertwhen ), dateonly => 1 });
 543                 $item->{transfertfrom} = $transfertfrom;
 544                 $item->{transfertto} = $transfertto;
 545                 $item->{nocancel} = 1;
 546             }
 547
 548             # If there is no loan, return and transfer, we show a checkbox.
 549             $item->{notforloan} ||= 0;
 550
 551             # if independent branches is on we need to check if the person can reserve
 552             # for branches they arent logged in to
 553             if ( C4::Context->preference("IndependentBranches") ) {
 554                 if (! C4::Context->preference("canreservefromotherbranches")){
 555                     # can't reserve items so need to check if item homebranch and userenv branch match if not we can't reserve
 556                     my $userenv = C4::Context->userenv;
 557                     unless ( C4::Context->IsSuperLibrarian ) {
 558                         $item->{cantreserve} = 1 if ( $item->{homebranch} ne $userenv->{branch} );
 559                     }
 560                 }
 561             }
 562
 563             if ( $patron ) {
 564                 my $patron_unblessed = $patron->unblessed;
 565                 my $branch = C4::Circulation::_GetCircControlBranch($item, $patron_unblessed);
 566
 567                 my $branchitemrule = GetBranchItemRule( $branch, $item->{'itype'} );
 568
 569                 $item->{'holdallowed'} = $branchitemrule->{'holdallowed'};
 570
 571                 my $can_item_be_reserved = CanItemBeReserved( $patron->borrowernumber, $itemnumber )->{status};
 572                 $item->{not_holdable} = $can_item_be_reserved unless ( $can_item_be_reserved eq 'OK' );
 573
 574                 $item->{item_level_holds} = Koha::CirculationRules->get_opacitemholds_policy( { item => $item_object, patron => $patron } );
 575
 576                 if (
 577                        !$item->{cantreserve}
 578                     && !$exceeded_maxreserves
 579                     && $can_item_be_reserved eq 'OK'
 580                     # items_any_available defined outside of the current loop,
 581                     # so we avoiding loop inside IsAvailableForItemLevelRequest:
 582                     && IsAvailableForItemLevelRequest($item_object, $patron, undef, $items_any_available)
 583                   )
 584                 {
 585                     # Send the pickup locations count to the UI, the pickup locations will be pulled using the API
 586                     my $pickup_locations = $item_object->pickup_locations({ patron => $patron });
 587                     $item->{pickup_locations_count} = $pickup_locations->count;
 588                     if ( $item->{pickup_locations_count} > 0 ) {
 589                         $num_available++;
 590                         $item->{available} = 1;
 591                         # pass the holding branch for use as default
 592                         my $default_pickup_location = $pickup_locations->search({ branchcode => $item->{holdingbranch} })->next;
 593                         $item->{default_pickup_location} = $default_pickup_location;
 594                     }
 595                     else {
 596                         $item->{available} = 0;
 597                         $item->{not_holdable} = "no_valid_pickup_location";
 598                     }
 599
 600                     push( @available_itemtypes, $item->{itype} );
 601                 }
 602                 elsif ( C4::Context->preference('AllowHoldPolicyOverride') ) {
 603                     # If AllowHoldPolicyOverride is set, it should override EVERY restriction, not just branch item rules
 604                     # with the exception of itemAlreadyOnHold because, you know, the item is already on hold
 605                     if ( $can_item_be_reserved ne 'itemAlreadyOnHold' ) {
 606                         $item->{override} = 1;
 607                         $num_override++;
 608                     } else { $num_alreadyheld++ }
 609
 610                     push( @available_itemtypes, $item->{itype} );
 611                 }
 612
 613                 # If none of the conditions hold true, then neither override nor available is set and the item cannot be checked
 614
 615                 # Show serial enumeration when needed
 616                 if ($item->{enumchron}) {
 617                     $itemdata_enumchron = 1;
 618                 }
 619                 # Show collection when needed
 620                 if ($item->{ccode}) {
 621                     $itemdata_ccode = 1;
 622                 }
 623             }
 624
 625             push @{ $biblioitem->{itemloop} }, $item;
 626         }
 627
 628         # While we can't override an alreay held item, we should be able to override the others
 629         # Unless all items are already held
 630         if ( $num_override > 0 && ($num_override + $num_alreadyheld) == scalar( @{ $biblioitem->{itemloop} } ) ) {
 631         # That is, if all items require an override
 632             $template->param( override_required => 1 );
 633         } elsif ( $num_available == 0 ) {
 634             $template->param( none_available => 1 );
 635             $biblioloopiter{warn} = 1;
 636             $biblioloopiter{none_avail} = 1;
 637         }
 638         $template->param( hiddencount => $hiddencount);
 639
 640         push @bibitemloop, $biblioitem;
 641     }
 642
 643     @available_itemtypes = uniq( @available_itemtypes );
 644     $template->param( available_itemtypes => \@available_itemtypes );
 645
 646     # existingreserves building
 647     my @reserveloop;
 648     my @reserves = Koha::Holds->search( { biblionumber => $biblionumber }, { order_by => 'priority' } );
 649     foreach my $res (
 650         sort {
 651             my $a_found = $a->found() || '';
 652             my $b_found = $a->found() || '';
 653             $a_found cmp $b_found;
 654         } @reserves
 655       )
 656     {
 657         my $priority = $res->priority();
 658         my %reserve;
 659         my @optionloop;
 660         for ( my $i = 1 ; $i <= $totalcount ; $i++ ) {
 661             push(
 662                 @optionloop,
 663                 {
 664                     num      => $i,
 665                     selected => ( $i == $priority ),
 666                 }
 667             );
 668         }
 669
 670         if ( $res->is_found() ) {
 671             $reserve{'holdingbranch'} = $res->item()->holdingbranch();
 672             $reserve{'biblionumber'}  = $res->item()->biblionumber();
 673             $reserve{'barcodenumber'} = $res->item()->barcode();
 674             $reserve{'wbrcode'}       = $res->branchcode();
 675             $reserve{'itemnumber'}    = $res->itemnumber();
 676             $reserve{'wbrname'}       = $res->branch()->branchname();
 677             $reserve{'atdestination'} = $res->is_at_destination();
 678             $reserve{'desk_name'}     = ( $res->desk() ) ? $res->desk()->desk_name() : '' ;
 679             $reserve{'found'}     = $res->is_found();
 680             $reserve{'inprocessing'} = $res->is_in_processing();
 681             $reserve{'intransit'} = $res->is_in_transit();
 682         }
 683         elsif ( $res->priority() > 0 ) {
 684             if ( my $item = $res->item() )  {
 685                 $reserve{'itemnumber'}      = $item->id();
 686                 $reserve{'barcodenumber'}   = $item->barcode();
 687                 $reserve{'item_level_hold'} = 1;
 688             }
 689         }
 690
 691         $reserve{'expirationdate'} = $res->expirationdate;
 692         $reserve{'date'}           = $res->reservedate;
 693         $reserve{'borrowernumber'} = $res->borrowernumber();
 694         $reserve{'biblionumber'}   = $res->biblionumber();
 695         $reserve{'patron'}         = $res->borrower;
 696         $reserve{'notes'}          = $res->reservenotes();
 697         $reserve{'waiting_date'}   = $res->waitingdate();
 698         $reserve{'ccode'}          = $res->item() ? $res->item()->ccode() : undef;
 699         $reserve{'barcode'}        = $res->item() ? $res->item()->barcode() : undef;
 700         $reserve{'priority'}       = $res->priority();
 701         $reserve{'lowestPriority'} = $res->lowestPriority();
 702         $reserve{'optionloop'}     = \@optionloop;
 703         $reserve{'suspend'}        = $res->suspend();
 704         $reserve{'suspend_until'}  = $res->suspend_until();
 705         $reserve{'reserve_id'}     = $res->reserve_id();
 706         $reserve{itemtype}         = $res->itemtype();
 707         $reserve{branchcode}       = $res->branchcode();
 708         $reserve{non_priority}     = $res->non_priority();
 709         $reserve{object}           = $res;
 710
 711         push( @reserveloop, \%reserve );
 712     }
 713
 714     # get the time for the form name...
 715     my $time = time();
 716
 717     $template->param(
 718                      time        => $time,
 719                      fixedRank   => $fixedRank,
 720                     );
 721
 722     # display infos
 723     $template->param(
 724                      optionloop        => \@optionloop,
 725                      bibitemloop       => \@bibitemloop,
 726                      itemdata_enumchron => $itemdata_enumchron,
 727                      itemdata_ccode    => $itemdata_ccode,
 728                      date              => $date,
 729                      biblionumber      => $biblionumber,
 730                      findborrower      => $findborrower,
 731                      biblio            => $biblio,
 732                      holdsview         => 1,
 733                      C4::Search::enabled_staff_search_views,
 734                     );
 735
 736     $biblioloopiter{biblionumber} = $biblionumber;
 737     $biblioloopiter{title} = $biblio->title;
 738     $biblioloopiter{rank} = $fixedRank;
 739     $biblioloopiter{reserveloop} = \@reserveloop;
 740
 741     if (@reserveloop) {
 742         $template->param( reserveloop => \@reserveloop );
 743     }
 744
 745     if ( $patron ) {
 746         # Add the valid pickup locations
 747         my @pickup_locations = $biblio->pickup_locations({ patron => $patron });
 748         $biblioloopiter{pickup_locations} = \@pickup_locations;
 749         $biblioloopiter{pickup_locations_codes} = [ map { $_->branchcode } @pickup_locations ];
 750     }
 751
 752     push @biblioloop, \%biblioloopiter;
 753 }
 754
 755 $template->param( biblioloop => \@biblioloop );
 756 $template->param( biblionumbers => $biblionumbers );
 757 $template->param( no_reserves_allowed => $no_reserves_allowed );
 758 $template->param( exceeded_maxreserves => $exceeded_maxreserves );
 759 $template->param( exceeded_holds_per_record => $exceeded_holds_per_record );
 760 $template->param( subscriptionsnumber => CountSubscriptionFromBiblionumber($biblionumber));
 761
 762 # pass the userenv branch if no pickup location selected
 763 $template->param( pickup => $pickup || C4::Context->userenv->{branch} );
 764
 765 if ( C4::Context->preference( 'AllowHoldDateInFuture' ) ) {
 766     $template->param( reserve_in_future => 1 );
 767 }
 768
 769 $template->param(
 770     SuspendHoldsIntranet => C4::Context->preference('SuspendHoldsIntranet'),
 771     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 772 );
 773
 774 # printout the page
 775 output_html_with_http_headers $input, $cookie, $template->output;
 776
 777 sub sort_borrowerlist {
 778     my $borrowerslist = shift;
 779     my $ref           = [];
 780     push @{$ref}, sort {
 781         uc( $a->{surname} . $a->{firstname} ) cmp
 782           uc( $b->{surname} . $b->{firstname} )
 783     } @{$borrowerslist};
 784     return $ref;
 785 }