koha-dev.rot13.org Git - srvgit/blob - koha-tmpl/opac-tmpl/bootstrap/en/xslt/MARC21slimUtils.xsl

   1 <?xml version='1.0'?>
   2 <!DOCTYPE stylesheet [<!ENTITY nbsp "&#160;" >]>
   3 <xsl:stylesheet version="1.0" xmlns:marc="http://www.loc.gov/MARC21/slim" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   4         <xsl:template name="datafield">
   5                 <xsl:param name="tag"/>
   6                 <xsl:param name="ind1"><xsl:text> </xsl:text></xsl:param>
   7                 <xsl:param name="ind2"><xsl:text> </xsl:text></xsl:param>
   8                 <xsl:param name="subfields"/>
   9                 <xsl:element name="datafield">
  10                         <xsl:attribute name="tag">
  11                                 <xsl:value-of select="$tag"/>
  12                         </xsl:attribute>
  13                         <xsl:attribute name="ind1">
  14                                 <xsl:value-of select="$ind1"/>
  15                         </xsl:attribute>
  16                         <xsl:attribute name="ind2">
  17                                 <xsl:value-of select="$ind2"/>
  18                         </xsl:attribute>
  19                         <xsl:copy-of select="$subfields"/>
  20                 </xsl:element>
  21         </xsl:template>
  22
  23         <xsl:template name="subfieldSelect">
  24                 <xsl:param name="codes"/>
  25                 <xsl:param name="delimeter"><xsl:text> </xsl:text></xsl:param>
  26                 <xsl:param name="subdivCodes"/>
  27                 <xsl:param name="subdivDelimiter"/>
  28         <xsl:param name="prefix"/>
  29         <xsl:param name="suffix"/>
  30                 <xsl:variable name="str">
  31                         <xsl:for-each select="marc:subfield">
  32                                 <xsl:if test="contains($codes, @code)">
  33                     <xsl:if test="contains($subdivCodes, @code)">
  34                         <xsl:value-of select="$subdivDelimiter"/>
  35                     </xsl:if>
  36                                         <xsl:value-of select="$prefix"/><xsl:value-of select="text()"/><xsl:value-of select="$suffix"/><xsl:value-of select="$delimeter"/>
  37                                 </xsl:if>
  38                         </xsl:for-each>
  39                 </xsl:variable>
  40                 <xsl:value-of select="substring($str,1,string-length($str)-string-length($delimeter))"/>
  41         </xsl:template>
  42
  43     <xsl:template name="subfieldSelectSpan">
  44         <xsl:param name="codes"/>
  45         <xsl:param name="delimeter"><xsl:text> </xsl:text></xsl:param>
  46         <xsl:param name="subdivCodes"/>
  47         <xsl:param name="subdivDelimiter"/>
  48         <xsl:param name="prefix"/>
  49         <xsl:param name="suffix"/>
  50             <xsl:for-each select="marc:subfield">
  51                 <xsl:if test="contains($codes, @code)">
  52                     <span>
  53                         <xsl:attribute name="class"><xsl:value-of select="@code"/></xsl:attribute>
  54                         <xsl:if test="contains($subdivCodes, @code)">
  55                             <xsl:value-of select="$subdivDelimiter"/>
  56                         </xsl:if>
  57                         <xsl:value-of select="$prefix"/><xsl:value-of select="text()"/><xsl:value-of select="$suffix"/><xsl:if test="position()!=last()"><xsl:value-of select="$delimeter"/></xsl:if>
  58                     </span>
  59                 </xsl:if>
  60             </xsl:for-each>
  61     </xsl:template>
  62
  63         <xsl:template name="buildSpaces">
  64                 <xsl:param name="spaces"/>
  65                 <xsl:param name="char"><xsl:text> </xsl:text></xsl:param>
  66                 <xsl:if test="$spaces>0">
  67                         <xsl:value-of select="$char"/>
  68                         <xsl:call-template name="buildSpaces">
  69                                 <xsl:with-param name="spaces" select="$spaces - 1"/>
  70                                 <xsl:with-param name="char" select="$char"/>
  71                         </xsl:call-template>
  72                 </xsl:if>
  73         </xsl:template>
  74
  75         <xsl:template name="chopPunctuation">
  76                 <xsl:param name="chopString"/>
  77                 <xsl:variable name="length" select="string-length($chopString)"/>
  78                 <xsl:choose>
  79                         <xsl:when test="$length=0"/>
  80                         <xsl:when test="contains('.:,;/ ', substring($chopString,$length,1))">
  81                                 <xsl:call-template name="chopPunctuation">
  82                                         <xsl:with-param name="chopString" select="substring($chopString,1,$length - 1)"/>
  83                                 </xsl:call-template>
  84                         </xsl:when>
  85                         <xsl:when test="not($chopString)"/>
  86                         <xsl:otherwise><xsl:value-of select="$chopString"/></xsl:otherwise>
  87                 </xsl:choose>
  88         </xsl:template>
  89
  90         <!-- Function extractControlNumber is used to extract the control number (record number) from MARC tags 773/80/85 [etc.] subfield $w.
  91              Parameter: control number string.
  92              Assumes LOC convention: (OrgCode)recordNumber.
  93              If OrgCode is not present, return full string.
  94              Additionally, handle various brackets/parentheses. Chop leading and trailing spaces.
  95         -->
  96         <xsl:template name="extractControlNumber">
  97             <xsl:param name="subfieldW"/>
  98             <xsl:variable name="tranW" select="translate($subfieldW,']})&gt;','))))')"/>
  99             <xsl:choose>
 100               <xsl:when test="contains($tranW,')')">
 101                 <xsl:value-of select="normalize-space(translate(substring-after($tranW,')'),'[]{}()&lt;&gt;',''))"/>
 102               </xsl:when>
 103               <xsl:otherwise>
 104                 <xsl:value-of select="normalize-space($subfieldW)"/>
 105               </xsl:otherwise>
 106             </xsl:choose>
 107         </xsl:template>
 108
 109     <!-- Function m880Select:  Display Alternate Graphic Representation (MARC 880) for selected latin "base"tags
 110         - should be called immediately before the corresonding latin tags are processed
 111         - tags in right-to-left languages are displayed floating right
 112         * Parameter:
 113            + basetags: display these tags if found in linkage section ( subfield 6) of tag 880
 114            + codes: display these subfields codes
 115         * Options:
 116             - class: wrap output in <span class="$class">...</span>
 117             - label: prefix each(!) tag with label $label
 118             - bibno: link to biblionumber $bibno
 119             - index: build a search link using index $index with subfield $a as key; if subfield $9 is present use index 'an' with key $9 instead.
 120          * Limitations:
 121             - displays every field on a separate line (to switch between rtl and ltr)
 122          * Pitfalls:
 123            (!) output might be empty
 124     -->
 125     <xsl:template name="m880Select">
 126          <xsl:param name="basetags"/> <!-- e.g.  100,700,110,710 -->
 127         <xsl:param name="codes"/> <!-- e.g. abc  -->
 128         <xsl:param name="class"/> <!-- e.g. results_summary -->
 129         <xsl:param name="label"/> <!-- e.g.  Edition -->
 130         <xsl:param name="bibno"/>
 131         <xsl:param name="index"/> <!-- e.g.  au -->
 132
 133         <xsl:for-each select="marc:datafield[@tag=880]">
 134             <xsl:variable name="code6" select="marc:subfield[@code=6]"/>
 135             <xsl:if test="contains(string($basetags), substring($code6,1,3))">
 136                 <span>
 137                     <xsl:choose>
 138                     <xsl:when test="boolean($class) and substring($code6,string-length($code6)-1,2) ='/r'">
 139                         <xsl:attribute name="class"><xsl:value-of select="$class"/> m880</xsl:attribute>
 140                         <xsl:attribute name="dir">rtl</xsl:attribute>
 141                     </xsl:when>
 142                      <xsl:when test="boolean($class)">
 143                         <xsl:attribute name="class"><xsl:value-of select="$class"/></xsl:attribute>
 144                         <xsl:attribute name="style">display:block; </xsl:attribute>
 145                     </xsl:when>
 146                      <xsl:when test="substring($code6,string-length($code6)-1,2) ='/r'">
 147                         <xsl:attribute name="class"><xsl:value-of select="$class"/> m880</xsl:attribute>
 148                     </xsl:when>
 149                     </xsl:choose>
 150                     <xsl:if test="boolean($label)">
 151                         <span class="label">
 152                             <xsl:value-of select="$label"/>
 153                         </span>
 154                     </xsl:if>
 155                     <xsl:variable name="str">
 156                         <xsl:for-each select="marc:subfield">
 157                             <xsl:if test="contains($codes, @code)">
 158                                 <xsl:value-of select="text()"/>
 159                                 <xsl:text> </xsl:text>
 160                             </xsl:if>
 161                         </xsl:for-each>
 162                     </xsl:variable>
 163                     <xsl:if test="string-length($str) &gt; 0">
 164                         <xsl:choose>
 165                             <xsl:when test="boolean($bibno)">
 166                                 <a>
 167                                     <xsl:attribute name="href">/cgi-bin/koha/opac-detail.pl?biblionumber=<xsl:value-of  select="$bibno"/></xsl:attribute>
 168                                     <xsl:value-of select="$str"/>
 169                                 </a>
 170                             </xsl:when>
 171                            <xsl:when test="boolean($index) and boolean(marc:subfield[@code=9])">
 172                                 <a>
 173                                     <xsl:attribute name="href">/cgi-bin/koha/opac-search.pl?q=an:<xsl:value-of  select="marc:subfield[@code=9]"/></xsl:attribute>
 174                                     <xsl:value-of select="$str"/>
 175                                 </a>
 176                             </xsl:when>
 177                             <xsl:when test="boolean($index)">
 178                                 <a>
 179                                     <xsl:attribute name="href">/cgi-bin/koha/opac-search.pl?q=<xsl:value-of  select="$index"/>:<xsl:value-of  select="marc:subfield[@code='a']"/></xsl:attribute>
 180                                     <xsl:value-of select="$str"/>
 181                                 </a>
 182                             </xsl:when>
 183                             <xsl:otherwise>
 184                                 <xsl:value-of select="$str"/>
 185                             </xsl:otherwise>
 186                         </xsl:choose>
 187                     </xsl:if>
 188                 </span>
 189             </xsl:if>
 190         </xsl:for-each>
 191     </xsl:template>
 192
 193     <xsl:template name="showRDAtag264">
 194     <!-- Function showRDAtag264 shows selected information from tag 264
 195          on the Publisher line (used by OPAC Detail and Results)
 196          Depending on how many tags you have, we will pick by preference
 197          Publisher-latest or Publisher or 'Other'-latest or 'Other'
 198          The preferred tag is saved in the fav variable and passed to a
 199          helper named-template -->
 200         <xsl:choose>
 201             <xsl:when test="marc:datafield[@tag=264 and @ind1=3 and @ind2=1]">
 202             <!-- ind1==3 means latest change -->
 203             <!-- ind2==1 means Publisher -->
 204               <xsl:variable name="fav" select="marc:datafield[@tag=264 and @ind1=3 and @ind2=1][1]"/>
 205               <xsl:call-template name="showRDAtag264helper">
 206                 <xsl:with-param name="field" select="$fav"/>
 207               </xsl:call-template>
 208             </xsl:when>
 209
 210             <xsl:when test="marc:datafield[@tag=264 and @ind2=1]">
 211               <xsl:variable name="fav" select="marc:datafield[@tag=264 and @ind2=1][last()]"/>
 212               <xsl:call-template name="showRDAtag264helper">
 213                 <xsl:with-param name="field" select="$fav"/>
 214               </xsl:call-template>
 215             </xsl:when>
 216
 217             <xsl:when test="marc:datafield[@tag=264 and @ind1=3]">
 218               <xsl:variable name="fav" select="marc:datafield[@tag=264 and @ind1=3][1]"/>
 219               <xsl:call-template name="showRDAtag264helper">
 220                 <xsl:with-param name="field" select="$fav"/>
 221               </xsl:call-template>
 222             </xsl:when>
 223
 224             <xsl:otherwise>
 225               <xsl:variable name="fav" select="marc:datafield[@tag=264][last()]"/>
 226               <xsl:call-template name="showRDAtag264helper">
 227                 <xsl:with-param name="field" select="$fav"/>
 228               </xsl:call-template>
 229             </xsl:otherwise>
 230         </xsl:choose>
 231     </xsl:template>
 232     <xsl:template name="showRDAtag264helper">
 233         <xsl:param name="field"/>
 234         <xsl:variable name="ind2" select="$field/@ind2"/>
 235         <xsl:choose>
 236             <xsl:when test="$ind2='0'">
 237                 <span class="label">Producer: </span>
 238             </xsl:when>
 239             <xsl:when test="$ind2='1'">
 240                 <span class="label">Publisher: </span>
 241             </xsl:when>
 242             <xsl:when test="$ind2='2'">
 243                 <span class="label">Distributor: </span>
 244             </xsl:when>
 245             <xsl:when test="$ind2='3'">
 246                 <span class="label">Manufacturer: </span>
 247             </xsl:when>
 248         </xsl:choose>
 249         <xsl:value-of select="$field/marc:subfield[@code='a']"/>
 250         <xsl:text> </xsl:text>
 251         <xsl:value-of select="$field/marc:subfield[@code='b']"/>
 252         <xsl:text> </xsl:text>
 253         <xsl:value-of select="$field/marc:subfield[@code='c']"/>
 254     </xsl:template>
 255
 256 </xsl:stylesheet>
 257
 258 <!-- Stylus Studio meta-information - (c)1998-2002 eXcelon Corp.
 259 <metaInformation>
 260 <scenarios/><MapperInfo srcSchemaPath="" srcSchemaRoot="" srcSchemaPathIsRelative="yes" srcSchemaInterpretAsXML="no" destSchemaPath="" destSchemaRoot="" destSchemaPathIsRelative="yes" destSchemaInterpretAsXML="no"/>
 261 </metaInformation>
 262 -->