koha-dev.rot13.org Git - srvgit/blob - opac/opac-main.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Parts Copyright (C) 2013  Mark Tompsett
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20
  21 use Modern::Perl;
  22 use CGI qw ( -utf8 );
  23 use C4::Auth;    # get_template_and_user
  24 use C4::Output;
  25 use C4::Languages qw(getTranslatedLanguages accept_language);
  26 use Koha::Quotes;
  27 use C4::Members;
  28 use C4::Overdues;
  29 use Koha::Checkouts;
  30 use Koha::Holds;
  31 use Koha::News;
  32 use Koha::Patron::Messages;
  33
  34 my $input = CGI->new;
  35 my $dbh   = C4::Context->dbh;
  36
  37 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  38     {
  39         template_name   => "opac-main.tt",
  40         type            => "opac",
  41         query           => $input,
  42         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  43     }
  44 );
  45
  46 my $casAuthentication = C4::Context->preference('casAuthentication');
  47 $template->param(
  48     casAuthentication   => $casAuthentication,
  49 );
  50
  51 my $homebranch;
  52 if (C4::Context->userenv) {
  53     $homebranch = C4::Context->userenv->{'branch'};
  54 }
  55 if (defined $input->param('branch') and length $input->param('branch')) {
  56     $homebranch = $input->param('branch');
  57 }
  58 elsif (C4::Context->userenv and defined $input->param('branch') and length $input->param('branch') == 0 ){
  59    $homebranch = "";
  60 }
  61
  62 my $news_id = $input->param('news_id');
  63 my $koha_news;
  64
  65 if (defined $news_id){
  66     $koha_news = Koha::News->search({ idnew => $news_id, lang => { '!=', 'koha' } }); # get news that is not staff-only news
  67     if ( $koha_news->count > 0){
  68         $template->param( news_item => $koha_news->next );
  69     } else {
  70         $template->param( single_news_error => 1 );
  71     }
  72 } else {
  73     $koha_news = Koha::News->search_for_display({
  74             location => 'opac',
  75             lang => $template->lang,
  76             library_id => $homebranch,
  77         });
  78 }
  79
  80 # For dashboard
  81 my $patron = Koha::Patrons->find( $borrowernumber );
  82
  83 if ( $patron ) {
  84     my $checkouts = Koha::Checkouts->search({ borrowernumber => $borrowernumber })->count;
  85     my ( $overdues_count, $overdues ) = checkoverdues($borrowernumber);
  86     my $holds_pending = Koha::Holds->search({ borrowernumber => $borrowernumber, found => undef })->count;
  87     my $holds_waiting = Koha::Holds->search({ borrowernumber => $borrowernumber })->waiting->count;
  88     my $patron_messages = Koha::Patron::Messages->search(
  89             {
  90                 borrowernumber => $borrowernumber,
  91                 message_type => 'B',
  92             });
  93     my $patron_note = $patron->opacnote;
  94     my $total = $patron->account->balance;
  95     if  ( $checkouts > 0 || $overdues_count > 0 || $holds_pending > 0 || $holds_waiting > 0 || $total > 0 || $patron_note || $patron_messages->count ) {
  96         $template->param(
  97             dashboard_info => 1,
  98             checkouts           => $checkouts,
  99             overdues            => $overdues_count,
 100             holds_pending       => $holds_pending,
 101             holds_waiting       => $holds_waiting,
 102             total_owing         => $total,
 103             patron_messages     => $patron_messages,
 104             opacnote            => $patron_note,
 105         );
 106     }
 107 }
 108
 109 $template->param(
 110     koha_news           => $koha_news,
 111     branchcode          => $homebranch,
 112     daily_quote         => Koha::Quotes->get_daily_quote(),
 113 );
 114
 115 output_html_with_http_headers $input, $cookie, $template->output;