Koha/REST/V1.pm

   1 package Koha::REST::V1;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Mojo::Base 'Mojolicious';
  21
  22 use C4::Context;
  23 use Koha::Logger;
  24 use Koha::Auth::Identity::Providers;
  25
  26 use Mojolicious::Plugin::OAuth2;
  27 use JSON::Validator::Schema::OpenAPIv2;
  28
  29 use Try::Tiny qw( catch try );
  30 use JSON qw( decode_json );
  31
  32 =head1 NAME
  33
  34 Koha::REST::V1 - Main v.1 REST api class
  35
  36 =head1 API
  37
  38 =head2 Class Methods
  39
  40 =head3 startup
  41
  42 Overloaded Mojolicious->startup method. It is called at application startup.
  43
  44 =cut
  45
  46 sub startup {
  47     my $self = shift;
  48
  49     my $logger = Koha::Logger->get({ interface => 'api' });
  50     $self->log($logger);
  51
  52     $self->hook(
  53         before_dispatch => sub {
  54             my $c = shift;
  55
  56             # Remove /api/v1/app.pl/ from the path
  57             $c->req->url->base->path('/');
  58
  59             # Handle CORS
  60             $c->res->headers->header( 'Access-Control-Allow-Origin' =>
  61                   C4::Context->preference('AccessControlAllowOrigin') )
  62               if C4::Context->preference('AccessControlAllowOrigin');
  63         }
  64     );
  65
  66     # Force charset=utf8 in Content-Type header for JSON responses
  67     $self->types->type( json    => 'application/json; charset=utf8' );
  68     # MARC-related types
  69     $self->types->type( marcxml => 'application/marcxml+xml' );
  70     $self->types->type( mij     => 'application/marc-in-json' );
  71     $self->types->type( marc    => 'application/marc' );
  72
  73     my $secret_passphrase = C4::Context->config('api_secret_passphrase');
  74     if ($secret_passphrase) {
  75         $self->secrets([$secret_passphrase]);
  76     }
  77
  78     my $spec_file = $self->home->rel_file("api/v1/swagger/swagger.yaml");
  79
  80     push @{$self->routes->namespaces}, 'Koha::Plugin';
  81
  82     # Try to load and merge all schemas first and validate the result just once.
  83     try {
  84
  85         my $schema = JSON::Validator::Schema::OpenAPIv2->new;
  86
  87         $schema->resolve( $spec_file );
  88
  89         my $spec = $schema->bundle->data;
  90
  91         $self->plugin(
  92             'Koha::REST::Plugin::PluginRoutes' => {
  93                 spec     => $spec,
  94                 validate => 0,
  95             }
  96         ) unless C4::Context->needs_install; # load only if Koha is installed
  97
  98         $self->plugin(
  99             OpenAPI => {
 100                 spec  => $spec,
 101                 route => $self->routes->under('/api/v1')->to('Auth#under'),
 102             }
 103         );
 104
 105         $self->plugin('RenderFile');
 106     }
 107     catch {
 108         # Validation of the complete spec failed. Resort to validation one-by-one
 109         # to catch bad ones.
 110
 111         # JSON::Validator uses confess, so trim call stack from the message.
 112         my $logger = Koha::Logger->get({ interface => 'api' });
 113         $logger->error("Warning: Could not load REST API spec bundle: " . $_);
 114
 115         try {
 116
 117             my $schema = JSON::Validator::Schema::OpenAPIv2->new;
 118             $schema->resolve( $spec_file );
 119
 120             my $spec = $schema->bundle->data;
 121
 122             $self->plugin(
 123                 'Koha::REST::Plugin::PluginRoutes' => {
 124                     spec     => $spec,
 125                     validate => 1
 126                 }
 127             )  unless C4::Context->needs_install; # load only if Koha is installed
 128
 129             $self->plugin(
 130                 OpenAPI => {
 131                     spec  => $spec,
 132                     route => $self->routes->under('/api/v1')->to('Auth#under'),
 133                 }
 134             );
 135         }
 136         catch {
 137             # JSON::Validator uses confess, so trim call stack from the message.
 138             $logger->error("Warning: Could not load REST API spec bundle: " . $_);
 139         };
 140     };
 141
 142     my $oauth_configuration = {};
 143     try {
 144         my $search_options = { protocol => [ "OIDC", "OAuth" ] };
 145
 146         my $providers = Koha::Auth::Identity::Providers->search($search_options);
 147         while ( my $provider = $providers->next ) {
 148             $oauth_configuration->{ $provider->code } = decode_json( $provider->config );
 149         }
 150     } catch {
 151         my $logger = Koha::Logger->get( { interface => 'api' } );
 152         $logger->warn( "Warning: Failed to fetch oauth configuration: " . $_ );
 153     };
 154
 155     $self->plugin( 'Koha::REST::Plugin::Pagination' );
 156     $self->plugin( 'Koha::REST::Plugin::Query' );
 157     $self->plugin( 'Koha::REST::Plugin::Objects' );
 158     $self->plugin( 'Koha::REST::Plugin::Exceptions' );
 159     $self->plugin( 'Koha::REST::Plugin::Auth::IdP' );
 160     $self->plugin( 'Mojolicious::Plugin::OAuth2' => $oauth_configuration );
 161 }
 162
 163 1;