cataloguing/additem.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2004-2010 BibLibre
   5 # Parts Copyright Catalyst IT 2011
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use Modern::Perl;
  23
  24 use CGI qw ( -utf8 );
  25
  26 use C4::Auth qw( get_template_and_user haspermission );
  27 use C4::Barcodes::ValueBuilder;
  28 use C4::Barcodes;
  29 use C4::Biblio qw( GetFrameworkCode GetMarcFromKohaField GetMarcStructure IsMarcStructureInternal ModBiblio );
  30 use C4::Circulation qw( barcodedecode LostItem );
  31 use C4::Context;
  32 use C4::Members;
  33 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  34 use C4::Search qw( enabled_staff_search_views );
  35 use Koha::Biblios;
  36 use Koha::Item::Templates;
  37 use Koha::ItemTypes;
  38 use Koha::Items;
  39 use Koha::Items;
  40 use Koha::Libraries;
  41 use Koha::Patrons;
  42 use Koha::SearchEngine::Indexer;
  43 use Koha::UI::Form::Builder::Item;
  44 use Koha::Result::Boolean;
  45
  46 use Encode qw( encode_utf8 );
  47 use List::MoreUtils qw( any uniq );
  48 use List::Util qw( first );
  49 use MARC::File::XML;
  50 use MIME::Base64 qw( decode_base64url encode_base64url );
  51 use Storable qw( freeze thaw );
  52 use URI::Escape qw( uri_escape_utf8 );
  53 use URI::Escape qw( uri_escape_utf8 );
  54
  55 our $dbh = C4::Context->dbh;
  56
  57 sub add_item_to_item_group {
  58     my ( $biblionumber, $itemnumber, $item_group, $item_group_description ) = @_;
  59
  60     return unless $item_group;
  61
  62     my $item_group_id;
  63     if ( $item_group eq 'create' ) {
  64         my $item_group = Koha::Biblio::ItemGroup->new(
  65             {
  66                 biblionumber => $biblionumber,
  67                 description  => $item_group_description,
  68             }
  69         )->store();
  70
  71         $item_group_id = $item_group->id;
  72     }
  73     else {
  74         $item_group_id = $item_group;
  75     }
  76
  77     my $item_group_item = Koha::Biblio::ItemGroup::Item->new(
  78         {
  79             itemnumber => $itemnumber,
  80             item_group_id  => $item_group_id,
  81         }
  82     )->store();
  83 }
  84
  85 sub get_item_from_template {
  86     my ( $template_id ) = @_;
  87
  88     my $template = Koha::Item::Templates->find($template_id);
  89
  90     return $template->decoded_contents if $template;
  91 }
  92
  93 sub get_item_from_cookie {
  94     my ( $input ) = @_;
  95
  96     my $item_from_cookie;
  97     my $lastitemcookie = $input->cookie('LastCreatedItem');
  98     if ($lastitemcookie) {
  99         $lastitemcookie = decode_base64url($lastitemcookie);
 100         eval {
 101             if ( thaw($lastitemcookie) ) {
 102                 $item_from_cookie = thaw($lastitemcookie);
 103             }
 104         };
 105         if ($@) {
 106             $lastitemcookie ||= 'undef';
 107             warn "Storable::thaw failed to thaw LastCreatedItem-cookie. Cookie value '".encode_base64url($lastitemcookie)."'. Caught error follows: '$@'";
 108         }
 109     }
 110     return $item_from_cookie;
 111 }
 112
 113 my $input        = CGI->new;
 114
 115 my $biblionumber;
 116 my $itemnumber;
 117 if( $input->param('itemnumber') && !$input->param('biblionumber') ){
 118     $itemnumber = $input->param('itemnumber');
 119     my $item = Koha::Items->find( $itemnumber );
 120     $biblionumber = $item->biblionumber;
 121 } else {
 122     $biblionumber = $input->param('biblionumber');
 123     $itemnumber = $input->param('itemnumber');
 124 }
 125
 126 my $biblio = Koha::Biblios->find($biblionumber);
 127
 128 my $op           = $input->param('op') || q{};
 129 my $hostitemnumber = $input->param('hostitemnumber');
 130 my $marcflavour  = C4::Context->preference("marcflavour");
 131 my $searchid     = $input->param('searchid');
 132 # fast cataloguing datas
 133 my $fa_circborrowernumber = $input->param('circborrowernumber');
 134 my $fa_barcode            = $input->param('barcode');
 135 my $fa_branch             = $input->param('branch');
 136 my $fa_stickyduedate      = $input->param('stickyduedate');
 137 my $fa_duedatespec        = $input->param('duedatespec');
 138 my $volume                = $input->param('volume');
 139 my $volume_description    = $input->param('volume_description');
 140
 141 our $frameworkcode = &GetFrameworkCode($biblionumber);
 142
 143 # Defining which userflag is needing according to the framework currently used
 144 my $userflags;
 145 if (defined $input->param('frameworkcode')) {
 146     $userflags = ($input->param('frameworkcode') eq 'FA') ? "fast_cataloging" : "edit_items";
 147 }
 148
 149 if (not defined $userflags) {
 150     $userflags = ($frameworkcode eq 'FA') ? "fast_cataloging" : "edit_items";
 151 }
 152
 153 my ($template, $loggedinuser, $cookie)
 154     = get_template_and_user({template_name => "cataloguing/additem.tt",
 155                  query => $input,
 156                  type => "intranet",
 157                  flagsrequired => {editcatalogue => $userflags},
 158                  });
 159
 160
 161 # Does the user have a restricted item editing permission?
 162 my $uid = Koha::Patrons->find( $loggedinuser )->userid;
 163 my $restrictededition = $uid ? haspermission($uid,  {'editcatalogue' => 'edit_items_restricted'}) : undef;
 164 # In case user is a superlibrarian, editing is not restricted
 165 $restrictededition = 0 if ($restrictededition != 0 &&  C4::Context->IsSuperLibrarian());
 166 # In case user has fast cataloging permission (and we're in fast cataloging), editing is not restricted
 167 $restrictededition = 0 if ($restrictededition != 0 && $frameworkcode eq 'FA' && haspermission($uid, {'editcatalogue' => 'fast_cataloging'}));
 168
 169 our $tagslib = &GetMarcStructure(1,$frameworkcode);
 170 my $record = $biblio->metadata->record;
 171
 172 output_and_exit_if_error( $input, $cookie, $template,
 173     { module => 'cataloguing', record => $record } );
 174
 175 my $current_item;
 176 my $nextop="additem";
 177 my @errors; # store errors found while checking data BEFORE saving item.
 178
 179 # Getting last created item cookie
 180 my $prefillitem = C4::Context->preference('PrefillItem');
 181
 182 my $load_template_submit = $input->param('load_template_submit');
 183 my $delete_template_submit = $input->param('delete_template_submit');
 184 my $unload_template_submit = $input->param('unload_template_submit');
 185 my $use_template_for_session = $input->param('use_template_for_session') || $input->cookie('ItemEditorSessionTemplateId');
 186 my $template_id = $input->param('template_id') || $input->cookie('ItemEditorSessionTemplateId');
 187 if ( $delete_template_submit ) {
 188     my $t = Koha::Item::Templates->find($template_id);
 189     $t->delete if $t && $t->borrowernumber eq $loggedinuser;
 190     $template_id = undef;
 191     $use_template_for_session = undef;
 192 }
 193 if ($load_template_submit || $unload_template_submit) {
 194     $op = q{} if $template_id;
 195
 196     $template_id = undef if !$input->param('template_id');
 197     $template_id = undef if $unload_template_submit;
 198
 199     # Unset the cookie if either no template id as submitted, or "use for session" checkbox as unchecked
 200     my $cookie_value = $input->param('use_template_for_session') && $template_id ? $template_id : q{};
 201     $use_template_for_session = $cookie_value;
 202
 203     # Update the cookie
 204     my $template_cookie = $input->cookie(
 205         -name     => 'ItemEditorSessionTemplateId',
 206         -value    => $cookie_value,
 207         -HttpOnly => 1,
 208         -expires  => '',
 209         -sameSite => 'Lax'
 210     );
 211
 212     $cookie = [ $cookie, $template_cookie ];
 213 }
 214 $template->param(
 215     template_id    => $template_id,
 216     item_templates => Koha::Item::Templates->get_available($loggedinuser),
 217     use_template_for_session => $use_template_for_session,
 218 );
 219
 220 #-------------------------------------------------------------------------------
 221 if ($op eq "additem") {
 222
 223     my $add_submit                 = $input->param('add_submit');
 224     my $add_duplicate_submit       = $input->param('add_duplicate_submit');
 225     my $add_multiple_copies_submit = $input->param('add_multiple_copies_submit');
 226     my $save_as_template_submit    = $input->param('save_as_template_submit');
 227     my $number_of_copies           = $input->param('number_of_copies');
 228
 229     my @columns = Koha::Items->columns;
 230     my $item = Koha::Item->new;
 231     $item->biblionumber($biblio->biblionumber);
 232     for my $c ( @columns ) {
 233         if ( $c eq 'more_subfields_xml' ) {
 234             my @more_subfields_xml = $input->multi_param("items.more_subfields_xml");
 235             my @unlinked_item_subfields;
 236             for my $subfield ( @more_subfields_xml ) {
 237                 my $v = $input->param('items.more_subfields_xml_' . $subfield);
 238                 push @unlinked_item_subfields, $subfield, $v;
 239             }
 240             if ( @unlinked_item_subfields ) {
 241                 my $marc = MARC::Record->new();
 242                 # use of tag 999 is arbitrary, and doesn't need to match the item tag
 243                 # used in the framework
 244                 $marc->append_fields(MARC::Field->new('999', ' ', ' ', @unlinked_item_subfields));
 245                 $marc->encoding("UTF-8");
 246                 $item->more_subfields_xml($marc->as_xml("USMARC"));
 247                 next;
 248             }
 249             $item->more_subfields_xml(undef);
 250         } else {
 251             my @v = grep { $_ ne "" }
 252                 uniq $input->multi_param( "items." . $c );
 253
 254             next unless @v;
 255
 256             if ( $c eq 'permanent_location' ) { # See 27837
 257                 $item->make_column_dirty('permanent_location');
 258             }
 259
 260             $item->$c(join ' | ', @v);
 261         }
 262     }
 263
 264     # if autoBarcode is set to 'incremental', calculate barcode...
 265     if ( ! defined $item->barcode && C4::Context->preference('autoBarcode') eq 'incremental' ) {
 266         my ( $barcode ) = C4::Barcodes::ValueBuilder::incremental::get_barcode;
 267         $item->barcode($barcode);
 268     }
 269
 270     $item->barcode(barcodedecode($item->barcode));
 271
 272     if ($save_as_template_submit) {
 273         my $template_name       = $input->param('template_name');
 274         my $template_is_shared  = $input->param('template_is_shared');
 275         my $replace_template_id = $input->param('replace_template_id');
 276
 277         if ($replace_template_id) {
 278             my $template = Koha::Item::Templates->find($replace_template_id);
 279             if ($template) {
 280                 $template->update(
 281                     {
 282                         id             => $replace_template_id,
 283                         is_shared      => $template_is_shared ? 1 : 0,
 284                         contents       => $item->unblessed,
 285                     }
 286                 );
 287             }
 288         }
 289         else {
 290             my $template = Koha::Item::Template->new(
 291                 {
 292                     name           => $template_name,
 293                     borrowernumber => $loggedinuser,
 294                     is_shared      => $template_is_shared ? 1 : 0,
 295                     contents       => $item->unblessed,
 296                 }
 297             )->store();
 298         }
 299     }
 300     # If we have to add or add & duplicate, we add the item
 301     elsif ( $add_submit || $add_duplicate_submit || $prefillitem) {
 302
 303         # check for item barcode # being unique
 304         if ( defined $item->barcode
 305             && Koha::Items->search( { barcode => $item->barcode } )->count )
 306         {
 307             # if barcode exists, don't create, but report The problem.
 308             push @errors, "barcode_not_unique";
 309
 310             $current_item = $item->unblessed; # Restore edit form for the same item
 311         }
 312         else {
 313             $item->store->discard_changes;
 314             add_item_to_item_group( $item->biblionumber, $item->biblioitemnumber, $volume, $volume_description );
 315
 316             # This is a bit tricky : if there is a cookie for the last created item and
 317             # we just added an item, the cookie value is not correct yet (it will be updated
 318             # next page). To prevent the form from being filled with outdated values, we
 319             # force the use of "add and duplicate" feature, so the form will be filled with
 320             # correct values.
 321
 322             # Pushing the last created item cookie back
 323             if ( $prefillitem ) {
 324                 my $last_created_item_cookie = $input->cookie(
 325                     -name => 'LastCreatedItem',
 326                     # We encode_base64url the whole freezed structure so we're sure we won't have any encoding problems
 327                     -value   => encode_base64url( freeze( { %{$item->unblessed}, itemnumber => undef } ) ),
 328                     -HttpOnly => 1,
 329                     -expires => '',
 330                     -sameSite => 'Lax'
 331                 );
 332
 333                 $cookie = [ $cookie, $last_created_item_cookie ];
 334             }
 335
 336         }
 337         $nextop = "additem";
 338
 339     }
 340
 341     # If we have to add & duplicate
 342     if ($prefillitem || $add_duplicate_submit) {
 343
 344         $current_item = $item->unblessed;
 345
 346         if (C4::Context->preference('autoBarcode') eq 'incremental') {
 347             my ( $barcode ) = C4::Barcodes::ValueBuilder::incremental::get_barcode;
 348             $current_item->{barcode} = $barcode;
 349         }
 350         else {
 351             # we have to clear the barcode field in the duplicate item record to make way for the new one generated by the javascript plugin
 352             $current_item->{barcode} = undef; # FIXME or delete?
 353         }
 354
 355         # Don't use the "prefill" feature if we want to generate the form with all the info from this item
 356         # It will remove subfields that are not in SubfieldsToUseWhenPrefill.
 357         $prefillitem = 0 if $add_duplicate_submit;
 358     }
 359
 360     # If we have to add multiple copies
 361     if ($add_multiple_copies_submit) {
 362
 363         $current_item = $item->unblessed;
 364
 365         my $copynumber = $current_item->{copynumber};
 366         my $oldbarcode = $current_item->{barcode};
 367
 368         # If there is a barcode and we can't find their new values, we can't add multiple copies
 369         my $testbarcode;
 370         my $barcodeobj = C4::Barcodes->new;
 371         $testbarcode = $barcodeobj->next_value($oldbarcode) if $barcodeobj;
 372         if ( $oldbarcode && !$testbarcode ) {
 373
 374             push @errors, "no_next_barcode";
 375
 376         }
 377         else {
 378             # We add each item
 379
 380             # For the first iteration
 381             my $barcodevalue = $oldbarcode;
 382             my $exist_itemnumber;
 383
 384             for ( my $i = 0 ; $i < $number_of_copies ; ) {
 385
 386                 # If there is a barcode
 387                 if ($barcodevalue) {
 388
 389 # Getting a new barcode (if it is not the first iteration or the barcode we tried already exists)
 390                     $barcodevalue = $barcodeobj->next_value($oldbarcode)
 391                       if ( $i > 0 || $exist_itemnumber );
 392
 393                     # Putting it into the record
 394                     if ($barcodevalue) {
 395                         if ( C4::Context->preference("autoBarcode") eq
 396                             'hbyymmincr' && $i > 0 )
 397                         { # The first copy already contains the homebranch prefix
 398                              # This is terribly hacky but the easiest way to fix the way hbyymmincr is working
 399                              # Contrary to what one might think, the barcode plugin does not prefix the returned string with the homebranch
 400                              # For a single item, it is handled with some JS code (see cataloguing/value_builder/barcode.pl)
 401                              # But when adding multiple copies we need to prefix it here,
 402                              # so we retrieve the homebranch from the item and prefix the barcode with it.
 403                             my $homebranch = $current_item->{homebranch};
 404                             $barcodevalue = $homebranch . $barcodevalue;
 405                         }
 406                         $current_item->{barcode} = $barcodevalue;
 407                     }
 408
 409                     # Checking if the barcode already exists
 410                     $exist_itemnumber = Koha::Items->search({ barcode => $barcodevalue })->count;
 411                 }
 412
 413                 # Updating record with the new copynumber
 414                 if ($copynumber) {
 415                     $current_item->{copynumber} = $copynumber;
 416                 }
 417
 418                 # Adding the item
 419                 if ( !$exist_itemnumber ) {
 420                     delete $current_item->{itemnumber};
 421                     $current_item = Koha::Item->new($current_item)->store(
 422                         { skip_record_index => 1 } );
 423                     $current_item->discard_changes; # Cannot chain discard_changes
 424                     $current_item = $current_item->unblessed;
 425                     add_item_to_item_group( $item->biblionumber, $item->biblioitemnumber, $volume, $volume_description );
 426
 427 # We count the item only if it was really added
 428 # That way, all items are added, even if there was some already existing barcodes
 429 # FIXME : Please note that there is a risk of infinite loop here if we never find a suitable barcode
 430                     $i++;
 431
 432                     # Only increment copynumber if item was really added
 433                     $copynumber++ if ( $copynumber && $copynumber =~ m/^\d+$/ );
 434                 }
 435
 436                 # Preparing the next iteration
 437                 $oldbarcode = $barcodevalue;
 438             }
 439
 440             my $indexer = Koha::SearchEngine::Indexer->new(
 441                 { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 442             $indexer->index_records( $biblionumber, "specialUpdate",
 443                 "biblioserver" );
 444
 445             undef($current_item);
 446         }
 447     }
 448     if ($frameworkcode eq 'FA' && $fa_circborrowernumber){
 449         print $input->redirect(
 450            '/cgi-bin/koha/circ/circulation.pl?'
 451            .'borrowernumber='.$fa_circborrowernumber
 452            .'&barcode='.uri_escape_utf8($fa_barcode)
 453            .'&duedatespec='.$fa_duedatespec
 454            .'&stickyduedate='.$fa_stickyduedate
 455         );
 456         exit;
 457     }
 458
 459
 460 #-------------------------------------------------------------------------------
 461 } elsif ($op eq "edititem") {
 462 #-------------------------------------------------------------------------------
 463 # retrieve item if exist => then, it's a modif
 464     $current_item = Koha::Items->find($itemnumber)->unblessed;
 465     # FIXME Handle non existent item
 466     $nextop = "saveitem";
 467 #-------------------------------------------------------------------------------
 468 } elsif ($op eq "dupeitem") {
 469 #-------------------------------------------------------------------------------
 470 # retrieve item if exist => then, it's a modif
 471     $current_item = Koha::Items->find($itemnumber)->unblessed;
 472     # FIXME Handle non existent item
 473     if (C4::Context->preference('autoBarcode') eq 'incremental') {
 474         my ( $barcode ) = C4::Barcodes::ValueBuilder::incremental::get_barcode;
 475         $current_item->{barcode} = $barcode;
 476     }
 477     else {
 478         $current_item->{barcode} = undef; # Don't save it!
 479     }
 480
 481     $nextop = "additem";
 482 #-------------------------------------------------------------------------------
 483 } elsif ($op eq "delitem") {
 484 #-------------------------------------------------------------------------------
 485     # check that there is no issue on this item before deletion.
 486     my $item = Koha::Items->find($itemnumber);
 487     my $deleted;
 488     if( $item ) {
 489         $deleted = $item->safe_delete;
 490     } else {
 491         $deleted = Koha::Result::Boolean->new(0)->add_message({ message => 'item_not_found' });
 492     }
 493     if ( $deleted ) {
 494         print $input->redirect("additem.pl?biblionumber=$biblionumber&frameworkcode=$frameworkcode&searchid=$searchid");
 495         exit;
 496     }
 497     else {
 498         push @errors, @{ $deleted->messages }[0]->message;
 499         $nextop = "additem";
 500     }
 501 #-------------------------------------------------------------------------------
 502 } elsif ($op eq "delallitems") {
 503 #-------------------------------------------------------------------------------
 504     my $items = Koha::Items->search({ biblionumber => $biblionumber });
 505     while ( my $item = $items->next ) {
 506         my $deleted = $item->safe_delete({ skip_record_index => 1 });
 507         push @errors, @{$deleted->messages}[0]->message unless $deleted;
 508     }
 509     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 510     $indexer->index_records( $biblionumber, "specialUpdate", "biblioserver" );
 511     if ( @errors ) {
 512         $nextop="additem";
 513     } else {
 514         my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 515         my $views = { C4::Search::enabled_staff_search_views };
 516         if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 517             print $input->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 518         } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 519             print $input->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 520         } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 521             print $input->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 522         } else {
 523             print $input->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&searchid=$searchid");
 524         }
 525         exit;
 526     }
 527 #-------------------------------------------------------------------------------
 528 } elsif ($op eq "saveitem") {
 529 #-------------------------------------------------------------------------------
 530
 531     my $itemnumber = $input->param('itemnumber');
 532     my $item = Koha::Items->find($itemnumber);
 533     # FIXME Handle non existent item
 534     my $olditemlost = $item->itemlost;
 535     my @columns = Koha::Items->columns;
 536     my $new_values = $item->unblessed;
 537     for my $c ( @columns ) {
 538         if ( $c eq 'more_subfields_xml' ) {
 539             my @more_subfields_xml = $input->multi_param("items.more_subfields_xml");
 540             my @unlinked_item_subfields;
 541             for my $subfield ( uniq @more_subfields_xml ) {
 542                 my @v = $input->multi_param('items.more_subfields_xml_' . encode_utf8($subfield));
 543                 push @unlinked_item_subfields, $subfield, $_ for @v;
 544             }
 545             if ( @unlinked_item_subfields ) {
 546                 my $marc = MARC::Record->new();
 547                 # use of tag 999 is arbitrary, and doesn't need to match the item tag
 548                 # used in the framework
 549                 $marc->append_fields(MARC::Field->new('999', ' ', ' ', @unlinked_item_subfields));
 550                 $marc->encoding("UTF-8");
 551                 $new_values->{more_subfields_xml} = $marc->as_xml("USMARC");
 552                 next;
 553             }
 554             $item->more_subfields_xml(undef);
 555         } else {
 556             my @v = map { ( defined $_ && $_ eq '' ) ? undef : $_ } $input->multi_param( "items." . $c );
 557             next unless @v;
 558
 559             if ( $c eq 'permanent_location' ) { # See 27837
 560                 $item->make_column_dirty('permanent_location');
 561             }
 562
 563             if ( scalar(@v) == 1 && not defined $v[0] ) {
 564                 delete $new_values->{$c};
 565             } else {
 566                 $new_values->{$c} = join ' | ', @v;
 567             }
 568         }
 569     }
 570     $item = $item->set_or_blank($new_values);
 571
 572     # check that the barcode don't exist already
 573     if (
 574         defined $item->barcode
 575         && Koha::Items->search(
 576             {
 577                 barcode    => $item->barcode,
 578                 itemnumber => { '!=' => $item->itemnumber }
 579             }
 580         )->count
 581       )
 582     {
 583         # FIXME We shouldn't need that, ->store would explode as there is a unique constraint on items.barcode
 584         push @errors,"barcode_not_unique";
 585         $current_item = $item->unblessed; # Restore edit form for the same item
 586     } else {
 587         my $newitemlost = $item->itemlost;
 588         if ( $newitemlost && $newitemlost ge '1' && !$olditemlost ) {
 589             LostItem( $item->itemnumber, 'additem' );
 590         }
 591         $item->store;
 592     }
 593
 594     $nextop="additem";
 595 } elsif ($op eq "delinkitem"){
 596
 597     my $analyticfield = '773';
 598     if ($marcflavour  eq 'MARC21'){
 599         $analyticfield = '773';
 600     } elsif ($marcflavour eq 'UNIMARC') {
 601         $analyticfield = '461';
 602     }
 603     foreach my $field ($record->field($analyticfield)){
 604         if ($field->subfield('9') eq $hostitemnumber){
 605             $record->delete_field($field);
 606             last;
 607         }
 608     }
 609         my $modbibresult = ModBiblio($record, $biblionumber,'');
 610 }
 611
 612 # update OAI-PMH sets
 613 if ($op) {
 614     if (C4::Context->preference("OAI-PMH:AutoUpdateSets")) {
 615         C4::OAI::Sets::UpdateOAISetsBiblio($biblionumber, $record);
 616     }
 617 }
 618
 619 #
 620 #-------------------------------------------------------------------------------
 621 # build screen with existing items. and "new" one
 622 #-------------------------------------------------------------------------------
 623
 624 # now, build existiing item list
 625
 626 my @items;
 627 for my $item ( $biblio->items->as_list, $biblio->host_items->as_list ) {
 628     push @items, $item->columns_to_str;
 629 }
 630
 631 my @witness_attributes = uniq map {
 632     my $item = $_;
 633     map { defined $item->{$_} && $item->{$_} ne "" ? $_ : () } keys %$item
 634 } @items;
 635
 636 our ( $itemtagfield, $itemtagsubfield ) = GetMarcFromKohaField("items.itemnumber");
 637
 638 my $subfieldcode_attribute_mappings;
 639 for my $subfield_code ( keys %{ $tagslib->{$itemtagfield} } ) {
 640
 641     my $subfield = $tagslib->{$itemtagfield}->{$subfield_code};
 642
 643     next if IsMarcStructureInternal( $subfield );
 644     next unless $subfield->{tab} eq 10; # Is this really needed?
 645
 646     my $attribute;
 647     if ( $subfield->{kohafield} ) {
 648         ( $attribute = $subfield->{kohafield} ) =~ s|^items\.||;
 649     } else {
 650         $attribute = $subfield_code; # It's in more_subfields_xml
 651     }
 652     next unless grep { $attribute eq $_ } @witness_attributes;
 653     $subfieldcode_attribute_mappings->{$subfield_code} = $attribute;
 654 }
 655
 656 my @header_value_loop = map {
 657     {
 658         header_value  => $tagslib->{$itemtagfield}->{$_}->{lib},
 659         attribute     => $subfieldcode_attribute_mappings->{$_},
 660         subfield_code => $_,
 661     }
 662 } sort keys %$subfieldcode_attribute_mappings;
 663
 664 # Using last created item if it exists
 665 if (
 666     $op ne "additem"
 667     && $op ne "edititem"
 668     && $op ne "dupeitem" )
 669 {
 670     if ( $template_id ) {
 671         my $item_from_template = get_item_from_template($template_id);
 672         $current_item = $item_from_template if $item_from_template;
 673     }
 674     elsif ( $prefillitem ) {
 675         my $item_from_cookie = get_item_from_cookie($input);
 676         $current_item = $item_from_cookie if $item_from_cookie;
 677     }
 678 }
 679
 680 if ( $current_item->{more_subfields_xml} ) {
 681     # FIXME Use Maybe MARC::Record::new_from_xml if encoding issues on subfield (??)
 682     $current_item->{marc_more_subfields_xml} = MARC::Record->new_from_xml($current_item->{more_subfields_xml}, 'UTF-8');
 683 }
 684
 685 my $branchcode = $input->param('branch') || C4::Context->userenv->{branch};
 686
 687 # If we are not adding a new item
 688 # OR
 689 # If the subfield must be prefilled with last catalogued item
 690 my @subfields_to_prefill;
 691 if ( $nextop eq 'additem' && $op ne 'dupeitem' && $prefillitem ) {
 692     @subfields_to_prefill = split(' ', C4::Context->preference('SubfieldsToUseWhenPrefill'));
 693 }
 694
 695 # Getting list of subfields to keep when restricted editing is enabled
 696 my @subfields_to_allow = $restrictededition ? split ' ', C4::Context->preference('SubfieldsToAllowForRestrictedEditing') : ();
 697
 698 my $subfields =
 699   Koha::UI::Form::Builder::Item->new(
 700     { biblionumber => $biblionumber, item => $current_item } )->edit_form(
 701     {
 702         branchcode           => $branchcode,
 703         restricted_editition => $restrictededition,
 704         (
 705             @subfields_to_allow
 706             ? ( subfields_to_allow => \@subfields_to_allow )
 707             : ()
 708         ),
 709         (
 710             @subfields_to_prefill
 711             ? ( subfields_to_prefill => \@subfields_to_prefill )
 712             : ()
 713         ),
 714         prefill_with_default_values => 1,
 715         branch_limit => C4::Context->userenv->{"branch"},
 716         (
 717             $op eq 'dupeitem'
 718             ? ( ignore_invisible_subfields => 1 )
 719             : ()
 720         ),
 721     }
 722 );
 723
 724 if (   $frameworkcode eq 'FA' ) {
 725     my ( $barcode_field ) = grep {$_->{kohafield} eq 'items.barcode'} @$subfields;
 726     $barcode_field->{marc_value}->{value} ||= $input->param('barcode');
 727 }
 728
 729 if( my $default_location = C4::Context->preference('NewItemsDefaultLocation') ) {
 730     my ( $location_field ) = grep {$_->{kohafield} eq 'items.location'} @$subfields;
 731     $location_field->{marc_value}->{value} ||= $default_location;
 732 }
 733
 734 my @ig = Koha::Biblio::ItemGroups->search({ biblio_id => $biblionumber })->as_list();
 735 # what's the next op ? it's what we are not in : an add if we're editing, otherwise, and edit.
 736 $template->param(
 737     biblio       => $biblio,
 738     items        => \@items,
 739     item_groups      => \@ig,
 740     item_header_loop => \@header_value_loop,
 741     subfields        => $subfields,
 742     itemnumber       => $itemnumber,
 743     barcode          => $current_item->{barcode},
 744     op      => $nextop,
 745     popup => scalar $input->param('popup') ? 1: 0,
 746     C4::Search::enabled_staff_search_views,
 747 );
 748 $template->{'VARS'}->{'searchid'} = $searchid;
 749
 750 if ($frameworkcode eq 'FA'){
 751     # fast cataloguing datas
 752     $template->param(
 753         'circborrowernumber' => $fa_circborrowernumber,
 754         'barcode'            => $fa_barcode,
 755         'branch'             => $fa_branch,
 756         'stickyduedate'      => $fa_stickyduedate,
 757         'duedatespec'        => $fa_duedatespec,
 758     );
 759 }
 760
 761 foreach my $error (@errors) {
 762     $template->param($error => 1);
 763 }
 764 output_html_with_http_headers $input, $cookie, $template->output;