koha-dev.rot13.org Git - srvgit/blob - misc/cronjobs/delete_records_via_leader.pl

   1 #!/usr/bin/perl
   2
   3 #-----------------------------------
   4 # Copyright 2013 ByWater Solutions
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 3 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #-----------------------------------
  21
  22 use Modern::Perl;
  23
  24 binmode( STDOUT, ":encoding(UTF-8)" );
  25
  26 BEGIN {
  27
  28     # find Koha's Perl modules
  29     # test carefully before changing this
  30     use FindBin;
  31     eval { require "$FindBin::Bin/../kohalib.pl" };
  32 }
  33
  34 use Getopt::Long;
  35
  36 use C4::Biblio;
  37 use C4::Items;
  38 use Koha::Database;
  39 use Koha::Biblio::Metadatas;
  40
  41 my $delete_items;
  42 my $confirm;
  43 my $test;
  44 my $verbose;
  45 my $help;
  46
  47 GetOptions(
  48     'i|di|delete-items' => \$delete_items,
  49     'c|confirm'         => \$confirm,
  50     't|test'            => \$test,
  51     'v|verbose'         => \$verbose,
  52     'h|help'            => \$help,
  53 );
  54
  55 if ( $help || !$confirm ) {
  56     say qq{
  57 delete_records_via_leader.pl - Attempt to delete any MARC records where the leader character 5 equals 'd'
  58 usage: delete_records_via_leader.pl --confirm --verbose [--test]
  59 This script has the following parameters :
  60     -h --help: Prints this message
  61     -c --confirm: Script will do nothing without this parameter
  62     -v --verbose: Be verbose
  63     -t --test: Test mode, does not delete records.
  64                Test mode cannot determine if a record/item will be deleted successfully,
  65                it will only tell you what records and items the script will attempt to delete.
  66     -i --delete-items: Try deleting items before deleting record.
  67                        Records with items cannot be deleted.
  68 };
  69     exit();
  70 }
  71
  72 my @metadatas =    # Should be replaced by a call to C4::Search on zebra index
  73                    # Record-status when bug 15537 will be pushed
  74   Koha::Biblio::Metadatas->search( { format => 'marcxml', marcflavour => C4::Context->preference('marcflavour'), metadata => { LIKE => '%<leader>_____d%' } } );
  75
  76 my $total_records_count   = @metadatas;
  77 my $deleted_records_count = 0;
  78 my $total_items_count     = 0;
  79 my $deleted_items_count   = 0;
  80
  81 foreach my $m (@metadatas) {
  82     my $biblionumber = $m->get_column('biblionumber');
  83
  84     say "RECORD: $biblionumber" if $verbose;
  85
  86     if ($delete_items) {
  87         my $deleted_count = 0;
  88         my $biblioitem = Koha::Biblioitem->find( $biblionumber );
  89         foreach my $item ( $biblioitem->items() ) {
  90             my $itemnumber = $item->itemnumber();
  91
  92             my $error = $test ? "Test mode enabled" : DelItemCheck( $biblionumber, $itemnumber );
  93             $error = undef if $error eq '1';
  94
  95             if ($error) {
  96                 say "ERROR DELETING ITEM $itemnumber: $error";
  97             }
  98             else {
  99                 say "DELETED ITEM $itemnumber" if $verbose;
 100                 $deleted_items_count++;
 101             }
 102
 103             $total_items_count++;
 104         }
 105
 106     }
 107
 108     my $error = $test ? q{Test mode enabled} : DelBiblio($biblionumber);
 109     if ( $error ) {
 110         say "ERROR DELETING BIBLIO $biblionumber: $error";
 111     } else {
 112         say "DELETED BIBLIO $biblionumber" if $verbose;
 113         $deleted_records_count++;
 114     }
 115
 116     say q{};
 117 }
 118
 119 if ( $verbose ) {
 120     say "DELETED $deleted_records_count OF $total_records_count RECORDS";
 121     say "DELETED $deleted_items_count OF $total_items_count ITEMS" if $delete_items;
 122 }