koha-dev.rot13.org Git - srvgit/blob - opac/sco/sco-main.pl

   1 #!/usr/bin/perl
   2 #
   3 # This code has been modified by Trendsetters (originally from opac-user.pl)
   4 # This code has been modified by rch
   5 # Parts Copyright 2010-2011, ByWater Solutions (those related to username/password auth)
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 # We're going to authenticate a self-check user.  we'll add a flag to borrowers 'selfcheck'
  23 #
  24 # We're in a controlled environment; we trust the user.
  25 # So the selfcheck station will accept a patronid and issue items to that borrower.
  26 # FIXME: NOT really a controlled environment...  We're on the internet!
  27 #
  28 # The checkout permission comes form the CGI cookie/session of a staff user.
  29 # The patron is not really logging in here in the same way as they do on the
  30 # rest of the OPAC.  So don't confuse loggedinuser with the patron user.
  31 #
  32 # FIXME: inputfocus not really used in TMPL
  33
  34 use Modern::Perl;
  35
  36 use CGI qw ( -utf8 );
  37
  38 use C4::Auth qw(get_template_and_user checkpw in_iprange);
  39 use C4::Koha;
  40 use C4::Circulation;
  41 use C4::Reserves;
  42 use C4::Output;
  43 use C4::Members;
  44 use C4::Biblio;
  45 use C4::Items;
  46 use Koha::DateUtils qw( dt_from_string );
  47 use Koha::Acquisition::Currencies;
  48 use Koha::Items;
  49 use Koha::Patrons;
  50 use Koha::Patron::Images;
  51 use Koha::Patron::Messages;
  52 use Koha::Token;
  53
  54 my $query = CGI->new;
  55
  56 unless (C4::Context->preference('WebBasedSelfCheck')) {
  57     # redirect to OPAC home if self-check is not enabled
  58     print $query->redirect("/cgi-bin/koha/opac-main.pl");
  59     exit;
  60 }
  61
  62 unless ( in_iprange(C4::Context->preference('SelfCheckAllowByIPRanges')) ) {
  63     # redirect to OPAC home if self-checkout not permitted from current IP
  64     print $query->redirect("/cgi-bin/koha/opac-main.pl");
  65     exit;
  66 }
  67
  68 if (C4::Context->preference('AutoSelfCheckAllowed'))
  69 {
  70     my $AutoSelfCheckID = C4::Context->preference('AutoSelfCheckID');
  71     my $AutoSelfCheckPass = C4::Context->preference('AutoSelfCheckPass');
  72     $query->param(-name=>'userid',-values=>[$AutoSelfCheckID]);
  73     $query->param(-name=>'password',-values=>[$AutoSelfCheckPass]);
  74     $query->param(-name=>'koha_login_context',-values=>['sco']);
  75 }
  76 $query->param(-name=>'sco_user_login',-values=>[1]);
  77
  78 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  79     {
  80         template_name   => "sco/sco-main.tt",
  81         flagsrequired   => { self_check => "self_checkout_module" },
  82         query           => $query,
  83         type            => "opac",
  84     }
  85 );
  86
  87 # Get the self checkout timeout preference, or use 120 seconds as a default
  88 my $selfchecktimeout = 120000;
  89 if (C4::Context->preference('SelfCheckTimeout')) {
  90     $selfchecktimeout = C4::Context->preference('SelfCheckTimeout') * 1000;
  91 }
  92 $template->param( SelfCheckTimeout => $selfchecktimeout );
  93
  94 # Checks policy laid out by SCOAllowCheckin, defaults to 'on' if preference is undefined
  95 my $allowselfcheckreturns = 1;
  96 if (defined C4::Context->preference('SCOAllowCheckin')) {
  97     $allowselfcheckreturns = C4::Context->preference('SCOAllowCheckin');
  98 }
  99
 100 my $issuerid = $loggedinuser;
 101 my ($op, $patronid, $patronlogin, $patronpw, $barcode, $confirmed, $newissues) = (
 102     $query->param("op")         || '',
 103     $query->param("patronid")   || '',
 104     $query->param("patronlogin")|| '',
 105     $query->param("patronpw")   || '',
 106     $query->param("barcode")    || '',
 107     $query->param("confirmed")  || '',
 108     $query->param("newissues")  || '',
 109 );
 110
 111 my @newissueslist = split /,/, $newissues;
 112 my $issuenoconfirm = 1; #don't need to confirm on issue.
 113 my $issuer   = Koha::Patrons->find( $issuerid )->unblessed;
 114 my $item     = Koha::Items->find({ barcode => $barcode });
 115 if (C4::Context->preference('SelfCheckoutByLogin') && !$patronid) {
 116     my $dbh = C4::Context->dbh;
 117     my $resval;
 118     ($resval, $patronid) = checkpw($dbh, $patronlogin, $patronpw);
 119 }
 120
 121 my ( $borrower, $patron );
 122 if ( $patronid ) {
 123     $patron = Koha::Patrons->find( { cardnumber => $patronid } );
 124     $borrower = $patron->unblessed if $patron;
 125 }
 126
 127 my $branch = $issuer->{branchcode};
 128 my $confirm_required = 0;
 129 my $return_only = 0;
 130 #warn "issuer cardnumber: " .   $issuer->{cardnumber};
 131 #warn "patron cardnumber: " . $borrower->{cardnumber};
 132 if ($op eq "logout") {
 133     $template->param( loggedout => 1 );
 134     $query->param( patronid => undef, patronlogin => undef, patronpw => undef );
 135 }
 136 elsif ( $op eq "returnbook" && $allowselfcheckreturns ) {
 137     my $success        = 0;
 138     my $human_required = 0;
 139     if ( C4::Context->preference("CircConfirmItemParts") ) {
 140         my $item = Koha::Items->find( { barcode => $barcode } );
 141         if ( defined($item)
 142             && $item->materials )
 143         {
 144             $human_required = 1;
 145         }
 146     }
 147
 148     ($success) = AddReturn( $barcode, $branch )
 149       unless $human_required;
 150     $template->param( returned => $success );
 151 }
 152 elsif ( $patron && ( $op eq 'checkout' ) ) {
 153     my $impossible  = {};
 154     my $needconfirm = {};
 155     ( $impossible, $needconfirm ) = CanBookBeIssued(
 156         $patron,
 157         $barcode,
 158         undef,
 159         0,
 160         C4::Context->preference("AllowItemsOnHoldCheckoutSCO")
 161     );
 162     my $issue_error;
 163     if ( $confirm_required = scalar keys %$needconfirm ) {
 164         for my $error ( qw( UNKNOWN_BARCODE max_loans_allowed ISSUED_TO_ANOTHER NO_MORE_RENEWALS NOT_FOR_LOAN DEBT WTHDRAWN RESTRICTED RESERVED ITEMNOTSAMEBRANCH EXPIRED DEBARRED CARD_LOST GNA INVALID_DATE UNKNOWN_BARCODE TOO_MANY DEBT_GUARANTEES DEBT_GUARANTORS USERBLOCKEDOVERDUE PATRON_CANT PREVISSUE NOT_FOR_LOAN_FORCING ITEM_LOST ADDITIONAL_MATERIALS ) ) {
 165             if ( $needconfirm->{$error} ) {
 166                 $issue_error = $error;
 167                 $confirmed = 0;
 168                 last;
 169             }
 170         }
 171     }
 172
 173     #warn "confirm_required: " . $confirm_required ;
 174     if (scalar keys %$impossible) {
 175
 176         my $issue_error = (keys %$impossible)[0]; # FIXME This is wrong, we assume only one error and keys are not ordered
 177         my $title = ( $item ) ? $item->biblio->title : '';
 178
 179         $template->param(
 180             impossible                => $issue_error,
 181             "circ_error_$issue_error" => 1,
 182             title                     => $title,
 183             hide_main                 => 1,
 184         );
 185         if ($issue_error eq 'DEBT') {
 186             $template->param(DEBT => $impossible->{DEBT});
 187         }
 188         #warn "issue_error: " . $issue_error ;
 189         if ( $issue_error eq "NO_MORE_RENEWALS" ) {
 190             $return_only = 1;
 191             $template->param(
 192                 returnitem => 1,
 193                 barcode    => $barcode,
 194             );
 195         }
 196     } elsif ( $needconfirm->{RENEW_ISSUE} ){
 197         $template->param(
 198                 renew               => 1,
 199                 barcode             => $barcode,
 200                 confirm             => 1,
 201                 confirm_renew_issue => 1,
 202                 hide_main           => 1,
 203         );
 204     } elsif ( $confirm_required && !$confirmed ) {
 205         #warn "failed confirmation";
 206         $template->param(
 207             impossible                => 1,
 208             "circ_error_$issue_error" => 1,
 209             hide_main                 => 1,
 210         );
 211         if ($issue_error eq 'DEBT') {
 212             $template->param(DEBT => $needconfirm->{DEBT});
 213         }
 214     } else {
 215         if ( $confirmed || $issuenoconfirm ) {    # we'll want to call getpatroninfo again to get updated issues.
 216             my ( $hold_existed, $item );
 217             if ( C4::Context->preference('HoldFeeMode') eq 'any_time_is_collected' ) {
 218                 # There is no easy way to know if the patron has been charged for this item.
 219                 # So we check if a hold existed for this item before the check in
 220                 $item = Koha::Items->find({ barcode => $barcode });
 221                 $hold_existed = Koha::Holds->search(
 222                     {
 223                         -and => {
 224                             borrowernumber => $borrower->{borrowernumber},
 225                             -or            => {
 226                                 biblionumber => $item->biblionumber,
 227                                 itemnumber   => $item->itemnumber
 228                             }
 229                         }
 230                     }
 231                 )->count;
 232             }
 233
 234             AddIssue( $borrower, $barcode );
 235             $template->param( issued => 1 );
 236             push @newissueslist, $barcode;
 237
 238             if ( $hold_existed ) {
 239                 my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 240                 $template->param(
 241                     # If the hold existed before the check in, let's confirm that the charge line exists
 242                     # Note that this should not be needed but since we do not have proper exception handling here we do it this way
 243                     patron_has_hold_fee => Koha::Account::Lines->search(
 244                         {
 245                             borrowernumber  => $borrower->{borrowernumber},
 246                             debit_type_code => 'RESERVE',
 247                             description     => $item->biblio->title,
 248                             date            => $dtf->format_date(dt_from_string)
 249                         }
 250                       )->count,
 251                 );
 252             }
 253         } else {
 254             $confirm_required = 1;
 255             #warn "issue confirmation";
 256             $template->param(
 257                 confirm    => "Issuing title: " . $item->biblio->title,
 258                 barcode    => $barcode,
 259                 hide_main  => 1,
 260                 inputfocus => 'confirm',
 261             );
 262         }
 263     }
 264 } # $op
 265
 266 if ( $patron && ( $op eq 'renew' ) ) {
 267     my ($status,$renewerror) = CanBookBeRenewed( $borrower->{borrowernumber}, $item->itemnumber );
 268     if ($status) {
 269         #warn "renewing";
 270         AddRenewal( $borrower->{borrowernumber}, $item->itemnumber, undef, undef, undef, undef, 1 );
 271         push @newissueslist, $barcode;
 272         $template->param( renewed => 1 );
 273     }
 274 }
 275
 276 if ($borrower) {
 277 #   warn "issuer's  branchcode: " .   $issuer->{branchcode};
 278 #   warn   "user's  branchcode: " . $borrower->{branchcode};
 279     my $borrowername = sprintf "%s %s", ($borrower->{firstname} || ''), ($borrower->{surname} || '');
 280     my $pending_checkouts = $patron->pending_checkouts;
 281     my @checkouts;
 282     while ( my $c = $pending_checkouts->next ) {
 283         my $checkout = $c->unblessed_all_relateds;
 284         my ($can_be_renewed, $renew_error) = CanBookBeRenewed(
 285             $borrower->{borrowernumber},
 286             $checkout->{itemnumber},
 287         );
 288         $checkout->{can_be_renewed} = $can_be_renewed; # In the future this will be $checkout->can_be_renewed
 289         $checkout->{renew_error} = $renew_error;
 290         $checkout->{overdue} = $c->is_overdue;
 291         push @checkouts, $checkout;
 292     }
 293
 294     my $show_priority;
 295     for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
 296         m/priority/ and $show_priority = 1;
 297     }
 298
 299     my $account = $patron->account;
 300     my $total = $account->balance;
 301     my $accountlines = $account->lines;
 302
 303     my $holds = $patron->holds;
 304     my $waiting_holds_count = 0;
 305
 306     while(my $hold = $holds->next) {
 307         $waiting_holds_count++ if $hold->is_waiting;
 308     }
 309
 310     $template->param(
 311         validuser => 1,
 312         borrowername => $borrowername,
 313         issues_count => scalar(@checkouts),
 314         ISSUES => \@checkouts,
 315         HOLDS => $holds,
 316         newissues => join(',',@newissueslist),
 317         patronid => $patronid,
 318         patronlogin => $patronlogin,
 319         patronpw => $patronpw,
 320         waiting_holds_count => $waiting_holds_count,
 321         noitemlinks => 1 ,
 322         borrowernumber => $borrower->{'borrowernumber'},
 323         SuspendHoldsOpac => C4::Context->preference('SuspendHoldsOpac'),
 324         AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 325         howpriority   => $show_priority,
 326         ACCOUNT_LINES => $accountlines,
 327         total => $total,
 328     );
 329
 330     my $patron_messages = Koha::Patron::Messages->search(
 331         {
 332             borrowernumber => $borrower->{'borrowernumber'},
 333             message_type => 'B',
 334         }
 335     );
 336     $template->param(
 337         patron_messages => $patron_messages,
 338         opacnote => $borrower->{opacnote},
 339     );
 340
 341     my $inputfocus = ($return_only      == 1) ? 'returnbook' :
 342                      ($confirm_required == 1) ? 'confirm'    : 'barcode' ;
 343     $template->param(
 344         inputfocus => $inputfocus,
 345         nofines => 1,
 346
 347     );
 348     if (C4::Context->preference('ShowPatronImageInWebBasedSelfCheck')) {
 349         my $patron_image = Koha::Patron::Images->find($borrower->{borrowernumber});
 350         $template->param(
 351             display_patron_image => 1,
 352             csrf_token           => Koha::Token->new->generate_csrf( { session_id => scalar $query->cookie('CGISESSID') . $borrower->{cardnumber}, id => $borrower->{userid}} ),
 353         ) if $patron_image;
 354     }
 355 } else {
 356     $template->param(
 357         patronid   => $patronid,
 358         nouser     => $patronid,
 359     );
 360 }
 361
 362 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };