koha-dev.rot13.org Git - srvgit/blob - Koha/REST/V1/Patrons/Password.pm

   1 package Koha::REST::V1::Patrons::Password;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Mojo::Base 'Mojolicious::Controller';
  21
  22 use C4::Auth qw(checkpw_internal);
  23
  24 use Koha::Patrons;
  25
  26 use Scalar::Util qw( blessed );
  27 use Try::Tiny qw( catch try );
  28
  29 =head1 NAME
  30
  31 Koha::REST::V1::Patrons::Password
  32
  33 =head1 API
  34
  35 =head2 Methods
  36
  37 =head3 set
  38
  39 Controller method that sets a patron's password, permission driven
  40
  41 =cut
  42
  43 sub set {
  44
  45     my $c = shift->openapi->valid_input or return;
  46
  47     my $patron = Koha::Patrons->find( $c->validation->param('patron_id') );
  48     my $body   = $c->validation->param('body');
  49
  50     unless ($patron) {
  51         return $c->render( status => 404, openapi => { error => "Patron not found." } );
  52     }
  53
  54     my $password   = $body->{password}   // "";
  55     my $password_2 = $body->{password_2} // "";
  56
  57     unless ( $password eq $password_2 ) {
  58         return $c->render( status => 400, openapi => { error => "Passwords don't match" } );
  59     }
  60
  61     return try {
  62
  63         ## Change password
  64         $patron->set_password({ password => $password });
  65
  66         return $c->render( status => 200, openapi => "" );
  67     }
  68     catch {
  69         if ( blessed $_ and $_->isa('Koha::Exceptions::Password') ) {
  70             return $c->render(
  71                 status  => 400,
  72                 openapi => { error => "$_" }
  73             );
  74         }
  75
  76         $c->unhandled_exception($_);
  77     };
  78 }
  79
  80 =head3 set_public
  81
  82 Controller method that sets a patron's password, for unprivileged users
  83
  84 =cut
  85
  86 sub set_public {
  87
  88     my $c = shift->openapi->valid_input or return;
  89
  90     my $body      = $c->validation->param('body');
  91     my $patron_id = $c->validation->param('patron_id');
  92
  93     unless ( C4::Context->preference('OpacPasswordChange') ) {
  94         return $c->render(
  95             status  => 403,
  96             openapi => { error => "Configuration prevents password changes by unprivileged users" }
  97         );
  98     }
  99
 100     my $user = $c->stash('koha.user');
 101
 102     unless ( $user->borrowernumber == $patron_id ) {
 103         return $c->render(
 104             status  => 403,
 105             openapi => {
 106                 error => "Changing other patron's password is forbidden"
 107             }
 108         );
 109     }
 110
 111     my $old_password = $body->{old_password};
 112     my $password     = $body->{password};
 113     my $password_2   = $body->{password_repeated};
 114
 115     unless ( $password eq $password_2 ) {
 116         return $c->render( status => 400, openapi => { error => "Passwords don't match" } );
 117     }
 118
 119     return try {
 120         my $dbh = C4::Context->dbh;
 121         unless ( checkpw_internal($dbh, $user->userid, $old_password ) ) {
 122             return $c->render(
 123                 status  => 400,
 124                 openapi => { error => "Invalid password" }
 125             );
 126         }
 127
 128         ## Change password
 129         $user->set_password({ password => $password });
 130
 131         return $c->render( status => 200, openapi => "" );
 132     }
 133     catch {
 134         if ( blessed $_ and $_->isa('Koha::Exceptions::Password') ) {
 135             return $c->render(
 136                 status  => 400,
 137                 openapi => { error => "$_" }
 138             );
 139         }
 140
 141         $c->unhandled_exception($_);
 142     };
 143 }
 144
 145 1;