catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output qw( output_html_with_http_headers pagination_bar );
 144 use C4::Auth qw( get_template_and_user );
 145 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 146 use C4::Languages qw( getlanguage getLanguages );
 147 use C4::Koha qw( getitemtypeimagelocation GetAuthorisedValues );
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158 use Koha::SearchFields;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = CGI->new;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 # limits are used to limit to results to a pre-defined category such as branch or language
 172 my @limits = map uri_unescape($_), $cgi->multi_param("limit");
 173 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 174 my %is_nolimit = map { $_ => 1 } @nolimits;
 175 @limits = grep { not $is_nolimit{$_} } @limits;
 176 if  (
 177         !$cgi->param('edit_search') &&
 178         ( (@limits>=1) || (defined $cgi->param("q") && $cgi->param("q") ne "" ) || ($cgi->param('limit-yr')) )
 179     ) {
 180     $template_name = 'catalogue/results.tt';
 181     $template_type = 'results';
 182 }
 183 else {
 184     $template_name = 'catalogue/advsearch.tt';
 185     $template_type = 'advsearch';
 186 }
 187 # load the template
 188 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 189     template_name => $template_name,
 190     query => $cgi,
 191     type => "intranet",
 192     flagsrequired   => { catalogue => 1 },
 193     }
 194 );
 195
 196 my $lang = C4::Languages::getlanguage($cgi);
 197
 198 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 199     $template->param('UNIMARC' => 1);
 200 }
 201
 202 if($cgi->cookie("holdfor")){
 203     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 204     if ( $holdfor_patron ) { # may have been deleted in the meanwhile
 205         $template->param(
 206             holdfor        => $cgi->cookie("holdfor"),
 207             holdfor_patron => $holdfor_patron,
 208         );
 209     }
 210 }
 211
 212 if($cgi->cookie("holdforclub")){
 213     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 214     if ( $holdfor_club ) { # May have been deleted in the meanwhile
 215         $template->param(
 216             holdforclub => $cgi->cookie("holdforclub"),
 217             holdforclub_name => $holdfor_club->name,
 218         );
 219     }
 220 }
 221
 222 if($cgi->cookie("searchToOrder")){
 223     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 224     $template->param(
 225         searchtoorder_basketno => $basketno,
 226         searchtoorder_vendorid => $vendorid
 227     );
 228 }
 229
 230 # get biblionumbers stored in the cart
 231 my @cart_list;
 232
 233 if($cgi->cookie("intranet_bib_list")){
 234     my $cart_list = $cgi->cookie("intranet_bib_list");
 235     @cart_list = split(/\//, $cart_list);
 236 }
 237
 238 my @search_groups =
 239   Koha::Library::Groups->get_search_groups( { interface => 'staff' } )->as_list;
 240
 241 $template->param(
 242     search_groups    => \@search_groups,
 243 );
 244
 245 # load the Type stuff
 246 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 247 my $advancedsearchesloop = prepare_adv_search_types($types);
 248 $template->param(advancedsearchesloop => $advancedsearchesloop);
 249
 250 $template->param( searchid => scalar $cgi->param('searchid'), );
 251
 252 # The following should only be loaded if we're bringing up the advanced search template
 253 if ( $template_type eq 'advsearch' ) {
 254
 255     my $expanded = $cgi->param('expanded_options');
 256     if( $cgi->param('edit_search') ){
 257         my @operators = $cgi->multi_param('op');
 258         my @indexes   = $cgi->multi_param('idx');
 259         my %limit_hash;
 260         foreach my $limit (@limits){
 261             if ( $limit eq 'available' ){
 262                 $template->param( limit_available => 1 );
 263             } else {
 264                 my ($index,$value) = split(':',$limit);
 265                 $value =~ s/"//g;
 266                 if ( $index =~ /mc-/ ){
 267                     $limit_hash{$index . "_" . $value} = 1;
 268                 } else {
 269                     push @{$limit_hash{$index}}, $value;
 270                 }
 271             }
 272         };
 273         $expanded = 1 if scalar @operators || scalar @limits;
 274         $template->param( operators => \@operators );
 275         $template->param( limits => \%limit_hash );
 276         $template->param(
 277            indexes   => \@indexes,
 278            sort      => $cgi->param('sort_by'),
 279         );
 280     }
 281     # load the servers (used for searching -- to do federated searching, etc.)
 282     my $primary_servers_loop;# = displayPrimaryServers();
 283     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 284
 285     my $secondary_servers_loop;
 286     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 287
 288     # set the default sorting
 289     if (   C4::Context->preference('defaultSortField')
 290         && C4::Context->preference('defaultSortOrder') ) {
 291         my $default_sort_by =
 292             C4::Context->preference('defaultSortField') . '_'
 293           . C4::Context->preference('defaultSortOrder');
 294         $template->param( sort_by => $default_sort_by  );
 295     }
 296
 297     # determine what to display next to the search boxes
 298     my @queries = $cgi->multi_param('q');
 299     while( scalar @queries < 3 ){
 300         push @queries, "";
 301     }
 302     $template->param(uc(C4::Context->preference("marcflavour")) =>1 );
 303
 304     # load the language limits (for search)
 305     my $languages_limit_loop = getLanguages($lang, 1);
 306     $template->param(search_languages_loop => $languages_limit_loop,);
 307     $template->param(       queries   => \@queries );
 308
 309     # Expanded search options in advanced search:
 310     # use the global setting by default, but let the user override it
 311     {
 312         $expanded = C4::Context->preference("expandedSearchOption") || 0
 313             if !defined($expanded) || $expanded !~ /^0|1$/;
 314         $template->param( expanded_options => $expanded );
 315     }
 316
 317     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 318
 319     output_html_with_http_headers $cgi, $cookie, $template->output;
 320     exit;
 321 }
 322
 323 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 324
 325 # Fetch the paramater list as a hash in scalar context:
 326 #  * returns paramater list as tied hash ref
 327 #  * we can edit the values by changing the key
 328 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 329 my $params = $cgi->Vars;
 330 # Params that can have more than one value
 331 # sort by is used to sort the query
 332 # in theory can have more than one but generally there's just one
 333 my @sort_by;
 334 my $default_sort_by;
 335 if (   C4::Context->preference('defaultSortField')
 336     && C4::Context->preference('defaultSortOrder') ) {
 337     $default_sort_by =
 338         C4::Context->preference('defaultSortField') . '_'
 339       . C4::Context->preference('defaultSortOrder');
 340 }
 341
 342 @sort_by = $cgi->multi_param('sort_by');
 343 $sort_by[0] = $default_sort_by unless $sort_by[0];
 344 foreach my $sort (@sort_by) {
 345     $template->param($sort => 1) if $sort;
 346 }
 347 $template->param('sort_by' => $sort_by[0]);
 348
 349 # Use the servers defined, or just search our local catalog(default)
 350 my @servers = $cgi->multi_param('server');
 351 unless (@servers) {
 352     #FIXME: this should be handled using Context.pm
 353     @servers = ("biblioserver");
 354     # @servers = C4::Context->config("biblioserver");
 355 }
 356 # operators include boolean and proximity operators and are used
 357 # to evaluate multiple operands
 358 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 359
 360 # indexes are query qualifiers, like 'title', 'author', etc. They
 361 # can be single or multiple parameters separated by comma: kw,right-Truncation
 362 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 363
 364 # if a simple index (only one)  display the index used in the top search box
 365 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 366     my $idx = "ms_".$indexes[0];
 367     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 368     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 369     $template->param(header_pulldown => $idx);
 370 }
 371
 372 # an operand can be a single term, a phrase, or a complete ccl query
 373 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 374
 375 # if a simple search, display the value in the search box
 376 my $basic_search = 0;
 377 if ($operands[0] && !$operands[1]) {
 378     my $ms_query = $operands[0];
 379     $ms_query =~ s/ #\S+//;
 380     $template->param(ms_value => $ms_query);
 381     $basic_search=1;
 382 }
 383
 384 my $available;
 385 foreach my $limit(@limits) {
 386     if ($limit =~/available/) {
 387         $available = 1;
 388     }
 389 }
 390 $template->param(available => $available);
 391
 392 # append year limits if they exist
 393 my $limit_yr;
 394 my $limit_yr_value;
 395 if ($params->{'limit-yr'}) {
 396     if ($params->{'limit-yr'} =~ /\d{4}/) {
 397         $limit_yr = "yr,st-numeric:$params->{'limit-yr'}";
 398         $limit_yr_value = $params->{'limit-yr'};
 399     }
 400     push @limits,$limit_yr;
 401     #FIXME: Should return a error to the user, incorect date format specified
 402 }
 403
 404 # convert indexes and operands to corresponding parameter names for the z3950 search
 405 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 406 my $z3950par;
 407 my $indexes2z3950 = {
 408     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 409     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 410     ti=>'title', 'ti,phr'=>'title', se=>'title'
 411 };
 412 for (my $ii = 0; $ii < @operands; ++$ii)
 413 {
 414     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 415     if (defined $name && defined $operands[$ii])
 416     {
 417         $z3950par ||= {};
 418         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 419     }
 420 }
 421
 422
 423 # Params that can only have one value
 424 my $scan = $params->{'scan'};
 425 my $count = C4::Context->preference('numSearchResults') || 20;
 426 my $results_per_page = $params->{'count'} || $count;
 427 my $offset = $params->{'offset'} || 0;
 428 my $whole_record = $params->{'whole_record'} || 0;
 429 my $weight_search = $params->{'advsearch'} ? $params->{'weight_search'} || 0 : 1;
 430 $offset = 0 if $offset < 0;
 431 my $page = $cgi->param('page') || 1;
 432 #my $offset = ($page-1)*$results_per_page;
 433
 434 # Define some global variables
 435 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 436
 437 my $builder = Koha::SearchEngine::QueryBuilder->new(
 438     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 439 my $searcher = Koha::SearchEngine::Search->new(
 440     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 441
 442 ## I. BUILD THE QUERY
 443 (
 444     $error,             $query, $simple_query, $query_cgi,
 445     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 446     $query_type
 447   )
 448   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 449     \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 450
 451 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 452
 453 ## parse the query_cgi string and put it into a form suitable for <input>s
 454 my @query_inputs;
 455 my $scan_index_to_use;
 456 my $scan_search_term_to_use;
 457
 458 if ($query_cgi) {
 459     for my $this_cgi ( split('&', $query_cgi) ) {
 460         next unless $this_cgi;
 461         $this_cgi =~ m/(.*?)=(.*)/;
 462         my $input_name = $1;
 463         my $input_value = $2;
 464         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 465         if ($input_name eq 'idx') {
 466             # The form contains multiple fields, so take the first value as the scan index
 467             $scan_index_to_use = $input_value unless $scan_index_to_use;
 468         }
 469         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 470             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 471         }
 472     }
 473 }
 474
 475 $template->param ( QUERY_INPUTS => \@query_inputs,
 476                    scan_index_to_use => $scan_index_to_use,
 477                    scan_search_term_to_use => $scan_search_term_to_use );
 478
 479 ## parse the limit_cgi string and put it into a form suitable for <input>s
 480 my @limit_inputs;
 481 if ($limit_cgi) {
 482     for my $this_cgi ( split('&', $limit_cgi) ) {
 483         next unless $this_cgi;
 484         # handle special case limit-yr
 485         if ($this_cgi =~ /yr,st-numeric/) {
 486             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 487             next;
 488         }
 489         $this_cgi =~ m/(.*=)(.*)/;
 490         my $input_name = $1;
 491         my $input_value = $2;
 492         $input_name =~ s/=$//;
 493         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 494     }
 495 }
 496 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 497
 498 ## II. DO THE SEARCH AND GET THE RESULTS
 499 my $total = 0; # the total results for the whole set
 500 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 501 my $results_hashref;
 502
 503 eval {
 504     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 505     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 506         $query,            $simple_query, \@sort_by,       \@servers,
 507         $results_per_page, $offset,       undef,           $itemtypes,
 508         $query_type,       $scan
 509     );
 510 };
 511
 512 if ($@ || $error) {
 513     my $query_error = q{};
 514     $query_error .= $error if $error;
 515     $query_error .= $@ if $@;
 516     $template->param(query_error => $query_error);
 517     output_html_with_http_headers $cgi, $cookie, $template->output;
 518     exit;
 519 }
 520
 521 # At this point, each server has given us a result set
 522 # now we build that set for template display
 523 my @sup_results_array;
 524 for (my $i=0;$i<@servers;$i++) {
 525     my $server = $servers[$i];
 526     if ($server =~/biblioserver/) { # this is the local bibliographic server
 527         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 528         if ( $hits == 0 && $basic_search ){
 529             $operands[0] = '"'.$operands[0].'"'; #quote it
 530             ## I. BUILD THE QUERY
 531             (
 532                 $error,             $query, $simple_query, $query_cgi,
 533                 $query_desc,        $limit, $limit_cgi,    $limit_desc,
 534                 $query_type
 535               )
 536               = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 537                 \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 538             my $quoted_results_hashref;
 539             eval {
 540                 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 541                 ( $error, $quoted_results_hashref, $facets ) = $searcher->search_compat(
 542                     $query,            $simple_query, \@sort_by,       ['biblioserver'],
 543                     $results_per_page, $offset,       undef,           $itemtypes,
 544                     $query_type,       $scan
 545                 );
 546             };
 547             my $quoted_hits = $quoted_results_hashref->{$server}->{"hits"} // 0;
 548             if ( $quoted_hits ){
 549                 $results_hashref->{'biblioserver'} = $quoted_results_hashref->{'biblioserver'};
 550                 $hits = $quoted_hits;
 551             }
 552         }
 553         my $page = $cgi->param('page') || 0;
 554         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 555                                        $results_hashref->{$server}->{"RECORDS"});
 556         $total = $total + $hits;
 557
 558         # Search history
 559         if (C4::Context->preference('EnableSearchHistory')) {
 560             unless ( $offset ) {
 561                 my $path_info = $cgi->url(-path_info=>1);
 562                 my $query_cgi_history = $cgi->url(-query=>1);
 563                 $query_cgi_history =~ s/^$path_info\?//;
 564                 $query_cgi_history =~ s/;/&/g;
 565                 my $query_desc_history = $query_desc;
 566                 $query_desc_history .= ", $limit_desc"
 567                     if $limit_desc;
 568
 569                 C4::Search::History::add({
 570                     userid => $borrowernumber,
 571                     sessionid => $cgi->cookie("CGISESSID"),
 572                     query_desc => $query_desc_history,
 573                     query_cgi => $query_cgi_history,
 574                     total => $total,
 575                     type => "biblio",
 576                 });
 577             }
 578             $template->param( EnableSearchHistory => 1 );
 579         }
 580
 581         ## If there's just one result, redirect to the detail page unless doing an index scan
 582         if ($total == 1 && !$scan) {
 583             my $biblionumber = $newresults[0]->{biblionumber};
 584             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 585             my $views = { C4::Search::enabled_staff_search_views };
 586             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 587                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&found1=1");
 588             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 589                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&found1=1");
 590             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 591                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&found1=1");
 592             } else {
 593                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&found1=1");
 594             }
 595             exit;
 596         }
 597
 598         # set up parameters if user wishes to re-run the search
 599         # as a Z39.50 search
 600         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 601         $template->param(limit_cgi => $limit_cgi);
 602         $template->param(query_cgi => $query_cgi);
 603         $template->param(query_desc => $query_desc);
 604         $template->param(limit_desc => $limit_desc);
 605         $template->param(offset     => $offset);
 606
 607         if ($hits) {
 608             $template->param(total => $hits);
 609             if ($limit_cgi) {
 610                 my $limit_cgi_not_availablity = $limit_cgi;
 611                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 612                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 613             }
 614             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 615             if ($query_desc || $limit_desc) {
 616                 $template->param(searchdesc => 1);
 617             }
 618             $template->param(results_per_page =>  $results_per_page);
 619             # must define a value for size if not present in DB
 620             # in order to avoid problems generated by the default size value in TT
 621             foreach my $line (@newresults) {
 622                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 623                 # while we're checking each line, see if item is in the cart
 624                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 625                     $line->{'incart'} = 1;
 626                 }
 627             }
 628             my( $page_numbers, $hits_to_paginate, $pages, $current_page_number, $previous_page_offset, $next_page_offset, $last_page_offset ) =
 629                 Koha::SearchEngine::Search->pagination_bar(
 630                     {
 631                         hits              => $hits,
 632                         max_result_window => $searcher->max_result_window,
 633                         results_per_page  => $results_per_page,
 634                         offset            => $offset,
 635                         sort_by           => \@sort_by
 636                     }
 637                 );
 638             $template->param( hits_to_paginate => $hits_to_paginate );
 639             $template->param(SEARCH_RESULTS => \@newresults);
 640             # FIXME: no previous_page_offset when pages < 2
 641             $template->param(   PAGE_NUMBERS => $page_numbers,
 642                                 last_page_offset => $last_page_offset,
 643                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 644             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 645         }
 646
 647
 648         # no hits
 649         else {
 650             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 651         }
 652
 653     } # end of the if local
 654
 655     # asynchronously search the authority server
 656     elsif ($server =~/authorityserver/) { # this is the local authority server
 657         my @inner_sup_results_array;
 658         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 659             my $marc_record_object = C4::Search::new_record_from_zebra(
 660                 'authorityserver',
 661                 $sup_record
 662             );
 663             # warn "Authority Found: ".$marc_record_object->as_formatted();
 664             push @inner_sup_results_array, {
 665                 'title' => $marc_record_object->field(100)->subfield('a'),
 666                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 667             };
 668         }
 669         push @sup_results_array, {  servername => $server,
 670                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 671     }
 672     # FIXME: can add support for other targets as needed here
 673     $template->param(           outer_sup_results_loop => \@sup_results_array);
 674 } #/end of the for loop
 675 #$template->param(FEDERATED_RESULTS => \@results_array);
 676
 677 my $gotonumber = $cgi->param('gotoNumber');
 678 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 679     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 680 }
 681 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 682 my $gotopage = $cgi->param('gotoPage');
 683 $template->{'VARS'}->{'gotoPage'} = $gotopage
 684   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 685
 686 for my $facet ( @$facets ) {
 687     for my $entry ( @{ $facet->{facets} } ) {
 688         my $index = $entry->{type_link_value};
 689         my $value = $entry->{facet_link_value};
 690         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 691     }
 692 }
 693
 694 $template->param(
 695             #classlist => $classlist,
 696             total => $total,
 697             opacfacets => 1,
 698             facets_loop => $facets,
 699             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 700             scan => $scan,
 701             search_error => $error,
 702 );
 703
 704 if ($query_desc || $limit_desc) {
 705     $template->param(searchdesc => 1);
 706 }
 707
 708 # VI. BUILD THE TEMPLATE
 709
 710 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 711     {
 712         borrowernumber => $borrowernumber,
 713         add_allowed    => 1,
 714         public         => 0,
 715     }
 716 );
 717 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 718     {
 719         borrowernumber => $borrowernumber,
 720         add_allowed    => 1,
 721         public         => 1,
 722     }
 723 );
 724
 725
 726 $template->param(
 727     add_to_some_private_shelves => $some_private_shelves,
 728     add_to_some_public_shelves  => $some_public_shelves,
 729 );
 730
 731 output_html_with_http_headers $cgi, $cookie, $template->output;
 732
 733
 734 =head2 prepare_adv_search_types
 735
 736     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 737     my @advanced_search_types = prepare_adv_search_types($type);
 738
 739 Different types can be searched for in the advanced search. This takes the
 740 system preference that defines these types and parses it into an arrayref for
 741 the template.
 742
 743 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 744 It also accounts for the "item-level_itypes" system preference.
 745
 746 =cut
 747
 748 sub prepare_adv_search_types {
 749     my ($types) = @_;
 750
 751     my @advanced_search_types = split( /\|/, $types );
 752
 753     # the index parameter is different for item-level itemtypes
 754     my $itype_or_itemtype =
 755       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 756     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 757
 758     my ( $cnt, @result );
 759     foreach my $advanced_srch_type (@advanced_search_types) {
 760         $advanced_srch_type =~ s/^\s*//;
 761         $advanced_srch_type =~ s/\s*$//;
 762         if ( $advanced_srch_type eq 'itemtypes' ) {
 763
 764        # itemtype is a special case, since it's not defined in authorized values
 765             my @itypesloop;
 766             foreach my $thisitemtype (
 767                 sort {
 768                     $itemtypes->{$a}->{'translated_description'}
 769                       cmp $itemtypes->{$b}->{'translated_description'}
 770                 } keys %$itemtypes
 771               )
 772             {
 773                 my %row = (
 774                     number      => $cnt++,
 775                     ccl         => "$itype_or_itemtype,phr",
 776                     code        => $thisitemtype,
 777                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 778                     imageurl    => getitemtypeimagelocation(
 779                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 780                     ),
 781                 );
 782                 push @itypesloop, \%row;
 783             }
 784             my %search_code = (
 785                 advanced_search_type => $advanced_srch_type,
 786                 code_loop            => \@itypesloop
 787             );
 788             push @result, \%search_code;
 789         }
 790         else {
 791             # covers all the other cases: non-itemtype authorized values
 792             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 793             my @authvalueloop;
 794             for my $thisitemtype (@$advsearchtypes) {
 795                 my %row = (
 796                     number      => $cnt++,
 797                     ccl         => $advanced_srch_type,
 798                     code        => $thisitemtype->{authorised_value},
 799                     description => $thisitemtype->{'lib'},
 800                     imageurl    => getitemtypeimagelocation(
 801                         'intranet', $thisitemtype->{'imageurl'}
 802                     ),
 803                 );
 804                 push @authvalueloop, \%row;
 805             }
 806             my %search_code = (
 807                 advanced_search_type => $advanced_srch_type,
 808                 code_loop            => \@authvalueloop
 809             );
 810             push @result, \%search_code;
 811         }
 812     }
 813     return \@result;
 814 }