Koha/REST/V1.pm

   1 package Koha::REST::V1;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Mojo::Base 'Mojolicious';
  21
  22 use C4::Context;
  23 use Carp;
  24 use JSON::Validator::OpenAPI::Mojolicious;
  25 use Try::Tiny;
  26
  27 =head1 NAME
  28
  29 Koha::REST::V1 - Main v.1 REST api class
  30
  31 =head1 API
  32
  33 =head2 Class Methods
  34
  35 =head3 startup
  36
  37 Overloaded Mojolicious->startup method. It is called at application startup.
  38
  39 =cut
  40
  41 sub startup {
  42     my $self = shift;
  43
  44     $self->hook(
  45         before_dispatch => sub {
  46             my $c = shift;
  47
  48             # Remove /api/v1/app.pl/ from the path
  49             $c->req->url->base->path('/');
  50
  51             # Handle CORS
  52             $c->res->headers->header( 'Access-Control-Allow-Origin' =>
  53                   C4::Context->preference('AccessControlAllowOrigin') )
  54               if C4::Context->preference('AccessControlAllowOrigin');
  55         }
  56     );
  57
  58     # Force charset=utf8 in Content-Type header for JSON responses
  59     $self->types->type( json    => 'application/json; charset=utf8' );
  60     # MARC-related types
  61     $self->types->type( marcxml => 'application/marcxml+xml' );
  62     $self->types->type( mij     => 'application/marc-in-json' );
  63     $self->types->type( marc    => 'application/marc' );
  64
  65     my $secret_passphrase = C4::Context->config('api_secret_passphrase');
  66     if ($secret_passphrase) {
  67         $self->secrets([$secret_passphrase]);
  68     }
  69
  70     my $validator = JSON::Validator::OpenAPI::Mojolicious->new;
  71
  72     push @{$self->routes->namespaces}, 'Koha::Plugin';
  73
  74     # Try to load and merge all schemas first and validate the result just once.
  75     my $spec;
  76     my $swagger_schema = $self->home->rel_file("api/swagger-v2-schema.json");
  77     try {
  78         $spec = $validator->bundle(
  79             {
  80                 replace => 1,
  81                 schema => $self->home->rel_file("api/v1/swagger/swagger.json")
  82             }
  83         );
  84
  85         $self->plugin(
  86             'Koha::REST::Plugin::PluginRoutes' => {
  87                 spec               => $spec,
  88                 validator          => undef
  89             }
  90         ) unless C4::Context->needs_install; # load only if Koha is installed
  91
  92         $self->plugin(
  93             OpenAPI => {
  94                 spec  => $spec,
  95                 route => $self->routes->under('/api/v1')->to('Auth#under'),
  96                 schema => ( $swagger_schema ) ? $swagger_schema : undef,
  97                 allow_invalid_ref =>
  98                 1,    # required by our spec because $ref directly under
  99                         # Paths-, Parameters-, Definitions- & Info-object
 100                         # is not allowed by the OpenAPI specification.
 101             }
 102         );
 103     }
 104     catch {
 105         # Validation of the complete spec failed. Resort to validation one-by-one
 106         # to catch bad ones.
 107
 108         # JSON::Validator uses confess, so trim call stack from the message.
 109         carp "Warning: Could not load REST API spec bundle: " . ($_ =~ /\A(.*?)$/ms)[0];
 110
 111         try {
 112             $validator->load_and_validate_schema(
 113                 $self->home->rel_file("api/v1/swagger/swagger.json"),
 114                 {
 115                     allow_invalid_ref  => 1,
 116                     schema => ( $swagger_schema ) ? $swagger_schema : undef,
 117                 }
 118             );
 119
 120             $spec = $validator->schema->data;
 121             $self->plugin(
 122                 'Koha::REST::Plugin::PluginRoutes' => {
 123                     spec      => $spec,
 124                     validator => $validator
 125                 }
 126             )  unless C4::Context->needs_install; # load only if Koha is installed
 127
 128             $self->plugin(
 129                 OpenAPI => {
 130                     spec  => $spec,
 131                     route => $self->routes->under('/api/v1')->to('Auth#under'),
 132                     allow_invalid_ref =>
 133                     1,    # required by our spec because $ref directly under
 134                             # Paths-, Parameters-, Definitions- & Info-object
 135                             # is not allowed by the OpenAPI specification.
 136                 }
 137             );
 138         }
 139         catch {
 140             # JSON::Validator uses confess, so trim call stack from the message.
 141             croak "Could not load REST API spec: " . ($_ =~ /\A(.*?)$/ms)[0];
 142         };
 143     };
 144
 145     $self->plugin( 'Koha::REST::Plugin::Pagination' );
 146     $self->plugin( 'Koha::REST::Plugin::Query' );
 147     $self->plugin( 'Koha::REST::Plugin::Objects' );
 148     $self->plugin( 'Koha::REST::Plugin::Exceptions' );
 149 }
 150
 151 1;