koha-dev.rot13.org Git - srvgit/blob - opac/opac-sendshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 SARL Biblibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode;
  24 use Carp qw( carp );
  25 use Try::Tiny qw( catch try );
  26
  27 use C4::Auth qw( get_template_and_user );
  28 use C4::Biblio qw(
  29   GetFrameworkCode
  30   GetMarcISBN
  31   GetMarcSubjects
  32 );
  33 use C4::Output qw( output_html_with_http_headers );
  34 use Koha::Biblios;
  35 use Koha::Email;
  36 use Koha::Patrons;
  37 use Koha::Virtualshelves;
  38
  39 my $query = CGI->new;
  40
  41 # if virtualshelves is disabled, leave immediately
  42 if ( !C4::Context->preference('virtualshelves') ) {
  43     print $query->redirect("/cgi-bin/koha/errors/404.pl");
  44     exit;
  45 }
  46
  47 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  48     {
  49         template_name => "opac-sendshelfform.tt",
  50         query         => $query,
  51         type          => "opac",
  52     }
  53 );
  54
  55 my $shelfid = $query->param('shelfid');
  56 my $email   = $query->param('email');
  57
  58 my $shelf = Koha::Virtualshelves->find($shelfid);
  59 if ( $shelf and $shelf->can_be_viewed($borrowernumber) ) {
  60     if ($email) {
  61         my $comment = $query->param('comment');
  62
  63         my $patron     = Koha::Patrons->find($borrowernumber);
  64         my $user_email = $patron->first_valid_email_address;
  65         my $shelf      = Koha::Virtualshelves->find($shelfid);
  66         my $contents   = $shelf->get_contents;
  67         my $iso2709;
  68
  69         my @biblionumbers;
  70         while ( my $content = $contents->next ) {
  71             push @biblionumbers, $content->biblionumber;
  72             my $biblio = Koha::Biblios->find( $content->biblionumber );
  73             $iso2709 .= $biblio->metadata->record->as_usmarc();
  74         }
  75
  76         if ( !defined $iso2709 ) {
  77             carp "Error sending mail: empty list";
  78             $template->param( error => 1 );
  79         }
  80         elsif ( !defined $user_email or $user_email eq '' ) {
  81             carp "Error sending mail: sender's email address is invalid";
  82             $template->param( error => 1 );
  83         }
  84         else {
  85             my %loops = ( biblio => \@biblionumbers, );
  86
  87             my %substitute = (
  88                 comment  => $comment,
  89                 listname => $shelf->shelfname,
  90             );
  91
  92             my $letter = C4::Letters::GetPreparedLetter(
  93                 module      => 'catalogue',
  94                 letter_code => 'LIST',
  95                 lang        => $patron->lang,
  96                 tables      => {
  97                     borrowers => $borrowernumber,
  98                 },
  99                 message_transport_type => 'email',
 100                 loops                  => \%loops,
 101                 substitute             => \%substitute,
 102             );
 103
 104             my $attachment = {
 105                 filename => 'list.iso2709',
 106                 type     => 'application/octet-stream',
 107                 content  => Encode::encode( "UTF-8", $iso2709 ),
 108             };
 109
 110             my $message_id = C4::Letters::EnqueueLetter(
 111                 {
 112                     letter                 => $letter,
 113                     message_transport_type => 'email',
 114                     borrowernumber         => $patron->borrowernumber,
 115                     to_address             => $email,
 116                     reply_address          => $user_email,
 117                     attachments            => [$attachment],
 118                 }
 119             );
 120
 121             C4::Letters::SendQueuedMessages( { message_id => $message_id } );
 122
 123             $template->param( SENT => 1 );
 124         }
 125
 126         $template->param(
 127             shelfid => $shelfid,
 128             email   => $email,
 129         );
 130         output_html_with_http_headers $query, $cookie, $template->output,
 131           undef, { force_no_caching => 1 };
 132
 133     }
 134     else {
 135         $template->param(
 136             shelfid => $shelfid,
 137             url     => "/cgi-bin/koha/opac-sendshelf.pl",
 138         );
 139         output_html_with_http_headers $query, $cookie, $template->output,
 140           undef, { force_no_caching => 1 };
 141     }
 142 }
 143 else {
 144     $template->param(
 145         invalidlist => 1,
 146         url         => "/cgi-bin/koha/opac-sendshelf.pl",
 147     );
 148     output_html_with_http_headers $query, $cookie, $template->output, undef,
 149       { force_no_caching => 1 };
 150 }