koha-dev.rot13.org Git - srvgit/blob - acqui/neworderempty.pl

   1 #!/usr/bin/perl
   2
   3 #script to show display basket of orders
   4 #written by chris@katipo.co.nz 24/2/2000
   5
   6 # Copyright 2000-2002 Katipo Communications
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 =head1 NAME
  25
  26 neworderempty.pl
  27
  28 =head1 DESCRIPTION
  29
  30 this script allows to create a new record to order it. This record shouldn't exist
  31 on database.
  32
  33 =head1 CGI PARAMETERS
  34
  35 =over 4
  36
  37 =item booksellerid
  38 the bookseller the librarian has to buy a new book.
  39
  40 =item title
  41 the title of this new record.
  42
  43 =item author
  44 the author of this new record.
  45
  46 =item publication year
  47 the publication year of this new record.
  48
  49 =item ordernumber
  50 the number of this order.
  51
  52 =item biblio
  53
  54 =item basketno
  55 the basket number for this new order.
  56
  57 =item suggestionid
  58 if this order comes from a suggestion.
  59
  60 =item breedingid
  61 the item's id in the breeding reservoir
  62
  63 =back
  64
  65 =cut
  66
  67 use Modern::Perl;
  68 use CGI qw ( -utf8 );
  69 use C4::Context;
  70
  71 use C4::Auth;
  72 use C4::Budgets;
  73
  74 use C4::Acquisition;
  75 use C4::Contract;
  76 use C4::Suggestions;    # GetSuggestion
  77 use C4::Biblio;                 # GetBiblioData GetMarcPrice
  78 use C4::Items; #PrepareItemRecord
  79 use C4::Output;
  80 use C4::Koha;
  81 use C4::Members;
  82 use C4::Search qw/FindDuplicate/;
  83
  84 #needed for z3950 import:
  85 use C4::ImportBatch qw/GetImportRecordMarc SetImportRecordStatus SetMatchedBiblionumber/;
  86
  87 use Koha::Acquisition::Booksellers;
  88 use Koha::Acquisition::Currencies;
  89 use Koha::BiblioFrameworks;
  90 use Koha::DateUtils qw( dt_from_string );
  91 use Koha::MarcSubfieldStructures;
  92 use Koha::ItemTypes;
  93 use Koha::Patrons;
  94 use Koha::RecordProcessor;
  95 use Koha::Subscriptions;
  96
  97 our $input           = CGI->new;
  98 my $booksellerid    = $input->param('booksellerid');    # FIXME: else ERROR!
  99 my $budget_id       = $input->param('budget_id') || 0;
 100 my $title           = $input->param('title');
 101 my $author          = $input->param('author');
 102 my $publicationyear = $input->param('publicationyear');
 103 my $ordernumber          = $input->param('ordernumber') || '';
 104 our $biblionumber    = $input->param('biblionumber');
 105 our $basketno        = $input->param('basketno');
 106 my $suggestionid    = $input->param('suggestionid');
 107 my $uncertainprice  = $input->param('uncertainprice');
 108 my $import_batch_id = $input->param('import_batch_id'); # if this is filled, we come from a staged file, and we will return here after saving the order !
 109 my $from_subscriptionid  = $input->param('from_subscriptionid');
 110 my $data;
 111 my $new = 'no';
 112
 113 our ( $template, $loggedinuser, $cookie, $userflags ) = get_template_and_user(
 114     {
 115         template_name   => "acqui/neworderempty.tt",
 116         query           => $input,
 117         type            => "intranet",
 118         flagsrequired   => { acquisition => 'order_manage' },
 119     }
 120 );
 121
 122 our $marcflavour = C4::Context->preference('marcflavour');
 123
 124 if(!$basketno) {
 125     my $order = GetOrder($ordernumber);
 126     $basketno = $order->{'basketno'};
 127 }
 128
 129 our $basket = GetBasket($basketno);
 130 my $basketobj = Koha::Acquisition::Baskets->find( $basketno );
 131 $booksellerid = $basket->{booksellerid} unless $booksellerid;
 132 my $bookseller = Koha::Acquisition::Booksellers->find( $booksellerid );
 133
 134 output_and_exit( $input, $cookie, $template, 'unknown_basket') unless $basketobj;
 135 output_and_exit( $input, $cookie, $template, 'unknown_vendor') unless $bookseller;
 136
 137 $template->param(
 138     ordernumber  => $ordernumber,
 139     basketno     => $basketno,
 140     basket       => $basket,
 141     booksellerid => $basket->{'booksellerid'},
 142     name         => $bookseller->name,
 143 );
 144 output_and_exit( $input, $cookie, $template, 'order_cannot_be_edited' )
 145     if $ordernumber and $basketobj->closedate;
 146
 147 my $contract = GetContract({
 148     contractnumber => $basket->{contractnumber}
 149 });
 150
 151 #simple parameters reading (all in one :-)
 152 our $params = $input->Vars;
 153 my $listprice=0; # the price, that can be in MARC record if we have one
 154 if ( $ordernumber eq '' and defined $params->{'breedingid'}){
 155 #we want to import from the breeding reservoir (from a z3950 search)
 156     my ($marcrecord, $encoding) = MARCfindbreeding($params->{'breedingid'});
 157     die("Could not find the selected record in the reservoir, bailing") unless $marcrecord;
 158
 159     # Remove all the items (952) from the imported record
 160     foreach my $item ($marcrecord->field('952')) {
 161         $marcrecord->delete_field($item);
 162     }
 163
 164     my $duplicatetitle;
 165 #look for duplicates
 166     ($biblionumber,$duplicatetitle) = FindDuplicate($marcrecord);
 167     if($biblionumber && !$input->param('use_external_source')) {
 168         #if duplicate record found and user did not decide yet, first warn user
 169         #and let them choose between using a new record or an existing record
 170         Load_Duplicate($duplicatetitle);
 171         exit;
 172     }
 173     #from this point: add a new record
 174     C4::Acquisition::FillWithDefaultValues($marcrecord, {only_mandatory => 1});
 175     my $bibitemnum;
 176     $params->{'frameworkcode'} or $params->{'frameworkcode'} = "";
 177     ( $biblionumber, $bibitemnum ) = AddBiblio( $marcrecord, $params->{'frameworkcode'} );
 178     # get the price if there is one.
 179     $listprice = GetMarcPrice($marcrecord, $marcflavour);
 180     SetImportRecordStatus($params->{'breedingid'}, 'imported');
 181
 182     SetMatchedBiblionumber( $params->{breedingid}, $biblionumber );
 183 }
 184
 185
 186
 187 my ( @order_user_ids, @order_users, @catalog_details );
 188 our $tagslib = GetMarcStructure(1, 'ACQ', { unsafe => 1 } );
 189 my ( $itemnumber_tag, $itemnumber_subtag ) = GetMarcFromKohaField( 'items.itemnumber' );
 190 if ( not $ordernumber ) {    # create order
 191     $new = 'yes';
 192
 193     if ( $biblionumber ) {
 194         $data = GetBiblioData($biblionumber);
 195     }
 196     # get suggestion fields if applicable. If it's a subscription renewal, then the biblio already exists
 197     # otherwise, retrieve suggestion information.
 198     elsif ($suggestionid) {
 199         $data = GetSuggestion($suggestionid);
 200         $budget_id ||= $data->{'budgetid'} // 0;
 201     }
 202
 203     if ( not $biblionumber and Koha::BiblioFrameworks->find('ACQ') ) {
 204         #my $acq_mss = Koha::MarcSubfieldStructures->search({ frameworkcode => 'ACQ', tagfield => { '!=' => $itemnumber_tag } });
 205         foreach my $tag ( sort keys %{$tagslib} ) {
 206             next if $tag eq '';
 207             next if $tag eq $itemnumber_tag;    # skip items fields
 208             foreach my $subfield ( sort keys %{ $tagslib->{$tag} } ) {
 209                 my $mss = $tagslib->{$tag}{$subfield};
 210                 next if IsMarcStructureInternal($mss);
 211                 next if $mss->{tab} == -1;
 212                 my $value = $mss->{defaultvalue};
 213
 214                 if ($suggestionid and $mss->{kohafield}) {
 215                     # Reading suggestion info if ordering from a suggestion
 216                     if ( $mss->{kohafield} eq 'biblio.title' ) {
 217                         $value = $data->{title};
 218                     }
 219                     elsif ( $mss->{kohafield} eq 'biblio.author' ) {
 220                         $value = $data->{author};
 221                     }
 222                     elsif ( $mss->{kohafield} eq 'biblioitems.publishercode' ) {
 223                         $value = $data->{publishercode};
 224                     }
 225                     elsif ( $mss->{kohafield} eq 'biblioitems.editionstatement' ) {
 226                         $value = $data->{editionstatement};
 227                     }
 228                     elsif ( $mss->{kohafield} eq 'biblioitems.publicationyear' ) {
 229                         $value = $data->{publicationyear};
 230                     }
 231                     elsif ( $mss->{kohafield} eq 'biblioitems.isbn' ) {
 232                         $value = $data->{isbn};
 233                     }
 234                     elsif ( $mss->{kohafield} eq 'biblio.seriestitle' ) {
 235                         $value = $data->{seriestitle};
 236                     }
 237                 }
 238
 239                 if ( $value ) {
 240
 241                     # get today date & replace <<YYYY>>, <<YY>>, <<MM>>, <<DD>> if provided in the default value
 242                     my $today_dt = dt_from_string;
 243                     my $year     = $today_dt->strftime('%Y');
 244                     my $shortyear = $today_dt->strftime('%y');
 245                     my $month    = $today_dt->strftime('%m');
 246                     my $day      = $today_dt->strftime('%d');
 247                     $value =~ s/<<YYYY>>/$year/g;
 248                     $value =~ s/<<YY>>/$shortyear/g;
 249                     $value =~ s/<<MM>>/$month/g;
 250                     $value =~ s/<<DD>>/$day/g;
 251
 252                     # And <<USER>> with surname (?)
 253                     my $username =
 254                       (   C4::Context->userenv
 255                         ? C4::Context->userenv->{'surname'}
 256                         : "superlibrarian" );
 257                     $value =~ s/<<USER>>/$username/g;
 258                 }
 259                 push @catalog_details, {
 260                     tag      => $tag,
 261                     subfield => $subfield,
 262                     %$mss,    # Do we need plugins support (?)
 263                     value => $value,
 264                 };
 265             }
 266         }
 267     }
 268 }
 269 else {    #modify order
 270     $data   = GetOrder($ordernumber);
 271     $budget_id = $data->{'budget_id'};
 272
 273     $template->param(
 274         subscriptionid => $data->{subscriptionid},
 275     );
 276
 277     $basket   = GetBasket( $data->{'basketno'} );
 278     $basketno = $basket->{'basketno'};
 279
 280     @order_user_ids = GetOrderUsers($ordernumber);
 281     foreach my $order_user_id (@order_user_ids) {
 282         # FIXME Could be improved with search -in
 283         my $order_patron = Koha::Patrons->find( $order_user_id );
 284         push @order_users, $order_patron if $order_patron;
 285     }
 286 }
 287 $biblionumber = $data->{biblionumber};
 288
 289 # We can have:
 290 # - no ordernumber but a biblionumber: from a subscription, from an existing record
 291 # - no ordernumber, no biblionumber: from a suggestion, from a new order
 292 if ( not $ordernumber or $biblionumber ) {
 293     if ( C4::Context->preference('UseACQFrameworkForBiblioRecords') ) {
 294         my $record = $biblionumber ? GetMarcBiblio({ biblionumber => $biblionumber }) : undef;
 295         foreach my $tag ( sort keys %{$tagslib} ) {
 296             next if $tag eq '';
 297             next if $tag eq $itemnumber_tag; # skip items fields
 298             my @fields = $biblionumber ? $record->field($tag) : ();
 299             foreach my $subfield ( sort keys %{ $tagslib->{$tag} } ) {
 300                 my $mss = $tagslib->{$tag}{$subfield};
 301                 next if IsMarcStructureInternal($mss);
 302                 next if $mss->{tab} == -1;
 303                 # We only need to display the values
 304                 my $value = join '; ', map { $tag < 10 ? $_->data : $_->subfield( $subfield ) } @fields;
 305                 if ( $value ) {
 306                     push @catalog_details, {
 307                         tag => $tag,
 308                         subfield => $subfield,
 309                         %$mss,
 310                         value => $value,
 311                     };
 312                 }
 313             }
 314         }
 315     }
 316 }
 317
 318 $template->param( catalog_details => \@catalog_details, );
 319
 320 my $suggestion;
 321 $suggestion = GetSuggestionInfo($suggestionid) if $suggestionid;
 322
 323 my @currencies = Koha::Acquisition::Currencies->search;
 324 my $active_currency = Koha::Acquisition::Currencies->get_active;
 325
 326 # build bookfund list
 327 my $patron = Koha::Patrons->find( $loggedinuser )->unblessed;
 328
 329 my $budget =  GetBudget($budget_id);
 330 # build budget list
 331 my $budget_loop = [];
 332 my $budgets = GetBudgetHierarchy;
 333 foreach my $r (@{$budgets}) {
 334     next unless (CanUserUseBudget($patron, $r, $userflags));
 335     push @{$budget_loop}, {
 336         b_id  => $r->{budget_id},
 337         b_txt => $r->{budget_name},
 338         b_sort1_authcat => $r->{'sort1_authcat'},
 339         b_sort2_authcat => $r->{'sort2_authcat'},
 340         b_active => $r->{budget_period_active},
 341         b_sel => ( $r->{budget_id} == $budget_id ) ? 1 : 0,
 342         b_level => $r->{budget_level},
 343     };
 344 }
 345
 346
 347 $template->param( sort1 => $data->{'sort1'} );
 348 $template->param( sort2 => $data->{'sort2'} );
 349
 350 if ($basketobj->effective_create_items eq 'ordering' && !$ordernumber) {
 351     # Check if ACQ framework exists
 352     my $marc = GetMarcStructure(1, 'ACQ', { unsafe => 1 } );
 353     unless($marc) {
 354         $template->param('NoACQframework' => 1);
 355     }
 356     $template->param(
 357         AcqCreateItemOrdering => 1,
 358         UniqueItemFields => C4::Context->preference('UniqueItemFields'),
 359     );
 360 }
 361
 362 # Get the item types list, but only if item_level_itype is YES. Otherwise, it will be in the item, no need to display it in the biblio
 363 my @itemtypes;
 364 @itemtypes = Koha::ItemTypes->search unless C4::Context->preference('item-level_itypes');
 365
 366 if ( defined $from_subscriptionid ) {
 367     # Get the last received order for this subscription
 368     my $lastOrderReceived = Koha::Acquisition::Orders->search(
 369         {
 370             subscriptionid => $from_subscriptionid,
 371             datereceived   => { '!=' => undef }
 372         },
 373         {
 374             order_by =>
 375               [ { -desc => 'datereceived' }, { -desc => 'ordernumber' } ]
 376         }
 377     );
 378     if ( $lastOrderReceived->count ) {
 379         $lastOrderReceived = $lastOrderReceived->next->unblessed; # FIXME We should send the object to the template
 380         $budget_id              = $lastOrderReceived->{budgetid};
 381         $data->{listprice}      = $lastOrderReceived->{listprice};
 382         $data->{uncertainprice} = $lastOrderReceived->{uncertainprice};
 383         $data->{tax_rate}       = $lastOrderReceived->{tax_rate_on_ordering};
 384         $data->{discount}       = $lastOrderReceived->{discount};
 385         $data->{rrp}            = $lastOrderReceived->{rrp};
 386         $data->{replacementprice} = $lastOrderReceived->{replacementprice};
 387         $data->{ecost}          = $lastOrderReceived->{ecost};
 388         $data->{quantity}       = $lastOrderReceived->{quantity};
 389         $data->{unitprice}       = $lastOrderReceived->{unitprice};
 390         $data->{order_internalnote} = $lastOrderReceived->{order_internalnote};
 391         $data->{order_vendornote}   = $lastOrderReceived->{order_vendornote};
 392         $data->{sort1}          = $lastOrderReceived->{sort1};
 393         $data->{sort2}          = $lastOrderReceived->{sort2};
 394
 395         $basket = GetBasket( $input->param('basketno') );
 396     }
 397
 398     my $subscription = Koha::Subscriptions->find($from_subscriptionid);
 399     $template->param(
 400         subscriptionid => $from_subscriptionid,
 401         subscription   => $subscription,
 402     );
 403 }
 404
 405 # Find the items.barcode subfield for barcode validations
 406 my (undef, $barcode_subfield) = GetMarcFromKohaField( 'items.barcode' );
 407
 408
 409 # get option values for TaxRates syspref
 410 my @gst_values = map {
 411     option => $_ + 0.0
 412 }, split( '\|', C4::Context->preference("TaxRates") );
 413
 414 my $quantity = $input->param('rr_quantity_to_order') ?
 415       $input->param('rr_quantity_to_order') :
 416       $data->{'quantity'};
 417 $quantity //= 0;
 418
 419 # fill template
 420 $template->param(
 421     existing         => $biblionumber,
 422     # basket informations
 423     basketname           => $basket->{'basketname'},
 424     basketnote           => $basket->{'note'},
 425     booksellerid         => $basket->{'booksellerid'},
 426     basketbooksellernote => $basket->{booksellernote},
 427     basketcontractno     => $basket->{contractnumber},
 428     basketcontractname   => $contract->{contractname},
 429     creationdate         => $basket->{creationdate},
 430     authorisedby         => $basket->{'authorisedby'},
 431     authorisedbyname     => $basket->{'authorisedbyname'},
 432     closedate            => $basket->{'closedate'},
 433     # order details
 434     suggestionid         => $suggestion->{suggestionid},
 435     surnamesuggestedby   => $suggestion->{surnamesuggestedby},
 436     firstnamesuggestedby => $suggestion->{firstnamesuggestedby},
 437     biblionumber         => $biblionumber,
 438     uncertainprice       => $data->{'uncertainprice'},
 439     discount_2dp         => sprintf( "%.2f",  $bookseller->discount ) ,   # for display
 440     discount             => $bookseller->discount,
 441     orderdiscount_2dp    => sprintf( "%.2f", $data->{'discount'} || 0 ),
 442     orderdiscount        => $data->{'discount'},
 443     order_internalnote   => $data->{'order_internalnote'},
 444     order_vendornote     => $data->{'order_vendornote'},
 445     listincgst       => $bookseller->listincgst,
 446     invoiceincgst    => $bookseller->invoiceincgst,
 447     cur_active_sym   => $active_currency->symbol,
 448     cur_active       => $active_currency->currency,
 449     currencies       => \@currencies,
 450     currency         => $data->{currency},
 451     vendor_currency  => $bookseller->listprice,
 452     orderexists      => ( $new eq 'yes' ) ? 0 : 1,
 453     title            => $data->{'title'},
 454     author           => $data->{'author'},
 455     publicationyear  => $data->{'publicationyear'} ? $data->{'publicationyear'} : $data->{'copyrightdate'},
 456     editionstatement => $data->{'editionstatement'},
 457     budget_loop      => $budget_loop,
 458     isbn             => $data->{'isbn'},
 459     ean              => $data->{'ean'},
 460     seriestitle      => $data->{'seriestitle'},
 461     itemtypeloop     => \@itemtypes,
 462     quantity         => $quantity,
 463     quantityrec      => $quantity,
 464     rrp              => $data->{'rrp'},
 465     replacementprice => $data->{'replacementprice'},
 466     gst_values       => \@gst_values,
 467     tax_rate         => $data->{tax_rate_on_ordering} ? $data->{tax_rate_on_ordering}+0.0 : $bookseller->tax_rate ? $bookseller->tax_rate+0.0 : 0,
 468     listprice        => sprintf( "%.2f", $data->{listprice} || $data->{price} || $listprice),
 469     total            => sprintf( "%.2f", ($data->{ecost} || 0) * ($data->{'quantity'} || 0) ),
 470     ecost            => sprintf( "%.2f", $data->{ecost} || 0),
 471     unitprice        => sprintf( "%.2f", $data->{unitprice} || 0),
 472     publishercode    => $data->{'publishercode'},
 473     barcode_subfield => $barcode_subfield,
 474     import_batch_id  => $import_batch_id,
 475     acqcreate        => $basketobj->effective_create_items eq "ordering" ? 1 : "",
 476     users_ids        => join(':', @order_user_ids),
 477     users            => \@order_users,
 478     (uc(C4::Context->preference("marcflavour"))) => 1
 479 );
 480
 481 output_html_with_http_headers $input, $cookie, $template->output;
 482
 483
 484 =head2 MARCfindbreeding
 485
 486   $record = MARCfindbreeding($breedingid);
 487
 488 Look up the import record repository for the record with
 489 record with id $breedingid.  If found, returns the decoded
 490 MARC::Record; otherwise, -1 is returned (FIXME).
 491 Returns as second parameter the character encoding.
 492
 493 =cut
 494
 495 sub MARCfindbreeding {
 496     my ( $id ) = @_;
 497     my ($marc, $encoding) = GetImportRecordMarc($id);
 498     # remove the - in isbn, koha store isbn without any -
 499     if ($marc) {
 500         my $record = MARC::Record->new_from_usmarc($marc);
 501         my ($isbnfield,$isbnsubfield) = GetMarcFromKohaField( 'biblioitems.isbn' );
 502         if ( $record->field($isbnfield) ) {
 503             foreach my $field ( $record->field($isbnfield) ) {
 504                 foreach my $subfield ( $field->subfield($isbnsubfield) ) {
 505                     my $newisbn = $field->subfield($isbnsubfield);
 506                     $newisbn =~ s/-//g;
 507                     $field->update( $isbnsubfield => $newisbn );
 508                 }
 509             }
 510         }
 511         # fix the unimarc 100 coded field (with unicode information)
 512         if ($marcflavour eq 'UNIMARC' && $record->subfield(100,'a')) {
 513             my $f100a=$record->subfield(100,'a');
 514             my $f100 = $record->field(100);
 515             my $f100temp = $f100->as_string;
 516             $record->delete_field($f100);
 517             if ( length($f100temp) > 28 ) {
 518                 substr( $f100temp, 26, 2, "50" );
 519                 $f100->update( 'a' => $f100temp );
 520                 my $f100 = MARC::Field->new( '100', '', '', 'a' => $f100temp );
 521                 $record->insert_fields_ordered($f100);
 522             }
 523         }
 524
 525         if ( !defined(ref($record)) ) {
 526             return -1;
 527         }
 528         else {
 529             # normalize author : probably UNIMARC specific...
 530             if (    C4::Context->preference("z3950NormalizeAuthor")
 531                 and C4::Context->preference("z3950AuthorAuthFields") )
 532             {
 533                 my ( $tag, $subfield ) = GetMarcFromKohaField( "biblio.author" );
 534
 535                 my $auth_fields =
 536                 C4::Context->preference("z3950AuthorAuthFields");
 537                 my @auth_fields = split /,/, $auth_fields;
 538                 my $field;
 539
 540                 if ( $record->field($tag) ) {
 541                     foreach my $tmpfield ( $record->field($tag)->subfields ) {
 542
 543                         my $subfieldcode  = shift @$tmpfield;
 544                         my $subfieldvalue = shift @$tmpfield;
 545                         if ($field) {
 546                             $field->add_subfields(
 547                                 "$subfieldcode" => $subfieldvalue )
 548                             if ( $subfieldcode ne $subfield );
 549                         }
 550                         else {
 551                             $field =
 552                             MARC::Field->new( $tag, "", "",
 553                                 $subfieldcode => $subfieldvalue )
 554                             if ( $subfieldcode ne $subfield );
 555                         }
 556                     }
 557                 }
 558                 $record->delete_field( $record->field($tag) );
 559                 foreach my $fieldtag (@auth_fields) {
 560                     next unless ( $record->field($fieldtag) );
 561                     my $lastname  = $record->field($fieldtag)->subfield('a');
 562                     my $firstname = $record->field($fieldtag)->subfield('b');
 563                     my $title     = $record->field($fieldtag)->subfield('c');
 564                     my $number    = $record->field($fieldtag)->subfield('d');
 565                     if ($title) {
 566                         $field->add_subfields(
 567                                 "$subfield" => ucfirst($title) . " "
 568                             . ucfirst($firstname) . " "
 569                             . $number );
 570                     }
 571                     else {
 572                         $field->add_subfields(
 573                             "$subfield" => ucfirst($firstname) . ", "
 574                             . ucfirst($lastname) );
 575                     }
 576                 }
 577                 $record->insert_fields_ordered($field);
 578             }
 579             return $record, $encoding;
 580         }
 581     }
 582     return -1;
 583 }
 584
 585 sub Load_Duplicate {
 586   my ($duplicatetitle)= @_;
 587   ($template, $loggedinuser, $cookie) = get_template_and_user(
 588     {
 589         template_name   => "acqui/neworderempty_duplicate.tt",
 590         query           => $input,
 591         type            => "intranet",
 592         flagsrequired   => { acquisition => 'order_manage' },
 593     }
 594   );
 595
 596   $template->param(
 597     biblionumber        => $biblionumber,
 598     basketno            => $basketno,
 599     booksellerid        => $basket->{'booksellerid'},
 600     breedingid          => $params->{'breedingid'},
 601     duplicatetitle      => $duplicatetitle,
 602     (uc(C4::Context->preference("marcflavour"))) => 1
 603   );
 604
 605   output_html_with_http_headers $input, $cookie, $template->output;
 606 }