koha-dev.rot13.org Git - srvgit/blob - members/member-flags.pl

   1 #!/usr/bin/perl
   2
   3 # script to edit a member's flags
   4 # Written by Steve Tonnesen
   5 # July 26, 2002 (my birthday!)
   6
   7 use Modern::Perl;
   8
   9 use CGI qw ( -utf8 );
  10 use C4::Output;
  11 use C4::Auth qw(:DEFAULT :EditPermissions);
  12 use C4::Context;
  13 use C4::Members;
  14 #use C4::Acquisitions;
  15
  16 use Koha::Patron::Categories;
  17 use Koha::Patrons;
  18
  19 use C4::Output;
  20 use Koha::Token;
  21
  22 my $input = CGI->new;
  23
  24 my $flagsrequired = { permissions => 1 };
  25 my $member=$input->param('member');
  26 my $patron = Koha::Patrons->find( $member );
  27 unless ( $patron ) {
  28     print $input->redirect("/cgi-bin/koha/circ/circulation.pl?borrowernumber=$member");
  29     exit;
  30 }
  31
  32 my $category_type = $patron->category->category_type;
  33 my $bor = $patron->unblessed;
  34 if( $category_type eq 'S' )  { # FIXME Is this really needed?
  35     $flagsrequired->{'staffaccess'} = 1;
  36 }
  37 my ($template, $loggedinuser, $cookie) = get_template_and_user({
  38         template_name   => "members/member-flags.tt",
  39         query           => $input,
  40         type            => "intranet",
  41         flagsrequired   => $flagsrequired,
  42 });
  43
  44 my $logged_in_user = Koha::Patrons->find( $loggedinuser );
  45 output_and_exit_if_error( $input, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
  46
  47 my %member2;
  48 $member2{'borrowernumber'}=$member;
  49
  50 if ($input->param('newflags')) {
  51
  52     output_and_exit( $input, $cookie, $template,  'wrong_csrf_token' )
  53         unless Koha::Token->new->check_csrf({
  54             session_id => scalar $input->cookie('CGISESSID'),
  55             token  => scalar $input->param('csrf_token'),
  56         });
  57
  58
  59     my $dbh=C4::Context->dbh();
  60
  61     my @perms = $input->multi_param('flag');
  62     my %all_module_perms = ();
  63     my %sub_perms = ();
  64     foreach my $perm (@perms) {
  65         if ($perm !~ /:/) {
  66             $all_module_perms{$perm} = 1;
  67         } else {
  68             my ($module, $sub_perm) = split /:/, $perm, 2;
  69             push @{ $sub_perms{$module} }, $sub_perm;
  70         }
  71     }
  72
  73     # construct flags
  74     my $module_flags = 0;
  75     my $sth=$dbh->prepare("SELECT bit,flag FROM userflags ORDER BY bit");
  76     $sth->execute();
  77     while (my ($bit, $flag) = $sth->fetchrow_array) {
  78         if (exists $all_module_perms{$flag}) {
  79             $module_flags += 2**$bit;
  80         }
  81     }
  82
  83     $sth = $dbh->prepare("UPDATE borrowers SET flags=? WHERE borrowernumber=?");
  84     my $old_flags = $patron->flags // 0;
  85     if( ( $old_flags == 1 || $module_flags == 1 ) &&
  86       $old_flags != $module_flags ) {
  87         die "Non-superlibrarian is changing superlibrarian privileges" if !C4::Context->IsSuperLibrarian && C4::Context->preference('ProtectSuperlibrarianPrivileges'); # Interface should not allow this, so we can just die here
  88     }
  89     $sth->execute($module_flags, $member);
  90
  91     # deal with subpermissions
  92     $sth = $dbh->prepare("DELETE FROM user_permissions WHERE borrowernumber = ?");
  93     $sth->execute($member);
  94     $sth = $dbh->prepare("INSERT INTO user_permissions (borrowernumber, module_bit, code)
  95                         SELECT ?, bit, ?
  96                         FROM userflags
  97                         WHERE flag = ?");
  98     foreach my $module (keys %sub_perms) {
  99         next if exists $all_module_perms{$module};
 100         foreach my $sub_perm (@{ $sub_perms{$module} }) {
 101             $sth->execute($member, $sub_perm, $module);
 102         }
 103     }
 104
 105     print $input->redirect("/cgi-bin/koha/members/moremember.pl?borrowernumber=$member");
 106 } else {
 107
 108     my $accessflags;
 109     my $dbh = C4::Context->dbh();
 110     # FIXME This needs to be improved to avoid doing the same query
 111     my $sth = $dbh->prepare("select bit,flag from userflags");
 112     $sth->execute;
 113     while ( my ( $bit, $flag ) = $sth->fetchrow ) {
 114         if ( $bor->{flags} && $bor->{flags} & 2**$bit ) {
 115             $accessflags->{$flag} = 1;
 116         }
 117     }
 118
 119     my $all_perms  = get_all_subpermissions();
 120     my $user_perms = get_user_subpermissions($bor->{'userid'});
 121     $sth = $dbh->prepare("SELECT bit, flag FROM userflags ORDER BY bit");
 122     $sth->execute;
 123     my @loop;
 124
 125     while (my ($bit, $flag) = $sth->fetchrow) {
 126         my $checked='';
 127         if ($accessflags->{$flag}) {
 128             $checked= 1;
 129         }
 130
 131         my %row = ( bit => $bit,
 132             flag => $flag,
 133             checked => $checked,
 134         );
 135
 136         my @sub_perm_loop = ();
 137         my $expand_parent = 0;
 138         if ($checked) {
 139             if (exists $all_perms->{$flag}) {
 140                 $expand_parent = 1;
 141                 foreach my $sub_perm (sort keys %{ $all_perms->{$flag} }) {
 142                     push @sub_perm_loop, {
 143                         id => "${flag}_$sub_perm",
 144                         perm => "$flag:$sub_perm",
 145                         code => $sub_perm,
 146                         checked => 1
 147                     };
 148                 }
 149             }
 150         } else {
 151             if (exists $user_perms->{$flag}) {
 152                 $expand_parent = 1;
 153                 # put selected ones first
 154                 foreach my $sub_perm (sort keys %{ $user_perms->{$flag} }) {
 155                     push @sub_perm_loop, {
 156                         id => "${flag}_$sub_perm",
 157                         perm => "$flag:$sub_perm",
 158                         code => $sub_perm,
 159                         checked => 1
 160                     };
 161                 }
 162             }
 163             # then ones not selected
 164             if (exists $all_perms->{$flag}) {
 165                 foreach my $sub_perm (sort keys %{ $all_perms->{$flag} }) {
 166                     push @sub_perm_loop, {
 167                         id => "${flag}_$sub_perm",
 168                         perm => "$flag:$sub_perm",
 169                         code => $sub_perm,
 170                         checked => 0
 171                     } unless exists $user_perms->{$flag} and exists $user_perms->{$flag}->{$sub_perm};
 172                 }
 173             }
 174         }
 175         $row{expand} = $expand_parent;
 176         if ($#sub_perm_loop > -1) {
 177             $row{sub_perm_loop} = \@sub_perm_loop;
 178         }
 179         next if ( ( $row{flag} eq 'cash_management' ) && !C4::Context->preference('UseCashRegisters') );
 180         push @loop, \%row;
 181     }
 182
 183 $template->param(
 184     patron         => $patron,
 185     loop           => \@loop,
 186     csrf_token =>
 187         Koha::Token->new->generate_csrf( { session_id => scalar $input->cookie('CGISESSID'), } ),
 188     disable_superlibrarian_privs => C4::Context->preference('ProtectSuperlibrarianPrivileges') ? !C4::Context->IsSuperLibrarian : 0,
 189 );
 190
 191     output_html_with_http_headers $input, $cookie, $template->output;
 192
 193 }