Koha/Patrons/Import.pm

   1 package Koha::Patrons::Import;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19 use Moo;
  20 use namespace::clean;
  21
  22 use Carp;
  23 use Text::CSV;
  24 use Encode qw( decode_utf8 );
  25
  26 use C4::Members;
  27 use C4::Members::Attributes qw(:all);
  28 use C4::Members::AttributeTypes;
  29
  30 use Koha::Libraries;
  31 use Koha::Patrons;
  32 use Koha::Patron::Categories;
  33 use Koha::Patron::Debarments;
  34 use Koha::DateUtils;
  35
  36 =head1 NAME
  37
  38 Koha::Patrons::Import - Perl Module containing import_patrons method exported from import_borrowers script.
  39
  40 =head1 SYNOPSIS
  41
  42 use Koha::Patrons::Import;
  43
  44 =head1 DESCRIPTION
  45
  46 This module contains one method for importing patrons in bulk.
  47
  48 =head1 FUNCTIONS
  49
  50 =head2 import_patrons
  51
  52  my $return = Koha::Patrons::Import::import_patrons($params);
  53
  54 Applies various checks and imports patrons in bulk from a csv file.
  55
  56 Further pod documentation needed here.
  57
  58 =cut
  59
  60 has 'today_iso' => ( is => 'ro', lazy => 1,
  61     default => sub { output_pref( { dt => dt_from_string(), dateonly => 1, dateformat => 'iso' } ); }, );
  62
  63 has 'text_csv' => ( is => 'rw', lazy => 1,
  64     default => sub { Text::CSV->new( { binary => 1, } ); },  );
  65
  66 sub import_patrons {
  67     my ($self, $params) = @_;
  68
  69     my $handle = $params->{file};
  70     unless( $handle ) { carp('No file handle passed in!'); return; }
  71
  72     my $matchpoint           = $params->{matchpoint};
  73     my $defaults             = $params->{defaults};
  74     my $ext_preserve         = $params->{preserve_extended_attributes};
  75     my $overwrite_cardnumber = $params->{overwrite_cardnumber};
  76     my $extended             = C4::Context->preference('ExtendedPatronAttributes');
  77     my $set_messaging_prefs  = C4::Context->preference('EnhancedMessagingPreferences');
  78
  79     my @columnkeys = $self->set_column_keys($extended);
  80     my @feedback;
  81     my @errors;
  82
  83     my $imported    = 0;
  84     my $alreadyindb = 0;
  85     my $overwritten = 0;
  86     my $invalid     = 0;
  87     my @imported_borrowers;
  88     my $matchpoint_attr_type = $self->set_attribute_types({ extended => $extended, matchpoint => $matchpoint, });
  89
  90     # Use header line to construct key to column map
  91     my %csvkeycol;
  92     my $borrowerline = <$handle>;
  93     my @csvcolumns   = $self->prepare_columns({headerrow => $borrowerline, keycol => \%csvkeycol, errors => \@errors, });
  94     push(@feedback, { feedback => 1, name => 'headerrow', value => join( ', ', @csvcolumns ) });
  95
  96     my @criticals = qw( surname );    # there probably should be others - rm branchcode && categorycode
  97   LINE: while ( my $borrowerline = <$handle> ) {
  98         my $line_number = $.;
  99         my %borrower;
 100         my @missing_criticals;
 101
 102         my $status  = $self->text_csv->parse($borrowerline);
 103         my @columns = $self->text_csv->fields();
 104         if ( !$status ) {
 105             push @missing_criticals, { badparse => 1, line => $line_number, lineraw => decode_utf8($borrowerline) };
 106         }
 107         elsif ( @columns == @columnkeys ) {
 108             @borrower{@columnkeys} = @columns;
 109
 110             # MJR: try to fill blanks gracefully by using default values
 111             foreach my $key (@columnkeys) {
 112                 if ( $borrower{$key} !~ /\S/ ) {
 113                     $borrower{$key} = $defaults->{$key};
 114                 }
 115             }
 116         }
 117         else {
 118             # MJR: try to recover gracefully by using default values
 119             foreach my $key (@columnkeys) {
 120                 if ( defined( $csvkeycol{$key} ) and $columns[ $csvkeycol{$key} ] =~ /\S/ ) {
 121                     $borrower{$key} = $columns[ $csvkeycol{$key} ];
 122                 }
 123                 elsif ( $defaults->{$key} ) {
 124                     $borrower{$key} = $defaults->{$key};
 125                 }
 126                 elsif ( scalar grep { $key eq $_ } @criticals ) {
 127
 128                     # a critical field is undefined
 129                     push @missing_criticals, { key => $key, line => $., lineraw => decode_utf8($borrowerline) };
 130                 }
 131                 else {
 132                     $borrower{$key} = '';
 133                 }
 134             }
 135         }
 136
 137         $borrower{cardnumber} = undef if $borrower{cardnumber} eq "";
 138
 139         # Check if borrower category code exists and if it matches to a known category. Pushing error to missing_criticals otherwise.
 140         $self->check_borrower_category($borrower{categorycode}, $borrowerline, $line_number, \@missing_criticals);
 141
 142         # Check if branch code exists and if it matches to a branch name. Pushing error to missing_criticals otherwise.
 143         $self->check_branch_code($borrower{branchcode}, $borrowerline, $line_number, \@missing_criticals);
 144
 145         # Popular spreadsheet applications make it difficult to force date outputs to be zero-padded, but we require it.
 146         $self->format_dates({borrower => \%borrower, lineraw => $borrowerline, line => $line_number, missing_criticals => \@missing_criticals, });
 147
 148         if (@missing_criticals) {
 149             foreach (@missing_criticals) {
 150                 $_->{borrowernumber} = $borrower{borrowernumber} || 'UNDEF';
 151                 $_->{surname}        = $borrower{surname}        || 'UNDEF';
 152             }
 153             $invalid++;
 154             ( 25 > scalar @errors ) and push @errors, { missing_criticals => \@missing_criticals };
 155
 156             # The first 25 errors are enough.  Keeping track of 30,000+ would destroy performance.
 157             next LINE;
 158         }
 159
 160         # Set patron attributes if extended.
 161         my $patron_attributes = $self->set_patron_attributes($extended, $borrower{patron_attributes}, \@feedback);
 162         if( $extended ) { delete $borrower{patron_attributes}; } # Not really a field in borrowers.
 163
 164         # Default date enrolled and date expiry if not already set.
 165         $borrower{dateenrolled} = $self->today_iso() unless $borrower{dateenrolled};
 166         $borrower{dateexpiry} = Koha::Patron::Categories->find( $borrower{categorycode} )->get_expiry_date( $borrower{dateenrolled} ) unless $borrower{dateexpiry};
 167
 168         my $borrowernumber;
 169         my ( $member, $patron );
 170         if ( defined($matchpoint) && ( $matchpoint eq 'cardnumber' ) && ( $borrower{'cardnumber'} ) ) {
 171             $patron = Koha::Patrons->find( { cardnumber => $borrower{'cardnumber'} } );
 172         }
 173         elsif ( defined($matchpoint) && ($matchpoint eq 'userid') && ($borrower{'userid'}) ) {
 174             $patron = Koha::Patrons->find( { userid => $borrower{userid} } );
 175         }
 176         elsif ($extended) {
 177             if ( defined($matchpoint_attr_type) ) {
 178                 foreach my $attr (@$patron_attributes) {
 179                     if ( $attr->{code} eq $matchpoint and $attr->{value} ne '' ) {
 180                         my @borrowernumbers = $matchpoint_attr_type->get_patrons( $attr->{value} );
 181                         $borrowernumber = $borrowernumbers[0] if scalar(@borrowernumbers) == 1;
 182                         $patron = Koha::Patrons->find( $borrowernumber );
 183                         last;
 184                     }
 185                 }
 186             }
 187         }
 188
 189         if ($patron) {
 190             $member = $patron->unblessed;
 191             $borrowernumber = $member->{'borrowernumber'};
 192         } else {
 193             $member = {};
 194         }
 195
 196         if ( C4::Members::checkcardnumber( $borrower{cardnumber}, $borrowernumber ) ) {
 197             push @errors,
 198               {
 199                 invalid_cardnumber => 1,
 200                 borrowernumber     => $borrowernumber,
 201                 cardnumber         => $borrower{cardnumber}
 202               };
 203             $invalid++;
 204             next;
 205         }
 206
 207
 208         # Check if the userid provided does not exist yet
 209         if (    defined($matchpoint)
 210             and $matchpoint ne 'userid'
 211             and exists $borrower{userid}
 212             and $borrower{userid}
 213             and not ( $borrowernumber ? $patron->userid( $borrower{userid} )->has_valid_userid : Koha::Patron->new( { userid => $borrower{userid} } )->has_valid_userid )
 214         ) {
 215             push @errors, { duplicate_userid => 1, userid => $borrower{userid} };
 216             $invalid++;
 217             next LINE;
 218         }
 219
 220         my $relationship        = $borrower{relationship};
 221         my $guarantor_id        = $borrower{guarantor_id};
 222         delete $borrower{relationship};
 223         delete $borrower{guarantor_id};
 224
 225         # Remove warning for int datatype that cannot be null
 226         # Argument "" isn't numeric in numeric eq (==) at /usr/share/perl5/DBIx/Class/Row.pm line 1018
 227         for my $field (
 228             qw( privacy privacy_guarantor_fines privacy_guarantor_checkouts anonymized ))
 229         {
 230             delete $borrower{$field}
 231               if exists $borrower{$field} and $borrower{$field} eq "";
 232         }
 233
 234         if ($borrowernumber) {
 235
 236             # borrower exists
 237             unless ($overwrite_cardnumber) {
 238                 $alreadyindb++;
 239                 push(
 240                     @feedback,
 241                     {
 242                         already_in_db => 1,
 243                         value         => $borrower{'surname'} . ' / ' . $borrowernumber
 244                     }
 245                 );
 246                 next LINE;
 247             }
 248             $borrower{'borrowernumber'} = $borrowernumber;
 249             for my $col ( keys %borrower ) {
 250
 251                 # use values from extant patron unless our csv file includes this column or we provided a default.
 252                 # FIXME : You cannot update a field with a  perl-evaluated false value using the defaults.
 253
 254                 # The password is always encrypted, skip it!
 255                 next if $col eq 'password';
 256
 257                 unless ( exists( $csvkeycol{$col} ) || $defaults->{$col} ) {
 258                     $borrower{$col} = $member->{$col} if ( $member->{$col} );
 259                 }
 260             }
 261
 262             my $patron = Koha::Patrons->find( $borrowernumber );
 263             eval { $patron->set(\%borrower)->store };
 264             if ( $@ ) {
 265                 $invalid++;
 266
 267                 push(
 268                     @errors,
 269                     {
 270                         # TODO We can raise a better error
 271                         name  => 'lastinvalid',
 272                         value => $borrower{'surname'} . ' / ' . $borrowernumber
 273                     }
 274                 );
 275                 next LINE;
 276             }
 277             # Don't add a new restriction if the existing 'combined' restriction matches this one
 278             if ( $borrower{debarred} && ( ( $borrower{debarred} ne $member->{debarred} ) || ( $borrower{debarredcomment} ne $member->{debarredcomment} ) ) ) {
 279
 280                 # Check to see if this debarment already exists
 281                 my $debarrments = GetDebarments(
 282                     {
 283                         borrowernumber => $borrowernumber,
 284                         expiration     => $borrower{debarred},
 285                         comment        => $borrower{debarredcomment}
 286                     }
 287                 );
 288
 289                 # If it doesn't, then add it!
 290                 unless (@$debarrments) {
 291                     AddDebarment(
 292                         {
 293                             borrowernumber => $borrowernumber,
 294                             expiration     => $borrower{debarred},
 295                             comment        => $borrower{debarredcomment}
 296                         }
 297                     );
 298                 }
 299             }
 300             if ($extended) {
 301                 if ($ext_preserve) {
 302                     my $old_attributes = $patron->extended_attributes->as_list;
 303                     $patron_attributes = extended_attributes_merge( $old_attributes, $patron_attributes );
 304                 }
 305                 eval {
 306                     # We do not want to filter by branch, maybe we should?
 307                     Koha::Patrons->find($borrowernumber)->extended_attributes->delete;
 308                     $patron->extended_attributes($patron_attributes);
 309                 };
 310                 if ($@) {
 311                     # FIXME This is not an unknown error, we can do better here
 312                     push @errors, { unknown_error => 1 };
 313                 }
 314             }
 315             $overwritten++;
 316             push(
 317                 @feedback,
 318                 {
 319                     feedback => 1,
 320                     name     => 'lastoverwritten',
 321                     value    => $borrower{'surname'} . ' / ' . $borrowernumber
 322                 }
 323             );
 324         }
 325         else {
 326             my $patron = eval {
 327                 Koha::Patron->new(\%borrower)->store;
 328             };
 329             unless ( $@ ) {
 330
 331                 if ( $patron->is_debarred ) {
 332                     AddDebarment(
 333                         {
 334                             borrowernumber => $patron->borrowernumber,
 335                             expiration     => $patron->debarred,
 336                             comment        => $patron->debarredcomment,
 337                         }
 338                     );
 339                 }
 340
 341                 if ($extended) {
 342                     # FIXME Hum, we did not filter earlier and now we do?
 343                     $patron->extended_attributes->filter_by_branch_limitations->delete;
 344                     $patron->extended_attributes($patron_attributes);
 345                 }
 346
 347                 if ($set_messaging_prefs) {
 348                     C4::Members::Messaging::SetMessagingPreferencesFromDefaults(
 349                         {
 350                             borrowernumber => $patron->borrowernumber,
 351                             categorycode   => $patron->categorycode,
 352                         }
 353                     );
 354                 }
 355
 356                 $imported++;
 357                 push @imported_borrowers, $patron->borrowernumber; #for patronlist
 358                 push(
 359                     @feedback,
 360                     {
 361                         feedback => 1,
 362                         name     => 'lastimported',
 363                         value    => $patron->surname . ' / ' . $patron->borrowernumber,
 364                     }
 365                 );
 366             }
 367             else {
 368                 $invalid++;
 369                 push @errors, { unknown_error => 1 };
 370                 push(
 371                     @errors,
 372                     {
 373                         name  => 'lastinvalid',
 374                         value => $borrower{'surname'} . ' / Create patron',
 375                     }
 376                 );
 377             }
 378         }
 379
 380         # Add a guarantor if we are given a relationship
 381         if ( $guarantor_id ) {
 382             Koha::Patron::Relationship->new(
 383                 {
 384                     guarantee_id => $borrowernumber,
 385                     relationship => $relationship,
 386                     guarantor_id => $guarantor_id,
 387                 }
 388             )->store();
 389         }
 390     }
 391
 392     return {
 393         feedback      => \@feedback,
 394         errors        => \@errors,
 395         imported      => $imported,
 396         overwritten   => $overwritten,
 397         already_in_db => $alreadyindb,
 398         invalid       => $invalid,
 399         imported_borrowers => \@imported_borrowers,
 400     };
 401 }
 402
 403 =head2 prepare_columns
 404
 405  my @csvcolumns = $self->prepare_columns({headerrow => $borrowerline, keycol => \%csvkeycol, errors => \@errors, });
 406
 407 Returns an array of all column key and populates a hash of colunm key positions.
 408
 409 =cut
 410
 411 sub prepare_columns {
 412     my ($self, $params) = @_;
 413
 414     my $status = $self->text_csv->parse($params->{headerrow});
 415     unless( $status ) {
 416         push( @{$params->{errors}}, { badheader => 1, line => 1, lineraw => $params->{headerrow} });
 417         return;
 418     }
 419
 420     my @csvcolumns = $self->text_csv->fields();
 421     my $col = 0;
 422     foreach my $keycol (@csvcolumns) {
 423         # columnkeys don't contain whitespace, but some stupid tools add it
 424         $keycol =~ s/ +//g;
 425         $keycol =~ s/^\N{BOM}//; # Strip BOM if exists, otherwise it will be part of first column key
 426         $params->{keycol}->{$keycol} = $col++;
 427     }
 428
 429     return @csvcolumns;
 430 }
 431
 432 =head2 set_attribute_types
 433
 434  my $matchpoint_attr_type = $self->set_attribute_types({ extended => $extended, matchpoint => $matchpoint, });
 435
 436 Returns an attribute type based on matchpoint parameter.
 437
 438 =cut
 439
 440 sub set_attribute_types {
 441     my ($self, $params) = @_;
 442
 443     my $attribute_types;
 444     if( $params->{extended} ) {
 445         $attribute_types = C4::Members::AttributeTypes->fetch($params->{matchpoint});
 446     }
 447
 448     return $attribute_types;
 449 }
 450
 451 =head2 set_column_keys
 452
 453  my @columnkeys = set_column_keys($extended);
 454
 455 Returns an array of borrowers' table columns.
 456
 457 =cut
 458
 459 sub set_column_keys {
 460     my ($self, $extended) = @_;
 461
 462     my @columnkeys = map { $_ ne 'borrowernumber' ? $_ : () } Koha::Patrons->columns();
 463     push( @columnkeys, 'patron_attributes' ) if $extended;
 464
 465     return @columnkeys;
 466 }
 467
 468 =head2 set_patron_attributes
 469
 470  my $patron_attributes = set_patron_attributes($extended, $borrower{patron_attributes}, $feedback);
 471
 472 Returns a reference to array of hashrefs data structure as expected by Koha::Patron->extended_attributes
 473
 474 =cut
 475
 476 sub set_patron_attributes {
 477     my ($self, $extended, $patron_attributes, $feedback) = @_;
 478
 479     unless( $extended ) { return; }
 480     unless( defined($patron_attributes) ) { return; }
 481
 482     # Fixup double quotes in case we are passed smart quotes
 483     $patron_attributes =~ s/\xe2\x80\x9c/"/g;
 484     $patron_attributes =~ s/\xe2\x80\x9d/"/g;
 485
 486     push (@$feedback, { feedback => 1, name => 'attribute string', value => $patron_attributes });
 487
 488     my $result = extended_attributes_code_value_arrayref($patron_attributes);
 489
 490     return $result;
 491 }
 492
 493 =head2 check_branch_code
 494
 495  check_branch_code($borrower{branchcode}, $borrowerline, $line_number, \@missing_criticals);
 496
 497 Pushes a 'missing_criticals' error entry if no branch code or branch code does not map to a branch name.
 498
 499 =cut
 500
 501 sub check_branch_code {
 502     my ($self, $branchcode, $borrowerline, $line_number, $missing_criticals) = @_;
 503
 504     # No branch code
 505     unless( $branchcode ) {
 506         push (@$missing_criticals, { key => 'branchcode', line => $line_number, lineraw => decode_utf8($borrowerline), });
 507         return;
 508     }
 509
 510     # look for branch code
 511     my $library = Koha::Libraries->find( $branchcode );
 512     unless( $library ) {
 513         push (@$missing_criticals, { key => 'branchcode', line => $line_number, lineraw => decode_utf8($borrowerline),
 514                                      value => $branchcode, branch_map => 1, });
 515     }
 516 }
 517
 518 =head2 check_borrower_category
 519
 520  check_borrower_category($borrower{categorycode}, $borrowerline, $line_number, \@missing_criticals);
 521
 522 Pushes a 'missing_criticals' error entry if no category code or category code does not map to a known category.
 523
 524 =cut
 525
 526 sub check_borrower_category {
 527     my ($self, $categorycode, $borrowerline, $line_number, $missing_criticals) = @_;
 528
 529     # No branch code
 530     unless( $categorycode ) {
 531         push (@$missing_criticals, { key => 'categorycode', line => $line_number, lineraw => decode_utf8($borrowerline), });
 532         return;
 533     }
 534
 535     # Looking for borrower category
 536     my $category = Koha::Patron::Categories->find($categorycode);
 537     unless( $category ) {
 538         push (@$missing_criticals, { key => 'categorycode', line => $line_number, lineraw => decode_utf8($borrowerline),
 539                                      value => $categorycode, category_map => 1, });
 540     }
 541 }
 542
 543 =head2 format_dates
 544
 545  format_dates({borrower => \%borrower, lineraw => $lineraw, line => $line_number, missing_criticals => \@missing_criticals, });
 546
 547 Pushes a 'missing_criticals' error entry for each of the 3 date types dateofbirth, dateenrolled and dateexpiry if it can not
 548 be formatted to the chosen date format. Populates the correctly formatted date otherwise.
 549
 550 =cut
 551
 552 sub format_dates {
 553     my ($self, $params) = @_;
 554
 555     foreach my $date_type (qw(dateofbirth dateenrolled dateexpiry date_renewed)) {
 556         my $tempdate = $params->{borrower}->{$date_type} or next();
 557         my $formatted_date = eval { output_pref( { dt => dt_from_string( $tempdate ), dateonly => 1, dateformat => 'iso' } ); };
 558
 559         if ($formatted_date) {
 560             $params->{borrower}->{$date_type} = $formatted_date;
 561         } else {
 562             $params->{borrower}->{$date_type} = '';
 563             push (@{$params->{missing_criticals}}, { key => $date_type, line => $params->{line}, lineraw => decode_utf8($params->{lineraw}), bad_date => 1 });
 564         }
 565     }
 566 }
 567
 568 1;
 569
 570 =head1 AUTHOR
 571
 572 Koha Team
 573
 574 =cut