koha-dev.rot13.org Git - srvgit/blob - Koha/Patron/Password/Recovery.pm

   1 package Koha::Patron::Password::Recovery;
   2
   3 # Copyright 2014 Solutions InLibro inc.
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use C4::Context;
  22 use C4::Letters;
  23 use Crypt::Eksblowfish::Bcrypt qw( en_base64 );
  24 use Koha::DateUtils qw( dt_from_string );
  25
  26 our (@ISA, @EXPORT_OK);
  27 BEGIN {
  28     require Exporter;
  29     @ISA = qw(Exporter);
  30     @EXPORT_OK = qw(
  31       &ValidateBorrowernumber
  32       &SendPasswordRecoveryEmail
  33       &GetValidLinkInfo
  34       &CompletePasswordRecovery
  35       &DeleteExpiredPasswordRecovery
  36     );
  37 }
  38
  39 =head1 NAME
  40
  41 Koha::Patron::Password::Recovery - Koha password recovery module
  42
  43 =head1 SYNOPSIS
  44
  45 use Koha::Patron::Password::Recovery;
  46
  47 =head1 FUNCTIONS
  48
  49 =head2 ValidateBorrowernumber
  50
  51 $alread = ValidateBorrowernumber( $borrower_number );
  52
  53 Check if the system already start recovery
  54
  55 Returns true false
  56
  57 =cut
  58
  59 sub ValidateBorrowernumber {
  60     my ($borrower_number) = @_;
  61     my $schema = Koha::Database->new->schema;
  62
  63     my $rs = $schema->resultset('BorrowerPasswordRecovery')->search(
  64         {
  65             borrowernumber => $borrower_number,
  66             valid_until    => \'> NOW()'
  67         },
  68         { columns => 'borrowernumber' }
  69     );
  70     if ( $rs->next ) {
  71         return 1;
  72     }
  73     return 0;
  74 }
  75
  76 =head2 GetValidLinkInfo
  77
  78     Check if the link is still valid and return some info.
  79
  80 =cut
  81
  82 sub GetValidLinkInfo {
  83     my ($uniqueKey) = @_;
  84     my $dbh         = C4::Context->dbh;
  85     my $query       = '
  86     SELECT borrower_password_recovery.borrowernumber, userid
  87     FROM borrower_password_recovery, borrowers
  88     WHERE borrowers.borrowernumber = borrower_password_recovery.borrowernumber
  89     AND NOW() < valid_until
  90     AND uuid = ?
  91     ';
  92     my $sth = $dbh->prepare($query);
  93     $sth->execute($uniqueKey);
  94     return $sth->fetchrow;
  95 }
  96
  97 =head2 SendPasswordRecoveryEmail
  98
  99  It creates an email using the templates and sends it to the user, using the specified email
 100
 101 =cut
 102
 103 sub SendPasswordRecoveryEmail {
 104     my $borrower  = shift;    # Koha::Patron
 105     my $userEmail = shift;    #to_address (the one specified in the request)
 106     my $update    = shift;
 107     my $staff     = shift // 0;
 108
 109     my $schema = Koha::Database->new->schema;
 110
 111     # generate UUID
 112     my $uuid_str;
 113     do {
 114         $uuid_str = '$2a$08$'.en_base64(Koha::AuthUtils::generate_salt('weak', 16));
 115     } while ( substr ( $uuid_str, -1, 1 ) eq '.' );
 116
 117     # insert into database
 118     my $days = $staff ? 5 : 2;
 119     my $expirydate =
 120       dt_from_string()->add( days => $days );
 121     if ($update) {
 122         my $rs =
 123           $schema->resultset('BorrowerPasswordRecovery')
 124           ->search( { borrowernumber => $borrower->borrowernumber, } );
 125         $rs->update(
 126             { uuid => $uuid_str, valid_until => $expirydate->datetime() } );
 127     }
 128     else {
 129         my $rs = $schema->resultset('BorrowerPasswordRecovery')->create(
 130             {
 131                 borrowernumber => $borrower->borrowernumber,
 132                 uuid           => $uuid_str,
 133                 valid_until    => $expirydate->datetime()
 134             }
 135         );
 136     }
 137
 138     # create link
 139     my $opacbase = C4::Context->preference('OPACBaseURL') || '';
 140     my $uuidLink = $opacbase
 141       . "/cgi-bin/koha/opac-password-recovery.pl?uniqueKey=$uuid_str";
 142
 143     # prepare the email
 144     my $letter = C4::Letters::GetPreparedLetter(
 145         module      => 'members',
 146         letter_code => $staff ? 'STAFF_PASSWORD_RESET' : 'PASSWORD_RESET',
 147         branchcode  => $borrower->branchcode,
 148         lang        => $borrower->lang,
 149         substitute =>
 150           { passwordreseturl => $uuidLink, user => $borrower->userid },
 151     );
 152
 153     # define from emails
 154     my $library = $borrower->library;
 155     my $kohaEmail = $library->from_email_address; # send from patron's branch or Koha Admin
 156
 157     my $message_id = C4::Letters::EnqueueLetter(
 158         {
 159             letter                 => $letter,
 160             borrowernumber         => $borrower->borrowernumber,
 161             to_address             => $userEmail,
 162             from_address           => $kohaEmail,
 163             message_transport_type => 'email',
 164         }
 165     );
 166
 167     my $num_letters_attempted =
 168       C4::Letters::SendQueuedMessages( { message_id => $message_id } );
 169
 170     return ($num_letters_attempted > 0);
 171 }
 172
 173 =head2 CompletePasswordRecovery
 174
 175     $bool = CompletePasswordRecovery($uuid);
 176
 177     Deletes a password recovery entry.
 178
 179 =cut
 180
 181 sub CompletePasswordRecovery {
 182     my $uniqueKey = shift;
 183     my $model =
 184       Koha::Database->new->schema->resultset('BorrowerPasswordRecovery');
 185     my $entry = $model->search(
 186         { -or => [ uuid => $uniqueKey, valid_until => \'< NOW()' ] } );
 187     return $entry->delete();
 188 }
 189
 190 =head2 DeleteExpiredPasswordRecovery
 191
 192     $bool = DeleteExpiredPasswordRecovery($borrowernumber)
 193
 194     Deletes an expired password recovery entry.
 195
 196 =cut
 197
 198 sub DeleteExpiredPasswordRecovery {
 199     my $borrower_number = shift;
 200     my $model =
 201       Koha::Database->new->schema->resultset('BorrowerPasswordRecovery');
 202     my $entry = $model->search(
 203         { borrowernumber => $borrower_number } );
 204     return $entry->delete();
 205 }
 206
 207
 208 END { }    # module clean-up code here (global destructor)
 209
 210 1;