koha-dev.rot13.org Git - srvgit/blob - misc/devel/update_dbix_class_files.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright (C) 2012 ByWater Solutions
   6 # Copyright (C) 2013 Equinox Software, Inc.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DBIx::Class::Schema::Loader qw/ make_schema_at /;
  23
  24 use Getopt::Long;
  25 use Pod::Usage;
  26
  27 my %db_defaults = (
  28     driver => 'mysql',
  29     host => 'localhost',
  30     port => '3306',
  31 );
  32
  33 my $path = "./";
  34 my $db_driver;
  35 my $db_host;
  36 my $db_port;
  37 my $db_name;
  38 my $db_user;
  39 my $db_passwd;
  40 my $koha_conf;
  41 my $force;
  42 my $help;
  43
  44 GetOptions(
  45     "path=s"      => \$path,
  46     "db_driver=s" => \$db_driver,
  47     "db_host=s"   => \$db_host,
  48     "db_port=s"   => \$db_port,
  49     "db_name=s"   => \$db_name,
  50     "db_user=s"   => \$db_user,
  51     "db_passwd=s" => \$db_passwd,
  52     "koha-conf:s" => \$koha_conf,
  53     "force"       => \$force,
  54     "h|help"      => \$help
  55 );
  56
  57 # If we were asked for usage instructions, do it
  58 pod2usage(1) if defined $help;
  59
  60 if (defined $koha_conf) {
  61     if ($koha_conf eq '' and not defined $ENV{KOHA_CONF}) {
  62         print STDERR "Error: KOHA_CONF is not defined\n";
  63         exit(1);
  64     }
  65
  66     $koha_conf ||= $ENV{KOHA_CONF};
  67     unless (-r $koha_conf) {
  68         print STDERR "Error: File $koha_conf does not exist or is not readable\n";
  69         exit(1);
  70     }
  71
  72     require C4::Context;
  73     my $context = C4::Context->new($koha_conf);
  74     unless ($context) {
  75         print STDERR "Error: Koha context creation failed. Please check that $koha_conf is correct\n";
  76         exit(1);
  77     }
  78
  79     $context->set_context;
  80     $db_defaults{driver} = $context->config('db_scheme');
  81     $db_defaults{host} = $context->config('hostname');
  82     $db_defaults{port} = $context->config('port');
  83     $db_defaults{name} = $context->config('database');
  84     $db_defaults{user} = $context->config('user');
  85     $db_defaults{passwd} = $context->config('pass');
  86 }
  87
  88 $db_driver //= $db_defaults{driver};
  89 $db_host //= $db_defaults{host};
  90 $db_port //= $db_defaults{port};
  91 $db_name //= $db_defaults{name};
  92 $db_user //= $db_defaults{user};
  93 $db_passwd //= $db_defaults{passwd};
  94
  95 if (! defined $db_name ) {
  96     print "Error: \'db_name\' parameter is mandatory.\n";
  97     pod2usage(1);
  98 } else {
  99
 100     $force //= 0;
 101
 102     make_schema_at(
 103         "Koha::Schema",
 104         { debug => 1, dump_directory => $path, preserve_case => 1, overwrite_modifications => $force },
 105         [
 106             "DBI:$db_driver:dbname=$db_name;host=$db_host;port=$db_port",
 107             $db_user,
 108             $db_passwd,
 109             { loader_class => 'Koha::Schema::Loader::mysql' }
 110         ]
 111     );
 112 }
 113
 114 1;
 115
 116 =head1 NAME
 117
 118 misc/devel/update_dbix_class_files.pl
 119
 120 =head1 SYNOPSIS
 121
 122  update_dbix_class_files.pl [--koha-conf <path>] --db_name=db-name \
 123                             --db_user=db-user --db_passwd=db-pass ...
 124
 125 The command in usually called from the root directory for the Koha source tree.
 126 If you are running from another directory, use the --path switch to specify
 127 a different path.
 128
 129 =head1 OPTIONS
 130
 131 =over 8
 132
 133 =item B<--koha-conf> <path>
 134
 135 Path to koha-conf.xml from which DB connection params will be retrieved.
 136
 137 <path> is optional and defaults to the value of environment variable KOHA_CONF,
 138 if set. It is an error to omit the <path> if KOHA_CONF is not set.
 139
 140 Any B<--db_*> options will override values retrieved from <path>.
 141
 142 =item B<--db_name>
 143
 144 DB name. (mandatory)
 145
 146 =item B<--db_user>
 147
 148 DB user name.
 149
 150 =item B<--db_passwd>
 151
 152 DB password.
 153
 154 =item B<--db_driver>
 155
 156 DB driver to be used. (defaults to 'mysql')
 157
 158 =item B<--db_host>
 159
 160 hostname for the DB server. (defaults to 'localhost')
 161
 162 =item B<--db_port>
 163
 164 port number for the DB server. (defaults to '3306')
 165
 166 =item B<--path>
 167
 168 path into which create the schema files. (defaults to './')
 169
 170 =item B<--force>
 171
 172 Force a schema overwrite.
 173
 174 WARNING: Use this at your own risk! it's helpful if you are maintaining a fork or in other such cases. You should always attempt to run the script without force first and only resort to using force if that fails. It is also very much worthwhile checking the diff after running with force to ensure you have not resulted in any unexpected changes.
 175
 176 =item B<-h|--help>
 177
 178 prints this help text
 179
 180 =back