koha-dev.rot13.org Git - srvgit/blob - Koha/Patron/Attribute.pm

   1 package Koha::Patron::Attribute;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Koha::Database;
  21 use Koha::Exceptions::Patron::Attribute;
  22 use Koha::Patron::Attribute::Types;
  23 use Koha::AuthorisedValues;
  24
  25 use base qw(Koha::Object);
  26
  27 =head1 NAME
  28
  29 Koha::Patron::Attribute - Koha Patron Attribute Object class
  30
  31 =head1 API
  32
  33 =head2 Class Methods
  34
  35 =cut
  36
  37 =head3 store
  38
  39     my $attribute = Koha::Patron::Attribute->new({ code => 'a_code', ... });
  40     try { $attribute->store }
  41     catch { handle_exception };
  42
  43 =cut
  44
  45 sub store {
  46
  47     my $self = shift;
  48
  49     $self->_check_repeatable;
  50     $self->check_unique_id;
  51
  52     return $self->SUPER::store();
  53 }
  54
  55 =head3 type
  56
  57     my $attribute_type = $attribute->type;
  58
  59 Returns a C<Koha::Patron::Attribute::Type> object corresponding to the current patron attribute
  60
  61 =cut
  62
  63 sub type {
  64
  65     my $self = shift;
  66
  67     return scalar Koha::Patron::Attribute::Types->find( $self->code );
  68 }
  69
  70 =head3 authorised_value
  71
  72 my $authorised_value = $attribute->authorised_value;
  73
  74 Return the Koha::AuthorisedValue object of this attribute when one is attached.
  75
  76 Return undef if this attribute is not attached to an authorised value
  77
  78 =cut
  79
  80 sub authorised_value {
  81     my ($self) = @_;
  82
  83     return unless $self->type->authorised_value_category;
  84
  85     my $av = Koha::AuthorisedValues->search(
  86         {
  87             category         => $self->type->authorised_value_category,
  88             authorised_value => $self->attribute,
  89         }
  90     );
  91     return unless $av->count; # Data inconsistency
  92     return $av->next;
  93 }
  94
  95 =head3 description
  96
  97 my $description = $patron_attribute->description;
  98
  99 Return the value of this attribute or the description of the authorised value (when attached).
 100
 101 This method must be called when the authorised value's description must be
 102 displayed instead of the code.
 103
 104 =cut
 105
 106 sub description {
 107     my ( $self) = @_;
 108     if ( $self->type->authorised_value_category ) {
 109         return $self->authorised_value->lib;
 110     }
 111     return $self->attribute;
 112 }
 113
 114
 115 =head2 Internal methods
 116
 117 =head3 _check_repeatable
 118
 119 _check_repeatable checks if the attribute type is repeatable and throws and exception
 120 if the attribute type isn't repeatable and there's already an attribute with the same
 121 code for the given patron.
 122
 123 =cut
 124
 125 sub _check_repeatable {
 126
 127     my $self = shift;
 128
 129     if ( !$self->type->repeatable ) {
 130         my $attr_count = Koha::Patron::Attributes->search(
 131             {   borrowernumber => $self->borrowernumber,
 132                 code           => $self->code
 133             }
 134             )->count;
 135         Koha::Exceptions::Patron::Attribute::NonRepeatable->throw()
 136             if $attr_count > 0;
 137     }
 138
 139     return $self;
 140 }
 141
 142 =head3 check_unique_id
 143
 144 check_unique_id checks if the attribute type is marked as unique id and throws and exception
 145 if the attribute type is a unique id and there's already an attribute with the same
 146 code and value on the database.
 147
 148 =cut
 149
 150 sub check_unique_id {
 151
 152     my $self = shift;
 153
 154     if ( $self->type->unique_id ) {
 155         my $params = { code => $self->code, attribute => $self->attribute };
 156
 157         $params->{borrowernumber} = { '!=' => $self->borrowernumber } if $self->borrowernumber;
 158         $params->{id}             = { '!=' => $self->id }             if $self->in_storage;
 159
 160         my $unique_count = Koha::Patron::Attributes
 161             ->search( $params )
 162             ->count;
 163         Koha::Exceptions::Patron::Attribute::UniqueIDConstraint->throw()
 164             if $unique_count > 0;
 165     }
 166
 167     return $self;
 168 }
 169
 170 =head3 _type
 171
 172 =cut
 173
 174 sub _type {
 175     return 'BorrowerAttribute';
 176 }
 177
 178 1;