koha-dev.rot13.org Git - srvgit/blob - opac/opac-ISBDdetail.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # parts copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 =head1 NAME
  23
  24 opac-ISBDdetail.pl - script to show a biblio in ISBD format
  25
  26 =head1 DESCRIPTION
  27
  28 This script needs a biblionumber as parameter
  29
  30 It shows the biblio
  31
  32 The template is in <templates_dir>/catalogue/ISBDdetail.tt.
  33 this template must be divided into 11 "tabs".
  34
  35 The first 10 tabs present the biblio, the 11th one presents
  36 the items attached to the biblio
  37
  38 =head1 FUNCTIONS
  39
  40 =cut
  41
  42 use Modern::Perl;
  43
  44 use C4::Auth;
  45 use C4::Context;
  46 use C4::Output;
  47 use CGI qw ( -utf8 );
  48 use C4::Biblio;
  49 use C4::Items;
  50 use C4::Reserves;
  51 use C4::Acquisition;
  52 use C4::Serials;    # uses getsubscriptionfrom biblionumber
  53 use C4::Koha;
  54 use Koha::CirculationRules;
  55 use Koha::ItemTypes;
  56 use Koha::Patrons;
  57 use Koha::RecordProcessor;
  58 use Koha::Biblios;
  59
  60 my $query = CGI->new();
  61 my $biblionumber = $query->param('biblionumber');
  62 my $biblio;
  63 $biblio = Koha::Biblios->find( $biblionumber, { prefetch => [ 'metadata', 'items' ] } ) if $biblionumber;
  64 if( !$biblio ) {
  65     print $query->redirect('/cgi-bin/koha/errors/404.pl');
  66     exit;
  67 }
  68
  69 #open template
  70 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  71     {
  72         template_name   => "opac-ISBDdetail.tt",
  73         query           => $query,
  74         type            => "opac",
  75         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  76     }
  77 );
  78
  79 my $patron = Koha::Patrons->find($loggedinuser);
  80
  81 my $opachiddenitems_rules = C4::Context->yaml_preference('OpacHiddenItems');
  82
  83 unless ( $patron and $patron->category->override_hidden_items ) {
  84     # only skip this check if there's a logged in user
  85     # and its category overrides OpacHiddenItems
  86     if ( $biblio->hidden_in_opac({ rules => $opachiddenitems_rules }) ) {
  87         print $query->redirect('/cgi-bin/koha/errors/404.pl'); # escape early
  88         exit;
  89     }
  90 }
  91
  92 my $record      = $biblio->metadata->record;
  93 my $marcflavour = C4::Context->preference("marcflavour");
  94
  95 my $record_processor = Koha::RecordProcessor->new({
  96     filters => 'ViewPolicy',
  97     options => {
  98         interface => 'opac',
  99         frameworkcode => $biblio->frameworkcode
 100     }
 101 });
 102 $record_processor->process($record);
 103
 104 # get biblionumbers stored in the cart
 105 if(my $cart_list = $query->cookie("bib_list")){
 106     my @cart_list = split(/\//, $cart_list);
 107     if ( grep {$_ eq $biblionumber} @cart_list) {
 108         $template->param( incart => 1 );
 109     }
 110 }
 111
 112 # some useful variables for enhanced content;
 113 # in each case, we're grabbing the first value we find in
 114 # the record and normalizing it
 115 my $upc  = GetNormalizedUPC( $record, $marcflavour );
 116 my $ean  = GetNormalizedEAN( $record, $marcflavour );
 117 my $oclc = GetNormalizedOCLCNumber( $record, $marcflavour );
 118 my $isbn = GetNormalizedISBN( undef, $record, $marcflavour );
 119 my $content_identifier_exists;
 120 if ( $isbn or $ean or $oclc or $upc ) {
 121     $content_identifier_exists = 1;
 122 }
 123 $template->param(
 124     normalized_upc            => $upc,
 125     normalized_ean            => $ean,
 126     normalized_oclc           => $oclc,
 127     normalized_isbn           => $isbn,
 128     content_identifier_exists => $content_identifier_exists,
 129 );
 130
 131 #coping with subscriptions
 132 my $subscriptionsnumber = CountSubscriptionFromBiblionumber($biblionumber);
 133 my $dat                 = TransformMarcToKoha( $record );
 134
 135 my @subscriptions       = SearchSubscriptions({ biblionumber => $biblionumber, orderby => 'title' });
 136 my @subs;
 137 foreach my $subscription (@subscriptions) {
 138     my %cell;
 139         my $serials_to_display;
 140     $cell{subscriptionid}    = $subscription->{subscriptionid};
 141     $cell{subscriptionnotes} = $subscription->{notes};
 142     $cell{branchcode}        = $subscription->{branchcode};
 143
 144     #get the three latest serials.
 145         $serials_to_display = $subscription->{opacdisplaycount};
 146         $serials_to_display = C4::Context->preference('OPACSerialIssueDisplayCount') unless $serials_to_display;
 147         $cell{opacdisplaycount} = $serials_to_display;
 148     $cell{latestserials} =
 149       GetLatestSerials( $subscription->{subscriptionid}, $serials_to_display );
 150     push @subs, \%cell;
 151 }
 152
 153 $template->param(
 154     subscriptions       => \@subs,
 155     subscriptionsnumber => $subscriptionsnumber,
 156 );
 157
 158 my $norequests = 1;
 159 my $allow_onshelf_holds;
 160 my $res = GetISBDView({
 161     'record'    => $record,
 162     'template'  => 'opac',
 163     'framework' => $biblio->frameworkcode
 164 });
 165
 166 my $items = $biblio->items;
 167 while ( my $item = $items->next ) {
 168     $norequests = 0
 169       if $norequests
 170         && !$item->withdrawn
 171         && !$item->itemlost
 172         && ($item->notforloan < 0 || not $item->notforloan )
 173         && !Koha::ItemTypes->find($item->effective_itemtype)->notforloan
 174         && $item->itemnumber;
 175
 176     $allow_onshelf_holds = Koha::CirculationRules->get_onshelfholds_policy( { item => $item, patron => $patron } )
 177       unless $allow_onshelf_holds;
 178 }
 179
 180 if( $allow_onshelf_holds || CountItemsIssued($biblionumber) || $biblio->has_items_waiting_or_intransit ) {
 181     $template->param( ReservableItems => 1 );
 182 }
 183
 184 $template->param(
 185     RequestOnOpac       => C4::Context->preference("RequestOnOpac"),
 186     norequests   => $norequests,
 187     ISBD         => $res,
 188     biblio       => $biblio,
 189 );
 190
 191 #Search for title in links
 192 my $marccontrolnumber   = GetMarcControlnumber ($record, $marcflavour);
 193 my $marcissns = GetMarcISSN ( $record, $marcflavour );
 194 my $issn = $marcissns->[0] || '';
 195
 196 if (my $search_for_title = C4::Context->preference('OPACSearchForTitleIn')){
 197     $dat->{title} =~ s/\/+$//; # remove trailing slash
 198     $dat->{title} =~ s/\s+$//; # remove trailing space
 199     $search_for_title = parametrized_url(
 200         $search_for_title,
 201         {
 202             TITLE         => $dat->{title},
 203             AUTHOR        => $dat->{author},
 204             ISBN          => $isbn,
 205             ISSN          => $issn,
 206             CONTROLNUMBER => $marccontrolnumber,
 207             BIBLIONUMBER  => $biblionumber,
 208         }
 209     );
 210     $template->param('OPACSearchForTitleIn' => $search_for_title);
 211 }
 212
 213 if( C4::Context->preference('ArticleRequests') ) {
 214     my $itemtype = Koha::ItemTypes->find($biblio->itemtype);
 215     my $artreqpossible = $patron
 216         ? $biblio->can_article_request( $patron )
 217         : $itemtype
 218         ? $itemtype->may_article_request
 219         : q{};
 220     $template->param( artreqpossible => $artreqpossible );
 221 }
 222
 223 output_html_with_http_headers $query, $cookie, $template->output;