koha-dev.rot13.org Git - srvgit/blob - catalogue/detail.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18
  19 use Modern::Perl;
  20
  21 use CGI qw ( -utf8 );
  22 use HTML::Entities;
  23 use C4::Auth qw( get_template_and_user );
  24 use C4::Context;
  25 use C4::Koha qw(
  26     GetAuthorisedValues
  27     getitemtypeimagelocation
  28     GetNormalizedEAN
  29     GetNormalizedISBN
  30     GetNormalizedOCLCNumber
  31     GetNormalizedUPC
  32 );
  33 use C4::Serials qw( CountSubscriptionFromBiblionumber SearchSubscriptions GetLatestSerials );
  34 use C4::Output qw( output_html_with_http_headers );
  35 use C4::Biblio qw( GetBiblioData GetFrameworkCode GetMarcBiblio );
  36 use C4::Items qw( GetAnalyticsCount GetHostItemsInfo GetItemsInfo );
  37 use C4::Circulation qw( GetTransfers );
  38 use C4::Reserves;
  39 use C4::Serials qw( CountSubscriptionFromBiblionumber SearchSubscriptions GetLatestSerials );
  40 use C4::XISBN qw( get_xisbns );
  41 use C4::External::Amazon qw( get_amazon_tld );
  42 use C4::Search qw( z3950_search_args enabled_staff_search_views new_record_from_zebra );
  43 use C4::Tags qw( get_tags );
  44 use C4::XSLT qw( XSLTParse4Display );
  45 use Koha::DateUtils qw( format_sqldatetime );
  46 use C4::HTML5Media;
  47 use C4::CourseReserves qw( GetItemCourseReservesInfo );
  48 use Koha::AuthorisedValues;
  49 use Koha::Biblios;
  50 use Koha::CoverImages;
  51 use Koha::Illrequests;
  52 use Koha::Items;
  53 use Koha::ItemTypes;
  54 use Koha::Patrons;
  55 use Koha::Virtualshelves;
  56 use Koha::Plugins;
  57 use Koha::Recalls;
  58 use Koha::SearchEngine::Search;
  59 use Koha::SearchEngine::QueryBuilder;
  60
  61 my $query = CGI->new();
  62
  63 my $analyze = $query->param('analyze');
  64
  65 my ( $template, $borrowernumber, $cookie, $flags ) = get_template_and_user(
  66     {
  67     template_name   =>  'catalogue/detail.tt',
  68         query           => $query,
  69         type            => "intranet",
  70         flagsrequired   => { catalogue => 1 },
  71     }
  72 );
  73
  74 # Determine if we should be offering any enhancement plugin buttons
  75 if ( C4::Context->config('enable_plugins') ) {
  76     # Only pass plugins that can offer a toolbar button
  77     my @plugins = Koha::Plugins->new()->GetPlugins({
  78         method => 'intranet_catalog_biblio_enhancements_toolbar_button'
  79     });
  80     $template->param(
  81         plugins => \@plugins,
  82     );
  83 }
  84
  85 my $biblionumber = $query->param('biblionumber');
  86 $biblionumber = HTML::Entities::encode($biblionumber);
  87 my $record       = GetMarcBiblio({ biblionumber => $biblionumber });
  88 my $biblio = Koha::Biblios->find( $biblionumber );
  89 $template->param( 'biblio', $biblio );
  90
  91 if ( not defined $record ) {
  92     # biblionumber invalid -> report and exit
  93     $template->param( unknownbiblionumber => 1,
  94                       biblionumber => $biblionumber );
  95     output_html_with_http_headers $query, $cookie, $template->output;
  96     exit;
  97 }
  98
  99 my $marc_record = eval { $biblio->metadata->record };
 100 $template->param( decoding_error => $@ );
 101
 102 if($query->cookie("holdfor")){
 103     my $holdfor_patron = Koha::Patrons->find( $query->cookie("holdfor") );
 104     if ( $holdfor_patron ) {
 105         $template->param(
 106             # FIXME Should pass the patron object
 107             holdfor => $query->cookie("holdfor"),
 108             holdfor_surname => $holdfor_patron->surname,
 109             holdfor_firstname => $holdfor_patron->firstname,
 110             holdfor_cardnumber => $holdfor_patron->cardnumber,
 111         );
 112     }
 113 }
 114
 115 if($query->cookie("searchToOrder")){
 116     my ( $basketno, $vendorid ) = split( /\//, $query->cookie("searchToOrder") );
 117     $template->param(
 118         searchtoorder_basketno => $basketno,
 119         searchtoorder_vendorid => $vendorid
 120     );
 121 }
 122
 123 my $fw           = GetFrameworkCode($biblionumber);
 124 my $showallitems = $query->param('showallitems');
 125 my $marcflavour  = C4::Context->preference("marcflavour");
 126
 127 $template->param( 'SpineLabelShowPrintOnBibDetails' => C4::Context->preference("SpineLabelShowPrintOnBibDetails") );
 128
 129 # Catch the exception as Koha::Biblio::Metadata->record can explode if the MARCXML is invalid
 130 # Do not propagate it as we already deal with it previously in this script
 131 my $coins = eval { $biblio->get_coins };
 132 $template->param( ocoins => $coins );
 133
 134 # some useful variables for enhanced content;
 135 # in each case, we're grabbing the first value we find in
 136 # the record and normalizing it
 137 my $upc = GetNormalizedUPC($record,$marcflavour);
 138 my $ean = GetNormalizedEAN($record,$marcflavour);
 139 my $oclc = GetNormalizedOCLCNumber($record,$marcflavour);
 140 my $isbn = GetNormalizedISBN(undef,$record,$marcflavour);
 141 my $content_identifier_exists;
 142 if ( $isbn or $ean or $oclc or $upc ) {
 143     $content_identifier_exists = 1;
 144 }
 145
 146 $template->param(
 147     normalized_upc => $upc,
 148     normalized_ean => $ean,
 149     normalized_oclc => $oclc,
 150     normalized_isbn => $isbn,
 151     content_identifier_exists =>  $content_identifier_exists,
 152 );
 153
 154 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search->unblessed } };
 155
 156 my $dbh = C4::Context->dbh;
 157
 158 my @all_items = GetItemsInfo( $biblionumber );
 159 my @items;
 160 my $patron = Koha::Patrons->find( $borrowernumber );
 161 for my $itm (@all_items) {
 162     push @items, $itm unless ( $itm->{itemlost} && $patron->category->hidelostitems && !$showallitems);
 163 }
 164
 165 # flag indicating existence of at least one item linked via a host record
 166 my $hostrecords;
 167 # adding items linked via host biblios
 168 my @hostitems = GetHostItemsInfo($record);
 169 if (@hostitems){
 170     $hostrecords =1;
 171     push (@items,@hostitems);
 172 }
 173
 174 my $dat = &GetBiblioData($biblionumber);
 175
 176 #coping with subscriptions
 177 my $subscriptionsnumber = CountSubscriptionFromBiblionumber($biblionumber);
 178 my @subscriptions       = SearchSubscriptions({ biblionumber => $biblionumber, orderby => 'title' });
 179 my @subs;
 180
 181 foreach my $subscription (@subscriptions) {
 182     my %cell;
 183     my $serials_to_display;
 184     $cell{subscriptionid}    = $subscription->{subscriptionid};
 185     $cell{subscriptionnotes} = $subscription->{internalnotes};
 186     $cell{missinglist}       = $subscription->{missinglist};
 187     $cell{librariannote}     = $subscription->{librariannote};
 188     $cell{branchcode}        = $subscription->{branchcode};
 189     $cell{hasalert}          = $subscription->{hasalert};
 190     $cell{callnumber}        = $subscription->{callnumber};
 191     $cell{location}          = $subscription->{location};
 192     $cell{closed}            = $subscription->{closed};
 193     #get the three latest serials.
 194     $serials_to_display = $subscription->{staffdisplaycount};
 195     $serials_to_display = C4::Context->preference('StaffSerialIssueDisplayCount') unless $serials_to_display;
 196     $cell{staffdisplaycount} = $serials_to_display;
 197     $cell{latestserials} =
 198       GetLatestSerials( $subscription->{subscriptionid}, $serials_to_display );
 199     push @subs, \%cell;
 200 }
 201
 202 # Get component parts details
 203 my $showcomp = C4::Context->preference('ShowComponentRecords');
 204 my $show_analytics;
 205 if ( $showcomp eq 'both' || $showcomp eq 'staff' ) {
 206     if ( my $components = $marc_record ? $biblio->get_marc_components(C4::Context->preference('MaxComponentRecords')) : undef ) {
 207         $show_analytics = 1 if @{$components}; # just show link when having results
 208         $template->param( analytics_error => 1 ) if grep { $_->message eq 'component_search' } @{$biblio->object_messages};
 209         my $parts;
 210         for my $part ( @{$components} ) {
 211             $part = C4::Search::new_record_from_zebra( 'biblioserver', $part );
 212             my $id = Koha::SearchEngine::Search::extract_biblionumber( $part );
 213
 214             push @{$parts},
 215               XSLTParse4Display(
 216                 {
 217                     biblionumber => $id,
 218                     record       => $part,
 219                     xsl_syspref  => "XSLTResultsDisplay",
 220                     fix_amps     => 1,
 221                 }
 222               );
 223         }
 224         $template->param( ComponentParts => $parts );
 225         $template->param( ComponentPartsQuery => $biblio->get_components_query );
 226     }
 227 } else { # check if we should show analytics anyway
 228     $show_analytics = 1 if $marc_record && @{$biblio->get_marc_components(1)}; # count matters here, results does not
 229     $template->param( analytics_error => 1 ) if grep { $_->message eq 'component_search' } @{$biblio->object_messages};
 230 }
 231
 232 # XSLT processing of some stuff
 233 my $xslt_variables = { show_analytics_link => $show_analytics };
 234 $template->param(
 235     XSLTDetailsDisplay => '1',
 236     XSLTBloc => XSLTParse4Display({
 237         biblionumber   => $biblionumber,
 238         record         => $record,
 239         xsl_syspref    => "XSLTDetailsDisplay",
 240         fix_amps       => 1,
 241         xslt_variables => $xslt_variables,
 242     }),
 243 );
 244
 245 # Get acquisition details
 246 if ( C4::Context->preference('AcquisitionDetails') ) {
 247     my $orders = Koha::Acquisition::Orders->search(
 248         { biblionumber => $biblionumber },
 249         {
 250             join => 'basketno',
 251             order_by => 'basketno.booksellerid'
 252         }
 253     );    # GetHistory sorted by aqbooksellerid, but does it make sense?
 254
 255     $template->param(
 256         orders => $orders,
 257     );
 258 }
 259
 260 if ( C4::Context->preference('suggestion') ) {
 261     my $suggestions = Koha::Suggestions->search(
 262         {
 263             biblionumber => $biblionumber,
 264             archived     => 0,
 265         },
 266         {
 267             order_by => { -desc => 'suggesteddate' }
 268         }
 269     );
 270     my $nb_archived_suggestions = Koha::Suggestions->search({ biblionumber => $biblionumber, archived => 1 })->count;
 271     $template->param( suggestions => $suggestions, nb_archived_suggestions => $nb_archived_suggestions );
 272 }
 273
 274 if ( defined $dat->{'itemtype'} ) {
 275     $dat->{imageurl} = getitemtypeimagelocation( 'intranet', $itemtypes->{ $dat->{itemtype} }{imageurl} );
 276 }
 277
 278 $dat->{'count'} = scalar @all_items + @hostitems;
 279 $dat->{'showncount'} = scalar @items + @hostitems;
 280 $dat->{'hiddencount'} = scalar @all_items + @hostitems - scalar @items;
 281
 282 my $shelflocations =
 283   { map { $_->{authorised_value} => $_->{lib} } Koha::AuthorisedValues->get_descriptions_by_koha_field( { frameworkcode => $fw, kohafield => 'items.location' } ) };
 284 my $collections =
 285   { map { $_->{authorised_value} => $_->{lib} } Koha::AuthorisedValues->get_descriptions_by_koha_field( { frameworkcode => $fw, kohafield => 'items.ccode' } ) };
 286 my $copynumbers =
 287   { map { $_->{authorised_value} => $_->{lib} } Koha::AuthorisedValues->get_descriptions_by_koha_field( { frameworkcode => $fw, kohafield => 'items.copynumber' } ) };
 288 my (@itemloop, @otheritemloop, %itemfields);
 289
 290 my $mss = Koha::MarcSubfieldStructures->search({ frameworkcode => $fw, kohafield => 'items.itemlost', authorised_value => [ -and => {'!=' => undef }, {'!=' => ''}] });
 291 if ( $mss->count ) {
 292     $template->param( itemlostloop => GetAuthorisedValues( $mss->next->authorised_value ) );
 293 }
 294 $mss = Koha::MarcSubfieldStructures->search({ frameworkcode => $fw, kohafield => 'items.damaged', authorised_value => [ -and => {'!=' => undef }, {'!=' => ''}] });
 295 if ( $mss->count ) {
 296     $template->param( itemdamagedloop => GetAuthorisedValues( $mss->next->authorised_value ) );
 297 }
 298 $mss = Koha::MarcSubfieldStructures->search({ frameworkcode => $fw, kohafield => 'items.withdrawn', authorised_value => { not => undef } });
 299 if ( $mss->count ) {
 300     $template->param( itemwithdrawnloop => GetAuthorisedValues( $mss->next->authorised_value) );
 301 }
 302
 303 $mss = Koha::MarcSubfieldStructures->search({ frameworkcode => $fw, kohafield => 'items.materials', authorised_value => [ -and => {'!=' => undef }, {'!=' => ''}] });
 304 my %materials_map;
 305 if ($mss->count) {
 306     my $materials_authvals = GetAuthorisedValues($mss->next->authorised_value);
 307     if ($materials_authvals) {
 308         foreach my $value (@$materials_authvals) {
 309             $materials_map{$value->{authorised_value}} = $value->{lib};
 310         }
 311     }
 312 }
 313
 314 my $analytics_flag;
 315 my $materials_flag; # set this if the items have anything in the materials field
 316 my $currentbranch = C4::Context->userenv ? C4::Context->userenv->{branch} : undef;
 317 if ($currentbranch and C4::Context->preference('SeparateHoldings')) {
 318     $template->param(SeparateHoldings => 1);
 319 }
 320 my $separatebranch = C4::Context->preference('SeparateHoldingsBranch') || 'homebranch';
 321 my ( $itemloop_has_images, $otheritemloop_has_images );
 322 foreach my $item (@items) {
 323     my $itembranchcode = $item->{$separatebranch};
 324
 325     $item->{imageurl} = defined $item->{itype} ? getitemtypeimagelocation('intranet', $itemtypes->{ $item->{itype} }{imageurl})
 326                                                : '';
 327
 328     $item->{datedue} = format_sqldatetime($item->{datedue});
 329
 330     #get shelf location and collection code description if they are authorised value.
 331     # same thing for copy number
 332     my $shelfcode = $item->{'location'};
 333     $item->{'location'} = $shelflocations->{$shelfcode} if ( defined( $shelfcode ) && defined($shelflocations) && exists( $shelflocations->{$shelfcode} ) );
 334     my $ccode = $item->{'ccode'};
 335     $item->{'ccode'} = $collections->{$ccode} if ( defined( $ccode ) && defined($collections) && exists( $collections->{$ccode} ) );
 336     my $copynumber = $item->{'copynumber'};
 337     $item->{'copynumber'} = $copynumbers->{$copynumber} if ( defined($copynumber) && defined($copynumbers) && exists( $copynumbers->{$copynumber} ) );
 338     foreach (qw(ccode enumchron copynumber stocknumber itemnotes itemnotes_nonpublic uri publisheddate)) { # Warning when removing GetItemsInfo - publisheddate (at least) is not part of the items table
 339         $itemfields{$_} = 1 if ( $item->{$_} );
 340     }
 341
 342     # checking for holds
 343     my $item_object = Koha::Items->find( $item->{itemnumber} );
 344     my $holds = $item_object->current_holds;
 345     if ( my $first_hold = $holds->next ) {
 346         $item->{first_hold} = $first_hold;
 347     }
 348
 349     if ( my $checkout = $item_object->checkout ) {
 350         $item->{CheckedOutFor} = $checkout->patron;
 351     }
 352
 353     # Check the transit status
 354     my ( $transfertwhen, $transfertfrom, $transfertto ) = GetTransfers($item->{itemnumber});
 355     if ( defined( $transfertwhen ) && ( $transfertwhen ne '' ) ) {
 356         $item->{transfertwhen} = $transfertwhen;
 357         $item->{transfertfrom} = $transfertfrom;
 358         $item->{transfertto}   = $transfertto;
 359         $item->{nocancel} = 1;
 360     }
 361
 362     foreach my $f (qw( itemnotes )) {
 363         if ($item->{$f}) {
 364             $item->{$f} =~ s|\n|<br />|g;
 365             $itemfields{$f} = 1;
 366         }
 367     }
 368
 369     #item has a host number if its biblio number does not match the current bib
 370
 371     if ($item->{biblionumber} ne $biblionumber){
 372         $item->{hostbiblionumber} = $item->{biblionumber};
 373         $item->{hosttitle} = GetBiblioData($item->{biblionumber})->{title};
 374     }
 375
 376
 377     if ( $analyze ) {
 378         # count if item is used in analytical bibliorecords
 379         # The 'countanalytics' flag is only used in the templates if analyze is set
 380         my $countanalytics = C4::Context->preference('EasyAnalyticalRecords') ? GetAnalyticsCount($item->{itemnumber}) : 0;
 381         if ($countanalytics > 0){
 382             $analytics_flag=1;
 383             $item->{countanalytics} = $countanalytics;
 384         }
 385     }
 386
 387     if (defined($item->{'materials'}) && $item->{'materials'} =~ /\S/){
 388         $materials_flag = 1;
 389         if (defined $materials_map{ $item->{materials} }) {
 390             $item->{materials} = $materials_map{ $item->{materials} };
 391         }
 392     }
 393
 394     if ( C4::Context->preference('UseCourseReserves') ) {
 395         $item->{'course_reserves'} = GetItemCourseReservesInfo( itemnumber => $item->{'itemnumber'} );
 396     }
 397
 398     if ( C4::Context->preference('IndependentBranches') ) {
 399         my $userenv = C4::Context->userenv();
 400         if ( not C4::Context->IsSuperLibrarian()
 401             and $userenv->{branch} ne $item->{homebranch} ) {
 402             $item->{cannot_be_edited} = 1;
 403         }
 404     }
 405
 406     if ( C4::Context->preference("LocalCoverImages") == 1 ) {
 407         $item->{cover_images} = $item_object->cover_images;
 408     }
 409
 410     if ( C4::Context->preference('UseRecalls') ) {
 411         my $recall = Koha::Recalls->find({ item_id => $item->{itemnumber}, completed => 0 });
 412         if ( defined $recall ) {
 413             $item->{recalled} = 1;
 414             $item->{recall} = $recall;
 415         }
 416     }
 417
 418     if ($currentbranch and C4::Context->preference('SeparateHoldings')) {
 419         if ($itembranchcode and $itembranchcode eq $currentbranch) {
 420             push @itemloop, $item;
 421             $itemloop_has_images++ if $item_object->cover_images->count;
 422         } else {
 423             push @otheritemloop, $item;
 424             $otheritemloop_has_images++ if $item_object->cover_images->count;
 425         }
 426     } else {
 427         push @itemloop, $item;
 428         $itemloop_has_images++ if $item_object->cover_images->count;
 429     }
 430 }
 431
 432 $template->param(
 433     itemloop_has_images      => $itemloop_has_images,
 434     otheritemloop_has_images => $otheritemloop_has_images,
 435 );
 436
 437 # Display only one tab if one items list is empty
 438 if (scalar(@itemloop) == 0 || scalar(@otheritemloop) == 0) {
 439     $template->param(SeparateHoldings => 0);
 440     if (scalar(@itemloop) == 0) {
 441         @itemloop = @otheritemloop;
 442     }
 443 }
 444
 445 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 446     {
 447         borrowernumber => $borrowernumber,
 448         add_allowed    => 1,
 449         public         => 0,
 450     }
 451 );
 452 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 453     {
 454         borrowernumber => $borrowernumber,
 455         add_allowed    => 1,
 456         public         => 1,
 457     }
 458 );
 459
 460
 461 $template->param(
 462     add_to_some_private_shelves => $some_private_shelves,
 463     add_to_some_public_shelves  => $some_public_shelves,
 464 );
 465
 466 $template->param(
 467     MARCNOTES   => $marc_record ? $biblio->get_marc_notes({ marcflavour => $marcflavour }) : undef,
 468     itemdata_ccode      => $itemfields{ccode},
 469     itemdata_enumchron  => $itemfields{enumchron},
 470     itemdata_uri        => $itemfields{uri},
 471     itemdata_copynumber => $itemfields{copynumber},
 472     itemdata_stocknumber => $itemfields{stocknumber},
 473     itemdata_publisheddate => $itemfields{publisheddate},
 474     volinfo                => $itemfields{enumchron},
 475         itemdata_itemnotes  => $itemfields{itemnotes},
 476         itemdata_nonpublicnotes => $itemfields{itemnotes_nonpublic},
 477     z3950_search_params    => C4::Search::z3950_search_args($dat),
 478         hostrecords         => $hostrecords,
 479     analytics_flag    => $analytics_flag,
 480     C4::Search::enabled_staff_search_views,
 481         materials       => $materials_flag,
 482 );
 483
 484 if (C4::Context->preference("AlternateHoldingsField") && scalar @items == 0) {
 485     my $fieldspec = C4::Context->preference("AlternateHoldingsField");
 486     my $subfields = substr $fieldspec, 3;
 487     my $holdingsep = C4::Context->preference("AlternateHoldingsSeparator") || ' ';
 488     my @alternateholdingsinfo = ();
 489     my @holdingsfields = $record->field(substr $fieldspec, 0, 3);
 490
 491     for my $field (@holdingsfields) {
 492         my %holding = ( holding => '' );
 493         my $havesubfield = 0;
 494         for my $subfield ($field->subfields()) {
 495             if ((index $subfields, $$subfield[0]) >= 0) {
 496                 $holding{'holding'} .= $holdingsep if (length $holding{'holding'} > 0);
 497                 $holding{'holding'} .= $$subfield[1];
 498                 $havesubfield++;
 499             }
 500         }
 501         if ($havesubfield) {
 502             push(@alternateholdingsinfo, \%holding);
 503         }
 504     }
 505
 506     $template->param(
 507         ALTERNATEHOLDINGS   => \@alternateholdingsinfo,
 508         );
 509 }
 510
 511 my @results = ( $dat, );
 512 foreach ( keys %{$dat} ) {
 513     $template->param( "$_" => defined $dat->{$_} ? $dat->{$_} : '' );
 514 }
 515
 516 # does not work: my %views_enabled = map { $_ => 1 } $template->query(loop => 'EnableViews');
 517 # method query not found?!?!
 518 $template->param( AmazonTld => get_amazon_tld() ) if ( C4::Context->preference("AmazonCoverImages"));
 519 $template->param(
 520     itemloop        => \@itemloop,
 521     otheritemloop   => \@otheritemloop,
 522     biblionumber        => $biblionumber,
 523     ($analyze? 'analyze':'detailview') =>1,
 524     subscriptions       => \@subs,
 525     subscriptionsnumber => $subscriptionsnumber,
 526     subscriptiontitle   => $dat->{title},
 527     searchid            => scalar $query->param('searchid'),
 528 );
 529
 530 # Lists
 531
 532 if (C4::Context->preference("virtualshelves") ) {
 533     my $shelves = Koha::Virtualshelves->search(
 534         {
 535             biblionumber => $biblionumber,
 536             public => 1,
 537         },
 538         {
 539             join => 'virtualshelfcontents',
 540         }
 541     );
 542     $template->param( 'shelves' => $shelves );
 543 }
 544
 545 # XISBN Stuff
 546 if (C4::Context->preference("FRBRizeEditions")==1) {
 547     eval {
 548         $template->param(
 549             XISBNS => scalar get_xisbns($isbn, $biblionumber)
 550         );
 551     };
 552     if ($@) { warn "XISBN Failed $@"; }
 553 }
 554
 555 if ( C4::Context->preference("LocalCoverImages") == 1 ) {
 556     my $images = $biblio->cover_images;
 557     $template->param( localimages => $biblio->cover_images );
 558 }
 559
 560 # HTML5 Media
 561 if ( (C4::Context->preference("HTML5MediaEnabled") eq 'both') or (C4::Context->preference("HTML5MediaEnabled") eq 'staff') ) {
 562     $template->param( C4::HTML5Media->gethtml5media($record));
 563 }
 564
 565 # Displaying tags
 566 my $tag_quantity;
 567 if (C4::Context->preference('TagsEnabled') and $tag_quantity = C4::Context->preference('TagsShowOnDetail')) {
 568     $template->param(
 569         TagsEnabled => 1,
 570         TagsShowOnDetail => $tag_quantity
 571     );
 572     $template->param(TagLoop => get_tags({biblionumber=>$biblionumber, approved=>1,
 573                                 'sort'=>'-weight', limit=>$tag_quantity}));
 574 }
 575
 576 #we only need to pass the number of holds to the template
 577 my $holds = $biblio->holds;
 578 $template->param( holdcount => $holds->count );
 579
 580 # Check if there are any ILL requests connected to the biblio
 581 my $illrequests =
 582     C4::Context->preference('ILLModule')
 583   ? Koha::Illrequests->search( { biblio_id => $biblionumber } )
 584   : [];
 585 $template->param( illrequests => $illrequests );
 586
 587 my $StaffDetailItemSelection = C4::Context->preference('StaffDetailItemSelection');
 588 if ($StaffDetailItemSelection) {
 589     # Only enable item selection if user can execute at least one action
 590     if (
 591         $flags->{superlibrarian}
 592         || (
 593             ref $flags->{tools} eq 'HASH' && (
 594                 $flags->{tools}->{items_batchmod}       # Modify selected items
 595                 || $flags->{tools}->{items_batchdel}    # Delete selected items
 596             )
 597         )
 598         || ( ref $flags->{tools} eq '' && $flags->{tools} )
 599       )
 600     {
 601         $template->param(
 602             StaffDetailItemSelection => $StaffDetailItemSelection );
 603     }
 604 }
 605
 606 # get biblionumbers stored in the cart
 607 my @cart_list;
 608
 609 if($query->cookie("intranet_bib_list")){
 610     my $cart_list = $query->cookie("intranet_bib_list");
 611     @cart_list = split(/\//, $cart_list);
 612     if ( grep {$_ eq $biblionumber} @cart_list) {
 613         $template->param( incart => 1 );
 614     }
 615 }
 616
 617 if ( C4::Context->preference('UseCourseReserves') ) {
 618     my $course_reserves = GetItemCourseReservesInfo( biblionumber => $biblionumber );
 619     $template->param( course_reserves => $course_reserves );
 620 }
 621
 622 $template->param(found1 => $query->param('found1') );
 623
 624 $template->param(biblio => $biblio);
 625
 626 output_html_with_http_headers $query, $cookie, $template->output;