Koha/Holds.pm

   1 package Koha::Holds;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use Koha::Database;
  25
  26 use Koha::Hold;
  27
  28 use base qw(Koha::Objects);
  29
  30 =head1 NAME
  31
  32 Koha::Holds - Koha Hold object set class
  33
  34 =head1 API
  35
  36 =head2 Class Methods
  37
  38 =cut
  39
  40 =head3 waiting
  41
  42 returns a set of holds that are waiting from an existing set
  43
  44 =cut
  45
  46 sub waiting {
  47     my ( $self ) = @_;
  48
  49     return $self->search( { found => 'W' } );
  50 }
  51
  52 =head3 unfilled
  53
  54 returns a set of holds that are unfilled from an existing set
  55
  56 =cut
  57
  58 sub unfilled {
  59     my ( $self ) = @_;
  60
  61     return $self->search( { found => undef } );
  62 }
  63
  64 =head3 forced_hold_level
  65
  66 If a patron has multiple holds for a single record,
  67 those holds must be either all record level holds,
  68 or they must all be item level holds.
  69
  70 This method should be used with Hold sets where all
  71 Hold objects share the same patron and record.
  72
  73 This method will return 'item' if the patron has
  74 at least one item level hold. It will return 'record'
  75 if the patron has holds but none are item level,
  76 Finally, if the patron has no holds, it will return
  77 undef which indicates the patron may select either
  78 record or item level holds, barring any other rules
  79 that would prevent one or the other.
  80
  81 =cut
  82
  83 sub forced_hold_level {
  84     my ($self) = @_;
  85
  86     my $item_level_count = $self->search( { itemnumber => { '!=' => undef } } )->count();
  87     return 'item' if $item_level_count > 0;
  88
  89     my $record_level_count = $self->search( { itemnumber => undef } )->count();
  90     return 'record' if $record_level_count > 0;
  91
  92     return;
  93 }
  94
  95 =head3 get_items_that_can_fill
  96
  97 Developer will certainly submit an appropriate description.
  98
  99 =cut
 100
 101 sub get_items_that_can_fill {
 102     my ( $self ) = @_;
 103
 104     my @biblionumbers = $self->get_column('biblionumber');
 105
 106     my @branchtransfers = map { $_->itemnumber }
 107       Koha::Item::Transfers->search(
 108           { datearrived => undef },
 109           {
 110               columns => ['itemnumber'],
 111               collapse => 1,
 112           }
 113       );
 114     my @waiting_holds = map { $_->itemnumber }
 115       Koha::Holds->search(
 116           { 'found' => 'W' },
 117           {
 118               columns => ['itemnumber'],
 119               collapse => 1,
 120           }
 121       );
 122
 123     return Koha::Items->search(
 124         {
 125             biblionumber => { in => \@biblionumbers },
 126             itemlost     => 0,
 127             withdrawn    => 0,
 128             notforloan   => 0,
 129             onloan       => undef,
 130             itemnumber   => { -not_in => [ @branchtransfers, @waiting_holds ] },
 131         }
 132     );
 133 }
 134
 135 =head3 type
 136
 137 =cut
 138
 139 sub _type {
 140     return 'Reserve';
 141 }
 142
 143 =head3 object_class
 144
 145 =cut
 146
 147 sub object_class {
 148     return 'Koha::Hold';
 149 }
 150
 151 =head1 AUTHOR
 152
 153 Kyle M Hall <kyle@bywatersolutions.com>
 154
 155 =cut
 156
 157 1;