koha-dev.rot13.org Git - srvgit/blob - catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output;
 144 use C4::Auth qw(:DEFAULT get_session);
 145 use C4::Search;
 146 use C4::Languages qw(getLanguages);
 147 use C4::Koha;
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search::History;
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158 use Koha::SearchFields;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = CGI->new;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 my @params = $cgi->multi_param("limit");
 172 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 173     $template_name = 'catalogue/results.tt';
 174     $template_type = 'results';
 175 }
 176 else {
 177     $template_name = 'catalogue/advsearch.tt';
 178     $template_type = 'advsearch';
 179 }
 180 # load the template
 181 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 182     template_name => $template_name,
 183     query => $cgi,
 184     type => "intranet",
 185     flagsrequired   => { catalogue => 1 },
 186     }
 187 );
 188
 189 my $lang = C4::Languages::getlanguage($cgi);
 190
 191 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 192     $template->param('UNIMARC' => 1);
 193 }
 194
 195 if($cgi->cookie("holdfor")){
 196     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 197     if ( $holdfor_patron ) { # may have been deleted in the meanwhile
 198         $template->param(
 199             holdfor => $cgi->cookie("holdfor"),
 200             holdfor_surname => $holdfor_patron->surname,
 201             holdfor_firstname => $holdfor_patron->firstname,
 202             holdfor_cardnumber => $holdfor_patron->cardnumber,
 203         );
 204     }
 205 }
 206
 207 if($cgi->cookie("holdforclub")){
 208     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 209     if ( $holdfor_club ) { # May have been deleted in the meanwhile
 210         $template->param(
 211             holdforclub => $cgi->cookie("holdforclub"),
 212             holdforclub_name => $holdfor_club->name,
 213         );
 214     }
 215 }
 216
 217 if($cgi->cookie("searchToOrder")){
 218     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 219     $template->param(
 220         searchtoorder_basketno => $basketno,
 221         searchtoorder_vendorid => $vendorid
 222     );
 223 }
 224
 225 # get biblionumbers stored in the cart
 226 my @cart_list;
 227
 228 if($cgi->cookie("intranet_bib_list")){
 229     my $cart_list = $cgi->cookie("intranet_bib_list");
 230     @cart_list = split(/\//, $cart_list);
 231 }
 232
 233 my @search_groups =
 234   Koha::Library::Groups->get_search_groups( { interface => 'staff' } );
 235 @search_groups = sort { $a->title cmp $b->title } @search_groups;
 236
 237 $template->param(
 238     selected_branchcode => ( C4::Context->IsSuperLibrarian ? C4::Context->userenv : '' ),
 239     search_groups    => \@search_groups,
 240 );
 241
 242 # load the Type stuff
 243 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 244 my $advancedsearchesloop = prepare_adv_search_types($types);
 245 $template->param(advancedsearchesloop => $advancedsearchesloop);
 246
 247 $template->param( searchid => scalar $cgi->param('searchid'), );
 248
 249 # The following should only be loaded if we're bringing up the advanced search template
 250 if ( $template_type eq 'advsearch' ) {
 251
 252     # load the servers (used for searching -- to do federated searching, etc.)
 253     my $primary_servers_loop;# = displayPrimaryServers();
 254     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 255
 256     my $secondary_servers_loop;
 257     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 258
 259     # set the default sorting
 260     if (   C4::Context->preference('defaultSortField')
 261         && C4::Context->preference('defaultSortOrder') ) {
 262         my $default_sort_by =
 263             C4::Context->preference('defaultSortField') . '_'
 264           . C4::Context->preference('defaultSortOrder');
 265         $template->param( sort_by => $default_sort_by  );
 266     }
 267
 268     # determine what to display next to the search boxes (ie, boolean option
 269     # shouldn't appear on the first one, scan indexes should, adding a new
 270     # box should only appear on the last, etc.
 271     my @search_boxes_array;
 272     my $search_boxes_count = 3; # begin with 3 boxes
 273     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 274     for (my $i=1;$i<=$search_boxes_count;$i++) {
 275         # if it's the first one, don't display boolean option, but show scan indexes
 276         if ($i==1) {
 277             push @search_boxes_array, {scan_index => 1};
 278         }
 279         # if it's the last one, show the 'add field' box
 280         elsif ($i==$search_boxes_count) {
 281             push @search_boxes_array,
 282                 {
 283                 boolean => 1,
 284                 add_field => 1,
 285                 };
 286         }
 287         else {
 288             push @search_boxes_array,
 289                 {
 290                 boolean => 1,
 291                 };
 292         }
 293
 294     }
 295     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 296                       search_boxes_loop => \@search_boxes_array);
 297
 298     # load the language limits (for search)
 299     my $languages_limit_loop = getLanguages($lang, 1);
 300     $template->param(search_languages_loop => $languages_limit_loop,);
 301
 302     # Expanded search options in advanced search:
 303     # use the global setting by default, but let the user override it
 304     {
 305         my $expanded = $cgi->param('expanded_options');
 306         $expanded = C4::Context->preference("expandedSearchOption") || 0
 307             if !defined($expanded) || $expanded !~ /^0|1$/;
 308         $template->param( expanded_options => $expanded );
 309     }
 310
 311     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 312
 313     output_html_with_http_headers $cgi, $cookie, $template->output;
 314     exit;
 315 }
 316
 317 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 318
 319 # Fetch the paramater list as a hash in scalar context:
 320 #  * returns paramater list as tied hash ref
 321 #  * we can edit the values by changing the key
 322 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 323 my $params = $cgi->Vars;
 324 # Params that can have more than one value
 325 # sort by is used to sort the query
 326 # in theory can have more than one but generally there's just one
 327 my @sort_by;
 328 my $default_sort_by;
 329 if (   C4::Context->preference('defaultSortField')
 330     && C4::Context->preference('defaultSortOrder') ) {
 331     $default_sort_by =
 332         C4::Context->preference('defaultSortField') . '_'
 333       . C4::Context->preference('defaultSortOrder');
 334 }
 335
 336 @sort_by = $cgi->multi_param('sort_by');
 337 $sort_by[0] = $default_sort_by unless $sort_by[0];
 338 foreach my $sort (@sort_by) {
 339     $template->param($sort => 1) if $sort;
 340 }
 341 $template->param('sort_by' => $sort_by[0]);
 342
 343 # Use the servers defined, or just search our local catalog(default)
 344 my @servers = $cgi->multi_param('server');
 345 unless (@servers) {
 346     #FIXME: this should be handled using Context.pm
 347     @servers = ("biblioserver");
 348     # @servers = C4::Context->config("biblioserver");
 349 }
 350 # operators include boolean and proximity operators and are used
 351 # to evaluate multiple operands
 352 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 353
 354 # indexes are query qualifiers, like 'title', 'author', etc. They
 355 # can be single or multiple parameters separated by comma: kw,right-Truncation
 356 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 357
 358 # if a simple index (only one)  display the index used in the top search box
 359 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 360     my $idx = "ms_".$indexes[0];
 361     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 362     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 363     $template->param($idx => 1);
 364 }
 365
 366 # an operand can be a single term, a phrase, or a complete ccl query
 367 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 368
 369 # if a simple search, display the value in the search box
 370 if ($operands[0] && !$operands[1]) {
 371     my $ms_query = $operands[0];
 372     $ms_query =~ s/ #\S+//;
 373     $template->param(ms_value => $ms_query);
 374 }
 375
 376 # limits are use to limit to results to a pre-defined category such as branch or language
 377 my @limits = map uri_unescape($_), $cgi->multi_param('limit');
 378 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 379 my %is_nolimit = map { $_ => 1 } @nolimits;
 380 @limits = grep { not $is_nolimit{$_} } @limits;
 381
 382 if ( $params->{'multibranchlimit'} ) {
 383     my $branchfield  = C4::Context->preference('SearchLimitLibrary');
 384     my $search_group = Koha::Library::Groups->find( $params->{multibranchlimit} );
 385     my @branchcodes  = map { $_->branchcode } $search_group->all_libraries;
 386
 387     if (@branchcodes) {
 388         if ( $branchfield eq "homebranch" ) {
 389             push @limits, sprintf "(%s)", join " or ", map { 'homebranch: ' . $_ } @branchcodes;
 390         }
 391         elsif ( $branchfield eq "holdingbranch" ) {
 392             push @limits, sprintf "(%s)", join " or ", map { 'holdingbranch: ' . $_ } @branchcodes;
 393         }
 394         else {
 395             push @limits, sprintf "(%s or %s)",
 396               join( " or ", map { 'homebranch: ' . $_ } @branchcodes ),
 397               join( " or ", map { 'holdingbranch: ' . $_ } @branchcodes );
 398         }
 399     }
 400 }
 401
 402 my $available;
 403 foreach my $limit(@limits) {
 404     if ($limit =~/available/) {
 405         $available = 1;
 406     }
 407 }
 408 $template->param(available => $available);
 409
 410 # append year limits if they exist
 411 my $limit_yr;
 412 my $limit_yr_value;
 413 if ($params->{'limit-yr'}) {
 414     if ($params->{'limit-yr'} =~ /\d{4}/) {
 415         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 416         $limit_yr_value = $params->{'limit-yr'};
 417     }
 418     push @limits,$limit_yr;
 419     #FIXME: Should return a error to the user, incorect date format specified
 420 }
 421
 422 # convert indexes and operands to corresponding parameter names for the z3950 search
 423 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 424 my $z3950par;
 425 my $indexes2z3950 = {
 426     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 427     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 428     ti=>'title', 'ti,phr'=>'title', se=>'title'
 429 };
 430 for (my $ii = 0; $ii < @operands; ++$ii)
 431 {
 432     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 433     if (defined $name && defined $operands[$ii])
 434     {
 435         $z3950par ||= {};
 436         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 437     }
 438 }
 439
 440
 441 # Params that can only have one value
 442 my $scan = $params->{'scan'};
 443 my $count = C4::Context->preference('numSearchResults') || 20;
 444 my $results_per_page = $params->{'count'} || $count;
 445 my $offset = $params->{'offset'} || 0;
 446 my $whole_record = $params->{'whole_record'} || 0;
 447 my $weight_search = $params->{'advsearch'} ? $params->{'weight_search'} || 0 : 1;
 448 $offset = 0 if $offset < 0;
 449 my $page = $cgi->param('page') || 1;
 450 #my $offset = ($page-1)*$results_per_page;
 451
 452 # Define some global variables
 453 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 454
 455 my $builder = Koha::SearchEngine::QueryBuilder->new(
 456     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 457 my $searcher = Koha::SearchEngine::Search->new(
 458     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 459
 460 ## I. BUILD THE QUERY
 461 (
 462     $error,             $query, $simple_query, $query_cgi,
 463     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 464     $query_type
 465   )
 466   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 467     \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 468
 469 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 470
 471 ## parse the query_cgi string and put it into a form suitable for <input>s
 472 my @query_inputs;
 473 my $scan_index_to_use;
 474 my $scan_search_term_to_use;
 475
 476 if ($query_cgi) {
 477     for my $this_cgi ( split('&', $query_cgi) ) {
 478         next unless $this_cgi;
 479         $this_cgi =~ m/(.*?)=(.*)/;
 480         my $input_name = $1;
 481         my $input_value = $2;
 482         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 483         if ($input_name eq 'idx') {
 484             # The form contains multiple fields, so take the first value as the scan index
 485             $scan_index_to_use = $input_value unless $scan_index_to_use;
 486         }
 487         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 488             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 489         }
 490     }
 491 }
 492
 493 $template->param ( QUERY_INPUTS => \@query_inputs,
 494                    scan_index_to_use => $scan_index_to_use,
 495                    scan_search_term_to_use => $scan_search_term_to_use );
 496
 497 ## parse the limit_cgi string and put it into a form suitable for <input>s
 498 my @limit_inputs;
 499 if ($limit_cgi) {
 500     for my $this_cgi ( split('&', $limit_cgi) ) {
 501         next unless $this_cgi;
 502         # handle special case limit-yr
 503         if ($this_cgi =~ /yr,st-numeric/) {
 504             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 505             next;
 506         }
 507         $this_cgi =~ m/(.*=)(.*)/;
 508         my $input_name = $1;
 509         my $input_value = $2;
 510         $input_name =~ s/=$//;
 511         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 512     }
 513 }
 514 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 515
 516 ## II. DO THE SEARCH AND GET THE RESULTS
 517 my $total = 0; # the total results for the whole set
 518 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 519 my $results_hashref;
 520
 521 eval {
 522     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 523     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 524         $query,            $simple_query, \@sort_by,       \@servers,
 525         $results_per_page, $offset,       undef,           $itemtypes,
 526         $query_type,       $scan
 527     );
 528 };
 529
 530 if ($@ || $error) {
 531     $template->param(query_error => $error.$@);
 532     output_html_with_http_headers $cgi, $cookie, $template->output;
 533     exit;
 534 }
 535
 536 # At this point, each server has given us a result set
 537 # now we build that set for template display
 538 my @sup_results_array;
 539 for (my $i=0;$i<@servers;$i++) {
 540     my $server = $servers[$i];
 541     if ($server =~/biblioserver/) { # this is the local bibliographic server
 542         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 543         my $page = $cgi->param('page') || 0;
 544         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 545                                        $results_hashref->{$server}->{"RECORDS"});
 546         $total = $total + $hits;
 547
 548         # Search history
 549         if (C4::Context->preference('EnableSearchHistory')) {
 550             unless ( $offset ) {
 551                 my $path_info = $cgi->url(-path_info=>1);
 552                 my $query_cgi_history = $cgi->url(-query=>1);
 553                 $query_cgi_history =~ s/^$path_info\?//;
 554                 $query_cgi_history =~ s/;/&/g;
 555                 my $query_desc_history = $query_desc;
 556                 $query_desc_history .= ", $limit_desc"
 557                     if $limit_desc;
 558
 559                 C4::Search::History::add({
 560                     userid => $borrowernumber,
 561                     sessionid => $cgi->cookie("CGISESSID"),
 562                     query_desc => $query_desc_history,
 563                     query_cgi => $query_cgi_history,
 564                     total => $total,
 565                     type => "biblio",
 566                 });
 567             }
 568             $template->param( EnableSearchHistory => 1 );
 569         }
 570
 571         ## If there's just one result, redirect to the detail page unless doing an index scan
 572         if ($total == 1 && !$scan) {
 573             my $biblionumber = $newresults[0]->{biblionumber};
 574             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 575             my $views = { C4::Search::enabled_staff_search_views };
 576             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 577                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&found1=1");
 578             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 579                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&found1=1");
 580             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 581                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&found1=1");
 582             } else {
 583                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&found1=1");
 584             }
 585             exit;
 586         }
 587
 588         # set up parameters if user wishes to re-run the search
 589         # as a Z39.50 search
 590         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 591
 592         if ($hits) {
 593             $template->param(total => $hits);
 594             if ($limit_cgi) {
 595                 my $limit_cgi_not_availablity = $limit_cgi;
 596                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 597                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 598             }
 599             $template->param(limit_cgi => $limit_cgi);
 600             $template->param(query_cgi => $query_cgi);
 601             $template->param(query_desc => $query_desc);
 602             $template->param(limit_desc => $limit_desc);
 603             $template->param(offset     => $offset);
 604             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 605             if ($query_desc || $limit_desc) {
 606                 $template->param(searchdesc => 1);
 607             }
 608             $template->param(results_per_page =>  $results_per_page);
 609             # must define a value for size if not present in DB
 610             # in order to avoid problems generated by the default size value in TT
 611             foreach my $line (@newresults) {
 612                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 613                 # while we're checking each line, see if item is in the cart
 614                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 615                     $line->{'incart'} = 1;
 616                 }
 617             }
 618             my( $page_numbers, $hits_to_paginate, $pages, $current_page_number, $previous_page_offset, $next_page_offset, $last_page_offset ) =
 619                 Koha::SearchEngine::Search->pagination_bar(
 620                     {
 621                         hits              => $hits,
 622                         max_result_window => $searcher->max_result_window,
 623                         results_per_page  => $results_per_page,
 624                         offset            => $offset,
 625                         sort_by           => \@sort_by
 626                     }
 627                 );
 628             $template->param( hits_to_paginate => $hits_to_paginate );
 629             $template->param(SEARCH_RESULTS => \@newresults);
 630             # FIXME: no previous_page_offset when pages < 2
 631             $template->param(   PAGE_NUMBERS => $page_numbers,
 632                                 last_page_offset => $last_page_offset,
 633                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 634             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 635         }
 636
 637
 638         # no hits
 639         else {
 640             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 641         }
 642
 643     } # end of the if local
 644
 645     # asynchronously search the authority server
 646     elsif ($server =~/authorityserver/) { # this is the local authority server
 647         my @inner_sup_results_array;
 648         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 649             my $marc_record_object = C4::Search::new_record_from_zebra(
 650                 'authorityserver',
 651                 $sup_record
 652             );
 653             # warn "Authority Found: ".$marc_record_object->as_formatted();
 654             push @inner_sup_results_array, {
 655                 'title' => $marc_record_object->field(100)->subfield('a'),
 656                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 657             };
 658         }
 659         push @sup_results_array, {  servername => $server,
 660                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 661     }
 662     # FIXME: can add support for other targets as needed here
 663     $template->param(           outer_sup_results_loop => \@sup_results_array);
 664 } #/end of the for loop
 665 #$template->param(FEDERATED_RESULTS => \@results_array);
 666
 667 my $gotonumber = $cgi->param('gotoNumber');
 668 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 669     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 670 }
 671 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 672 my $gotopage = $cgi->param('gotoPage');
 673 $template->{'VARS'}->{'gotoPage'} = $gotopage
 674   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 675
 676 for my $facet ( @$facets ) {
 677     for my $entry ( @{ $facet->{facets} } ) {
 678         my $index = $entry->{type_link_value};
 679         my $value = $entry->{facet_link_value};
 680         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 681     }
 682 }
 683
 684 $template->param(
 685             #classlist => $classlist,
 686             total => $total,
 687             opacfacets => 1,
 688             facets_loop => $facets,
 689             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 690             scan => $scan,
 691             search_error => $error,
 692 );
 693
 694 if ($query_desc || $limit_desc) {
 695     $template->param(searchdesc => 1);
 696 }
 697
 698 # VI. BUILD THE TEMPLATE
 699
 700 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 701     {
 702         borrowernumber => $borrowernumber,
 703         add_allowed    => 1,
 704         category       => 1,
 705     }
 706 );
 707 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 708     {
 709         borrowernumber => $borrowernumber,
 710         add_allowed    => 1,
 711         category       => 2,
 712     }
 713 );
 714
 715
 716 $template->param(
 717     add_to_some_private_shelves => $some_private_shelves,
 718     add_to_some_public_shelves  => $some_public_shelves,
 719 );
 720
 721 output_html_with_http_headers $cgi, $cookie, $template->output;
 722
 723
 724 =head2 prepare_adv_search_types
 725
 726     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 727     my @advanced_search_types = prepare_adv_search_types($type);
 728
 729 Different types can be searched for in the advanced search. This takes the
 730 system preference that defines these types and parses it into an arrayref for
 731 the template.
 732
 733 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 734 It also accounts for the "item-level_itypes" system preference.
 735
 736 =cut
 737
 738 sub prepare_adv_search_types {
 739     my ($types) = @_;
 740
 741     my @advanced_search_types = split( /\|/, $types );
 742
 743     # the index parameter is different for item-level itemtypes
 744     my $itype_or_itemtype =
 745       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 746     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 747
 748     my ( $cnt, @result );
 749     foreach my $advanced_srch_type (@advanced_search_types) {
 750         $advanced_srch_type =~ s/^\s*//;
 751         $advanced_srch_type =~ s/\s*$//;
 752         if ( $advanced_srch_type eq 'itemtypes' ) {
 753
 754        # itemtype is a special case, since it's not defined in authorized values
 755             my @itypesloop;
 756             foreach my $thisitemtype (
 757                 sort {
 758                     $itemtypes->{$a}->{'translated_description'}
 759                       cmp $itemtypes->{$b}->{'translated_description'}
 760                 } keys %$itemtypes
 761               )
 762             {
 763                 my %row = (
 764                     number      => $cnt++,
 765                     ccl         => "$itype_or_itemtype,phr",
 766                     code        => $thisitemtype,
 767                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 768                     imageurl    => getitemtypeimagelocation(
 769                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 770                     ),
 771                 );
 772                 push @itypesloop, \%row;
 773             }
 774             my %search_code = (
 775                 advanced_search_type => $advanced_srch_type,
 776                 code_loop            => \@itypesloop
 777             );
 778             push @result, \%search_code;
 779         }
 780         else {
 781             # covers all the other cases: non-itemtype authorized values
 782             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 783             my @authvalueloop;
 784             for my $thisitemtype (@$advsearchtypes) {
 785                 my %row = (
 786                     number      => $cnt++,
 787                     ccl         => $advanced_srch_type,
 788                     code        => $thisitemtype->{authorised_value},
 789                     description => $thisitemtype->{'lib'},
 790                     imageurl    => getitemtypeimagelocation(
 791                         'intranet', $thisitemtype->{'imageurl'}
 792                     ),
 793                 );
 794                 push @authvalueloop, \%row;
 795             }
 796             my %search_code = (
 797                 advanced_search_type => $advanced_srch_type,
 798                 code_loop            => \@authvalueloop
 799             );
 800             push @result, \%search_code;
 801         }
 802     }
 803     return \@result;
 804 }