koha-dev.rot13.org Git - srvgit/blob - Koha/BackgroundJob/BatchUpdateBiblio.pm

   1 package Koha::BackgroundJob::BatchUpdateBiblio;
   2
   3 use Modern::Perl;
   4 use Koha::BackgroundJobs;
   5 use Koha::DateUtils qw( dt_from_string );
   6 use JSON qw( encode_json decode_json );
   7
   8 use base 'Koha::BackgroundJob';
   9
  10 sub process {
  11     my ( $self, $args ) = @_;
  12
  13     my $job_type = $args->{job_type};
  14
  15     my $job = Koha::BackgroundJobs->find( $args->{job_id} );
  16
  17     if ( !exists $args->{job_id} || !$job || $job->status eq 'cancelled' ) {
  18         return;
  19     }
  20
  21     my $job_progress = 0;
  22     $job->started_on(dt_from_string)
  23         ->progress($job_progress)
  24         ->status('started')
  25         ->store;
  26
  27     my $mmtid = $args->{mmtid};
  28     my $record_type = $args->{record_type};
  29     my @record_ids = @{ $args->{record_ids} };
  30
  31     my $report = {
  32         total_records => scalar @record_ids,
  33         total_success => 0,
  34     };
  35     my @messages;
  36     my $dbh = C4::Context->dbh;
  37     $dbh->{RaiseError} = 1;
  38     RECORD_IDS: for my $biblionumber ( sort { $a <=> $b } @record_ids ) {
  39
  40         last if $job->get_from_storage->status eq 'cancelled';
  41
  42         next unless $biblionumber;
  43
  44         # Modify the biblio
  45         my $error = eval {
  46             my $record = C4::Biblio::GetMarcBiblio({ biblionumber => $biblionumber });
  47             C4::MarcModificationTemplates::ModifyRecordWithTemplate( $mmtid, $record );
  48             my $frameworkcode = C4::Biblio::GetFrameworkCode( $biblionumber );
  49             C4::Biblio::ModBiblio( $record, $biblionumber, $frameworkcode );
  50         };
  51         if ( $error and $error != 1 or $@ ) { # ModBiblio returns 1 if everything as gone well
  52             push @messages, {
  53                 type => 'error',
  54                 code => 'biblio_not_modified',
  55                 biblionumber => $biblionumber,
  56                 error => ($@ ? $@ : $error),
  57             };
  58         } else {
  59             push @messages, {
  60                 type => 'success',
  61                 code => 'biblio_modified',
  62                 biblionumber => $biblionumber,
  63             };
  64             $report->{total_success}++;
  65         }
  66         $job->progress( ++$job_progress )->store;
  67     }
  68
  69     my $job_data = decode_json $job->data;
  70     $job_data->{messages} = \@messages;
  71     $job_data->{report} = $report;
  72
  73     $job->ended_on(dt_from_string)
  74         ->data(encode_json $job_data);
  75     $job->status('finished') if $job->status ne 'cancelled';
  76     $job->store;
  77 }
  78
  79 sub enqueue {
  80     my ( $self, $args) = @_;
  81
  82     # TODO Raise exception instead
  83     return unless exists $args->{mmtid};
  84     return unless exists $args->{record_type}; #FIXME RMME
  85     return unless exists $args->{record_ids};
  86
  87     my $mmtid = $args->{mmtid};
  88     my $record_type = $args->{record_type};
  89     my @record_ids = @{ $args->{record_ids} };
  90
  91     $self->SUPER::enqueue({
  92         job_type => 'batch_biblio_record_modification', # FIXME Must be a global const
  93         job_size => scalar @record_ids,
  94         job_args => {mmtid => $mmtid, record_type => $record_type, record_ids => \@record_ids,}
  95     });
  96 }
  97
  98 1;