koha-dev.rot13.org Git - srvgit/blob - opac/opac-sendbasket.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright Doxulting 2004
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode;
  24 use Carp qw( carp );
  25 use Try::Tiny qw( catch try );
  26
  27 use C4::Biblio qw(
  28     GetMarcSubjects
  29 );
  30 use C4::Items qw( GetItemsInfo );
  31 use C4::Auth qw( get_template_and_user );
  32 use C4::Output qw( output_html_with_http_headers );
  33 use C4::Templates;
  34 use Koha::Biblios;
  35 use Koha::Email;
  36 use Koha::Patrons;
  37 use Koha::Token;
  38
  39 my $query = CGI->new;
  40
  41 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  42     {
  43         template_name   => "opac-sendbasketform.tt",
  44         query           => $query,
  45         type            => "opac",
  46     }
  47 );
  48
  49 my $bib_list     = $query->param('bib_list') || '';
  50 my $email_add    = $query->param('email_add');
  51
  52 my $dbh          = C4::Context->dbh;
  53
  54 if ( $email_add ) {
  55     die "Wrong CSRF token" unless Koha::Token->new->check_csrf({
  56         session_id => scalar $query->cookie('CGISESSID'),
  57         token  => scalar $query->param('csrf_token'),
  58     });
  59     my $patron = Koha::Patrons->find( $borrowernumber );
  60     my $user_email = $patron->first_valid_email_address
  61     || C4::Context->preference('KohaAdminEmailAddress');
  62
  63     my $email_replyto = $patron->firstname . " " . $patron->surname . " <$user_email>";
  64     my $comment    = $query->param('comment');
  65
  66     # Since we are already logged in, no need to check credentials again
  67     # when loading a second template.
  68     my $template2 = C4::Templates::gettemplate(
  69         'opac-sendbasket.tt', 'opac', $query,
  70     );
  71
  72     my @bibs = split( /\//, $bib_list );
  73     my @results;
  74     my $iso2709;
  75     my $marcflavour = C4::Context->preference('marcflavour');
  76     foreach my $biblionumber (@bibs) {
  77         $template2->param( biblionumber => $biblionumber );
  78
  79         my $biblio           = Koha::Biblios->find( $biblionumber ) or next;
  80         my $dat              = $biblio->unblessed;
  81         my $record = $biblio->metadata->record(
  82             {
  83                 embed_items => 1,
  84                 opac        => 1,
  85                 patron      => $patron,
  86             }
  87         );
  88         my $marcauthorsarray = $biblio->get_marc_authors;
  89         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  90
  91         my @items = GetItemsInfo( $biblionumber );
  92
  93         my $hasauthors = 0;
  94         if($dat->{'author'} || @$marcauthorsarray) {
  95           $hasauthors = 1;
  96         }
  97
  98
  99         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
 100         $dat->{MARCAUTHORS}    = $marcauthorsarray;
 101         $dat->{HASAUTHORS}     = $hasauthors;
 102         $dat->{'biblionumber'} = $biblionumber;
 103         $dat->{ITEM_RESULTS}   = \@items;
 104
 105         $iso2709 .= $record->as_usmarc();
 106
 107         push( @results, $dat );
 108     }
 109
 110     my $resultsarray = \@results;
 111
 112     $template2->param(
 113         BIBLIO_RESULTS => $resultsarray,
 114         comment        => $comment,
 115         firstname      => $patron->firstname,
 116         surname        => $patron->surname,
 117     );
 118
 119     # Getting template result
 120     my $template_res = $template2->output();
 121     my $body;
 122
 123     # Analysing information and getting mail properties
 124     my $subject;
 125     if ( $template_res =~ /\<SUBJECT\>(?<subject>.*)\<END_SUBJECT\>/s ) {
 126         $subject = $+{subject};
 127         $subject =~ s|\n?(.*)\n?|$1|;
 128     }
 129     else {
 130         $subject = "no subject";
 131     }
 132
 133     my $email_header = "";
 134     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 135         $email_header = $1;
 136         $email_header =~ s|\n?(.*)\n?|$1|;
 137     }
 138
 139     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 140         $body = $1;
 141         $body =~ s|\n?(.*)\n?|$1|;
 142     }
 143
 144     my $THE_body = <<END_OF_BODY;
 145 $email_header
 146 $body
 147 END_OF_BODY
 148
 149     if ( !defined $iso2709 ) {
 150         carp "Error sending mail: empty basket";
 151         $template->param( error => 1 );
 152     }
 153     else {
 154         try {
 155             # if you want to use the KohaAdmin address as from, that is the default no need to set it
 156             my $email = Koha::Email->create({
 157                 to       => $email_add,
 158                 reply_to => $email_replyto,
 159                 subject  => $subject,
 160             });
 161             $email->header( 'X-Abuse-Report' => C4::Context->preference('KohaAdminEmailAddress') );
 162             $email->text_body( $THE_body );
 163             $email->attach(
 164                 Encode::encode( "UTF-8", $iso2709 ),
 165                 content_type => 'application/octet-stream',
 166                 name         => 'basket.iso2709',
 167                 disposition  => 'attachment',
 168             );
 169             my $library = $patron->library;
 170             $email->transport( $library->smtp_server->transport );
 171             $email->send_or_die;
 172             $template->param( SENT => "1" );
 173         }
 174         catch {
 175             carp "Error sending mail: $_";
 176             $template->param( error => 1 );
 177         };
 178     }
 179
 180     $template->param( email_add => $email_add );
 181     output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };
 182 }
 183 else {
 184     my $new_session_id = $query->cookie('CGISESSID');
 185     $template->param(
 186         bib_list       => $bib_list,
 187         url            => "/cgi-bin/koha/opac-sendbasket.pl",
 188         suggestion     => C4::Context->preference("suggestion"),
 189         virtualshelves => C4::Context->preference("virtualshelves"),
 190         csrf_token => Koha::Token->new->generate_csrf(
 191             { session_id => $new_session_id, } ),
 192     );
 193     output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };
 194 }