koha-dev.rot13.org Git - srvgit/blob - C4/Reports/Guided.pm

   1 package C4::Reports::Guided;
   2
   3 # Copyright 2007 Liblime Ltd
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use CGI qw ( -utf8 );
  22 use Carp;
  23 use JSON qw( from_json );
  24
  25 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  26 use C4::Context;
  27 use C4::Templates qw/themelanguage/;
  28 use C4::Koha;
  29 use Koha::DateUtils;
  30 use Koha::Patrons;
  31 use Koha::Reports;
  32 use C4::Output;
  33 use C4::Debug;
  34 use C4::Log;
  35 use Koha::Notice::Templates;
  36 use C4::Letters;
  37
  38 use Koha::AuthorisedValues;
  39 use Koha::Patron::Categories;
  40 use Koha::SharedContent;
  41
  42 BEGIN {
  43     require Exporter;
  44     @ISA    = qw(Exporter);
  45     @EXPORT = qw(
  46       get_report_types get_report_areas get_report_groups get_columns build_query get_criteria
  47       save_report get_saved_reports execute_query
  48       get_column_type get_distinct_values save_dictionary get_from_dictionary
  49       delete_definition delete_report format_results get_sql
  50       nb_rows update_sql
  51       GetReservedAuthorisedValues
  52       GetParametersFromSQL
  53       IsAuthorisedValueValid
  54       ValidateSQLParameters
  55       nb_rows update_sql
  56     );
  57 }
  58
  59 =head1 NAME
  60
  61 C4::Reports::Guided - Module for generating guided reports
  62
  63 =head1 SYNOPSIS
  64
  65   use C4::Reports::Guided;
  66
  67 =head1 DESCRIPTION
  68
  69 =cut
  70
  71 =head1 METHODS
  72
  73 =head2 get_report_areas
  74
  75 This will return a list of all the available report areas
  76
  77 =cut
  78
  79 sub get_area_name_sql_snippet {
  80     my @REPORT_AREA = (
  81         [CIRC => "Circulation"],
  82         [CAT  => "Catalogue"],
  83         [PAT  => "Patrons"],
  84         [ACQ  => "Acquisition"],
  85         [ACC  => "Accounts"],
  86         [SER  => "Serials"],
  87     );
  88
  89     return "CASE report_area " .
  90     join (" ", map "WHEN '$_->[0]' THEN '$_->[1]'", @REPORT_AREA) .
  91     " END AS areaname";
  92 }
  93
  94 sub get_report_areas {
  95
  96     my $report_areas = [ 'CIRC', 'CAT', 'PAT', 'ACQ', 'ACC', 'SER' ];
  97
  98     return $report_areas;
  99 }
 100
 101 sub get_table_areas {
 102     return (
 103     CIRC => [ 'borrowers', 'statistics', 'items', 'biblioitems' ],
 104     CAT  => [ 'items', 'biblioitems', 'biblio' ],
 105     PAT  => ['borrowers'],
 106     ACQ  => [ 'aqorders', 'biblio', 'items' ],
 107     ACC  => [ 'borrowers', 'accountlines' ],
 108     SER  => [ 'serial', 'serialitems', 'subscription', 'subscriptionhistory', 'subscriptionroutinglist', 'biblioitems', 'biblio', 'aqbooksellers' ],
 109     );
 110 }
 111
 112 =head2 get_report_types
 113
 114 This will return a list of all the available report types
 115
 116 =cut
 117
 118 sub get_report_types {
 119     my $dbh = C4::Context->dbh();
 120
 121     # FIXME these should be in the database perhaps
 122     my @reports = ( 'Tabular', 'Summary', 'Matrix' );
 123     my @reports2;
 124     for ( my $i = 0 ; $i < 3 ; $i++ ) {
 125         my %hashrep;
 126         $hashrep{id}   = $i + 1;
 127         $hashrep{name} = $reports[$i];
 128         push @reports2, \%hashrep;
 129     }
 130     return ( \@reports2 );
 131
 132 }
 133
 134 =head2 get_report_groups
 135
 136 This will return a list of all the available report areas with groups
 137
 138 =cut
 139
 140 sub get_report_groups {
 141     my $dbh = C4::Context->dbh();
 142
 143     my $groups = GetAuthorisedValues('REPORT_GROUP');
 144     my $subgroups = GetAuthorisedValues('REPORT_SUBGROUP');
 145
 146     my %groups_with_subgroups = map { $_->{authorised_value} => {
 147                         name => $_->{lib},
 148                         groups => {}
 149                     } } @$groups;
 150     foreach (@$subgroups) {
 151         my $sg = $_->{authorised_value};
 152         my $g = $_->{lib_opac}
 153           or warn( qq{REPORT_SUBGROUP "$sg" without REPORT_GROUP (lib_opac)} ),
 154              next;
 155         my $g_sg = $groups_with_subgroups{$g}
 156           or warn( qq{REPORT_SUBGROUP "$sg" with invalid REPORT_GROUP "$g"} ),
 157              next;
 158         $g_sg->{subgroups}{$sg} = $_->{lib};
 159     }
 160     return \%groups_with_subgroups
 161 }
 162
 163 =head2 get_all_tables
 164
 165 This will return a list of all tables in the database
 166
 167 =cut
 168
 169 sub get_all_tables {
 170     my $dbh   = C4::Context->dbh();
 171     my $query = "SHOW TABLES";
 172     my $sth   = $dbh->prepare($query);
 173     $sth->execute();
 174     my @tables;
 175     while ( my $data = $sth->fetchrow_arrayref() ) {
 176         push @tables, $data->[0];
 177     }
 178     $sth->finish();
 179     return ( \@tables );
 180
 181 }
 182
 183 =head2 get_columns($area)
 184
 185 This will return a list of all columns for a report area
 186
 187 =cut
 188
 189 sub get_columns {
 190
 191     # this calls the internal function _get_columns
 192     my ( $area, $cgi ) = @_;
 193     my %table_areas = get_table_areas;
 194     my $tables = $table_areas{$area}
 195       or die qq{Unsuported report area "$area"};
 196
 197     my @allcolumns;
 198     my $first = 1;
 199     foreach my $table (@$tables) {
 200         my @columns = _get_columns($table,$cgi, $first);
 201         $first = 0;
 202         push @allcolumns, @columns;
 203     }
 204     return ( \@allcolumns );
 205 }
 206
 207 sub _get_columns {
 208     my ($tablename,$cgi, $first) = @_;
 209     my $dbh         = C4::Context->dbh();
 210     my $sth         = $dbh->prepare("show columns from $tablename");
 211     $sth->execute();
 212     my @columns;
 213         my $column_defs = _get_column_defs($cgi);
 214         my %tablehash;
 215         $tablehash{'table'}=$tablename;
 216     $tablehash{'__first__'} = $first;
 217         push @columns, \%tablehash;
 218     while ( my $data = $sth->fetchrow_arrayref() ) {
 219         my %temphash;
 220         $temphash{'name'}        = "$tablename.$data->[0]";
 221         $temphash{'description'} = $column_defs->{"$tablename.$data->[0]"};
 222         push @columns, \%temphash;
 223     }
 224     $sth->finish();
 225     return (@columns);
 226 }
 227
 228 =head2 build_query($columns,$criteria,$orderby,$area)
 229
 230 This will build the sql needed to return the results asked for,
 231 $columns is expected to be of the format tablename.columnname.
 232 This is what get_columns returns.
 233
 234 =cut
 235
 236 sub build_query {
 237     my ( $columns, $criteria, $orderby, $area, $totals, $definition ) = @_;
 238
 239     my %keys = (
 240         CIRC => [ 'statistics.borrowernumber=borrowers.borrowernumber',
 241                   'items.itemnumber = statistics.itemnumber',
 242                   'biblioitems.biblioitemnumber = items.biblioitemnumber' ],
 243         CAT  => [ 'items.biblioitemnumber=biblioitems.biblioitemnumber',
 244                   'biblioitems.biblionumber=biblio.biblionumber' ],
 245         PAT  => [],
 246         ACQ  => [ 'aqorders.biblionumber=biblio.biblionumber',
 247                   'biblio.biblionumber=items.biblionumber' ],
 248         ACC  => ['borrowers.borrowernumber=accountlines.borrowernumber'],
 249         SER  => [ 'serial.serialid=serialitems.serialid', 'serial.subscriptionid=subscription.subscriptionid', 'serial.subscriptionid=subscriptionhistory.subscriptionid', 'serial.subscriptionid=subscriptionroutinglist.subscriptionid', 'biblioitems.biblionumber=serial.biblionumber', 'biblio.biblionumber=biblioitems.biblionumber', 'subscription.aqbooksellerid=aqbooksellers.id'],
 250     );
 251
 252
 253 ### $orderby
 254     my $keys   = $keys{$area};
 255     my %table_areas = get_table_areas;
 256     my $tables = $table_areas{$area};
 257
 258     my $sql =
 259       _build_query( $tables, $columns, $criteria, $keys, $orderby, $totals, $definition );
 260     return ($sql);
 261 }
 262
 263 sub _build_query {
 264     my ( $tables, $columns, $criteria, $keys, $orderby, $totals, $definition) = @_;
 265 ### $orderby
 266     # $keys is an array of joining constraints
 267     my $dbh           = C4::Context->dbh();
 268     my $joinedtables  = join( ',', @$tables );
 269     my $joinedcolumns = join( ',', @$columns );
 270     my $query =
 271       "SELECT $totals $joinedcolumns FROM $tables->[0] ";
 272         for (my $i=1;$i<@$tables;$i++){
 273                 $query .= "LEFT JOIN $tables->[$i] on ($keys->[$i-1]) ";
 274         }
 275
 276     if ($criteria) {
 277                 $criteria =~ s/AND/WHERE/;
 278         $query .= " $criteria";
 279     }
 280         if ($definition){
 281                 my @definitions = split(',',$definition);
 282                 my $deftext;
 283                 foreach my $def (@definitions){
 284                         my $defin=get_from_dictionary('',$def);
 285                         $deftext .=" ".$defin->[0]->{'saved_sql'};
 286                 }
 287                 if ($query =~ /WHERE/i){
 288                         $query .= $deftext;
 289                 }
 290                 else {
 291                         $deftext  =~ s/AND/WHERE/;
 292                         $query .= $deftext;
 293                 }
 294         }
 295     if ($totals) {
 296         my $groupby;
 297         my @totcolumns = split( ',', $totals );
 298         foreach my $total (@totcolumns) {
 299             if ( $total =~ /\((.*)\)/ ) {
 300                 if ( $groupby eq '' ) {
 301                     $groupby = " GROUP BY $1";
 302                 }
 303                 else {
 304                     $groupby .= ",$1";
 305                 }
 306             }
 307         }
 308         $query .= $groupby;
 309     }
 310     if ($orderby) {
 311         $query .= $orderby;
 312     }
 313     return ($query);
 314 }
 315
 316 =head2 get_criteria($area,$cgi);
 317
 318 Returns an arraref to hashrefs suitable for using in a tmpl_loop. With the criteria and available values.
 319
 320 =cut
 321
 322 sub get_criteria {
 323     my ($area,$cgi) = @_;
 324     my $dbh    = C4::Context->dbh();
 325
 326     # have to do someting here to know if its dropdown, free text, date etc
 327     my %criteria = (
 328         CIRC => [ 'statistics.type', 'borrowers.categorycode', 'statistics.branch',
 329                   'biblioitems.publicationyear|date', 'items.dateaccessioned|date' ],
 330         CAT  => [ 'items.itemnumber|textrange', 'items.biblionumber|textrange',
 331                   'items.barcode|textrange', 'biblio.frameworkcode',
 332                   'items.holdingbranch', 'items.homebranch',
 333                   'biblio.datecreated|daterange', 'biblio.timestamp|daterange',
 334                   'items.onloan|daterange', 'items.ccode',
 335                   'items.itemcallnumber|textrange', 'items.itype', 'items.itemlost',
 336                   'items.location' ],
 337         PAT  => [ 'borrowers.branchcode', 'borrowers.categorycode' ],
 338         ACQ  => ['aqorders.datereceived|date'],
 339         ACC  => [ 'borrowers.branchcode', 'borrowers.categorycode' ],
 340         SER  => ['subscription.startdate|date', 'subscription.enddate|date', 'subscription.periodicity', 'subscription.callnumber', 'subscription.location', 'subscription.branchcode'],
 341     );
 342
 343     # Adds itemtypes to criteria, according to the syspref
 344     if ( C4::Context->preference('item-level_itypes') ) {
 345         unshift @{ $criteria{'CIRC'} }, 'items.itype';
 346         unshift @{ $criteria{'CAT'} }, 'items.itype';
 347     } else {
 348         unshift @{ $criteria{'CIRC'} }, 'biblioitems.itemtype';
 349         unshift @{ $criteria{'CAT'} }, 'biblioitems.itemtype';
 350     }
 351
 352
 353     my $crit   = $criteria{$area};
 354     my $column_defs = _get_column_defs($cgi);
 355     my @criteria_array;
 356     foreach my $localcrit (@$crit) {
 357         my ( $value, $type )   = split( /\|/, $localcrit );
 358         my ( $table, $column ) = split( /\./, $value );
 359         if ($type eq 'textrange') {
 360             my %temp;
 361             $temp{'name'}        = $value;
 362             $temp{'from'}        = "from_" . $value;
 363             $temp{'to'}          = "to_" . $value;
 364             $temp{'textrange'}   = 1;
 365             $temp{'description'} = $column_defs->{$value};
 366             push @criteria_array, \%temp;
 367         }
 368         elsif ($type eq 'date') {
 369             my %temp;
 370             $temp{'name'}        = $value;
 371             $temp{'date'}        = 1;
 372             $temp{'description'} = $column_defs->{$value};
 373             push @criteria_array, \%temp;
 374         }
 375         elsif ($type eq 'daterange') {
 376             my %temp;
 377             $temp{'name'}        = $value;
 378             $temp{'from'}        = "from_" . $value;
 379             $temp{'to'}          = "to_" . $value;
 380             $temp{'daterange'}   = 1;
 381             $temp{'description'} = $column_defs->{$value};
 382             push @criteria_array, \%temp;
 383         }
 384         else {
 385             my $query =
 386             "SELECT distinct($column) as availablevalues FROM $table";
 387             my $sth = $dbh->prepare($query);
 388             $sth->execute();
 389             my @values;
 390             # push the runtime choosing option
 391             my $list;
 392             $list='branches' if $column eq 'branchcode' or $column eq 'holdingbranch' or $column eq 'homebranch';
 393             $list='categorycode' if $column eq 'categorycode';
 394             $list='itemtypes' if $column eq 'itype';
 395             $list='ccode' if $column eq 'ccode';
 396             # TODO : improve to let the librarian choose the description at runtime
 397             push @values, {
 398                 availablevalues => "<<$column" . ( $list ? "|$list" : '' ) . ">>",
 399                 display_value   => "<<$column" . ( $list ? "|$list" : '' ) . ">>",
 400             };
 401             while ( my $row = $sth->fetchrow_hashref() ) {
 402                 if ($row->{'availablevalues'} eq '') { $row->{'default'} = 1 }
 403                 else { $row->{display_value} = _get_display_value( $row->{'availablevalues'}, $column ); }
 404                 push @values, $row;
 405             }
 406             $sth->finish();
 407
 408             my %temp;
 409             $temp{'name'}        = $value;
 410             $temp{'description'} = $column_defs->{$value};
 411             $temp{'values'}      = \@values;
 412
 413             push @criteria_array, \%temp;
 414         }
 415     }
 416     return ( \@criteria_array );
 417 }
 418
 419 sub nb_rows {
 420     my $sql = shift or return;
 421
 422     my $derived_name = 'xxx';
 423     # make sure the derived table name is not already used
 424     while ( $sql =~ m/$derived_name/ ) {
 425         $derived_name .= 'x';
 426     }
 427
 428
 429     my $dbh = C4::Context->dbh;
 430     my $sth;
 431     my $n = 0;
 432
 433     my $RaiseError = $dbh->{RaiseError};
 434     my $PrintError = $dbh->{PrintError};
 435     $dbh->{RaiseError} = 1;
 436     $dbh->{PrintError} = 0;
 437     eval {
 438         $sth = $dbh->prepare(qq{
 439             SELECT COUNT(*) FROM
 440             ( $sql ) $derived_name
 441         });
 442
 443         $sth->execute();
 444     };
 445     $dbh->{RaiseError} = $RaiseError;
 446     $dbh->{PrintError} = $PrintError;
 447     if ($@) { # To catch "Duplicate column name" caused by the derived table, or any other syntax error
 448         eval {
 449             $sth = $dbh->prepare($sql);
 450             $sth->execute;
 451         };
 452         warn $@ if $@;
 453         # Loop through the complete results, fetching 1,000 rows at a time.  This
 454         # lowers memory requirements but increases execution time.
 455         while (my $rows = $sth->fetchall_arrayref(undef, 1000)) {
 456             $n += @$rows;
 457         }
 458         return $n;
 459     }
 460
 461     my $results = $sth->fetch;
 462     return $results ? $results->[0] : 0;
 463 }
 464
 465 =head2 execute_query
 466
 467   ($sth, $error) = execute_query($sql, $offset, $limit[, \@sql_params])
 468
 469
 470 This function returns a DBI statement handler from which the caller can
 471 fetch the results of the SQL passed via C<$sql>.
 472
 473 If passed any query other than a SELECT, or if there is a DB error,
 474 C<$errors> is returned, and is a hashref containing the error after this
 475 manner:
 476
 477 C<$error->{'sqlerr'}> contains the offending SQL keyword.
 478 C<$error->{'queryerr'}> contains the native db engine error returned
 479 for the query.
 480
 481 C<$offset>, and C<$limit> are required parameters.
 482
 483 C<\@sql_params> is an optional list of parameter values to paste in.
 484 The caller is responsible for making sure that C<$sql> has placeholders
 485 and that the number placeholders matches the number of parameters.
 486
 487 =cut
 488
 489 # returns $sql, $offset, $limit
 490 # $sql returned will be transformed to:
 491 #  ~ remove any LIMIT clause
 492 #  ~ repace SELECT clause w/ SELECT count(*)
 493
 494 sub select_2_select_count {
 495     # Modify the query passed in to create a count query... (I think this covers all cases -crn)
 496     my ($sql) = strip_limit(shift) or return;
 497     $sql =~ s/\bSELECT\W+(?:\w+\W+){1,}?FROM\b|\bSELECT\W\*\WFROM\b/SELECT count(*) FROM /ig;
 498     return $sql;
 499 }
 500
 501 # This removes the LIMIT from the query so that a custom one can be specified.
 502 # Usage:
 503 #   ($new_sql, $offset, $limit) = strip_limit($sql);
 504 #
 505 # Where:
 506 #   $sql is the query to modify
 507 #   $new_sql is the resulting query
 508 #   $offset is the offset value, if the LIMIT was the two-argument form,
 509 #       0 if it wasn't otherwise given.
 510 #   $limit is the limit value
 511 #
 512 # Notes:
 513 #   * This makes an effort to not break subqueries that have their own
 514 #     LIMIT specified. It does that by only removing a LIMIT if it comes after
 515 #     a WHERE clause (which isn't perfect, but at least should make more cases
 516 #     work - subqueries with a limit in the WHERE will still break.)
 517 #   * If your query doesn't have a WHERE clause then all LIMITs will be
 518 #     removed. This may break some subqueries, but is hopefully rare enough
 519 #     to not be a big issue.
 520 sub strip_limit {
 521     my ($sql) = @_;
 522
 523     return unless $sql;
 524     return ($sql, 0, undef) unless $sql =~ /\bLIMIT\b/i;
 525
 526     # Two options: if there's no WHERE clause in the SQL, we simply capture
 527     # any LIMIT that's there. If there is a WHERE, we make sure that we only
 528     # capture a LIMIT after the last one. This prevents stomping on subqueries.
 529     if ($sql !~ /\bWHERE\b/i) {
 530         (my $res = $sql) =~ s/\bLIMIT\b\s*(\d+)(\s*\,\s*(\d+))?\s*/ /ig;
 531         return ($res, (defined $2 ? $1 : 0), (defined $3 ? $3 : $1));
 532     } else {
 533         my $res = $sql;
 534         $res =~ m/.*\bWHERE\b/gsi;
 535         $res =~ s/\G(.*)\bLIMIT\b\s*(\d+)(\s*\,\s*(\d+))?\s*/$1 /is;
 536         return ($res, (defined $3 ? $2 : 0), (defined $4 ? $4 : $2));
 537     }
 538 }
 539
 540 sub execute_query {
 541
 542     my ( $sql, $offset, $limit, $sql_params, $report_id ) = @_;
 543
 544     $sql_params = [] unless defined $sql_params;
 545
 546     # check parameters
 547     unless ($sql) {
 548         carp "execute_query() called without SQL argument";
 549         return;
 550     }
 551     $offset = 0    unless $offset;
 552     $limit  = 999999 unless $limit;
 553     $debug and print STDERR "execute_query($sql, $offset, $limit)\n";
 554
 555     my $errors = Koha::Reports->validate_sql($sql);
 556     return (undef, @{$errors}[0]) if (scalar(@$errors));
 557
 558     foreach my $sql_param ( @$sql_params ){
 559         if ( $sql_param =~ m/\n/ ){
 560             my @list = split /\n/, $sql_param;
 561             my @quoted_list;
 562             foreach my $item ( @list ){
 563                 $item =~ s/\r//;
 564               push @quoted_list, C4::Context->dbh->quote($item);
 565             }
 566             $sql_param = "(".join(",",@quoted_list).")";
 567         }
 568     }
 569
 570     my ($useroffset, $userlimit);
 571
 572     # Grab offset/limit from user supplied LIMIT and drop the LIMIT so we can control pagination
 573     ($sql, $useroffset, $userlimit) = strip_limit($sql);
 574     $debug and warn sprintf "User has supplied (OFFSET,) LIMIT = %s, %s",
 575         $useroffset,
 576         (defined($userlimit ) ? $userlimit  : 'UNDEF');
 577     $offset += $useroffset;
 578     if (defined($userlimit)) {
 579         if ($offset + $limit > $userlimit ) {
 580             $limit = $userlimit - $offset;
 581         } elsif ( ! $offset && $limit < $userlimit ) {
 582             $limit = $userlimit;
 583         }
 584     }
 585     $sql .= " LIMIT ?, ?";
 586
 587     my $dbh = C4::Context->dbh;
 588
 589     $dbh->do( 'UPDATE saved_sql SET last_run = NOW() WHERE id = ?', undef, $report_id ) if $report_id;
 590
 591     my $sth = $dbh->prepare($sql);
 592     eval {
 593         $sth->execute(@$sql_params, $offset, $limit);
 594     };
 595     warn $@ if $@;
 596
 597     return ( $sth, { queryerr => $sth->errstr } ) if ($sth->err);
 598     return ( $sth );
 599 }
 600
 601 =head2 save_report($sql,$name,$type,$notes)
 602
 603 Given some sql and a name this will saved it so that it can reused
 604 Returns id of the newly created report
 605
 606 =cut
 607
 608 sub save_report {
 609     my ($fields) = @_;
 610     my $borrowernumber = $fields->{borrowernumber};
 611     my $sql = $fields->{sql};
 612     my $name = $fields->{name};
 613     my $type = $fields->{type};
 614     my $notes = $fields->{notes};
 615     my $area = $fields->{area};
 616     my $group = $fields->{group};
 617     my $subgroup = $fields->{subgroup};
 618     my $cache_expiry = $fields->{cache_expiry};
 619     my $public = $fields->{public};
 620
 621     $sql =~ s/(\s*\;\s*)$//;    # removes trailing whitespace and /;/
 622     my $now = dt_from_string;
 623     my $report = Koha::Report->new(
 624         {
 625             borrowernumber  => $borrowernumber,
 626             date_created    => $now, # Must be moved to Koha::Report->store
 627             last_modified   => $now, # Must be moved to Koha::Report->store
 628             savedsql        => $sql,
 629             report_name     => $name,
 630             report_area     => $area,
 631             report_group    => $group,
 632             report_subgroup => $subgroup,
 633             type            => $type,
 634             notes           => $notes,
 635             cache_expiry    => $cache_expiry,
 636             public          => $public,
 637         }
 638     )->store;
 639
 640     return $report->id;
 641 }
 642
 643 sub update_sql {
 644     my $id         = shift || croak "No Id given";
 645     my $fields     = shift;
 646     my $sql = $fields->{sql};
 647     my $name = $fields->{name};
 648     my $notes = $fields->{notes};
 649     my $group = $fields->{group};
 650     my $subgroup = $fields->{subgroup};
 651     my $cache_expiry = $fields->{cache_expiry};
 652     my $public = $fields->{public};
 653
 654     $sql =~ s/(\s*\;\s*)$//;    # removes trailing whitespace and /;/
 655     my $report = Koha::Reports->find($id);
 656     $report->last_modified(dt_from_string);
 657     $report->savedsql($sql);
 658     $report->report_name($name);
 659     $report->notes($notes);
 660     $report->report_group($group);
 661     $report->report_subgroup($subgroup);
 662     $report->cache_expiry($cache_expiry) if defined $cache_expiry;
 663     $report->public($public);
 664     $report->store();
 665     if( $cache_expiry >= 2592000 ){
 666       die "Please specify a cache expiry less than 30 days\n"; # That's a bit harsh
 667     }
 668
 669     return $report;
 670 }
 671
 672 sub store_results {
 673     my ( $id, $json ) = @_;
 674     my $dbh = C4::Context->dbh();
 675     $dbh->do(q|
 676         INSERT INTO saved_reports ( report_id, report, date_run ) VALUES ( ?, ?, NOW() );
 677     |, undef, $id, $json );
 678 }
 679
 680 sub format_results {
 681     my ( $id ) = @_;
 682     my $dbh = C4::Context->dbh();
 683     my ( $report_name, $notes, $json, $date_run ) = $dbh->selectrow_array(q|
 684        SELECT ss.report_name, ss.notes, sr.report, sr.date_run
 685        FROM saved_sql ss
 686        LEFT JOIN saved_reports sr ON sr.report_id = ss.id
 687        WHERE sr.id = ?
 688     |, undef, $id);
 689     return {
 690         report_name => $report_name,
 691         notes => $notes,
 692         results => from_json( $json ),
 693         date_run => $date_run,
 694     };
 695 }
 696
 697 sub delete_report {
 698     my (@ids) = @_;
 699     return unless @ids;
 700     foreach my $id (@ids) {
 701         my $data = Koha::Reports->find($id);
 702         logaction( "REPORTS", "DELETE", $id, $data->report_name." | ".$data->savedsql ) if C4::Context->preference("ReportsLog");
 703     }
 704     my $dbh = C4::Context->dbh;
 705     my $query = 'DELETE FROM saved_sql WHERE id IN (' . join( ',', ('?') x @ids ) . ')';
 706     my $sth = $dbh->prepare($query);
 707     return $sth->execute(@ids);
 708 }
 709
 710 sub get_saved_reports_base_query {
 711     my $area_name_sql_snippet = get_area_name_sql_snippet;
 712     return <<EOQ;
 713 SELECT s.*, $area_name_sql_snippet, av_g.lib AS groupname, av_sg.lib AS subgroupname,
 714 b.firstname AS borrowerfirstname, b.surname AS borrowersurname
 715 FROM saved_sql s
 716 LEFT JOIN saved_reports r ON r.report_id = s.id
 717 LEFT OUTER JOIN authorised_values av_g ON (av_g.category = 'REPORT_GROUP' AND av_g.authorised_value = s.report_group)
 718 LEFT OUTER JOIN authorised_values av_sg ON (av_sg.category = 'REPORT_SUBGROUP' AND av_sg.lib_opac = s.report_group AND av_sg.authorised_value = s.report_subgroup)
 719 LEFT OUTER JOIN borrowers b USING (borrowernumber)
 720 EOQ
 721 }
 722
 723 sub get_saved_reports {
 724 # $filter is either { date => $d, author => $a, keyword => $kw, }
 725 # or $keyword. Optional.
 726     my ($filter) = @_;
 727     $filter = { keyword => $filter } if $filter && !ref( $filter );
 728     my ($group, $subgroup) = @_;
 729
 730     my $dbh   = C4::Context->dbh();
 731     my $query = get_saved_reports_base_query;
 732     my (@cond,@args);
 733     if ($filter) {
 734         if (my $date = $filter->{date}) {
 735             $date = eval { output_pref( { dt => dt_from_string( $date ), dateonly => 1, dateformat => 'iso' }); };
 736             push @cond, "DATE(last_modified) = ? OR
 737                          DATE(last_run) = ?";
 738             push @args, $date, $date, $date;
 739         }
 740         if (my $author = $filter->{author}) {
 741             $author = "%$author%";
 742             push @cond, "surname LIKE ? OR
 743                          firstname LIKE ?";
 744             push @args, $author, $author;
 745         }
 746         if (my $keyword = $filter->{keyword}) {
 747             push @cond, q|
 748                        report LIKE ?
 749                     OR report_name LIKE ?
 750                     OR notes LIKE ?
 751                     OR savedsql LIKE ?
 752                     OR s.id = ?
 753             |;
 754             push @args, "%$keyword%", "%$keyword%", "%$keyword%", "%$keyword%", $keyword;
 755         }
 756         if ($filter->{group}) {
 757             push @cond, "report_group = ?";
 758             push @args, $filter->{group};
 759         }
 760         if ($filter->{subgroup}) {
 761             push @cond, "report_subgroup = ?";
 762             push @args, $filter->{subgroup};
 763         }
 764     }
 765     $query .= " WHERE ".join( " AND ", map "($_)", @cond ) if @cond;
 766     $query .= " GROUP BY s.id, s.borrowernumber, s.date_created, s.last_modified, s.savedsql, s.last_run, s.report_name, s.type, s.notes, s.cache_expiry, s.public, s.report_area, s.report_group, s.report_subgroup, s.mana_id, av_g.lib, av_sg.lib, b.firstname, b.surname";
 767     $query .= " ORDER by date_created";
 768
 769     my $result = $dbh->selectall_arrayref($query, {Slice => {}}, @args);
 770
 771     return $result;
 772 }
 773
 774 =head2 get_column_type($column)
 775
 776 This takes a column name of the format table.column and will return what type it is
 777 (free text, set values, date)
 778
 779 =cut
 780
 781 sub get_column_type {
 782         my ($tablecolumn) = @_;
 783         my ($table,$column) = split(/\./,$tablecolumn);
 784         my $dbh = C4::Context->dbh();
 785         my $catalog;
 786         my $schema;
 787
 788     # mysql doesn't support a column selection, set column to %
 789         my $tempcolumn='%';
 790         my $sth = $dbh->column_info( $catalog, $schema, $table, $tempcolumn ) || die $dbh->errstr;
 791         while (my $info = $sth->fetchrow_hashref()){
 792                 if ($info->{'COLUMN_NAME'} eq $column){
 793                         #column we want
 794                         if ($info->{'TYPE_NAME'} eq 'CHAR' || $info->{'TYPE_NAME'} eq 'VARCHAR'){
 795                                 $info->{'TYPE_NAME'} = 'distinct';
 796                         }
 797                         return $info->{'TYPE_NAME'};
 798                 }
 799         }
 800 }
 801
 802 =head2 get_distinct_values($column)
 803
 804 Given a column name, return an arrary ref of hashrefs suitable for use as a tmpl_loop
 805 with the distinct values of the column
 806
 807 =cut
 808
 809 sub get_distinct_values {
 810         my ($tablecolumn) = @_;
 811         my ($table,$column) = split(/\./,$tablecolumn);
 812         my $dbh = C4::Context->dbh();
 813         my $query =
 814           "SELECT distinct($column) as availablevalues FROM $table";
 815         my $sth = $dbh->prepare($query);
 816         $sth->execute();
 817     return $sth->fetchall_arrayref({});
 818 }
 819
 820 sub save_dictionary {
 821     my ( $name, $description, $sql, $area ) = @_;
 822     my $dbh   = C4::Context->dbh();
 823     my $query = "INSERT INTO reports_dictionary (name,description,saved_sql,report_area,date_created,date_modified)
 824   VALUES (?,?,?,?,now(),now())";
 825     my $sth = $dbh->prepare($query);
 826     $sth->execute($name,$description,$sql,$area) || return 0;
 827     return 1;
 828 }
 829
 830 sub get_from_dictionary {
 831     my ( $area, $id ) = @_;
 832     my $dbh   = C4::Context->dbh();
 833     my $area_name_sql_snippet = get_area_name_sql_snippet;
 834     my $query = <<EOQ;
 835 SELECT d.*, $area_name_sql_snippet
 836 FROM reports_dictionary d
 837 EOQ
 838
 839     if ($area) {
 840         $query .= " WHERE report_area = ?";
 841     } elsif ($id) {
 842         $query .= " WHERE id = ?";
 843     }
 844     my $sth = $dbh->prepare($query);
 845     if ($id) {
 846         $sth->execute($id);
 847     } elsif ($area) {
 848         $sth->execute($area);
 849     } else {
 850         $sth->execute();
 851     }
 852     my @loop;
 853     while ( my $data = $sth->fetchrow_hashref() ) {
 854         push @loop, $data;
 855     }
 856     return ( \@loop );
 857 }
 858
 859 sub delete_definition {
 860         my ($id) = @_ or return;
 861         my $dbh = C4::Context->dbh();
 862         my $query = "DELETE FROM reports_dictionary WHERE id = ?";
 863         my $sth = $dbh->prepare($query);
 864         $sth->execute($id);
 865 }
 866
 867 =head2 get_sql($report_id)
 868
 869 Given a report id, return the SQL statement for that report.
 870 Otherwise, it just returns.
 871
 872 =cut
 873
 874 sub get_sql {
 875         my ($id) = @_ or return;
 876         my $dbh = C4::Context->dbh();
 877         my $query = "SELECT * FROM saved_sql WHERE id = ?";
 878         my $sth = $dbh->prepare($query);
 879         $sth->execute($id);
 880         my $data=$sth->fetchrow_hashref();
 881         return $data->{'savedsql'};
 882 }
 883
 884 sub get_results {
 885     my ( $report_id ) = @_;
 886     my $dbh = C4::Context->dbh;
 887     return $dbh->selectall_arrayref(q|
 888         SELECT id, report, date_run
 889         FROM saved_reports
 890         WHERE report_id = ?
 891     |, { Slice => {} }, $report_id);
 892 }
 893
 894 sub _get_column_defs {
 895     my ($cgi) = @_;
 896     my %columns;
 897     my $columns_def_file = "columns.def";
 898     my $htdocs = C4::Context->config('intrahtdocs');
 899     my $section = 'intranet';
 900
 901     # We need the theme and the lang
 902     # Since columns.def is not in the modules directory, we cannot sent it for the $tmpl var
 903     my ($theme, $lang, $availablethemes) = C4::Templates::themelanguage($htdocs, 'about.tt', $section, $cgi);
 904
 905     my $full_path_to_columns_def_file="$htdocs/$theme/$lang/$columns_def_file";
 906     open (my $fh, '<:encoding(utf-8)', $full_path_to_columns_def_file);
 907     while ( my $input = <$fh> ){
 908         chomp $input;
 909         if ( $input =~ m|<field name="(.*)">(.*)</field>| ) {
 910             my ( $field, $translation ) = ( $1, $2 );
 911             $columns{$field} = $translation;
 912         }
 913     }
 914     close $fh;
 915     return \%columns;
 916 }
 917
 918 =head2 GetReservedAuthorisedValues
 919
 920     my %reserved_authorised_values = GetReservedAuthorisedValues();
 921
 922 Returns a hash containig all reserved words
 923
 924 =cut
 925
 926 sub GetReservedAuthorisedValues {
 927     my %reserved_authorised_values =
 928             map { $_ => 1 } ( 'date',
 929                               'list',
 930                               'branches',
 931                               'itemtypes',
 932                               'cn_source',
 933                               'categorycode',
 934                               'biblio_framework' );
 935
 936    return \%reserved_authorised_values;
 937 }
 938
 939
 940 =head2 IsAuthorisedValueValid
 941
 942     my $is_valid_ath_value = IsAuthorisedValueValid($authorised_value)
 943
 944 Returns 1 if $authorised_value is on the reserved authorised values list or
 945 in the authorised value categories defined in
 946
 947 =cut
 948
 949 sub IsAuthorisedValueValid {
 950
 951     my $authorised_value = shift;
 952     my $reserved_authorised_values = GetReservedAuthorisedValues();
 953
 954     if ( exists $reserved_authorised_values->{$authorised_value} ||
 955          Koha::AuthorisedValues->search({ category => $authorised_value })->count ) {
 956         return 1;
 957     }
 958
 959     return 0;
 960 }
 961
 962 =head2 GetParametersFromSQL
 963
 964     my @sql_parameters = GetParametersFromSQL($sql)
 965
 966 Returns an arrayref of hashes containing the keys name and authval
 967
 968 =cut
 969
 970 sub GetParametersFromSQL {
 971
 972     my $sql = shift ;
 973     my @split = split(/<<|>>/,$sql);
 974     my @sql_parameters = ();
 975
 976     for ( my $i = 0; $i < ($#split/2) ; $i++ ) {
 977         my ($name,$authval) = split(/\|/,$split[$i*2+1]);
 978         $authval =~ s/\:all$// if $authval;
 979         push @sql_parameters, { 'name' => $name, 'authval' => $authval };
 980     }
 981
 982     return \@sql_parameters;
 983 }
 984
 985 =head2 ValidateSQLParameters
 986
 987     my @problematic_parameters = ValidateSQLParameters($sql)
 988
 989 Returns an arrayref of hashes containing the keys name and authval of
 990 those SQL parameters that do not correspond to valid authorised names
 991
 992 =cut
 993
 994 sub ValidateSQLParameters {
 995
 996     my $sql = shift;
 997     my @problematic_parameters = ();
 998     my $sql_parameters = GetParametersFromSQL($sql);
 999
1000     foreach my $sql_parameter (@$sql_parameters) {
1001         if ( defined $sql_parameter->{'authval'} ) {
1002             push @problematic_parameters, $sql_parameter unless
1003                 IsAuthorisedValueValid($sql_parameter->{'authval'});
1004         }
1005     }
1006
1007     return \@problematic_parameters;
1008 }
1009
1010 =head2 EmailReport
1011
1012     my ( $emails, $arrayrefs ) = EmailReport($report_id, $letter_code, $module, $branch, $email)
1013
1014 Take a report and use it to process a Template Toolkit formatted notice
1015 Returns arrayrefs containing prepared letters and errors respectively
1016
1017 =cut
1018
1019 sub EmailReport {
1020
1021     my $params     = shift;
1022     my $report_id  = $params->{report_id};
1023     my $from       = $params->{from};
1024     my $email_col  = $params->{email} || 'email';
1025     my $module     = $params->{module};
1026     my $code       = $params->{code};
1027     my $branch     = $params->{branch} || "";
1028
1029     my @errors = ();
1030     my @emails = ();
1031
1032     return ( undef, [{ FATAL => "MISSING_PARAMS" }] ) unless ($report_id && $module && $code);
1033
1034     return ( undef, [{ FATAL => "NO_LETTER" }] ) unless
1035     my $letter = Koha::Notice::Templates->find({
1036         module     => $module,
1037         code       => $code,
1038         branchcode => $branch,
1039         message_transport_type => 'email',
1040     });
1041     $letter = $letter->unblessed;
1042
1043     my $report = Koha::Reports->find( $report_id );
1044     my $sql = $report->savedsql;
1045     return ( { FATAL => "NO_REPORT" } ) unless $sql;
1046
1047     my ( $sth, $errors ) = execute_query( $sql ); #don't pass offset or limit, hardcoded limit of 999,999 will be used
1048     return ( undef, [{ FATAL => "REPORT_FAIL" }] ) if $errors;
1049
1050     my $counter = 1;
1051     my $template = $letter->{content};
1052
1053     while ( my $row = $sth->fetchrow_hashref() ) {
1054         my $email;
1055         my $err_count = scalar @errors;
1056         push ( @errors, { NO_BOR_COL => $counter } ) unless defined $row->{borrowernumber};
1057         push ( @errors, { NO_EMAIL_COL => $counter } ) unless ( defined $row->{$email_col} );
1058         push ( @errors, { NO_FROM_COL => $counter } ) unless defined ( $from || $row->{from} );
1059         push ( @errors, { NO_BOR => $row->{borrowernumber} } ) unless Koha::Patrons->find({borrowernumber=>$row->{borrowernumber}});
1060
1061         my $from_address = $from || $row->{from};
1062         my $to_address = $row->{$email_col};
1063         push ( @errors, { NOT_PARSE => $counter } ) unless my $content = _process_row_TT( $row, $template );
1064         $counter++;
1065         next if scalar @errors > $err_count; #If any problems, try next
1066
1067         $letter->{content}       = $content;
1068         $email->{borrowernumber} = $row->{borrowernumber};
1069         $email->{letter}         = { %$letter };
1070         $email->{from_address}   = $from_address;
1071         $email->{to_address}     = $to_address;
1072
1073         push ( @emails, $email );
1074     }
1075
1076     return ( \@emails, \@errors );
1077
1078 }
1079
1080
1081
1082 =head2 ProcessRowTT
1083
1084    my $content = ProcessRowTT($row_hashref, $template);
1085
1086 Accepts a hashref containing values and processes them against Template Toolkit
1087 to produce content
1088
1089 =cut
1090
1091 sub _process_row_TT {
1092
1093     my ($row, $template) = @_;
1094
1095     return 0 unless ($row && $template);
1096     my $content;
1097     my $processor = Template->new();
1098     $processor->process( \$template, $row, \$content);
1099     return $content;
1100
1101 }
1102
1103 sub _get_display_value {
1104     my ( $original_value, $column ) = @_;
1105     if ( $column eq 'periodicity' ) {
1106         my $dbh = C4::Context->dbh();
1107         my $query = "SELECT description FROM subscription_frequencies WHERE id = ?";
1108         my $sth   = $dbh->prepare($query);
1109         $sth->execute($original_value);
1110         return $sth->fetchrow;
1111     }
1112     return $original_value;
1113 }
1114
1115
1116 =head3 convert_sql
1117
1118 my $updated_sql = C4::Reports::Guided::convert_sql( $sql );
1119
1120 Convert a sql query using biblioitems.marcxml to use the new
1121 biblio_metadata.metadata field instead
1122
1123 =cut
1124
1125 sub convert_sql {
1126     my ( $sql ) = @_;
1127     my $updated_sql = $sql;
1128     if ( $sql =~ m|biblioitems| and $sql =~ m|marcxml| ) {
1129         $updated_sql =~ s|biblioitems|biblio_metadata|g;
1130         $updated_sql =~ s|marcxml|metadata|g;
1131     }
1132     return $updated_sql;
1133 }
1134
1135 1;
1136 __END__
1137
1138 =head1 AUTHOR
1139
1140 Chris Cormack <crc@liblime.com>
1141
1142 =cut