koha-dev.rot13.org Git - koha_fer/blob - C4/Context.pm

   1 package C4::Context;
   2 # Copyright 2002 Katipo Communications
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along
  16 # with Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use vars qw($VERSION $AUTOLOAD $context @context_stack $servers $memcached $ismemcached);
  22 BEGIN {
  23         if ($ENV{'HTTP_USER_AGENT'})    {
  24                 require CGI::Carp;
  25         # FIXME for future reference, CGI::Carp doc says
  26         #  "Note that fatalsToBrowser does not work with mod_perl version 2.0 and higher."
  27                 import CGI::Carp qw(fatalsToBrowser);
  28                         sub handle_errors {
  29                             my $msg = shift;
  30                             my $debug_level;
  31                             eval {C4::Context->dbh();};
  32                             if ($@){
  33                                 $debug_level = 1;
  34                             }
  35                             else {
  36                                 $debug_level =  C4::Context->preference("DebugLevel");
  37                             }
  38
  39                 print q(<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
  40                             "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
  41                        <html lang="en" xml:lang="en"  xmlns="http://www.w3.org/1999/xhtml">
  42                        <head><title>Koha Error</title></head>
  43                        <body>
  44                 );
  45                                 if ($debug_level eq "2"){
  46                                         # debug 2 , print extra info too.
  47                                         my %versions = get_versions();
  48
  49                 # a little example table with various version info";
  50                                         print "
  51                                                 <h1>Koha error</h1>
  52                                                 <p>The following fatal error has occurred:</p>
  53                         <pre><code>$msg</code></pre>
  54                                                 <table>
  55                                                 <tr><th>Apache</th><td>  $versions{apacheVersion}</td></tr>
  56                                                 <tr><th>Koha</th><td>    $versions{kohaVersion}</td></tr>
  57                                                 <tr><th>Koha DB</th><td> $versions{kohaDbVersion}</td></tr>
  58                                                 <tr><th>MySQL</th><td>   $versions{mysqlVersion}</td></tr>
  59                                                 <tr><th>OS</th><td>      $versions{osVersion}</td></tr>
  60                                                 <tr><th>Perl</th><td>    $versions{perlVersion}</td></tr>
  61                                                 </table>";
  62
  63                                 } elsif ($debug_level eq "1"){
  64                                         print "
  65                                                 <h1>Koha error</h1>
  66                                                 <p>The following fatal error has occurred:</p>
  67                         <pre><code>$msg</code></pre>";
  68                                 } else {
  69                                         print "<p>production mode - trapped fatal error</p>";
  70                                 }
  71                 print "</body></html>";
  72                         }
  73                 #CGI::Carp::set_message(\&handle_errors);
  74                 ## give a stack backtrace if KOHA_BACKTRACES is set
  75                 ## can't rely on DebugLevel for this, as we're not yet connected
  76                 if ($ENV{KOHA_BACKTRACES}) {
  77                         $main::SIG{__DIE__} = \&CGI::Carp::confess;
  78                 }
  79     }   # else there is no browser to send fatals to!
  80
  81     # Check if there are memcached servers set
  82     $servers = $ENV{'MEMCACHED_SERVERS'};
  83     if ($servers) {
  84         # Load required libraries and create the memcached object
  85         require Cache::Memcached;
  86         $memcached = Cache::Memcached->new({
  87         servers => [ $servers ],
  88         debug   => 0,
  89         compress_threshold => 10_000,
  90         expire_time => 600,
  91         namespace => $ENV{'MEMCACHED_NAMESPACE'} || 'koha'
  92     });
  93         # Verify memcached available (set a variable and test the output)
  94     $ismemcached = $memcached->set('ismemcached','1');
  95     }
  96
  97     $VERSION = '3.07.00.049';
  98 }
  99
 100 use DBI;
 101 use ZOOM;
 102 use XML::Simple;
 103 use C4::Boolean;
 104 use C4::Debug;
 105 use POSIX ();
 106 use DateTime::TimeZone;
 107 use Module::Load::Conditional qw(can_load);
 108 use Carp;
 109
 110 =head1 NAME
 111
 112 C4::Context - Maintain and manipulate the context of a Koha script
 113
 114 =head1 SYNOPSIS
 115
 116   use C4::Context;
 117
 118   use C4::Context("/path/to/koha-conf.xml");
 119
 120   $config_value = C4::Context->config("config_variable");
 121
 122   $koha_preference = C4::Context->preference("preference");
 123
 124   $db_handle = C4::Context->dbh;
 125
 126   $Zconn = C4::Context->Zconn;
 127
 128   $stopwordhash = C4::Context->stopwords;
 129
 130 =head1 DESCRIPTION
 131
 132 When a Koha script runs, it makes use of a certain number of things:
 133 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
 134 databases, and so forth. These things make up the I<context> in which
 135 the script runs.
 136
 137 This module takes care of setting up the context for a script:
 138 figuring out which configuration file to load, and loading it, opening
 139 a connection to the right database, and so forth.
 140
 141 Most scripts will only use one context. They can simply have
 142
 143   use C4::Context;
 144
 145 at the top.
 146
 147 Other scripts may need to use several contexts. For instance, if a
 148 library has two databases, one for a certain collection, and the other
 149 for everything else, it might be necessary for a script to use two
 150 different contexts to search both databases. Such scripts should use
 151 the C<&set_context> and C<&restore_context> functions, below.
 152
 153 By default, C4::Context reads the configuration from
 154 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
 155 environment variable to the pathname of a configuration file to use.
 156
 157 =head1 METHODS
 158
 159 =cut
 160
 161 #'
 162 # In addition to what is said in the POD above, a Context object is a
 163 # reference-to-hash with the following fields:
 164 #
 165 # config
 166 #    A reference-to-hash whose keys and values are the
 167 #    configuration variables and values specified in the config
 168 #    file (/etc/koha/koha-conf.xml).
 169 # dbh
 170 #    A handle to the appropriate database for this context.
 171 # dbh_stack
 172 #    Used by &set_dbh and &restore_dbh to hold other database
 173 #    handles for this context.
 174 # Zconn
 175 #     A connection object for the Zebra server
 176
 177 # Koha's main configuration file koha-conf.xml
 178 # is searched for according to this priority list:
 179 #
 180 # 1. Path supplied via use C4::Context '/path/to/koha-conf.xml'
 181 # 2. Path supplied in KOHA_CONF environment variable.
 182 # 3. Path supplied in INSTALLED_CONFIG_FNAME, as long
 183 #    as value has changed from its default of
 184 #    '__KOHA_CONF_DIR__/koha-conf.xml', as happens
 185 #    when Koha is installed in 'standard' or 'single'
 186 #    mode.
 187 # 4. Path supplied in CONFIG_FNAME.
 188 #
 189 # The first entry that refers to a readable file is used.
 190
 191 use constant CONFIG_FNAME => "/etc/koha/koha-conf.xml";
 192                 # Default config file, if none is specified
 193
 194 my $INSTALLED_CONFIG_FNAME = '__KOHA_CONF_DIR__/koha-conf.xml';
 195                 # path to config file set by installer
 196                 # __KOHA_CONF_DIR__ is set by rewrite-confg.PL
 197                 # when Koha is installed in 'standard' or 'single'
 198                 # mode.  If Koha was installed in 'dev' mode,
 199                 # __KOHA_CONF_DIR__ is *not* rewritten; instead
 200                 # developers should set the KOHA_CONF environment variable
 201
 202 $context = undef;        # Initially, no context is set
 203 @context_stack = ();        # Initially, no saved contexts
 204
 205
 206 =head2 KOHAVERSION
 207
 208 returns the kohaversion stored in kohaversion.pl file
 209
 210 =cut
 211
 212 sub KOHAVERSION {
 213     my $cgidir = C4::Context->intranetdir;
 214
 215     # Apparently the GIT code does not run out of a CGI-BIN subdirectory
 216     # but distribution code does?  (Stan, 1jan08)
 217     if(-d $cgidir . "/cgi-bin"){
 218         my $cgidir .= "/cgi-bin";
 219     }
 220
 221     do $cgidir."/kohaversion.pl" || die "NO $cgidir/kohaversion.pl";
 222     return kohaversion();
 223 }
 224
 225 =head2 final_linear_version
 226
 227 Returns the version number of the final update to run in updatedatabase.pl.
 228 This number is equal to the version in kohaversion.pl
 229
 230 =cut
 231
 232 sub final_linear_version {
 233     return KOHAVERSION;
 234 }
 235
 236 =head2 read_config_file
 237
 238 Reads the specified Koha config file.
 239
 240 Returns an object containing the configuration variables. The object's
 241 structure is a bit complex to the uninitiated ... take a look at the
 242 koha-conf.xml file as well as the XML::Simple documentation for details. Or,
 243 here are a few examples that may give you what you need:
 244
 245 The simple elements nested within the <config> element:
 246
 247     my $pass = $koha->{'config'}->{'pass'};
 248
 249 The <listen> elements:
 250
 251     my $listen = $koha->{'listen'}->{'biblioserver'}->{'content'};
 252
 253 The elements nested within the <server> element:
 254
 255     my $ccl2rpn = $koha->{'server'}->{'biblioserver'}->{'cql2rpn'};
 256
 257 Returns undef in case of error.
 258
 259 =cut
 260
 261 sub read_config_file {          # Pass argument naming config file to read
 262     my $koha = XMLin(shift, keyattr => ['id'], forcearray => ['listen', 'server', 'serverinfo'], suppressempty => '');
 263
 264     if ($ismemcached) {
 265       $memcached->set('kohaconf',$koha);
 266     }
 267
 268     return $koha;                       # Return value: ref-to-hash holding the configuration
 269 }
 270
 271 =head2 ismemcached
 272
 273 Returns the value of the $ismemcached variable (0/1)
 274
 275 =cut
 276
 277 sub ismemcached {
 278     return $ismemcached;
 279 }
 280
 281 =head2 memcached
 282
 283 If $ismemcached is true, returns the $memcache variable.
 284 Returns undef otherwise
 285
 286 =cut
 287
 288 sub memcached {
 289     if ($ismemcached) {
 290       return $memcached;
 291     } else {
 292       return;
 293     }
 294 }
 295
 296 =head2 db_scheme2dbi
 297
 298     my $dbd_driver_name = C4::Context::db_schema2dbi($scheme);
 299
 300 This routines translates a database type to part of the name
 301 of the appropriate DBD driver to use when establishing a new
 302 database connection.  It recognizes 'mysql' and 'Pg'; if any
 303 other scheme is supplied it defaults to 'mysql'.
 304
 305 =cut
 306
 307 sub db_scheme2dbi {
 308     my $scheme = shift // '';
 309     return $scheme eq 'Pg' ? $scheme : 'mysql';
 310 }
 311
 312 sub import {
 313     # Create the default context ($C4::Context::Context)
 314     # the first time the module is called
 315     # (a config file can be optionaly passed)
 316
 317     # default context allready exists?
 318     return if $context;
 319
 320     # no ? so load it!
 321     my ($pkg,$config_file) = @_ ;
 322     my $new_ctx = __PACKAGE__->new($config_file);
 323     return unless $new_ctx;
 324
 325     # if successfully loaded, use it by default
 326     $new_ctx->set_context;
 327     1;
 328 }
 329
 330 =head2 new
 331
 332   $context = new C4::Context;
 333   $context = new C4::Context("/path/to/koha-conf.xml");
 334
 335 Allocates a new context. Initializes the context from the specified
 336 file, which defaults to either the file given by the C<$KOHA_CONF>
 337 environment variable, or F</etc/koha/koha-conf.xml>.
 338
 339 It saves the koha-conf.xml values in the declared memcached server(s)
 340 if currently available and uses those values until them expire and
 341 re-reads them.
 342
 343 C<&new> does not set this context as the new default context; for
 344 that, use C<&set_context>.
 345
 346 =cut
 347
 348 #'
 349 # Revision History:
 350 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 351 sub new {
 352     my $class = shift;
 353     my $conf_fname = shift;        # Config file to load
 354     my $self = {};
 355
 356     # check that the specified config file exists and is not empty
 357     undef $conf_fname unless
 358         (defined $conf_fname && -s $conf_fname);
 359     # Figure out a good config file to load if none was specified.
 360     if (!defined($conf_fname))
 361     {
 362         # If the $KOHA_CONF environment variable is set, use
 363         # that. Otherwise, use the built-in default.
 364         if (exists $ENV{"KOHA_CONF"} and $ENV{'KOHA_CONF'} and -s  $ENV{"KOHA_CONF"}) {
 365             $conf_fname = $ENV{"KOHA_CONF"};
 366         } elsif ($INSTALLED_CONFIG_FNAME !~ /__KOHA_CONF_DIR/ and -s $INSTALLED_CONFIG_FNAME) {
 367             # NOTE: be careful -- don't change __KOHA_CONF_DIR in the above
 368             # regex to anything else -- don't want installer to rewrite it
 369             $conf_fname = $INSTALLED_CONFIG_FNAME;
 370         } elsif (-s CONFIG_FNAME) {
 371             $conf_fname = CONFIG_FNAME;
 372         } else {
 373             warn "unable to locate Koha configuration file koha-conf.xml";
 374             return;
 375         }
 376     }
 377
 378     if ($ismemcached) {
 379         # retreive from memcached
 380         $self = $memcached->get('kohaconf');
 381         if (not defined $self) {
 382             # not in memcached yet
 383             $self = read_config_file($conf_fname);
 384         }
 385     } else {
 386         # non-memcached env, read from file
 387         $self = read_config_file($conf_fname);
 388     }
 389
 390     $self->{"config_file"} = $conf_fname;
 391     warn "read_config_file($conf_fname) returned undef" if !defined($self->{"config"});
 392     return if !defined($self->{"config"});
 393
 394     $self->{"dbh"} = undef;        # Database handle
 395     $self->{"Zconn"} = undef;    # Zebra Connections
 396     $self->{"stopwords"} = undef; # stopwords list
 397     $self->{"marcfromkohafield"} = undef; # the hash with relations between koha table fields and MARC field/subfield
 398     $self->{"userenv"} = undef;        # User env
 399     $self->{"activeuser"} = undef;        # current active user
 400     $self->{"shelves"} = undef;
 401     $self->{tz} = undef; # local timezone object
 402
 403     bless $self, $class;
 404     $self->{db_driver} = db_scheme2dbi($self->config('db_scheme'));  # cache database driver
 405     return $self;
 406 }
 407
 408 =head2 set_context
 409
 410   $context = new C4::Context;
 411   $context->set_context();
 412 or
 413   set_context C4::Context $context;
 414
 415   ...
 416   restore_context C4::Context;
 417
 418 In some cases, it might be necessary for a script to use multiple
 419 contexts. C<&set_context> saves the current context on a stack, then
 420 sets the context to C<$context>, which will be used in future
 421 operations. To restore the previous context, use C<&restore_context>.
 422
 423 =cut
 424
 425 #'
 426 sub set_context
 427 {
 428     my $self = shift;
 429     my $new_context;    # The context to set
 430
 431     # Figure out whether this is a class or instance method call.
 432     #
 433     # We're going to make the assumption that control got here
 434     # through valid means, i.e., that the caller used an instance
 435     # or class method call, and that control got here through the
 436     # usual inheritance mechanisms. The caller can, of course,
 437     # break this assumption by playing silly buggers, but that's
 438     # harder to do than doing it properly, and harder to check
 439     # for.
 440     if (ref($self) eq "")
 441     {
 442         # Class method. The new context is the next argument.
 443         $new_context = shift;
 444     } else {
 445         # Instance method. The new context is $self.
 446         $new_context = $self;
 447     }
 448
 449     # Save the old context, if any, on the stack
 450     push @context_stack, $context if defined($context);
 451
 452     # Set the new context
 453     $context = $new_context;
 454 }
 455
 456 =head2 restore_context
 457
 458   &restore_context;
 459
 460 Restores the context set by C<&set_context>.
 461
 462 =cut
 463
 464 #'
 465 sub restore_context
 466 {
 467     my $self = shift;
 468
 469     if ($#context_stack < 0)
 470     {
 471         # Stack underflow.
 472         die "Context stack underflow";
 473     }
 474
 475     # Pop the old context and set it.
 476     $context = pop @context_stack;
 477
 478     # FIXME - Should this return something, like maybe the context
 479     # that was current when this was called?
 480 }
 481
 482 =head2 config
 483
 484   $value = C4::Context->config("config_variable");
 485
 486   $value = C4::Context->config_variable;
 487
 488 Returns the value of a variable specified in the configuration file
 489 from which the current context was created.
 490
 491 The second form is more compact, but of course may conflict with
 492 method names. If there is a configuration variable called "new", then
 493 C<C4::Config-E<gt>new> will not return it.
 494
 495 =cut
 496
 497 sub _common_config {
 498         my $var = shift;
 499         my $term = shift;
 500     return if !defined($context->{$term});
 501        # Presumably $self->{$term} might be
 502        # undefined if the config file given to &new
 503        # didn't exist, and the caller didn't bother
 504        # to check the return value.
 505
 506     # Return the value of the requested config variable
 507     return $context->{$term}->{$var};
 508 }
 509
 510 sub config {
 511         return _common_config($_[1],'config');
 512 }
 513 sub zebraconfig {
 514         return _common_config($_[1],'server');
 515 }
 516 sub ModZebrations {
 517         return _common_config($_[1],'serverinfo');
 518 }
 519
 520 =head2 preference
 521
 522   $sys_preference = C4::Context->preference('some_variable');
 523
 524 Looks up the value of the given system preference in the
 525 systempreferences table of the Koha database, and returns it. If the
 526 variable is not set or does not exist, undef is returned.
 527
 528 In case of an error, this may return 0.
 529
 530 Note: It is impossible to tell the difference between system
 531 preferences which do not exist, and those whose values are set to NULL
 532 with this method.
 533
 534 =cut
 535
 536 # FIXME: running this under mod_perl will require a means of
 537 # flushing the caching mechanism.
 538
 539 my %sysprefs;
 540 my $use_syspref_cache = 1;
 541
 542 sub preference {
 543     my $self = shift;
 544     my $var  = shift;    # The system preference to return
 545
 546     if ($use_syspref_cache && exists $sysprefs{lc $var}) {
 547         return $sysprefs{lc $var};
 548     }
 549
 550     my $dbh  = C4::Context->dbh or return 0;
 551
 552     my $value;
 553     if ( defined $ENV{"OVERRIDE_SYSPREF_$var"} ) {
 554         $value = $ENV{"OVERRIDE_SYSPREF_$var"};
 555     } else {
 556         # Look up systempreferences.variable==$var
 557         my $sql = q{
 558             SELECT  value
 559             FROM    systempreferences
 560             WHERE   variable = ?
 561             LIMIT   1
 562         };
 563         $value = $dbh->selectrow_array( $sql, {}, lc $var );
 564     }
 565
 566     $sysprefs{lc $var} = $value;
 567     return $value;
 568 }
 569
 570 sub boolean_preference {
 571     my $self = shift;
 572     my $var = shift;        # The system preference to return
 573     my $it = preference($self, $var);
 574     return defined($it)? C4::Boolean::true_p($it): undef;
 575 }
 576
 577 =head2 enable_syspref_cache
 578
 579   C4::Context->enable_syspref_cache();
 580
 581 Enable the in-memory syspref cache used by C4::Context. This is the
 582 default behavior.
 583
 584 =cut
 585
 586 sub enable_syspref_cache {
 587     my ($self) = @_;
 588     $use_syspref_cache = 1;
 589 }
 590
 591 =head2 disable_syspref_cache
 592
 593   C4::Context->disable_syspref_cache();
 594
 595 Disable the in-memory syspref cache used by C4::Context. This should be
 596 used with Plack and other persistent environments.
 597
 598 =cut
 599
 600 sub disable_syspref_cache {
 601     my ($self) = @_;
 602     $use_syspref_cache = 0;
 603     $self->clear_syspref_cache();
 604 }
 605
 606 =head2 clear_syspref_cache
 607
 608   C4::Context->clear_syspref_cache();
 609
 610 cleans the internal cache of sysprefs. Please call this method if
 611 you update the systempreferences table. Otherwise, your new changes
 612 will not be seen by this process.
 613
 614 =cut
 615
 616 sub clear_syspref_cache {
 617     %sysprefs = ();
 618 }
 619
 620 =head2 set_preference
 621
 622   C4::Context->set_preference( $variable, $value );
 623
 624 This updates a preference's value both in the systempreferences table and in
 625 the sysprefs cache.
 626
 627 =cut
 628
 629 sub set_preference {
 630     my $self = shift;
 631     my $var = lc(shift);
 632     my $value = shift;
 633
 634     my $dbh = C4::Context->dbh or return 0;
 635
 636     my $type = $dbh->selectrow_array( "SELECT type FROM systempreferences WHERE variable = ?", {}, $var );
 637
 638     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 639
 640     my $sth = $dbh->prepare( "
 641       INSERT INTO systempreferences
 642         ( variable, value )
 643         VALUES( ?, ? )
 644         ON DUPLICATE KEY UPDATE value = VALUES(value)
 645     " );
 646
 647     if($sth->execute( $var, $value )) {
 648         $sysprefs{$var} = $value;
 649     }
 650     $sth->finish;
 651 }
 652
 653 # AUTOLOAD
 654 # This implements C4::Config->foo, and simply returns
 655 # C4::Context->config("foo"), as described in the documentation for
 656 # &config, above.
 657
 658 # FIXME - Perhaps this should be extended to check &config first, and
 659 # then &preference if that fails. OTOH, AUTOLOAD could lead to crappy
 660 # code, so it'd probably be best to delete it altogether so as not to
 661 # encourage people to use it.
 662 sub AUTOLOAD
 663 {
 664     my $self = shift;
 665
 666     $AUTOLOAD =~ s/.*:://;        # Chop off the package name,
 667                     # leaving only the function name.
 668     return $self->config($AUTOLOAD);
 669 }
 670
 671 =head2 Zconn
 672
 673   $Zconn = C4::Context->Zconn
 674
 675 Returns a connection to the Zebra database for the current
 676 context. If no connection has yet been made, this method
 677 creates one and connects.
 678
 679 C<$self>
 680
 681 C<$server> one of the servers defined in the koha-conf.xml file
 682
 683 C<$async> whether this is a asynchronous connection
 684
 685 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 686
 687
 688 =cut
 689
 690 sub Zconn {
 691     my $self=shift;
 692     my $server=shift;
 693     my $async=shift;
 694     my $auth=shift;
 695     my $piggyback=shift;
 696     my $syntax=shift;
 697     if ( defined($context->{"Zconn"}->{$server}) && (0 == $context->{"Zconn"}->{$server}->errcode()) ) {
 698         return $context->{"Zconn"}->{$server};
 699     # No connection object or it died. Create one.
 700     }else {
 701         # release resources if we're closing a connection and making a new one
 702         # FIXME: this needs to be smarter -- an error due to a malformed query or
 703         # a missing index does not necessarily require us to close the connection
 704         # and make a new one, particularly for a batch job.  However, at
 705         # first glance it does not look like there's a way to easily check
 706         # the basic health of a ZOOM::Connection
 707         $context->{"Zconn"}->{$server}->destroy() if defined($context->{"Zconn"}->{$server});
 708
 709         $context->{"Zconn"}->{$server} = &_new_Zconn($server,$async,$auth,$piggyback,$syntax);
 710         return $context->{"Zconn"}->{$server};
 711     }
 712 }
 713
 714 =head2 _new_Zconn
 715
 716 $context->{"Zconn"} = &_new_Zconn($server,$async);
 717
 718 Internal function. Creates a new database connection from the data given in the current context and returns it.
 719
 720 C<$server> one of the servers defined in the koha-conf.xml file
 721
 722 C<$async> whether this is a asynchronous connection
 723
 724 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 725
 726 =cut
 727
 728 sub _new_Zconn {
 729     my ($server,$async,$auth,$piggyback,$syntax) = @_;
 730
 731     my $tried=0; # first attempt
 732     my $Zconn; # connection object
 733     my $elementSetName;
 734     my $index_mode;
 735
 736     $server //= "biblioserver";
 737     $syntax //= "XML";
 738
 739     if ( $server eq 'biblioserver' ) {
 740         $index_mode = $context->{'config'}->{'zebra_bib_index_mode'} // 'grs1';
 741     } elsif ( $server eq 'authorityserver' ) {
 742         $index_mode = $context->{'config'}->{'zebra_auth_index_mode'} // 'dom';
 743     }
 744
 745     if ( $index_mode eq 'grs1' ) {
 746
 747         $elementSetName = 'F';
 748         $syntax = ( $context->preference("marcflavour") eq 'UNIMARC' )
 749                 ? 'unimarc'
 750                 : 'usmarc';
 751
 752     } else {
 753
 754         $elementSetName = 'marcxml';
 755         $syntax = 'XML';
 756     }
 757
 758     my $host = $context->{'listen'}->{$server}->{'content'};
 759     my $servername = $context->{"config"}->{$server};
 760     my $user = $context->{"serverinfo"}->{$server}->{"user"};
 761     my $password = $context->{"serverinfo"}->{$server}->{"password"};
 762     $auth = 1 if($user && $password);
 763     retry:
 764     eval {
 765         # set options
 766         my $o = new ZOOM::Options();
 767         $o->option(user=>$user) if $auth;
 768         $o->option(password=>$password) if $auth;
 769         $o->option(async => 1) if $async;
 770         $o->option(count => $piggyback) if $piggyback;
 771         $o->option(cqlfile=> $context->{"server"}->{$server}->{"cql2rpn"});
 772         $o->option(cclfile=> $context->{"serverinfo"}->{$server}->{"ccl2rpn"});
 773         $o->option(preferredRecordSyntax => $syntax);
 774         $o->option(elementSetName => $elementSetName);
 775         $o->option(databaseName => ($servername?$servername:"biblios"));
 776
 777         # create a new connection object
 778         $Zconn= create ZOOM::Connection($o);
 779
 780         # forge to server
 781         $Zconn->connect($host, 0);
 782
 783         # check for errors and warn
 784         if ($Zconn->errcode() !=0) {
 785             warn "something wrong with the connection: ". $Zconn->errmsg();
 786         }
 787
 788     };
 789
 790     return $Zconn;
 791 }
 792
 793 # _new_dbh
 794 # Internal helper function (not a method!). This creates a new
 795 # database connection from the data given in the current context, and
 796 # returns it.
 797 sub _new_dbh
 798 {
 799
 800     ## $context
 801     ## correct name for db_scheme
 802     my $db_driver = $context->{db_driver};
 803
 804     my $db_name   = $context->config("database");
 805     my $db_host   = $context->config("hostname");
 806     my $db_port   = $context->config("port") || '';
 807     my $db_user   = $context->config("user");
 808     my $db_passwd = $context->config("pass");
 809     # MJR added or die here, as we can't work without dbh
 810     my $dbh = DBI->connect("DBI:$db_driver:dbname=$db_name;host=$db_host;port=$db_port",
 811     $db_user, $db_passwd, {'RaiseError' => $ENV{DEBUG}?1:0 }) or die $DBI::errstr;
 812
 813     # Check for the existence of a systempreference table; if we don't have this, we don't
 814     # have a valid database and should not set RaiseError in order to allow the installer
 815     # to run; installer will not run otherwise since we raise all db errors
 816
 817     eval {
 818                 local $dbh->{PrintError} = 0;
 819                 local $dbh->{RaiseError} = 1;
 820                 $dbh->do(qq{SELECT * FROM systempreferences WHERE 1 = 0 });
 821     };
 822
 823     if ($@) {
 824         $dbh->{RaiseError} = 0;
 825     }
 826
 827     if ( $db_driver eq 'mysql' ) {
 828         $dbh->{mysql_auto_reconnect} = 1;
 829     }
 830
 831         my $tz = $ENV{TZ};
 832     if ( $db_driver eq 'mysql' ) {
 833         # Koha 3.0 is utf-8, so force utf8 communication between mySQL and koha, whatever the mysql default config.
 834         # this is better than modifying my.cnf (and forcing all communications to be in utf8)
 835         $dbh->{'mysql_enable_utf8'}=1; #enable
 836         $dbh->do("set NAMES 'utf8'");
 837         ($tz) and $dbh->do(qq(SET time_zone = "$tz"));
 838     }
 839     elsif ( $db_driver eq 'Pg' ) {
 840             $dbh->do( "set client_encoding = 'UTF8';" );
 841         ($tz) and $dbh->do(qq(SET TIME ZONE = "$tz"));
 842     }
 843     return $dbh;
 844 }
 845
 846 =head2 dbh
 847
 848   $dbh = C4::Context->dbh;
 849
 850 Returns a database handle connected to the Koha database for the
 851 current context. If no connection has yet been made, this method
 852 creates one, and connects to the database.
 853
 854 This database handle is cached for future use: if you call
 855 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 856 times. If you need a second database handle, use C<&new_dbh> and
 857 possibly C<&set_dbh>.
 858
 859 =cut
 860
 861 #'
 862 sub dbh
 863 {
 864     my $self = shift;
 865     my $params = shift;
 866     my $sth;
 867
 868     unless ( $params->{new} ) {
 869         if ( defined($context->{db_driver}) && $context->{db_driver} eq 'mysql' && $context->{"dbh"} ) {
 870             return $context->{"dbh"};
 871         } elsif ( defined($context->{"dbh"}) && $context->{"dbh"}->ping() ) {
 872             return $context->{"dbh"};
 873         }
 874     }
 875
 876     # No database handle or it died . Create one.
 877     $context->{"dbh"} = &_new_dbh();
 878
 879     return $context->{"dbh"};
 880 }
 881
 882 =head2 new_dbh
 883
 884   $dbh = C4::Context->new_dbh;
 885
 886 Creates a new connection to the Koha database for the current context,
 887 and returns the database handle (a C<DBI::db> object).
 888
 889 The handle is not saved anywhere: this method is strictly a
 890 convenience function; the point is that it knows which database to
 891 connect to so that the caller doesn't have to know.
 892
 893 =cut
 894
 895 #'
 896 sub new_dbh
 897 {
 898     my $self = shift;
 899
 900     return &_new_dbh();
 901 }
 902
 903 =head2 set_dbh
 904
 905   $my_dbh = C4::Connect->new_dbh;
 906   C4::Connect->set_dbh($my_dbh);
 907   ...
 908   C4::Connect->restore_dbh;
 909
 910 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 911 C<&set_context> and C<&restore_context>.
 912
 913 C<&set_dbh> saves the current database handle on a stack, then sets
 914 the current database handle to C<$my_dbh>.
 915
 916 C<$my_dbh> is assumed to be a good database handle.
 917
 918 =cut
 919
 920 #'
 921 sub set_dbh
 922 {
 923     my $self = shift;
 924     my $new_dbh = shift;
 925
 926     # Save the current database handle on the handle stack.
 927     # We assume that $new_dbh is all good: if the caller wants to
 928     # screw himself by passing an invalid handle, that's fine by
 929     # us.
 930     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 931     $context->{"dbh"} = $new_dbh;
 932 }
 933
 934 =head2 restore_dbh
 935
 936   C4::Context->restore_dbh;
 937
 938 Restores the database handle saved by an earlier call to
 939 C<C4::Context-E<gt>set_dbh>.
 940
 941 =cut
 942
 943 #'
 944 sub restore_dbh
 945 {
 946     my $self = shift;
 947
 948     if ($#{$context->{"dbh_stack"}} < 0)
 949     {
 950         # Stack underflow
 951         die "DBH stack underflow";
 952     }
 953
 954     # Pop the old database handle and set it.
 955     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 956
 957     # FIXME - If it is determined that restore_context should
 958     # return something, then this function should, too.
 959 }
 960
 961 =head2 queryparser
 962
 963   $queryparser = C4::Context->queryparser
 964
 965 Returns a handle to an initialized Koha::QueryParser::Driver::PQF object.
 966
 967 =cut
 968
 969 sub queryparser {
 970     my $self = shift;
 971     unless (defined $context->{"queryparser"}) {
 972         $context->{"queryparser"} = &_new_queryparser();
 973     }
 974
 975     return
 976       defined( $context->{"queryparser"} )
 977       ? $context->{"queryparser"}->new
 978       : undef;
 979 }
 980
 981 =head2 _new_queryparser
 982
 983 Internal helper function to create a new QueryParser object. QueryParser
 984 is loaded dynamically so as to keep the lack of the QueryParser library from
 985 getting in anyone's way.
 986
 987 =cut
 988
 989 sub _new_queryparser {
 990     my $qpmodules = {
 991         'OpenILS::QueryParser'           => undef,
 992         'Koha::QueryParser::Driver::PQF' => undef
 993     };
 994     if ( can_load( 'modules' => $qpmodules ) ) {
 995         my $QParser     = Koha::QueryParser::Driver::PQF->new();
 996         my $config_file = $context->config('queryparser_config');
 997         $config_file ||= '/etc/koha/searchengine/queryparser.yaml';
 998         if ( $QParser->load_config($config_file) ) {
 999             # TODO: allow indexes to be configured in the database
1000             return $QParser;
1001         }
1002     }
1003     return;
1004 }
1005
1006 =head2 marcfromkohafield
1007
1008   $dbh = C4::Context->marcfromkohafield;
1009
1010 Returns a hash with marcfromkohafield.
1011
1012 This hash is cached for future use: if you call
1013 C<C4::Context-E<gt>marcfromkohafield> twice, you will get the same hash without real DB access
1014
1015 =cut
1016
1017 #'
1018 sub marcfromkohafield
1019 {
1020     my $retval = {};
1021
1022     # If the hash already exists, return it.
1023     return $context->{"marcfromkohafield"} if defined($context->{"marcfromkohafield"});
1024
1025     # No hash. Create one.
1026     $context->{"marcfromkohafield"} = &_new_marcfromkohafield();
1027
1028     return $context->{"marcfromkohafield"};
1029 }
1030
1031 # _new_marcfromkohafield
1032 # Internal helper function (not a method!). This creates a new
1033 # hash with stopwords
1034 sub _new_marcfromkohafield
1035 {
1036     my $dbh = C4::Context->dbh;
1037     my $marcfromkohafield;
1038     my $sth = $dbh->prepare("select frameworkcode,kohafield,tagfield,tagsubfield from marc_subfield_structure where kohafield > ''");
1039     $sth->execute;
1040     while (my ($frameworkcode,$kohafield,$tagfield,$tagsubfield) = $sth->fetchrow) {
1041         my $retval = {};
1042         $marcfromkohafield->{$frameworkcode}->{$kohafield} = [$tagfield,$tagsubfield];
1043     }
1044     return $marcfromkohafield;
1045 }
1046
1047 =head2 stopwords
1048
1049   $dbh = C4::Context->stopwords;
1050
1051 Returns a hash with stopwords.
1052
1053 This hash is cached for future use: if you call
1054 C<C4::Context-E<gt>stopwords> twice, you will get the same hash without real DB access
1055
1056 =cut
1057
1058 #'
1059 sub stopwords
1060 {
1061     my $retval = {};
1062
1063     # If the hash already exists, return it.
1064     return $context->{"stopwords"} if defined($context->{"stopwords"});
1065
1066     # No hash. Create one.
1067     $context->{"stopwords"} = &_new_stopwords();
1068
1069     return $context->{"stopwords"};
1070 }
1071
1072 # _new_stopwords
1073 # Internal helper function (not a method!). This creates a new
1074 # hash with stopwords
1075 sub _new_stopwords
1076 {
1077     my $dbh = C4::Context->dbh;
1078     my $stopwordlist;
1079     my $sth = $dbh->prepare("select word from stopwords");
1080     $sth->execute;
1081     while (my $stopword = $sth->fetchrow_array) {
1082         $stopwordlist->{$stopword} = uc($stopword);
1083     }
1084     $stopwordlist->{A} = "A" unless $stopwordlist;
1085     return $stopwordlist;
1086 }
1087
1088 =head2 userenv
1089
1090   C4::Context->userenv;
1091
1092 Retrieves a hash for user environment variables.
1093
1094 This hash shall be cached for future use: if you call
1095 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1096
1097 =cut
1098
1099 #'
1100 sub userenv {
1101     my $var = $context->{"activeuser"};
1102     if (defined $var and defined $context->{"userenv"}->{$var}) {
1103         return $context->{"userenv"}->{$var};
1104     } else {
1105         return;
1106     }
1107 }
1108
1109 =head2 set_userenv
1110
1111   C4::Context->set_userenv($usernum, $userid, $usercnum, $userfirstname,
1112                   $usersurname, $userbranch, $userflags, $emailaddress, $branchprinter,
1113                   $persona);
1114
1115 Establish a hash of user environment variables.
1116
1117 set_userenv is called in Auth.pm
1118
1119 =cut
1120
1121 #'
1122 sub set_userenv {
1123     my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter, $persona)= @_;
1124     my $var=$context->{"activeuser"} || '';
1125     my $cell = {
1126         "number"     => $usernum,
1127         "id"         => $userid,
1128         "cardnumber" => $usercnum,
1129         "firstname"  => $userfirstname,
1130         "surname"    => $usersurname,
1131         #possibly a law problem
1132         "branch"     => $userbranch,
1133         "branchname" => $branchname,
1134         "flags"      => $userflags,
1135         "emailaddress"     => $emailaddress,
1136         "branchprinter"    => $branchprinter,
1137         "persona"    => $persona,
1138     };
1139     $context->{userenv}->{$var} = $cell;
1140     return $cell;
1141 }
1142
1143 sub set_shelves_userenv {
1144         my ($type, $shelves) = @_ or return;
1145         my $activeuser = $context->{activeuser} or return;
1146         $context->{userenv}->{$activeuser}->{barshelves} = $shelves if $type eq 'bar';
1147         $context->{userenv}->{$activeuser}->{pubshelves} = $shelves if $type eq 'pub';
1148         $context->{userenv}->{$activeuser}->{totshelves} = $shelves if $type eq 'tot';
1149 }
1150
1151 sub get_shelves_userenv {
1152         my $active;
1153         unless ($active = $context->{userenv}->{$context->{activeuser}}) {
1154                 $debug and warn "get_shelves_userenv cannot retrieve context->{userenv}->{context->{activeuser}}";
1155                 return;
1156         }
1157         my $totshelves = $active->{totshelves} or undef;
1158         my $pubshelves = $active->{pubshelves} or undef;
1159         my $barshelves = $active->{barshelves} or undef;
1160         return ($totshelves, $pubshelves, $barshelves);
1161 }
1162
1163 =head2 _new_userenv
1164
1165   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
1166
1167 Builds a hash for user environment variables.
1168
1169 This hash shall be cached for future use: if you call
1170 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1171
1172 _new_userenv is called in Auth.pm
1173
1174 =cut
1175
1176 #'
1177 sub _new_userenv
1178 {
1179     shift;  # Useless except it compensates for bad calling style
1180     my ($sessionID)= @_;
1181      $context->{"activeuser"}=$sessionID;
1182 }
1183
1184 =head2 _unset_userenv
1185
1186   C4::Context->_unset_userenv;
1187
1188 Destroys the hash for activeuser user environment variables.
1189
1190 =cut
1191
1192 #'
1193
1194 sub _unset_userenv
1195 {
1196     my ($sessionID)= @_;
1197     undef $context->{"activeuser"} if ($context->{"activeuser"} eq $sessionID);
1198 }
1199
1200
1201 =head2 get_versions
1202
1203   C4::Context->get_versions
1204
1205 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
1206
1207 =cut
1208
1209 #'
1210
1211 # A little example sub to show more debugging info for CGI::Carp
1212 sub get_versions {
1213     my %versions;
1214     $versions{kohaVersion}  = KOHAVERSION();
1215     $versions{kohaDbVersion} = C4::Context->preference('version');
1216     $versions{osVersion} = join(" ", POSIX::uname());
1217     $versions{perlVersion} = $];
1218     {
1219         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
1220         $versions{mysqlVersion}  = `mysql -V`;
1221         $versions{apacheVersion} = `httpd -v`;
1222         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
1223         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
1224         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
1225     }
1226     return %versions;
1227 }
1228
1229
1230 =head2 tz
1231
1232   C4::Context->tz
1233
1234   Returns a DateTime::TimeZone object for the system timezone
1235
1236 =cut
1237
1238 sub tz {
1239     my $self = shift;
1240     if (!defined $context->{tz}) {
1241         $context->{tz} = DateTime::TimeZone->new(name => 'local');
1242     }
1243     return $context->{tz};
1244 }
1245
1246
1247 =head2 IsSuperLibrarian
1248
1249     C4::Context->IsSuperlibrarian();
1250
1251 =cut
1252
1253 sub IsSuperLibrarian {
1254     my $userenv = C4::Context->userenv;
1255
1256     unless ( $userenv and exists $userenv->{flags} ) {
1257         # If we reach this without a user environment,
1258         # assume that we're running from a command-line script,
1259         # and act as a superlibrarian.
1260         carp("C4::Context->userenv not defined!");
1261         return 1;
1262     }
1263
1264     return ($userenv->{flags}//0) % 2;
1265 }
1266
1267 1;
1268 __END__
1269
1270 =head1 ENVIRONMENT
1271
1272 =head2 C<KOHA_CONF>
1273
1274 Specifies the configuration file to read.
1275
1276 =head1 SEE ALSO
1277
1278 XML::Simple
1279
1280 =head1 AUTHORS
1281
1282 Andrew Arensburger <arensb at ooblick dot com>
1283
1284 Joshua Ferraro <jmf at liblime dot com>
1285
1286 =cut