koha-dev.rot13.org Git - srvgit/blob - Koha/Patron/Relationship.pm

   1 package Koha::Patron::Relationship;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Carp;
  21 use List::MoreUtils qw( any );
  22 use Try::Tiny;
  23
  24 use Koha::Database;
  25 use Koha::Exceptions::Patron::Relationship;
  26
  27 use base qw(Koha::Object);
  28
  29 =head1 NAME
  30
  31 Koha::Patron::Relationship - A class to represent relationships between patrons
  32
  33 Patrons in Koha may be guarantors or guarantees. This class models that relationship
  34 and provides a way to access those relationships.
  35
  36 =head1 API
  37
  38 =head2 Class methods
  39
  40 =cut
  41
  42 =head3 store
  43
  44 Overloaded method that makes some checks before storing on the DB
  45
  46 =cut
  47
  48 sub store {
  49     my ( $self ) = @_;
  50
  51     my @valid_relationships = split /,|\|/, C4::Context->preference('borrowerRelationship');
  52
  53     Koha::Exceptions::Patron::Relationship::InvalidRelationship->throw(
  54         no_relationship => 1 )
  55         unless defined $self->relationship;
  56
  57     Koha::Exceptions::Patron::Relationship::InvalidRelationship->throw(
  58         relationship => $self->relationship )
  59         unless any { $_ eq $self->relationship } @valid_relationships;
  60
  61     return try {
  62         $self->SUPER::store;
  63     }
  64     catch {
  65         if ( ref($_) eq 'Koha::Exceptions::Object::DuplicateID' ) {
  66             Koha::Exceptions::Patron::Relationship::DuplicateRelationship->throw(
  67                 guarantee_id => $self->guarantee_id,
  68                 guarantor_id => $self->guarantor_id
  69             );
  70         }
  71     };
  72 }
  73
  74 =head3 guarantor
  75
  76 Returns the Koha::Patron object for the guarantor, if there is one
  77
  78 =cut
  79
  80 sub guarantor {
  81     my ( $self ) = @_;
  82
  83     return unless $self->guarantor_id;
  84
  85     return Koha::Patrons->find( $self->guarantor_id );
  86 }
  87
  88 =head3 guarantee
  89
  90 Returns the Koha::Patron object for the guarantee
  91
  92 =cut
  93
  94 sub guarantee {
  95     my ( $self ) = @_;
  96
  97     return Koha::Patrons->find( $self->guarantee_id );
  98 }
  99
 100 =head3 type
 101
 102 =cut
 103
 104 sub _type {
 105     return 'BorrowerRelationship';
 106 }
 107
 108 1;