koha-dev.rot13.org Git - srvgit/blob - acqui/basket.pl

   1 #!/usr/bin/perl
   2
   3 #script to show display basket of orders
   4
   5 # Copyright 2000 - 2004 Katipo
   6 # Copyright 2008 - 2009 BibLibre SARL
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 use Modern::Perl;
  24 use C4::Auth;
  25 use C4::Koha;
  26 use C4::Output;
  27 use CGI qw ( -utf8 );
  28 use C4::Acquisition;
  29 use C4::Budgets;
  30 use C4::Contract;
  31 use C4::Debug;
  32 use C4::Biblio;
  33 use C4::Items;
  34 use C4::Suggestions;
  35 use Koha::Biblios;
  36 use Koha::Acquisition::Baskets;
  37 use Koha::Acquisition::Booksellers;
  38 use Koha::Acquisition::Orders;
  39 use Koha::Libraries;
  40 use C4::Letters qw/SendAlerts/;
  41 use Date::Calc qw/Add_Delta_Days/;
  42 use Koha::Database;
  43 use Koha::EDI qw( create_edi_order get_edifact_ean );
  44 use Koha::CsvProfiles;
  45 use Koha::Patrons;
  46
  47 use Koha::AdditionalFields;
  48
  49 =head1 NAME
  50
  51 basket.pl
  52
  53 =head1 DESCRIPTION
  54
  55  This script display all informations about basket for the supplier given
  56  on input arg.  Moreover, it allows us to add a new order for this supplier from
  57  an existing record, a suggestion or a new record.
  58
  59 =head1 CGI PARAMETERS
  60
  61 =over 4
  62
  63 =item $basketno
  64
  65 The basket number.
  66
  67 =item booksellerid
  68
  69 the supplier this script have to display the basket.
  70
  71 =item order
  72
  73 =back
  74
  75 =cut
  76
  77 our $query        = CGI->new;
  78 our $basketno     = $query->param('basketno');
  79 our $ean          = $query->param('ean');
  80 our $booksellerid = $query->param('booksellerid');
  81 my $duplinbatch =  $query->param('duplinbatch');
  82
  83 our ( $template, $loggedinuser, $cookie, $userflags ) = get_template_and_user(
  84     {
  85         template_name   => "acqui/basket.tt",
  86         query           => $query,
  87         type            => "intranet",
  88         flagsrequired   => { acquisition => 'order_manage' },
  89     }
  90 );
  91
  92 my $logged_in_patron = Koha::Patrons->find( $loggedinuser );
  93
  94 our $basket = GetBasket($basketno);
  95 $booksellerid = $basket->{booksellerid} unless $booksellerid;
  96 my $bookseller = Koha::Acquisition::Booksellers->find( $booksellerid );
  97 my $schema = Koha::Database->new()->schema();
  98 my $rs = $schema->resultset('VendorEdiAccount')->search(
  99     { vendor_id => $booksellerid, } );
 100 $template->param( ediaccount => ($rs->count > 0));
 101
 102 unless (CanUserManageBasket($loggedinuser, $basket, $userflags)) {
 103     $template->param(
 104         cannot_manage_basket => 1,
 105         basketno => $basketno,
 106         basketname => $basket->{basketname},
 107         booksellerid => $booksellerid,
 108         booksellername => $bookseller->name,
 109     );
 110     output_html_with_http_headers $query, $cookie, $template->output;
 111     exit;
 112 }
 113
 114 # FIXME : what about the "discount" percentage?
 115 # FIXME : the query->param('booksellerid') below is probably useless. The bookseller is always known from the basket
 116 # if no booksellerid in parameter, get it from basket
 117 # warn "=>".$basket->{booksellerid};
 118 my $op = $query->param('op') // 'list';
 119
 120 our $confirm_pref= C4::Context->preference("BasketConfirmations") || '1';
 121 $template->param( skip_confirm_reopen => 1) if $confirm_pref eq '2';
 122
 123 my @messages;
 124
 125 if ( $op eq 'delete_confirm' ) {
 126
 127     output_and_exit( $query, $cookie, $template, 'insufficient_permission' )
 128       unless $logged_in_patron->has_permission( { acquisition => 'delete_baskets' } );
 129
 130     my $basketno   = $query->param('basketno');
 131     my $delbiblio  = $query->param('delbiblio');
 132     my $basket_obj = Koha::Acquisition::Baskets->find($basketno);
 133
 134     my $orders = $basket_obj->orders;
 135
 136     my @cannotdelbiblios;
 137
 138     while ( my $order = $orders->next ) {
 139         # cancel the order
 140         $order->cancel({ delete_biblio => $delbiblio });
 141         my @messages = @{ $order->messages };
 142
 143         if ( scalar @messages > 0 ) {
 144
 145             my $biblio = $order->biblio;
 146
 147             push @cannotdelbiblios, {
 148                 biblionumber  => $biblio->id,
 149                 title         => $biblio->title // '',
 150                 author        => $biblio->author // '',
 151                 countbiblio   => $biblio->active_orders->count,
 152                 itemcount     => $biblio->items->count,
 153                 subscriptions => $biblio->subscriptions->count,
 154             };
 155         }
 156     }
 157
 158     $template->param( cannotdelbiblios => \@cannotdelbiblios );
 159
 160     # delete the basket
 161     $basket_obj->delete;
 162     $template->param(
 163         delete_confirmed => 1,
 164         booksellername => $bookseller->name,
 165         booksellerid => $booksellerid,
 166     );
 167 } elsif ( !$bookseller ) {
 168     $template->param( NO_BOOKSELLER => 1 );
 169 } elsif ($op eq 'export') {
 170     print $query->header(
 171         -type       => 'text/csv',
 172         -attachment => 'basket' . $basket->{'basketno'} . '.csv',
 173     );
 174     my $csv_profile_id = $query->param('csv_profile');
 175     print GetBasketAsCSV( scalar $query->param('basketno'), $query, $csv_profile_id ); # if no csv_profile_id passed, using default rows
 176     exit;
 177 } elsif ($op eq 'email') {
 178     my $err = eval {
 179         SendAlerts( 'orderacquisition', $query->param('basketno'), 'ACQORDER' );
 180     };
 181     if ( $@ ) {
 182         push @messages, { type => 'error', code => $@ };
 183     } elsif ( ref $err and exists $err->{error} ) {
 184         push @messages, { type => 'error', code => $err->{error} };
 185     } else {
 186         push @messages, { type => 'message', code => 'email_sent' };
 187     }
 188
 189     $op = 'list';
 190 } elsif ($op eq 'close') {
 191     my $confirm = $query->param('confirm') || $confirm_pref eq '2';
 192     if ($confirm) {
 193
 194         # close the basket
 195         # FIXME: we should fetch the object at the beginning of this script
 196         #        and get rid of the hash that is passed around
 197         Koha::Acquisition::Baskets->find($basketno)->close;
 198
 199         # if requested, create basket group, close it and attach the basket
 200         if ($query->param('createbasketgroup')) {
 201             my $branchcode;
 202             if(C4::Context->userenv and C4::Context->userenv->{'branch'}) {
 203                 $branchcode = C4::Context->userenv->{'branch'};
 204             }
 205             my $basketgroupid = NewBasketgroup( { name => $basket->{basketname},
 206                             booksellerid => $booksellerid,
 207                             deliveryplace => $branchcode,
 208                             billingplace => $branchcode,
 209                             closed => 1,
 210                             });
 211             ModBasket( { basketno => $basketno,
 212                          basketgroupid => $basketgroupid } );
 213             print $query->redirect('/cgi-bin/koha/acqui/basketgroup.pl?booksellerid='.$booksellerid.'&closed=1');
 214         } else {
 215             print $query->redirect('/cgi-bin/koha/acqui/booksellers.pl?booksellerid=' . $booksellerid);
 216         }
 217         exit;
 218     } else {
 219     $template->param(
 220         confirm_close   => "1",
 221         booksellerid    => $booksellerid,
 222         booksellername  => $bookseller->name,
 223         basketno        => $basket->{'basketno'},
 224         basketname      => $basket->{'basketname'},
 225         basketgroupname => $basket->{'basketname'},
 226     );
 227     }
 228 } elsif ($op eq 'reopen') {
 229     ReopenBasket(scalar $query->param('basketno'));
 230     print $query->redirect('/cgi-bin/koha/acqui/basket.pl?basketno='.$basket->{'basketno'})
 231 }
 232 elsif ( $op eq 'ediorder' ) {
 233     edi_close_and_order()
 234 } elsif ( $op eq 'mod_users' ) {
 235     my $basketusers_ids = $query->param('users_ids');
 236     my @basketusers = split( /:/, $basketusers_ids );
 237     ModBasketUsers($basketno, @basketusers);
 238     print $query->redirect("/cgi-bin/koha/acqui/basket.pl?basketno=$basketno");
 239     exit;
 240 } elsif ( $op eq 'mod_branch' ) {
 241     my $branch = $query->param('branch');
 242     $branch = undef if(defined $branch and $branch eq '');
 243     ModBasket({
 244         basketno => $basket->{basketno},
 245         branch   => $branch
 246     });
 247     print $query->redirect("/cgi-bin/koha/acqui/basket.pl?basketno=$basketno");
 248     exit;
 249 }
 250
 251 if ( $op eq 'list' ) {
 252     my @branches_loop;
 253     # get librarian branch...
 254     if ( C4::Context->preference("IndependentBranches") ) {
 255         my $userenv = C4::Context->userenv;
 256         unless ( C4::Context->IsSuperLibrarian() ) {
 257             my $validtest = ( $basket->{creationdate} eq '' )
 258               || ( $userenv->{branch} eq $basket->{branch} )
 259               || ( $userenv->{branch} eq '' )
 260               || ( $basket->{branch}  eq '' );
 261             unless ($validtest) {
 262                 print $query->redirect("../mainpage.pl");
 263                 exit 0;
 264             }
 265         }
 266
 267         if (!defined $basket->{branch} or $basket->{branch} eq $userenv->{branch}) {
 268             push @branches_loop, {
 269                 branchcode => $userenv->{branch},
 270                 branchname => $userenv->{branchname},
 271                 selected => 1,
 272             };
 273         }
 274     } else {
 275         # get branches
 276         my $branches = Koha::Libraries->search( {}, { order_by => ['branchname'] } )->unblessed;
 277         foreach my $branch (@$branches) {
 278             my $selected = 0;
 279             if (defined $basket->{branch}) {
 280                 $selected = 1 if $branch->{branchcode} eq $basket->{branch};
 281             } else {
 282                 $selected = 1 if $branch->{branchcode} eq C4::Context->userenv->{branch};
 283             }
 284             push @branches_loop, {
 285                 branchcode => $branch->{branchcode},
 286                 branchname => $branch->{branchname},
 287                 selected => $selected
 288             };
 289         }
 290     }
 291
 292 #if the basket is closed,and the user has the permission to edit basketgroups, display a list of basketgroups
 293     my ($basketgroup, $basketgroups);
 294     my $patron = Koha::Patrons->find($loggedinuser);
 295     if ($basket->{closedate} && haspermission($patron->userid, { acquisition => 'group_manage'} )) {
 296         $basketgroups = GetBasketgroups($basket->{booksellerid});
 297         for my $bg ( @{$basketgroups} ) {
 298             if ($basket->{basketgroupid} && $basket->{basketgroupid} == $bg->{id}){
 299                 $bg->{default} = 1;
 300                 $basketgroup = $bg;
 301             }
 302         }
 303     }
 304
 305     # if the basket is closed, calculate estimated delivery date
 306     my $estimateddeliverydate;
 307     if( $basket->{closedate} ) {
 308         my ($year, $month, $day) = ($basket->{closedate} =~ /(\d+)-(\d+)-(\d+)/);
 309         ($year, $month, $day) = Add_Delta_Days($year, $month, $day, $bookseller->deliverytime);
 310         $estimateddeliverydate = sprintf( "%04d-%02d-%02d", $year, $month, $day );
 311     }
 312
 313     # if new basket, pre-fill infos
 314     $basket->{creationdate} = ""            unless ( $basket->{creationdate} );
 315     $basket->{authorisedby} = $loggedinuser unless ( $basket->{authorisedby} );
 316     $debug
 317       and warn sprintf
 318       "loggedinuser: $loggedinuser; creationdate: %s; authorisedby: %s",
 319       $basket->{creationdate}, $basket->{authorisedby};
 320
 321     my @basketusers_ids = GetBasketUsers($basketno);
 322     my @basketusers;
 323     foreach my $basketuser_id (@basketusers_ids) {
 324         # FIXME Could be improved with a search -in
 325         my $basket_patron = Koha::Patrons->find( $basketuser_id );
 326         push @basketusers, $basket_patron if $basket_patron;
 327     }
 328
 329     my $active_currency = Koha::Acquisition::Currencies->get_active;
 330
 331     my @orders = GetOrders( $basketno );
 332     my @books_loop;
 333
 334     my @book_foot_loop;
 335     my %foot;
 336     my $total_quantity = 0;
 337     my $total_tax_excluded = 0;
 338     my $total_tax_included = 0;
 339     my $total_tax_value = 0;
 340     for my $order (@orders) {
 341         my $line = get_order_infos( $order, $bookseller);
 342         if ( $line->{uncertainprice} ) {
 343             $template->param( uncertainprices => 1 );
 344         }
 345
 346         $line->{tax_rate} = $line->{tax_rate_on_ordering} // 0;
 347         $line->{tax_value} = $line->{tax_value_on_ordering} // 0;
 348
 349         push @books_loop, $line;
 350
 351         $foot{$$line{tax_rate}}{tax_rate} = $$line{tax_rate};
 352         $foot{$$line{tax_rate}}{tax_value} += get_rounded_price($$line{tax_value});
 353         $total_tax_value += $$line{tax_value};
 354         $foot{$$line{tax_rate}}{quantity}  += get_rounded_price($$line{quantity});
 355         $total_quantity += $$line{quantity};
 356         $foot{$$line{tax_rate}}{total_tax_excluded} += $$line{total_tax_excluded};
 357         $total_tax_excluded += $$line{total_tax_excluded};
 358         $foot{$$line{tax_rate}}{total_tax_included} += $$line{total_tax_included};
 359         $total_tax_included += $$line{total_tax_included};
 360     }
 361
 362     push @book_foot_loop, map {$_} values %foot;
 363
 364     # Get cancelled orders
 365     my @cancelledorders = GetOrders($basketno, { cancelled => 1 });
 366     my @cancelledorders_loop;
 367     for my $order (@cancelledorders) {
 368         my $line = get_order_infos( $order, $bookseller);
 369         push @cancelledorders_loop, $line;
 370     }
 371
 372     my $contract = GetContract({
 373         contractnumber => $basket->{contractnumber}
 374     });
 375
 376     if ($basket->{basketgroupid}){
 377         $basketgroup = GetBasketgroup($basket->{basketgroupid});
 378     }
 379     my $budgets = GetBudgetHierarchy;
 380     my $has_budgets = 0;
 381     foreach my $r (@{$budgets}) {
 382         next unless (CanUserUseBudget($loggedinuser, $r, $userflags));
 383
 384         $has_budgets = 1;
 385         last;
 386     }
 387
 388     $template->param(
 389         basketno             => $basketno,
 390         basket               => $basket,
 391         basketname           => $basket->{'basketname'},
 392         basketbranchcode     => $basket->{branch},
 393         basketnote           => $basket->{note},
 394         basketbooksellernote => $basket->{booksellernote},
 395         basketcontractno     => $basket->{contractnumber},
 396         basketcontractname   => $contract->{contractname},
 397         branches_loop        => \@branches_loop,
 398         creationdate         => $basket->{creationdate},
 399         authorisedby         => $basket->{authorisedby},
 400         authorisedbyname     => $basket->{authorisedbyname},
 401         users_ids            => join(':', @basketusers_ids),
 402         users                => \@basketusers,
 403         closedate            => $basket->{closedate},
 404         estimateddeliverydate=> $estimateddeliverydate,
 405         is_standing          => $basket->{is_standing},
 406         deliveryplace        => $basket->{deliveryplace},
 407         billingplace         => $basket->{billingplace},
 408         active               => $bookseller->active,
 409         booksellerid         => $bookseller->id,
 410         booksellername       => $bookseller->name,
 411         books_loop           => \@books_loop,
 412         book_foot_loop       => \@book_foot_loop,
 413         cancelledorders_loop => \@cancelledorders_loop,
 414         total_quantity       => $total_quantity,
 415         total_tax_excluded   => $total_tax_excluded,
 416         total_tax_included   => $total_tax_included,
 417         total_tax_value      => $total_tax_value,
 418         currency             => $active_currency->currency,
 419         listincgst           => $bookseller->listincgst,
 420         basketgroups         => $basketgroups,
 421         basketgroup          => $basketgroup,
 422         grouped              => $basket->{basketgroupid},
 423         # The double negatives and booleans here mean:
 424         # "A basket cannot be closed if there are no orders in it or it's a standing order basket."
 425         #
 426         # (The template has another implicit restriction that the order cannot be closed if there
 427         # are any orders with uncertain prices.)
 428         unclosable           => @orders || @cancelledorders ? $basket->{is_standing} : 1,
 429         has_budgets          => $has_budgets,
 430         duplinbatch          => $duplinbatch,
 431         csv_profiles         => [ Koha::CsvProfiles->search({ type => 'sql', used_for => 'export_basket' }) ],
 432         available_additional_fields => [ Koha::AdditionalFields->search( { tablename => 'aqbasket' } ) ],
 433         additional_field_values => { map {
 434             $_->field->name => $_->value
 435         } Koha::Acquisition::Baskets->find($basketno)->additional_field_values->as_list },
 436     );
 437 }
 438
 439 $template->param( messages => \@messages );
 440 output_html_with_http_headers $query, $cookie, $template->output;
 441
 442 sub get_order_infos {
 443     my $order = shift;
 444     my $bookseller = shift;
 445     my $qty = $order->{'quantity'} || 0;
 446     if ( !defined $order->{quantityreceived} ) {
 447         $order->{quantityreceived} = 0;
 448     }
 449     my $budget = GetBudget($order->{budget_id});
 450     my $basket = GetBasket($order->{basketno});
 451
 452     my %line = %{ $order };
 453     # Don't show unreceived standing orders as received
 454     $line{order_received} = ( $qty == $order->{'quantityreceived'} && ( $basket->{is_standing} ? $qty : 1 ) );
 455     $line{basketno}       = $basketno;
 456     $line{budget_name}    = $budget->{budget_name};
 457
 458     # If we have an actual cost that should be the total, otherwise use the ecost
 459     $line{unitprice_tax_included} += 0;
 460     $line{unitprice_tax_excluded} += 0;
 461     my $cost_tax_included = $line{unitprice_tax_included} || $line{ecost_tax_included};
 462     my $cost_tax_excluded = $line{unitprice_tax_excluded} || $line{ecost_tax_excluded};
 463     $line{total_tax_included} = get_rounded_price($cost_tax_included) * $line{quantity};
 464     $line{total_tax_excluded} = get_rounded_price($cost_tax_excluded) * $line{quantity};
 465     $line{tax_value} = $line{tax_value_on_ordering};
 466     $line{tax_rate} = $line{tax_rate_on_ordering};
 467
 468     if ( $line{'title'} ) {
 469         my $volume      = $order->{'volume'};
 470         my $seriestitle = $order->{'seriestitle'};
 471         $line{'title'} .= " / $seriestitle" if $seriestitle;
 472         $line{'title'} .= " / $volume"      if $volume;
 473     }
 474
 475     my $biblionumber = $order->{'biblionumber'};
 476     if ( $biblionumber ) { # The biblio still exists
 477         my $biblio = Koha::Biblios->find( $biblionumber );
 478         my $countbiblio = $biblio->active_orders->count;
 479
 480         my $ordernumber = $order->{'ordernumber'};
 481         my $cnt_subscriptions = $biblio->subscriptions->count;
 482         my $itemcount   = $biblio->items->count;
 483         my $holds_count = $biblio->holds->count;
 484         my $order = Koha::Acquisition::Orders->find($ordernumber); # FIXME We should certainly do that at the beginning of this sub
 485         my $items = $order->items;
 486         my $itemholds  = $biblio->holds->search({ itemnumber => { -in => [ $items->get_column('itemnumber') ] } })->count;
 487
 488         # if the biblio is not in other orders and if there is no items elsewhere and no subscriptions and no holds we can then show the link "Delete order and Biblio" see bug 5680
 489         $line{can_del_bib}          = 1 if $countbiblio <= 1 && $itemcount == $items->count && !($cnt_subscriptions) && !($holds_count);
 490         $line{items}                = $itemcount - $items->count;
 491         $line{left_item}            = 1 if $line{items} >= 1;
 492         $line{left_biblio}          = 1 if $countbiblio > 1;
 493         $line{biblios}              = $countbiblio - 1;
 494         $line{left_subscription}    = 1 if $cnt_subscriptions;
 495         $line{subscriptions}        = $cnt_subscriptions;
 496         ($holds_count >= 1) ? $line{left_holds} = 1 : $line{left_holds} = 0;
 497         $line{left_holds_on_order}  = 1 if $line{left_holds}==1 && ($line{items} == 0 || $itemholds );
 498         $line{holds}                = $holds_count;
 499         $line{holds_on_order}       = $itemholds?$itemholds:$holds_count if $line{left_holds_on_order};
 500         $line{order_object}         = $order;
 501     }
 502
 503
 504     my $suggestion   = GetSuggestionInfoFromBiblionumber($line{biblionumber});
 505     $line{suggestionid}         = $$suggestion{suggestionid};
 506     $line{surnamesuggestedby}   = $$suggestion{surnamesuggestedby};
 507     $line{firstnamesuggestedby} = $$suggestion{firstnamesuggestedby};
 508
 509     foreach my $key (qw(transferred_from transferred_to)) {
 510         if ($line{$key}) {
 511             my $order = GetOrder($line{$key});
 512             my $basket = GetBasket($order->{basketno});
 513             my $bookseller = Koha::Acquisition::Booksellers->find( $basket->{booksellerid} );
 514             $line{$key} = {
 515                 order => $order,
 516                 basket => $basket,
 517                 bookseller => $bookseller,
 518                 timestamp => $line{$key . '_timestamp'},
 519             };
 520         }
 521     }
 522
 523     return \%line;
 524 }
 525
 526 sub edi_close_and_order {
 527     my $confirm = $query->param('confirm') || $confirm_pref eq '2';
 528     if ($confirm) {
 529         my $edi_params = {
 530             basketno => $basketno,
 531             ean    => $ean,
 532         };
 533         if ( $basket->{branch} ) {
 534             $edi_params->{branchcode} = $basket->{branch};
 535         }
 536         if ( create_edi_order($edi_params) ) {
 537             #$template->param( edifile => 1 );
 538         }
 539         Koha::Acquisition::Baskets->find($basketno)->close;
 540
 541         # if requested, create basket group, close it and attach the basket
 542         if ( $query->param('createbasketgroup') ) {
 543             my $branchcode;
 544             if (    C4::Context->userenv
 545                 and C4::Context->userenv->{'branch'} )
 546             {
 547                 $branchcode = C4::Context->userenv->{'branch'};
 548             }
 549             my $basketgroupid = NewBasketgroup(
 550                 {
 551                     name          => $basket->{basketname},
 552                     booksellerid  => $booksellerid,
 553                     deliveryplace => $branchcode,
 554                     billingplace  => $branchcode,
 555                     closed        => 1,
 556                 }
 557             );
 558             ModBasket(
 559                 {
 560                     basketno       => $basketno,
 561                     basketgroupid  => $basketgroupid
 562                 }
 563             );
 564             print $query->redirect(
 565 "/cgi-bin/koha/acqui/basketgroup.pl?booksellerid=$booksellerid&closed=1"
 566             );
 567         }
 568         else {
 569             print $query->redirect(
 570                 "/cgi-bin/koha/acqui/booksellers.pl?booksellerid=$booksellerid"
 571             );
 572         }
 573         exit;
 574     }
 575     else {
 576         $template->param(
 577             edi_confirm     => 1,
 578             booksellerid    => $booksellerid,
 579             basketno        => $basket->{basketno},
 580             basketname      => $basket->{basketname},
 581             basketgroupname => $basket->{basketname},
 582         );
 583         if ($ean) {
 584             $template->param( ean => $ean );
 585         }
 586
 587     }
 588     return;
 589 }