C4/Log.pm

   1 package C4::Log;
   2
   3 #package to deal with Logging Actions in DB
   4
   5
   6 # Copyright 2000-2002 Katipo Communications
   7 # Copyright 2011 MJ Ray and software.coop
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 3 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  23
  24 use strict;
  25 use warnings;
  26
  27 use Data::Dumper qw( Dumper );
  28 use JSON qw( to_json );
  29
  30 use C4::Context;
  31 use Koha::Logger;
  32
  33 use vars qw(@ISA @EXPORT);
  34
  35 BEGIN {
  36         require Exporter;
  37         @ISA = qw(Exporter);
  38         @EXPORT = qw(logaction cronlogaction);
  39 }
  40
  41 =head1 NAME
  42
  43 C4::Log - Koha Log Facility functions
  44
  45 =head1 SYNOPSIS
  46
  47   use C4::Log;
  48
  49 =head1 DESCRIPTION
  50
  51 The functions in this module perform various functions in order to log all the operations done on the Database, including deleting and undeleting books, adding/editing members, etc.
  52
  53 =head1 FUNCTIONS
  54
  55 =over 2
  56
  57 =item logaction
  58
  59   &logaction($modulename, $actionname, $objectnumber, $infos, $interface);
  60
  61 Adds a record into action_logs table to report the different changes upon the database.
  62 Each log entry includes the number of the user currently logged in.  For batch
  63 jobs, which operate without authenticating a user and setting up a session, the user
  64 number is set to 0, which is the same as the superlibrarian's number.
  65
  66 =cut
  67
  68 #'
  69 sub logaction {
  70     my ($modulename, $actionname, $objectnumber, $infos, $interface)=@_;
  71
  72     # Get ID of logged in user.  if called from a batch job,
  73     # no user session exists and C4::Context->userenv() returns
  74     # the scalar '0'.
  75     my $userenv = C4::Context->userenv();
  76     my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : 0;
  77     $usernumber ||= 0;
  78     $interface //= C4::Context->interface;
  79
  80     if ( ref($infos) && ref($infos) !~ /HASH|ARRAY/ && $infos->isa('Koha::Object') ) {
  81         $infos = $infos->get_from_storage if $infos->in_storage;
  82         $infos = Dumper( $infos->unblessed );
  83
  84         if ( $infos->isa('Koha::Item') && $modulename eq 'CATALOGUING' && $actionname eq 'MODIFY' ) {
  85             $infos = "item " . $infos;
  86         }
  87     }
  88
  89     my $dbh = C4::Context->dbh;
  90     my $sth=$dbh->prepare("Insert into action_logs (timestamp,user,module,action,object,info,interface) values (now(),?,?,?,?,?,?)");
  91     $sth->execute($usernumber,$modulename,$actionname,$objectnumber,$infos,$interface);
  92     $sth->finish;
  93
  94     my $logger = Koha::Logger->get(
  95         {
  96             interface => $interface,
  97             category  => "ActionLogs.$modulename.$actionname"
  98         }
  99     );
 100     $logger->debug(
 101         sub {
 102             "ACTION LOG: " . to_json(
 103                 {
 104                     user   => $usernumber,
 105                     module => $modulename,
 106                     action => $actionname,
 107                     object => $objectnumber,
 108                     info   => $infos
 109                 }
 110             );
 111         }
 112     );
 113 }
 114
 115 =item cronlogaction
 116
 117   &cronlogaction($infos);
 118
 119 Convenience routine to add a record into action_logs table from a cron job.
 120 Logs the path and name of the calling script plus the information privided by param $infos.
 121
 122 =cut
 123
 124 #'
 125 sub cronlogaction {
 126     my ($infos)=@_;
 127     my $loginfo = (caller(0))[1];
 128     $loginfo .= ' ' . $infos if $infos;
 129     logaction( 'CRONJOBS', 'Run', undef, $loginfo ) if C4::Context->preference('CronjobLog');
 130 }
 131
 132 1;
 133 __END__
 134
 135 =back
 136
 137 =head1 AUTHOR
 138
 139 Koha Development Team <http://koha-community.org/>
 140
 141 =cut