C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use C4::Context;
  28 use C4::Stats qw( UpdateStats );
  29 use C4::Reserves qw( CheckReserves CanItemBeReserved MoveReserve ModReserve ModReserveMinusPriority RevertWaitingStatus IsItemOnHoldAndFound IsAvailableForItemLevelRequest ItemsAnyAvailableAndNotRestricted );
  30 use C4::Biblio qw( UpdateTotalIssues );
  31 use C4::Items qw( ModItemTransfer ModDateLastSeen CartToShelf );
  32 use C4::Accounts;
  33 use C4::ItemCirculationAlertPreference;
  34 use C4::Message;
  35 use C4::Log qw( logaction ); # logaction
  36 use C4::Overdues;
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits qw( CheckDigits );
  39
  40 use Data::Dumper qw( Dumper );
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils qw( dt_from_string );
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::Illrequests;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments qw( DelUniqueDebarment GetDebarments AddUniqueDebarment );
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Account::Lines;
  55 use Koha::Holds;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Config::SysPref;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Koha::SearchEngine::Indexer;
  63 use Koha::Exceptions::Checkout;
  64 use Koha::Plugins;
  65 use Koha::Recalls;
  66 use Carp qw( carp );
  67 use List::MoreUtils qw( any );
  68 use Scalar::Util qw( looks_like_number );
  69 use Date::Calc qw( Date_to_Days );
  70 our (@ISA, @EXPORT_OK);
  71 BEGIN {
  72
  73     require Exporter;
  74     @ISA = qw(Exporter);
  75
  76     # FIXME subs that should probably be elsewhere
  77     push @EXPORT_OK, qw(
  78       barcodedecode
  79       LostItem
  80       ReturnLostItem
  81       GetPendingOnSiteCheckouts
  82
  83       CanBookBeIssued
  84       checkHighHolds
  85       CanBookBeRenewed
  86       AddIssue
  87       GetLoanLength
  88       GetHardDueDate
  89       AddRenewal
  90       GetRenewCount
  91       GetSoonestRenewDate
  92       GetLatestAutoRenewDate
  93       GetIssuingCharges
  94       AddIssuingCharge
  95       GetBranchBorrowerCircRule
  96       GetBranchItemRule
  97       GetBiblioIssues
  98       GetUpcomingDueIssues
  99       CheckIfIssuedToPatron
 100       IsItemIssued
 101       GetAgeRestriction
 102       GetTopIssues
 103
 104       AddReturn
 105       MarkIssueReturned
 106
 107       transferbook
 108       TooMany
 109       GetTransfersFromTo
 110       updateWrongTransfer
 111       CalcDateDue
 112       CheckValidBarcode
 113       IsBranchTransferAllowed
 114       CreateBranchTransferLimit
 115       DeleteBranchTransferLimits
 116       TransferSlip
 117
 118       GetOfflineOperations
 119       GetOfflineOperation
 120       AddOfflineOperation
 121       DeleteOfflineOperation
 122       ProcessOfflineOperation
 123       ProcessOfflinePayment
 124       ProcessOfflineIssue
 125     );
 126     push @EXPORT_OK, '_GetCircControlBranch';    # This is wrong!
 127 }
 128
 129 =head1 NAME
 130
 131 C4::Circulation - Koha circulation module
 132
 133 =head1 SYNOPSIS
 134
 135 use C4::Circulation;
 136
 137 =head1 DESCRIPTION
 138
 139 The functions in this module deal with circulation, issues, and
 140 returns, as well as general information about the library.
 141 Also deals with inventory.
 142
 143 =head1 FUNCTIONS
 144
 145 =head2 barcodedecode
 146
 147   $str = &barcodedecode($barcode, [$filter]);
 148
 149 Generic filter function for barcode string.
 150 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 151 Will do some manipulation of the barcode for systems that deliver a barcode
 152 to circulation.pl that differs from the barcode stored for the item.
 153 For proper functioning of this filter, calling the function on the
 154 correct barcode string (items.barcode) should return an unaltered barcode.
 155 Barcode is going to be automatically trimmed of leading/trailing whitespaces.
 156
 157 The optional $filter argument is to allow for testing or explicit
 158 behavior that ignores the System Pref.  Valid values are the same as the
 159 System Pref options.
 160
 161 =cut
 162
 163 # FIXME -- the &decode fcn below should be wrapped into this one.
 164 # FIXME -- these plugins should be moved out of Circulation.pm
 165 #
 166 sub barcodedecode {
 167     my ($barcode, $filter) = @_;
 168
 169     return unless defined $barcode;
 170
 171     my $branch = C4::Context::mybranch();
 172     $barcode =~ s/^\s+|\s+$//g;
 173     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 174     Koha::Plugins->call('item_barcode_transform',  \$barcode );
 175     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 176         if ($filter eq 'whitespace') {
 177                 $barcode =~ s/\s//g;
 178         } elsif ($filter eq 'cuecat') {
 179                 chomp($barcode);
 180             my @fields = split( /\./, $barcode );
 181             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 182             ($#results == 2) and return $results[2];
 183         } elsif ($filter eq 'T-prefix') {
 184                 if ($barcode =~ /^[Tt](\d)/) {
 185                         (defined($1) and $1 eq '0') and return $barcode;
 186             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 187                 }
 188         return sprintf("T%07d", $barcode);
 189         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 190         # Why drop the nonzero digit after the T?
 191         # Why pass non-digits (or empty string) to "T%07d"?
 192         } elsif ($filter eq 'libsuite8') {
 193                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 194                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 195                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 196                         }else{
 197                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 198                         }
 199                 }
 200     } elsif ($filter eq 'EAN13') {
 201         my $ean = CheckDigits('ean');
 202         if ( $ean->is_valid($barcode) ) {
 203             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 204             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 205         } else {
 206             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 207         }
 208         }
 209     return $barcode;    # return barcode, modified or not
 210 }
 211
 212 =head2 _decode
 213
 214   $str = &_decode($chunk);
 215
 216 Decodes a segment of a string emitted by a CueCat barcode scanner and
 217 returns it.
 218
 219 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 220 or Javascript based decoding on the client side.
 221
 222 =cut
 223
 224 sub _decode {
 225     my ($encoded) = @_;
 226     my $seq =
 227       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 228     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 229     my $l = ( $#s + 1 ) % 4;
 230     if ($l) {
 231         if ( $l == 1 ) {
 232             # warn "Error: Cuecat decode parsing failed!";
 233             return;
 234         }
 235         $l = 4 - $l;
 236         $#s += $l;
 237     }
 238     my $r = '';
 239     while ( $#s >= 0 ) {
 240         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 241         $r .=
 242             chr( ( $n >> 16 ) ^ 67 )
 243          .chr( ( $n >> 8 & 255 ) ^ 67 )
 244          .chr( ( $n & 255 ) ^ 67 );
 245         @s = @s[ 4 .. $#s ];
 246     }
 247     $r = substr( $r, 0, length($r) - $l );
 248     return $r;
 249 }
 250
 251 =head2 transferbook
 252
 253   ($dotransfer, $messages, $iteminformation) = &transferbook({
 254                                                    from_branch => $frombranch
 255                                                    to_branch => $tobranch,
 256                                                    barcode => $barcode,
 257                                                    ignore_reserves => $ignore_reserves,
 258                                                    trigger => $trigger
 259                                                 });
 260
 261 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 262
 263 C<$fbr> is the code for the branch initiating the transfer.
 264 C<$tbr> is the code for the branch to which the item should be transferred.
 265
 266 C<$barcode> is the barcode of the item to be transferred.
 267
 268 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 269 Otherwise, if an item is reserved, the transfer fails.
 270
 271 C<$trigger> is the enum value for what triggered the transfer.
 272
 273 Returns three values:
 274
 275 =over
 276
 277 =item $dotransfer
 278
 279 is true if the transfer was successful.
 280
 281 =item $messages
 282
 283 is a reference-to-hash which may have any of the following keys:
 284
 285 =over
 286
 287 =item C<BadBarcode>
 288
 289 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 290
 291 =item C<DestinationEqualsHolding>
 292
 293 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 294
 295 =item C<WasReturned>
 296
 297 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 298
 299 =item C<ResFound>
 300
 301 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 302
 303 =item C<WasTransferred>
 304
 305 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 306
 307 =item C<RecallPlacedAtHoldingBranch>
 308
 309 A recall for this item was found, and the transfer has already been completed as the item's branch matches the recall's pickup branch.
 310
 311 =item C<RecallFound>
 312
 313 A recall for this item was found, and the item needs to be transferred to the recall's pickup branch.
 314
 315 =back
 316
 317 =back
 318
 319 =cut
 320
 321 sub transferbook {
 322     my $params = shift;
 323     my $tbr      = $params->{to_branch};
 324     my $fbr      = $params->{from_branch};
 325     my $ignoreRs = $params->{ignore_reserves};
 326     my $barcode  = $params->{barcode};
 327     my $trigger  = $params->{trigger};
 328     my $messages;
 329     my $dotransfer      = 1;
 330     my $item = Koha::Items->find( { barcode => $barcode } );
 331
 332     Koha::Exceptions::MissingParameter->throw(
 333         "Missing mandatory parameter: from_branch")
 334       unless $fbr;
 335
 336     Koha::Exceptions::MissingParameter->throw(
 337         "Missing mandatory parameter: to_branch")
 338       unless $tbr;
 339
 340     # bad barcode..
 341     unless ( $item ) {
 342         $messages->{'BadBarcode'} = $barcode;
 343         $dotransfer = 0;
 344         return ( $dotransfer, $messages );
 345     }
 346
 347     my $itemnumber = $item->itemnumber;
 348     # get branches of book...
 349     my $hbr = $item->homebranch;
 350
 351     # if using Branch Transfer Limits
 352     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 353         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 354         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 355             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 356                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 357                 $dotransfer = 0;
 358             }
 359         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 360             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 361             $dotransfer = 0;
 362         }
 363     }
 364
 365     # can't transfer book if is already there....
 366     if ( $fbr eq $tbr ) {
 367         $messages->{'DestinationEqualsHolding'} = 1;
 368         $dotransfer = 0;
 369     }
 370
 371     # check if it is still issued to someone, return it...
 372     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 373     if ( $issue ) {
 374         AddReturn( $barcode, $fbr );
 375         $messages->{'WasReturned'} = $issue->borrowernumber;
 376     }
 377
 378     # find reserves.....
 379     # That'll save a database query.
 380     my ( $resfound, $resrec, undef ) =
 381       CheckReserves( $itemnumber );
 382     if ( $resfound ) {
 383         $resrec->{'ResFound'} = $resfound;
 384         $messages->{'ResFound'} = $resrec;
 385         $dotransfer = 0 unless $ignoreRs;
 386     }
 387
 388     # find recall
 389     if ( C4::Context->preference('UseRecalls') ) {
 390         my $recall = Koha::Recalls->find({ item_id => $itemnumber, status => 'in_transit' });
 391         if ( defined $recall ) {
 392             # do a transfer if the recall branch is different to the item holding branch
 393             if ( $recall->pickup_library_id eq $fbr ) {
 394                 $dotransfer = 0;
 395                 $messages->{'RecallPlacedAtHoldingBranch'} = 1;
 396             } else {
 397                 $dotransfer = 1;
 398                 $messages->{'RecallFound'} = $recall;
 399             }
 400         }
 401     }
 402
 403     #actually do the transfer....
 404     if ($dotransfer) {
 405         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 406
 407         # don't need to update MARC anymore, we do it in batch now
 408         $messages->{'WasTransfered'} = $tbr;
 409
 410     }
 411     ModDateLastSeen( $itemnumber );
 412     return ( $dotransfer, $messages );
 413 }
 414
 415
 416 sub TooMany {
 417     my $borrower        = shift;
 418     my $item_object = shift;
 419     my $params = shift;
 420     my $onsite_checkout = $params->{onsite_checkout} || 0;
 421     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 422     my $cat_borrower    = $borrower->{'categorycode'};
 423     my $dbh             = C4::Context->dbh;
 424     # Get which branchcode we need
 425     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 426     my $type = $item_object->effective_itemtype;
 427
 428     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 429     $type_object = Koha::ItemTypes->find( $type );
 430     $parent_type = $type_object->parent_type if $type_object;
 431     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 432     # Find any children if we are a parent_type;
 433
 434     # given branch, patron category, and item type, determine
 435     # applicable issuing rule
 436
 437     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 438         {
 439             categorycode => $cat_borrower,
 440             itemtype     => $parent_type,
 441             branchcode   => $branch,
 442             rule_name    => 'maxissueqty',
 443         }
 444     ) if $parent_type;
 445     # If the parent rule is for default type we discount it
 446     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 447
 448     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 449         {
 450             categorycode => $cat_borrower,
 451             itemtype     => $type,
 452             branchcode   => $branch,
 453             rule_name    => 'maxissueqty',
 454         }
 455     );
 456
 457     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 458         {
 459             categorycode => $cat_borrower,
 460             itemtype     => $type,
 461             branchcode   => $branch,
 462             rule_name    => 'maxonsiteissueqty',
 463         }
 464     );
 465
 466
 467     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 468     # if a rule is found and has a loan limit set, count
 469     # how many loans the patron already has that meet that
 470     # rule
 471     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 472
 473         my $checkouts;
 474         if ( $maxissueqty_rule->branchcode ) {
 475             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 476                 $checkouts = $patron->checkouts->search(
 477                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 478             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 479                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 480             } else {
 481                 $checkouts = $patron->checkouts->search(
 482                     { 'item.homebranch' => $maxissueqty_rule->branchcode } );
 483             }
 484         } else {
 485             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 486         }
 487         $checkouts = $checkouts->search(undef, { prefetch => 'item' });
 488
 489         my $sum_checkouts;
 490         my $rule_itemtype = $maxissueqty_rule->itemtype;
 491
 492         my @types;
 493         unless ( $rule_itemtype ) {
 494             # matching rule has the default item type, so count only
 495             # those existing loans that don't fall under a more
 496             # specific rule
 497             @types = Koha::CirculationRules->search(
 498                 {
 499                     branchcode => $maxissueqty_rule->branchcode,
 500                     categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 501                     itemtype  => { '!=' => undef },
 502                     rule_name => 'maxissueqty'
 503                 }
 504             )->get_column('itemtype');
 505         } else {
 506             if ( $parent_maxissueqty_rule ) {
 507                 # if we have a parent item type then we count loans of the
 508                 # specific item type or its siblings or parent
 509                 my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 510                 @types = $children->get_column('itemtype');
 511                 push @types, $parent_type;
 512             } elsif ( $child_types ) {
 513                 # If we are a parent type, we need to count all child types and our own type
 514                 @types = $child_types->get_column('itemtype');
 515                 push @types, $type; # And don't forget to count our own types
 516             } else {
 517                 # Otherwise only count the specific itemtype
 518                 push @types, $type;
 519             }
 520         }
 521
 522         while ( my $c = $checkouts->next ) {
 523             my $itemtype = $c->item->effective_itemtype;
 524
 525             unless ( $rule_itemtype ) {
 526                 next if grep {$_ eq $itemtype} @types;
 527             } else {
 528                 next unless grep {$_ eq $itemtype} @types;
 529             }
 530
 531             $sum_checkouts->{total}++;
 532             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 533             $sum_checkouts->{itemtype}->{$itemtype}++;
 534         }
 535
 536         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 537         my $checkout_count = $sum_checkouts->{total} || 0;
 538         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 539
 540         my $checkout_rules = {
 541             checkout_count               => $checkout_count,
 542             onsite_checkout_count        => $onsite_checkout_count,
 543             onsite_checkout              => $onsite_checkout,
 544             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 545             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 546             switch_onsite_checkout       => $switch_onsite_checkout,
 547         };
 548         # If parent rules exists
 549         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 550             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 551             my $qty_over = _check_max_qty($checkout_rules);
 552             return $qty_over if defined $qty_over;
 553
 554             # If the parent rule is less than or equal to the child, we only need check the parent
 555             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 556                 $checkout_rules->{checkout_count} = $checkout_count_type;
 557                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 558                 my $qty_over = _check_max_qty($checkout_rules);
 559                 return $qty_over if defined $qty_over;
 560             }
 561         } else {
 562             my $qty_over = _check_max_qty($checkout_rules);
 563             return $qty_over if defined $qty_over;
 564         }
 565     }
 566
 567     # Now count total loans against the limit for the branch
 568     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 569     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 570         my $checkouts;
 571         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 572             $checkouts = $patron->checkouts->search(
 573                 { 'me.branchcode' => $branch} );
 574         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 575             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 576         } else {
 577             $checkouts = $patron->checkouts->search(
 578                 { 'item.homebranch' => $branch},
 579                 { prefetch          => 'item' } );
 580         }
 581
 582         my $checkout_count = $checkouts->count;
 583         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 584         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 585         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 586
 587         my $qty_over = _check_max_qty(
 588             {
 589                 checkout_count               => $checkout_count,
 590                 onsite_checkout_count        => $onsite_checkout_count,
 591                 onsite_checkout              => $onsite_checkout,
 592                 max_checkouts_allowed        => $max_checkouts_allowed,
 593                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 594                 switch_onsite_checkout       => $switch_onsite_checkout
 595             }
 596         );
 597         return $qty_over if defined $qty_over;
 598     }
 599
 600     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 601         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 602     }
 603
 604     # OK, the patron can issue !!!
 605     return;
 606 }
 607
 608 sub _check_max_qty {
 609     my $params                       = shift;
 610     my $checkout_count               = $params->{checkout_count};
 611     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 612     my $onsite_checkout              = $params->{onsite_checkout};
 613     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 614     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 615     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 616
 617     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 618         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 619         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 620             return {
 621                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 622                 count       => $onsite_checkout_count,
 623                 max_allowed => $max_onsite_checkouts_allowed,
 624             };
 625         }
 626     }
 627     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 628         if ( $max_checkouts_allowed eq '' ) { return; }
 629         my $delta = $switch_onsite_checkout ? 1 : 0;
 630         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 631             return {
 632                 reason      => 'TOO_MANY_CHECKOUTS',
 633                 count       => $checkout_count,
 634                 max_allowed => $max_checkouts_allowed,
 635             };
 636         }
 637     }
 638     elsif ( not $onsite_checkout ) {
 639         if ( $max_checkouts_allowed eq '' ) { return; }
 640         if (
 641             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 642         {
 643             return {
 644                 reason      => 'TOO_MANY_CHECKOUTS',
 645                 count       => $checkout_count - $onsite_checkout_count,
 646                 max_allowed => $max_checkouts_allowed,
 647             };
 648         }
 649     }
 650
 651     return;
 652 }
 653
 654 =head2 CanBookBeIssued
 655
 656   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 657                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 658
 659 Check if a book can be issued.
 660
 661 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 662
 663 IMPORTANT: The assumption by users of this routine is that causes blocking
 664 the issue are keyed by uppercase labels and other returned
 665 data is keyed in lower case!
 666
 667 =over 4
 668
 669 =item C<$patron> is a Koha::Patron
 670
 671 =item C<$barcode> is the bar code of the book being issued.
 672
 673 =item C<$duedates> is a DateTime object.
 674
 675 =item C<$inprocess> boolean switch
 676
 677 =item C<$ignore_reserves> boolean switch
 678
 679 =item C<$params> Hashref of additional parameters
 680
 681 Available keys:
 682     override_high_holds - Ignore high holds
 683     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 684
 685 =back
 686
 687 Returns :
 688
 689 =over 4
 690
 691 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 692 Possible values are :
 693
 694 =back
 695
 696 =head3 INVALID_DATE
 697
 698 sticky due date is invalid
 699
 700 =head3 GNA
 701
 702 borrower gone with no address
 703
 704 =head3 CARD_LOST
 705
 706 borrower declared it's card lost
 707
 708 =head3 DEBARRED
 709
 710 borrower debarred
 711
 712 =head3 UNKNOWN_BARCODE
 713
 714 barcode unknown
 715
 716 =head3 NOT_FOR_LOAN
 717
 718 item is not for loan
 719
 720 =head3 WTHDRAWN
 721
 722 item withdrawn.
 723
 724 =head3 RESTRICTED
 725
 726 item is restricted (set by ??)
 727
 728 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 729 could be prevented, but ones that can be overriden by the operator.
 730
 731 Possible values are :
 732
 733 =head3 DEBT
 734
 735 borrower has debts.
 736
 737 =head3 RENEW_ISSUE
 738
 739 renewing, not issuing
 740
 741 =head3 ISSUED_TO_ANOTHER
 742
 743 issued to someone else.
 744
 745 =head3 RESERVED
 746
 747 reserved for someone else.
 748
 749 =head3 TRANSFERRED
 750
 751 reserved and being transferred for someone else.
 752
 753 =head3 INVALID_DATE
 754
 755 sticky due date is invalid or due date in the past
 756
 757 =head3 TOO_MANY
 758
 759 if the borrower borrows to much things
 760
 761 =head3 RECALLED
 762
 763 recalled by someone else
 764
 765 =cut
 766
 767 sub CanBookBeIssued {
 768     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 769     my %needsconfirmation;    # filled with problems that needs confirmations
 770     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 771     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 772     my %messages;             # filled with information messages that should be displayed.
 773
 774     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 775     my $override_high_holds = $params->{override_high_holds} || 0;
 776
 777     my $item_object = Koha::Items->find({barcode => $barcode });
 778
 779     # MANDATORY CHECKS - unless item exists, nothing else matters
 780     unless ( $item_object ) {
 781         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 782     }
 783     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 784
 785     my $item_unblessed = $item_object->unblessed; # Transition...
 786     my $issue = $item_object->checkout;
 787     my $biblio = $item_object->biblio;
 788
 789     my $biblioitem = $biblio->biblioitem;
 790     my $effective_itemtype = $item_object->effective_itemtype;
 791     my $dbh             = C4::Context->dbh;
 792     my $patron_unblessed = $patron->unblessed;
 793
 794     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 795
 796     my $now = dt_from_string();
 797     $duedate ||= CalcDateDue( $now, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 798     if (DateTime->compare($duedate,$now) == -1 ) { # duedate cannot be before now
 799          $needsconfirmation{INVALID_DATE} = $duedate;
 800     }
 801
 802     my $fees = Koha::Charges::Fees->new(
 803         {
 804             patron    => $patron,
 805             library   => $circ_library,
 806             item      => $item_object,
 807             to_date   => $duedate,
 808         }
 809     );
 810
 811     #
 812     # BORROWER STATUS
 813     #
 814     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 815         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 816         C4::Stats::UpdateStats(
 817             {
 818                 branch         => C4::Context->userenv->{'branch'},
 819                 type           => 'localuse',
 820                 itemnumber     => $item_object->itemnumber,
 821                 itemtype       => $effective_itemtype,
 822                 borrowernumber => $patron->borrowernumber,
 823                 ccode          => $item_object->ccode,
 824                 categorycode   => $patron->categorycode,
 825             }
 826         );
 827         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 828         return( { STATS => 1 }, {});
 829     }
 830
 831     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 832         $issuingimpossible{GNA} = 1;
 833     }
 834
 835     if ( $patron->lost && $patron->lost == 1 ) {
 836         $issuingimpossible{CARD_LOST} = 1;
 837     }
 838     if ( $patron->is_debarred ) {
 839         $issuingimpossible{DEBARRED} = 1;
 840     }
 841
 842     if ( $patron->is_expired ) {
 843         $issuingimpossible{EXPIRED} = 1;
 844     }
 845
 846     #
 847     # BORROWER STATUS
 848     #
 849
 850     # DEBTS
 851     my $account = $patron->account;
 852     my $balance = $account->balance;
 853     my $non_issues_charges = $account->non_issues_charges;
 854     my $other_charges = $balance - $non_issues_charges;
 855
 856     my $amountlimit = C4::Context->preference("noissuescharge");
 857     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 858     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 859
 860     # Check the debt of this patrons guarantees
 861     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 862     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 863     if ( defined $no_issues_charge_guarantees ) {
 864         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships->as_list;
 865         my $guarantees_non_issues_charges = 0;
 866         foreach my $g ( @guarantees ) {
 867             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 868         }
 869
 870         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 871             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 872         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 873             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 874         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 875             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 876         }
 877     }
 878
 879     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 880     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 881     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 882     if ( defined $no_issues_charge_guarantors ) {
 883         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 884
 885         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 886             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 887         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 888             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 889         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 890             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 891         }
 892     }
 893
 894     if ( C4::Context->preference("IssuingInProcess") ) {
 895         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 896             $issuingimpossible{DEBT} = $non_issues_charges;
 897         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 898             $needsconfirmation{DEBT} = $non_issues_charges;
 899         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 900             $needsconfirmation{DEBT} = $non_issues_charges;
 901         }
 902     }
 903     else {
 904         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 905             $needsconfirmation{DEBT} = $non_issues_charges;
 906         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 907             $issuingimpossible{DEBT} = $non_issues_charges;
 908         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 909             $needsconfirmation{DEBT} = $non_issues_charges;
 910         }
 911     }
 912
 913     if ($balance > 0 && $other_charges > 0) {
 914         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 915     }
 916
 917     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 918     $patron_unblessed = $patron->unblessed;
 919
 920     if ( my $debarred_date = $patron->is_debarred ) {
 921          # patron has accrued fine days or has a restriction. $count is a date
 922         if ($debarred_date eq '9999-12-31') {
 923             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 924         }
 925         else {
 926             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 927         }
 928     } elsif ( my $num_overdues = $patron->has_overdues ) {
 929         ## patron has outstanding overdue loans
 930         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 931             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 932         }
 933         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 934             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 935         }
 936     }
 937
 938     # Additional Materials Check
 939     if ( C4::Context->preference("CircConfirmItemParts")
 940         && $item_object->materials )
 941     {
 942         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 943     }
 944
 945     #
 946     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 947     #
 948     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 949
 950         # Already issued to current borrower.
 951         # If it is an on-site checkout if it can be switched to a normal checkout
 952         # or ask whether the loan should be renewed
 953
 954         if ( $issue->onsite_checkout
 955                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 956             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 957         } else {
 958             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 959                 $patron->borrowernumber,
 960                 $item_object->itemnumber,
 961             );
 962             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 963                 if ( $renewerror eq 'onsite_checkout' ) {
 964                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 965                 }
 966                 else {
 967                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 968                 }
 969             }
 970             else {
 971                 $needsconfirmation{RENEW_ISSUE} = 1;
 972             }
 973         }
 974     }
 975     elsif ( $issue ) {
 976
 977         # issued to someone else
 978
 979         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 980
 981         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 982
 983         unless ( $can_be_returned ) {
 984             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 985             $issuingimpossible{branch_to_return} = $message;
 986         } else {
 987             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 988                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 989             } else {
 990             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 991             $needsconfirmation{issued_firstname} = $patron->firstname;
 992             $needsconfirmation{issued_surname} = $patron->surname;
 993             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 994             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 995             }
 996         }
 997     }
 998
 999     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
1000     #
1001     my $switch_onsite_checkout = (
1002           C4::Context->preference('SwitchOnSiteCheckouts')
1003       and $issue
1004       and $issue->onsite_checkout
1005       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
1006     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
1007     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
1008     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
1009         if ( $toomany->{max_allowed} == 0 ) {
1010             $needsconfirmation{PATRON_CANT} = 1;
1011         }
1012         if ( C4::Context->preference("AllowTooManyOverride") ) {
1013             $needsconfirmation{TOO_MANY} = $toomany->{reason};
1014             $needsconfirmation{current_loan_count} = $toomany->{count};
1015             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
1016         } else {
1017             $issuingimpossible{TOO_MANY} = $toomany->{reason};
1018             $issuingimpossible{current_loan_count} = $toomany->{count};
1019             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
1020         }
1021     }
1022
1023     #
1024     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1025     #
1026     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1027     my $wants_check = $patron->wants_check_for_previous_checkout;
1028     $needsconfirmation{PREVISSUE} = 1
1029         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1030
1031     #
1032     # ITEM CHECKING
1033     #
1034     if ( $item_object->notforloan )
1035     {
1036         if(!C4::Context->preference("AllowNotForLoanOverride")){
1037             $issuingimpossible{NOT_FOR_LOAN} = 1;
1038             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1039         }else{
1040             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1041             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1042         }
1043     }
1044     else {
1045         # we have to check itemtypes.notforloan also
1046         if (C4::Context->preference('item-level_itypes')){
1047             # this should probably be a subroutine
1048             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1049             $sth->execute($effective_itemtype);
1050             my $notforloan=$sth->fetchrow_hashref();
1051             if ($notforloan->{'notforloan'}) {
1052                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1053                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1054                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1055                 } else {
1056                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1057                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1058                 }
1059             }
1060         }
1061         else {
1062             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1063             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1064                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1065                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1066                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1067                 } else {
1068                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1069                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1070                 }
1071             }
1072         }
1073     }
1074     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1075     {
1076         $issuingimpossible{WTHDRAWN} = 1;
1077     }
1078     if (   $item_object->restricted
1079         && $item_object->restricted == 1 )
1080     {
1081         $issuingimpossible{RESTRICTED} = 1;
1082     }
1083     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1084         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1085         my $code = $av->count ? $av->next->lib : '';
1086         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1087         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1088     }
1089     if ( C4::Context->preference("IndependentBranches") ) {
1090         my $userenv = C4::Context->userenv;
1091         unless ( C4::Context->IsSuperLibrarian() ) {
1092             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1093             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1094                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1095                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1096             }
1097             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1098               if ( $patron->branchcode ne $userenv->{branch} );
1099         }
1100     }
1101
1102     #
1103     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1104     #
1105     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1106     if ($rentalConfirmation) {
1107         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1108
1109         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1110         if ($itemtype_object) {
1111             my $accumulate_charge = $fees->accumulate_rentalcharge();
1112             if ( $accumulate_charge > 0 ) {
1113                 $rentalCharge += $accumulate_charge;
1114             }
1115         }
1116
1117         if ( $rentalCharge > 0 ) {
1118             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1119         }
1120     }
1121
1122     my $recall;
1123     # CHECK IF ITEM HAS BEEN RECALLED BY ANOTHER PATRON
1124     # Only bother doing this if UseRecalls is enabled and the item is recallable
1125     # Don't look at recalls that are in transit
1126     if ( C4::Context->preference('UseRecalls') and $item_object->can_be_waiting_recall ) {
1127         my @recalls = $biblio->recalls({},{ order_by => { -asc => 'created_date' } })->filter_by_current->as_list;
1128
1129         foreach my $r ( @recalls ) {
1130             if ( $r->item_id and
1131                 $r->item_id == $item_object->itemnumber and
1132                 $r->patron_id == $patron->borrowernumber and
1133                 ( $r->waiting or $r->requested ) ) {
1134                 $messages{RECALLED} = $r->id;
1135                 $recall = $r;
1136                 # this item is recalled by or already waiting for this borrower and the recall can be fulfilled
1137                 last;
1138             }
1139             elsif ( $r->item_id and
1140                 $r->item_id == $item_object->itemnumber and
1141                 $r->in_transit ) {
1142                 # recalled item is in transit
1143                 $issuingimpossible{RECALLED_INTRANSIT} = $r->pickup_library_id;
1144             }
1145             elsif ( $r->item_level and
1146                 $r->item_id == $item_object->itemnumber and
1147                 $r->patron_id != $patron->borrowernumber and
1148                 !$r->in_transit ) {
1149                 # this specific item has been recalled by a different patron
1150                 $needsconfirmation{RECALLED} = $r;
1151                 $recall = $r;
1152                 last;
1153             }
1154             elsif ( !$r->item_level and
1155                 $r->patron_id != $patron->borrowernumber and
1156                 !$r->in_transit ) {
1157                 # a different patron has placed a biblio-level recall and this item is eligible to fill it
1158                 $needsconfirmation{RECALLED} = $r;
1159                 $recall = $r;
1160                 last;
1161             }
1162         }
1163     }
1164
1165     unless ( $ignore_reserves and defined $recall ) {
1166         # See if the item is on reserve.
1167         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1168         if ($restype) {
1169             my $resbor = $res->{'borrowernumber'};
1170             if ( $resbor ne $patron->borrowernumber ) {
1171                 my $patron = Koha::Patrons->find( $resbor );
1172                 if ( $restype eq "Waiting" )
1173                 {
1174                     # The item is on reserve and waiting, but has been
1175                     # reserved by some other patron.
1176                     $needsconfirmation{RESERVE_WAITING} = 1;
1177                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1178                     $needsconfirmation{'ressurname'} = $patron->surname;
1179                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1180                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1181                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1182                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1183                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1184                 }
1185                 elsif ( $restype eq "Reserved" ) {
1186                     # The item is on reserve for someone else.
1187                     $needsconfirmation{RESERVED} = 1;
1188                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1189                     $needsconfirmation{'ressurname'} = $patron->surname;
1190                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1191                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1192                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1193                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1194                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1195                 }
1196                 elsif ( $restype eq "Transferred" ) {
1197                     # The item is determined hold being transferred for someone else.
1198                     $needsconfirmation{TRANSFERRED} = 1;
1199                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1200                     $needsconfirmation{'ressurname'} = $patron->surname;
1201                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1202                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1203                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1204                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1205                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1206                 }
1207                 elsif ( $restype eq "Processing" ) {
1208                     # The item is determined hold being processed for someone else.
1209                     $needsconfirmation{PROCESSING} = 1;
1210                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1211                     $needsconfirmation{'ressurname'} = $patron->surname;
1212                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1213                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1214                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1215                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1216                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1217                 }
1218             }
1219         }
1220     }
1221
1222     ## CHECK AGE RESTRICTION
1223     my $agerestriction  = $biblioitem->agerestriction;
1224     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1225     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1226         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1227             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1228         }
1229         else {
1230             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1231         }
1232     }
1233
1234     ## check for high holds decreasing loan period
1235     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1236         my $check = checkHighHolds( $item_object, $patron );
1237
1238         if ( $check->{exceeded} ) {
1239             my $highholds = {
1240                 num_holds  => $check->{outstanding},
1241                 duration   => $check->{duration},
1242                 returndate => $check->{due_date},
1243             };
1244             if ($override_high_holds) {
1245                 $alerts{HIGHHOLDS} = $highholds;
1246             }
1247             else {
1248                 $needsconfirmation{HIGHHOLDS} = $highholds;
1249             }
1250         }
1251     }
1252
1253     if (
1254         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1255         # don't do the multiple loans per bib check if we've
1256         # already determined that we've got a loan on the same item
1257         !$issuingimpossible{NO_MORE_RENEWALS} &&
1258         !$needsconfirmation{RENEW_ISSUE}
1259     ) {
1260         # Check if borrower has already issued an item from the same biblio
1261         # Only if it's not a subscription
1262         my $biblionumber = $item_object->biblionumber;
1263         require C4::Serials;
1264         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1265         unless ($is_a_subscription) {
1266             # FIXME Should be $patron->checkouts($args);
1267             my $checkouts = Koha::Checkouts->search(
1268                 {
1269                     borrowernumber => $patron->borrowernumber,
1270                     biblionumber   => $biblionumber,
1271                 },
1272                 {
1273                     join => 'item',
1274                 }
1275             );
1276             # if we get here, we don't already have a loan on this item,
1277             # so if there are any loans on this bib, ask for confirmation
1278             if ( $checkouts->count ) {
1279                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1280             }
1281         }
1282     }
1283
1284     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1285 }
1286
1287 =head2 CanBookBeReturned
1288
1289   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1290
1291 Check whether the item can be returned to the provided branch
1292
1293 =over 4
1294
1295 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1296
1297 =item C<$branch> is the branchcode where the return is taking place
1298
1299 =back
1300
1301 Returns:
1302
1303 =over 4
1304
1305 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1306
1307 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1308
1309 =back
1310
1311 =cut
1312
1313 sub CanBookBeReturned {
1314   my ($item, $branch) = @_;
1315   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1316
1317   # assume return is allowed to start
1318   my $allowed = 1;
1319   my $message;
1320
1321   # identify all cases where return is forbidden
1322   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1323      $allowed = 0;
1324      $message = $item->{'homebranch'};
1325   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1326      $allowed = 0;
1327      $message = $item->{'holdingbranch'};
1328   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1329      $allowed = 0;
1330      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1331   }
1332
1333   return ($allowed, $message);
1334 }
1335
1336 =head2 CheckHighHolds
1337
1338     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1339     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1340     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1341
1342 =cut
1343
1344 sub checkHighHolds {
1345     my ( $item, $patron ) = @_;
1346     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
1347
1348     my $return_data = {
1349         exceeded    => 0,
1350         outstanding => 0,
1351         duration    => 0,
1352         due_date    => undef,
1353     };
1354
1355     my $holds = Koha::Holds->search( { biblionumber => $item->biblionumber } );
1356
1357     if ( $holds->count() ) {
1358         $return_data->{outstanding} = $holds->count();
1359
1360         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1361         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1362         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1363
1364         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1365
1366         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1367
1368             # static means just more than a given number of holds on the record
1369
1370             # If the number of holds is less than the threshold, we can stop here
1371             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1372                 return $return_data;
1373             }
1374         }
1375         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1376
1377             # dynamic means X more than the number of holdable items on the record
1378
1379             # let's get the items
1380             my @items = $holds->next()->biblio()->items()->as_list;
1381
1382             # Remove any items with status defined to be ignored even if the would not make item unholdable
1383             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1384                 @items = grep { !$_->$status } @items;
1385             }
1386
1387             # Remove any items that are not holdable for this patron
1388             @items = grep { CanItemBeReserved( $patron , $_, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1389
1390             my $items_count = scalar @items;
1391
1392             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1393
1394             # If the number of holds is less than the count of items we have
1395             # plus the number of holds allowed above that count, we can stop here
1396             if ( $holds->count() <= $threshold ) {
1397                 return $return_data;
1398             }
1399         }
1400
1401         my $issuedate = dt_from_string();
1402
1403         my $itype = $item->effective_itemtype;
1404         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1405             {
1406                 categorycode => $patron->categorycode,
1407                 itemtype     => $itype,
1408                 branchcode   => $branchcode,
1409             }
1410         );
1411         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1412
1413         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $patron->unblessed );
1414
1415         my $rule = Koha::CirculationRules->get_effective_rule_value(
1416             {
1417                 categorycode => $patron->categorycode,
1418                 itemtype     => $item->effective_itemtype,
1419                 branchcode   => $branchcode,
1420                 rule_name    => 'decreaseloanholds',
1421             }
1422         );
1423
1424         my $duration;
1425         if ( defined($rule) && $rule ne '' ){
1426             # overrides decreaseLoanHighHoldsDuration syspref
1427             $duration = $rule;
1428         } else {
1429             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1430         }
1431         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1432         $reduced_datedue->set_hour($orig_due->hour);
1433         $reduced_datedue->set_minute($orig_due->minute);
1434         $reduced_datedue->truncate( to => 'minute' );
1435
1436         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1437             $return_data->{exceeded} = 1;
1438             $return_data->{duration} = $duration;
1439             $return_data->{due_date} = $reduced_datedue;
1440         }
1441     }
1442
1443     return $return_data;
1444 }
1445
1446 =head2 AddIssue
1447
1448   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1449
1450 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1451
1452 =over 4
1453
1454 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1455
1456 =item C<$barcode> is the barcode of the item being issued.
1457
1458 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1459 Calculated if empty.
1460
1461 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1462
1463 =item C<$issuedate> is a DateTime object for the date to issue the item (optional).
1464 Defaults to today.
1465
1466 AddIssue does the following things :
1467
1468   - step 01: check that there is a borrowernumber & a barcode provided
1469   - check for RENEWAL (book issued & being issued to the same patron)
1470       - renewal YES = Calculate Charge & renew
1471       - renewal NO  =
1472           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1473           * RESERVE PLACED ?
1474               - fill reserve if reserve to this patron
1475               - cancel reserve or not, otherwise
1476           * RECALL PLACED ?
1477               - fill recall if recall to this patron
1478               - cancel recall or not
1479               - revert recall's waiting status or not
1480           * TRANSFERT PENDING ?
1481               - complete the transfert
1482           * ISSUE THE BOOK
1483
1484 =back
1485
1486 =cut
1487
1488 sub AddIssue {
1489     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1490
1491     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1492     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1493     my $auto_renew = $params && $params->{auto_renew};
1494     my $cancel_recall = $params && $params->{cancel_recall};
1495     my $recall_id = $params && $params->{recall_id};
1496     my $dbh          = C4::Context->dbh;
1497     my $barcodecheck = CheckValidBarcode($barcode);
1498
1499     my $issue;
1500
1501     if ( $datedue && ref $datedue ne 'DateTime' ) {
1502         $datedue = dt_from_string($datedue);
1503     }
1504
1505     # $issuedate defaults to today.
1506     if ( !defined $issuedate ) {
1507         $issuedate = dt_from_string();
1508     }
1509     else {
1510         if ( ref $issuedate ne 'DateTime' ) {
1511             $issuedate = dt_from_string($issuedate);
1512
1513         }
1514     }
1515
1516     # Stop here if the patron or barcode doesn't exist
1517     if ( $borrower && $barcode && $barcodecheck ) {
1518         # find which item we issue
1519         my $item_object = Koha::Items->find({ barcode => $barcode })
1520           or return;    # if we don't get an Item, abort.
1521         my $item_unblessed = $item_object->unblessed;
1522
1523         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1524
1525         # get actual issuing if there is one
1526         my $actualissue = $item_object->checkout;
1527
1528         # check if we just renew the issue.
1529         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1530                 and not $switch_onsite_checkout ) {
1531             $datedue = AddRenewal(
1532                 $borrower->{'borrowernumber'},
1533                 $item_object->itemnumber,
1534                 $branchcode,
1535                 $datedue,
1536                 $issuedate,    # here interpreted as the renewal date
1537             );
1538         }
1539         else {
1540             unless ($datedue) {
1541                 my $itype = $item_object->effective_itemtype;
1542                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1543
1544             }
1545
1546             # Check if we need to use an exact due date set by the ILL module
1547             if ( C4::Context->preference('ILLModule') ) {
1548                 # Check if there is an ILL connected with the biblio of the item we are issuing
1549                 my $ill_request = Koha::Illrequests->search({
1550                     biblio_id => $item_object->biblionumber,
1551                     borrowernumber => $borrower->{'borrowernumber'},
1552                     completed => undef,
1553                     due_date => { '!=', undef },
1554                 })->next;
1555
1556                 if ( $ill_request and length( $ill_request->due_date ) > 0 ) {
1557                     my $ill_dt = dt_from_string( $ill_request->due_date );
1558                     $ill_dt->set_hour(23);
1559                     $ill_dt->set_minute(59);
1560                     $datedue = $ill_dt;
1561                 }
1562             }
1563
1564             $datedue->truncate( to => 'minute' );
1565
1566             my $patron = Koha::Patrons->find( $borrower );
1567             my $library = Koha::Libraries->find( $branchcode );
1568             my $fees = Koha::Charges::Fees->new(
1569                 {
1570                     patron    => $patron,
1571                     library   => $library,
1572                     item      => $item_object,
1573                     to_date   => $datedue,
1574                 }
1575             );
1576
1577             # it's NOT a renewal
1578             if ( $actualissue and not $switch_onsite_checkout ) {
1579                 # This book is currently on loan, but not to the person
1580                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1581                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1582                 return unless $allowed;
1583                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1584                 # AddReturn certainly has side-effects, like onloan => undef
1585                 $item_object->discard_changes;
1586             }
1587
1588             if ( C4::Context->preference('UseRecalls') ) {
1589                 Koha::Recalls->move_recall(
1590                     {
1591                         action         => $cancel_recall,
1592                         recall_id      => $recall_id,
1593                         item           => $item_object,
1594                         borrowernumber => $borrower->{borrowernumber},
1595                     }
1596                 );
1597             }
1598
1599             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1600
1601             # Starting process for transfer job (checking transfert and validate it if we have one)
1602             if ( my $transfer = $item_object->get_transfer ) {
1603                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1604                 $transfer->set(
1605                     {
1606                         datearrived => dt_from_string,
1607                         tobranch    => C4::Context->userenv->{branch},
1608                         comments    => 'Forced branchtransfer'
1609                     }
1610                 )->store;
1611                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1612                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1613                     if ( $hold ) { # Is this really needed?
1614                         $hold->set( { found => undef } )->store;
1615                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1616                     }
1617                 }
1618             }
1619
1620             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1621             unless ($auto_renew) {
1622                 my $rule = Koha::CirculationRules->get_effective_rule_value(
1623                     {
1624                         categorycode => $borrower->{categorycode},
1625                         itemtype     => $item_object->effective_itemtype,
1626                         branchcode   => $branchcode,
1627                         rule_name    => 'auto_renew'
1628                     }
1629                 );
1630
1631                 $auto_renew = $rule if defined $rule && $rule ne '';
1632             }
1633
1634             my $issue_attributes = {
1635                 borrowernumber  => $borrower->{'borrowernumber'},
1636                 issuedate       => $issuedate,
1637                 date_due        => $datedue,
1638                 branchcode      => C4::Context->userenv->{'branch'},
1639                 onsite_checkout => $onsite_checkout,
1640                 auto_renew      => $auto_renew ? 1 : 0,
1641             };
1642
1643             # Get ID of logged in user.  if called from a batch job,
1644             # no user session exists and C4::Context->userenv() returns
1645             # the scalar '0'. Only do this if the syspref says so
1646             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1647                 my $userenv = C4::Context->userenv();
1648                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1649                 if ($usernumber) {
1650                     $issue_attributes->{issuer_id} = $usernumber;
1651                 }
1652             }
1653
1654             # In the case that the borrower has an on-site checkout
1655             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1656             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1657             if ($issue) {
1658                 $issue->set($issue_attributes)->store;
1659             }
1660             else {
1661                 $issue = Koha::Checkout->new(
1662                     {
1663                         itemnumber => $item_object->itemnumber,
1664                         %$issue_attributes,
1665                     }
1666                 )->store;
1667             }
1668             $issue->discard_changes;
1669             C4::Auth::track_login_daily( $borrower->{userid} );
1670             if ( $item_object->location && $item_object->location eq 'CART'
1671                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1672             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1673                 CartToShelf( $item_object->itemnumber );
1674             }
1675
1676             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1677                 UpdateTotalIssues( $item_object->biblionumber, 1, undef, { skip_holds_queue => 1 } );
1678             }
1679
1680             # Record if item was lost
1681             my $was_lost = $item_object->itemlost;
1682
1683             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1684             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1685             $item_object->itemlost(0);
1686             $item_object->onloan($datedue->ymd());
1687             $item_object->datelastborrowed( dt_from_string()->ymd() );
1688             $item_object->datelastseen( dt_from_string()->ymd() );
1689             $item_object->store( { log_action => 0, skip_holds_queue => 1 } );
1690
1691             # If the item was lost, it has now been found, charge the overdue if necessary
1692             if ($was_lost) {
1693                 if ( $item_object->{_charge} ) {
1694                     $actualissue //= Koha::Old::Checkouts->search(
1695                         { itemnumber => $item_unblessed->{itemnumber} },
1696                         {
1697                             order_by => { '-desc' => 'returndate' },
1698                             rows     => 1
1699                         }
1700                     )->single;
1701                     unless ( exists( $borrower->{branchcode} ) ) {
1702                         my $patron = $actualissue->patron;
1703                         $borrower = $patron->unblessed;
1704                     }
1705                     _CalculateAndUpdateFine(
1706                         {
1707                             issue       => $actualissue,
1708                             item        => $item_unblessed,
1709                             borrower    => $borrower,
1710                             return_date => $issuedate
1711                         }
1712                     );
1713                     _FixOverduesOnReturn( $borrower->{borrowernumber},
1714                         $item_object->itemnumber, undef, 'RENEWED' );
1715                 }
1716             }
1717
1718             # If it costs to borrow this book, charge it to the patron's account.
1719             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1720             if ( $charge && $charge > 0 ) {
1721                 AddIssuingCharge( $issue, $charge, 'RENT' );
1722             }
1723
1724             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1725             if ( $itemtype_object ) {
1726                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1727                 if ( $accumulate_charge > 0 ) {
1728                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1729                     $charge += $accumulate_charge;
1730                     $item_unblessed->{charge} = $charge;
1731                 }
1732             }
1733
1734             # Record the fact that this book was issued.
1735             C4::Stats::UpdateStats(
1736                 {
1737                     branch => C4::Context->userenv->{'branch'},
1738                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1739                     amount         => $charge,
1740                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1741                     itemnumber     => $item_object->itemnumber,
1742                     itemtype       => $item_object->effective_itemtype,
1743                     location       => $item_object->location,
1744                     borrowernumber => $borrower->{'borrowernumber'},
1745                     ccode          => $item_object->ccode,
1746                     categorycode   => $borrower->{'categorycode'}
1747                 }
1748             );
1749
1750             # Send a checkout slip.
1751             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1752             my %conditions        = (
1753                 branchcode   => $branchcode,
1754                 categorycode => $borrower->{categorycode},
1755                 item_type    => $item_object->effective_itemtype,
1756                 notification => 'CHECKOUT',
1757             );
1758             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1759                 SendCirculationAlert(
1760                     {
1761                         type     => 'CHECKOUT',
1762                         item     => $item_object->unblessed,
1763                         borrower => $borrower,
1764                         branch   => $branchcode,
1765                     }
1766                 );
1767             }
1768             logaction(
1769                 "CIRCULATION", "ISSUE",
1770                 $borrower->{'borrowernumber'},
1771                 $item_object->itemnumber,
1772             ) if C4::Context->preference("IssueLog");
1773
1774             Koha::Plugins->call('after_circ_action', {
1775                 action  => 'checkout',
1776                 payload => {
1777                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1778                     checkout => $issue->get_from_storage
1779                 }
1780             });
1781
1782             Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
1783                 {
1784                     biblio_ids => [ $item_object->biblionumber ]
1785                 }
1786             ) if C4::Context->preference('RealTimeHoldsQueue');
1787         }
1788     }
1789     return $issue;
1790 }
1791
1792 =head2 GetLoanLength
1793
1794   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1795
1796 Get loan length for an itemtype, a borrower type and a branch
1797
1798 =cut
1799
1800 sub GetLoanLength {
1801     my ( $categorycode, $itemtype, $branchcode ) = @_;
1802
1803     # Initialize default values
1804     my $rules = {
1805         issuelength   => 0,
1806         renewalperiod => 0,
1807         lengthunit    => 'days',
1808     };
1809
1810     my $found = Koha::CirculationRules->get_effective_rules( {
1811         branchcode => $branchcode,
1812         categorycode => $categorycode,
1813         itemtype => $itemtype,
1814         rules => [
1815             'issuelength',
1816             'renewalperiod',
1817             'lengthunit'
1818         ],
1819     } );
1820
1821     # Search for rules!
1822     foreach my $rule_name (keys %$found) {
1823         $rules->{$rule_name} = $found->{$rule_name};
1824     }
1825
1826     return $rules;
1827 }
1828
1829
1830 =head2 GetHardDueDate
1831
1832   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1833
1834 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1835
1836 =cut
1837
1838 sub GetHardDueDate {
1839     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1840
1841     my $rules = Koha::CirculationRules->get_effective_rules(
1842         {
1843             categorycode => $borrowertype,
1844             itemtype     => $itemtype,
1845             branchcode   => $branchcode,
1846             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1847         }
1848     );
1849
1850     if ( defined( $rules->{hardduedate} ) ) {
1851         if ( $rules->{hardduedate} ) {
1852             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1853         }
1854         else {
1855             return ( undef, undef );
1856         }
1857     }
1858 }
1859
1860 =head2 GetBranchBorrowerCircRule
1861
1862   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1863
1864 Retrieves circulation rule attributes that apply to the given
1865 branch and patron category, regardless of item type.
1866 The return value is a hashref containing the following key:
1867
1868 patron_maxissueqty - maximum number of loans that a
1869 patron of the given category can have at the given
1870 branch.  If the value is undef, no limit.
1871
1872 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1873 patron of the given category can have at the given
1874 branch.  If the value is undef, no limit.
1875
1876 This will check for different branch/category combinations in the following order:
1877 branch and category
1878 branch only
1879 category only
1880 default branch and category
1881
1882 If no rule has been found in the database, it will default to
1883 the buillt in rule:
1884
1885 patron_maxissueqty - undef
1886 patron_maxonsiteissueqty - undef
1887
1888 C<$branchcode> and C<$categorycode> should contain the
1889 literal branch code and patron category code, respectively - no
1890 wildcards.
1891
1892 =cut
1893
1894 sub GetBranchBorrowerCircRule {
1895     my ( $branchcode, $categorycode ) = @_;
1896
1897     # Initialize default values
1898     my $rules = {
1899         patron_maxissueqty       => undef,
1900         patron_maxonsiteissueqty => undef,
1901     };
1902
1903     # Search for rules!
1904     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1905         my $rule = Koha::CirculationRules->get_effective_rule(
1906             {
1907                 categorycode => $categorycode,
1908                 itemtype     => undef,
1909                 branchcode   => $branchcode,
1910                 rule_name    => $rule_name,
1911             }
1912         );
1913
1914         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1915     }
1916
1917     return $rules;
1918 }
1919
1920 =head2 GetBranchItemRule
1921
1922   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1923
1924 Retrieves circulation rule attributes that apply to the given
1925 branch and item type, regardless of patron category.
1926
1927 The return value is a hashref containing the following keys:
1928
1929 holdallowed => Hold policy for this branch and itemtype. Possible values:
1930   not_allowed:           No holds allowed.
1931   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
1932   from_any_library:      Holds allowed from any patron.
1933   from_local_hold_group: Holds allowed from libraries in hold group
1934
1935 returnbranch => branch to which to return item.  Possible values:
1936   noreturn: do not return, let item remain where checked in (floating collections)
1937   homebranch: return to item's home branch
1938   holdingbranch: return to issuer branch
1939
1940 This searches branchitemrules in the following order:
1941
1942   * Same branchcode and itemtype
1943   * Same branchcode, itemtype '*'
1944   * branchcode '*', same itemtype
1945   * branchcode and itemtype '*'
1946
1947 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1948
1949 =cut
1950
1951 sub GetBranchItemRule {
1952     my ( $branchcode, $itemtype ) = @_;
1953
1954     # Search for rules!
1955     my $rules = Koha::CirculationRules->get_effective_rules({
1956         branchcode => $branchcode,
1957         itemtype => $itemtype,
1958         rules => ['holdallowed', 'hold_fulfillment_policy', 'returnbranch']
1959     });
1960
1961     # built-in default circulation rule
1962     $rules->{holdallowed} //= 'from_any_library';
1963     $rules->{hold_fulfillment_policy} //= 'any';
1964     $rules->{returnbranch} //= 'homebranch';
1965
1966     return $rules;
1967 }
1968
1969 =head2 AddReturn
1970
1971   ($doreturn, $messages, $iteminformation, $borrower) =
1972       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1973
1974 Returns a book.
1975
1976 =over 4
1977
1978 =item C<$barcode> is the bar code of the book being returned.
1979
1980 =item C<$branch> is the code of the branch where the book is being returned.
1981
1982 =item C<$exemptfine> indicates that overdue charges for the item will be
1983 removed. Optional.
1984
1985 =item C<$return_date> allows the default return date to be overridden
1986 by the given return date. Optional.
1987
1988 =back
1989
1990 C<&AddReturn> returns a list of four items:
1991
1992 C<$doreturn> is true iff the return succeeded.
1993
1994 C<$messages> is a reference-to-hash giving feedback on the operation.
1995 The keys of the hash are:
1996
1997 =over 4
1998
1999 =item C<BadBarcode>
2000
2001 No item with this barcode exists. The value is C<$barcode>.
2002
2003 =item C<NotIssued>
2004
2005 The book is not currently on loan. The value is C<$barcode>.
2006
2007 =item C<withdrawn>
2008
2009 This book has been withdrawn/cancelled. The value should be ignored.
2010
2011 =item C<Wrongbranch>
2012
2013 This book has was returned to the wrong branch.  The value is a hashref
2014 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
2015 contain the branchcode of the incorrect and correct return library, respectively.
2016
2017 =item C<ResFound>
2018
2019 The item was reserved. The value is a reference-to-hash whose keys are
2020 fields from the reserves table of the Koha database, and
2021 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
2022 either C<Waiting>, C<Reserved>, or 0.
2023
2024 =item C<WasReturned>
2025
2026 Value 1 if return is successful.
2027
2028 =item C<NeedsTransfer>
2029
2030 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
2031
2032 =item C<RecallFound>
2033
2034 This item can fill a recall. The recall object is returned. If the recall pickup branch differs from
2035 the branch this item is being returned at, C<RecallNeedsTransfer> is also returned which contains this
2036 branchcode.
2037
2038 =item C<TransferredRecall>
2039
2040 This item has been transferred to this branch to fill a recall. The recall object is returned.
2041
2042 =back
2043
2044 C<$iteminformation> is a reference-to-hash, giving information about the
2045 returned item from the issues table.
2046
2047 C<$borrower> is a reference-to-hash, giving information about the
2048 patron who last borrowed the book.
2049
2050 =cut
2051
2052 sub AddReturn {
2053     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
2054
2055     if ($branch and not Koha::Libraries->find($branch)) {
2056         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
2057         undef $branch;
2058     }
2059     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
2060     my $return_date_specified = !!$return_date;
2061     $return_date //= dt_from_string();
2062     my $messages;
2063     my $patron;
2064     my $doreturn       = 1;
2065     my $validTransfer = 1;
2066     my $stat_type = 'return';
2067
2068     # get information on item
2069     my $item = Koha::Items->find({ barcode => $barcode });
2070     unless ($item) {
2071         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
2072     }
2073
2074     my $itemnumber = $item->itemnumber;
2075     my $itemtype = $item->effective_itemtype;
2076
2077     my $issue  = $item->checkout;
2078     if ( $issue ) {
2079         $patron = $issue->patron
2080             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
2081                 . Dumper($issue->unblessed) . "\n";
2082     } else {
2083         $messages->{'NotIssued'} = $barcode;
2084         $item->onloan(undef)->store( { skip_record_index => 1, skip_holds_queue => 1 } ) if defined $item->onloan;
2085
2086         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2087         $doreturn = 0;
2088         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2089         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2090         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2091            $messages->{'LocalUse'} = 1;
2092            $stat_type = 'localuse';
2093         }
2094     }
2095
2096         # full item data, but no borrowernumber or checkout info (no issue)
2097     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
2098         # get the proper branch to which to return the item
2099     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
2100         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2101     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2102
2103     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2104     my $patron_unblessed = $patron ? $patron->unblessed : {};
2105
2106     my $update_loc_rules = Koha::Config::SysPrefs->find('UpdateItemLocationOnCheckin')->get_yaml_pref_hash();
2107     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
2108     if ($update_loc_rules) {
2109         if (defined $update_loc_rules->{_ALL_}) {
2110             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
2111             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
2112             if (
2113                 ( defined $item->location && $item->location ne $update_loc_rules->{_ALL_}) ||
2114                 (!defined $item->location && $update_loc_rules->{_ALL_} ne "")
2115                ) {
2116                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
2117                 $item->location($update_loc_rules->{_ALL_})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1});
2118             }
2119         }
2120         else {
2121             foreach my $key ( keys %$update_loc_rules ) {
2122                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
2123                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
2124                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
2125                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
2126                     $item->location($update_loc_rules->{$key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1});
2127                     last;
2128                 }
2129             }
2130         }
2131     }
2132
2133     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2134     if ($yaml) {
2135         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2136         my $rules;
2137         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2138         if ($@) {
2139             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2140         }
2141         else {
2142             foreach my $key ( keys %$rules ) {
2143                 if ( $item->notforloan eq $key ) {
2144                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2145                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2146                     last;
2147                 }
2148             }
2149         }
2150     }
2151
2152     # check if the return is allowed at this branch
2153     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2154     unless ($returnallowed){
2155         $messages->{'Wrongbranch'} = {
2156             Wrongbranch => $branch,
2157             Rightbranch => $message
2158         };
2159         $doreturn = 0;
2160         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2161         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2162         return ( $doreturn, $messages, $issue, $patron_unblessed);
2163     }
2164
2165     if ( $item->withdrawn ) { # book has been cancelled
2166         $messages->{'withdrawn'} = 1;
2167         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
2168     }
2169
2170     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2171         $doreturn = 0;
2172     }
2173
2174     # case of a return of document (deal with issues and holdingbranch)
2175     if ($doreturn) {
2176         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2177         $patron or warn "AddReturn without current borrower";
2178
2179         if ($patron) {
2180             eval {
2181                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1, skip_holds_queue => 1} );
2182             };
2183             unless ( $@ ) {
2184                 if (
2185                     (
2186                         C4::Context->preference('CalculateFinesOnReturn')
2187                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2188                     )
2189                     && !$item->itemlost
2190                   )
2191                 {
2192                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2193                 }
2194             } else {
2195                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2196
2197                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2198                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2199
2200                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2201             }
2202
2203             # FIXME is the "= 1" right?  This could be the borrower hash.
2204             $messages->{'WasReturned'} = 1;
2205
2206         } else {
2207             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1, skip_holds_queue => 1 });
2208         }
2209     }
2210
2211     # the holdingbranch is updated if the document is returned to another location.
2212     # this is always done regardless of whether the item was on loan or not
2213     if ($item->holdingbranch ne $branch) {
2214         $item->holdingbranch($branch)->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2215     }
2216
2217     my $item_was_lost = $item->itemlost;
2218     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2219     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1, skip_holds_queue => 1 } ); # will unset itemlost if needed
2220
2221     # fix up the accounts.....
2222     if ($item_was_lost) {
2223         $messages->{'WasLost'} = 1;
2224         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2225             my @object_messages = @{ $updated_item->object_messages };
2226             for my $message (@object_messages) {
2227                 $messages->{'LostItemFeeRefunded'} = 1
2228                   if $message->message eq 'lost_refunded';
2229                 $messages->{'LostItemFeeRestored'} = 1
2230                   if $message->message eq 'lost_restored';
2231
2232                 if ( $message->message eq 'lost_charge' ) {
2233                     $issue //= Koha::Old::Checkouts->search(
2234                         { itemnumber => $item->itemnumber },
2235                         { order_by   => { '-desc' => 'returndate' }, rows => 1 }
2236                     )->single;
2237                     unless ( exists( $patron_unblessed->{branchcode} ) ) {
2238                         my $patron = $issue->patron;
2239                         $patron_unblessed = $patron->unblessed;
2240                     }
2241                     _CalculateAndUpdateFine(
2242                         {
2243                             issue       => $issue,
2244                             item        => $item->unblessed,
2245                             borrower    => $patron_unblessed,
2246                             return_date => $return_date
2247                         }
2248                     );
2249                     _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2250                         $item->itemnumber, undef, 'RETURNED' );
2251                     $messages->{'LostItemFeeCharged'} = 1;
2252                 }
2253             }
2254         }
2255     }
2256
2257     # check if we have a transfer for this document
2258     my $transfer = $item->get_transfer;
2259
2260     # if we have a transfer to complete, we update the line of transfers with the datearrived
2261     if ($transfer) {
2262         $validTransfer = 0;
2263         if ( $transfer->in_transit ) {
2264             if ( $transfer->tobranch eq $branch ) {
2265                 $transfer->receive;
2266                 $messages->{'TransferArrived'} = $transfer->frombranch;
2267                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2268                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2269             }
2270             else {
2271                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2272                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2273                 $messages->{'TransferTrigger'}   = $transfer->reason;
2274             }
2275         }
2276         else {
2277             if ( $transfer->tobranch eq $branch ) {
2278                 $transfer->receive;
2279                 $messages->{'TransferArrived'} = $transfer->frombranch;
2280                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2281                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2282             }
2283             else {
2284                 $messages->{'WasTransfered'}   = $transfer->tobranch;
2285                 $messages->{'TransferTrigger'} = $transfer->reason;
2286             }
2287         }
2288     }
2289
2290     # fix up the overdues in accounts...
2291     if ($borrowernumber) {
2292         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2293         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2294
2295         if ( $issue and $issue->is_overdue($return_date) ) {
2296         # fix fine days
2297             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2298             if ($reminder){
2299                 $messages->{'PrevDebarred'} = $debardate;
2300             } else {
2301                 $messages->{'Debarred'} = $debardate if $debardate;
2302             }
2303         # there's no overdue on the item but borrower had been previously debarred
2304         } elsif ( $issue->date_due and $patron->debarred ) {
2305              if ( $patron->debarred eq "9999-12-31") {
2306                 $messages->{'ForeverDebarred'} = $patron->debarred;
2307              } else {
2308                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2309                   $borrower_debar_dt->truncate(to => 'day');
2310                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2311                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2312                       $messages->{'PrevDebarred'} = $patron->debarred;
2313                   }
2314              }
2315         }
2316     }
2317
2318     # find recalls...
2319     if ( C4::Context->preference('UseRecalls') ) {
2320         # check if this item is recallable first, which includes checking if UseRecalls syspref is enabled
2321         my $recall = undef;
2322         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2323         if ( defined $recall ) {
2324             $messages->{RecallFound} = $recall;
2325             if ( $recall->pickup_library_id ne $branch ) {
2326                 $messages->{RecallNeedsTransfer} = $branch;
2327             }
2328         }
2329     }
2330
2331     # find reserves.....
2332     # launch the Checkreserves routine to find any holds
2333     my ($resfound, $resrec);
2334     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2335     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2336     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2337     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2338         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2339         $resfound = 'Reserved';
2340         $resrec = $hold->unblessed;
2341     }
2342     if ($resfound) {
2343           $resrec->{'ResFound'} = $resfound;
2344         $messages->{'ResFound'} = $resrec;
2345     }
2346
2347     # Record the fact that this book was returned.
2348     C4::Stats::UpdateStats({
2349         branch         => $branch,
2350         type           => $stat_type,
2351         itemnumber     => $itemnumber,
2352         itemtype       => $itemtype,
2353         location       => $item->location,
2354         borrowernumber => $borrowernumber,
2355         ccode          => $item->ccode,
2356         categorycode   => $patron->categorycode,
2357     });
2358
2359     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2360     if ( $patron ) {
2361         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2362         my %conditions = (
2363             branchcode   => $branch,
2364             categorycode => $patron->categorycode,
2365             item_type    => $itemtype,
2366             notification => 'CHECKIN',
2367         );
2368         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2369             SendCirculationAlert({
2370                 type     => 'CHECKIN',
2371                 item     => $item->unblessed,
2372                 borrower => $patron->unblessed,
2373                 branch   => $branch,
2374                 issue    => $issue
2375             });
2376         }
2377
2378         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2379             if C4::Context->preference("ReturnLog");
2380         }
2381
2382     # Check if this item belongs to a biblio record that is attached to an
2383     # ILL request, if it is we need to update the ILL request's status
2384     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2385         my $request = Koha::Illrequests->find(
2386             { biblio_id => $item->biblio->biblionumber }
2387         );
2388         $request->status('RET') if $request;
2389     }
2390
2391     if ( C4::Context->preference('UseRecalls') ) {
2392         # all recalls that have triggered a transfer will have an allocated itemnumber
2393         my $transfer_recall = Koha::Recalls->find({ item_id => $item->itemnumber, status => 'in_transit' });
2394         if ( $transfer_recall and $transfer_recall->pickup_library_id eq $branch ) {
2395             $messages->{TransferredRecall} = $transfer_recall;
2396         }
2397     }
2398
2399     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2400     if ( $validTransfer && !C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber )
2401         && ( $doreturn or $messages->{'NotIssued'} )
2402         and !$resfound
2403         and ( $branch ne $returnbranch )
2404         and not $messages->{'WrongTransfer'}
2405         and not $messages->{'WasTransfered'}
2406         and not $messages->{TransferredRecall}
2407         and not $messages->{RecallNeedsTransfer} )
2408     {
2409         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2410         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2411             (C4::Context->preference("UseBranchTransferLimits") and
2412              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2413            )) {
2414             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2415             $messages->{'WasTransfered'} = $returnbranch;
2416             $messages->{'TransferTrigger'} = $transfer_trigger;
2417         } else {
2418             $messages->{'NeedsTransfer'} = $returnbranch;
2419             $messages->{'TransferTrigger'} = $transfer_trigger;
2420         }
2421     }
2422
2423     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2424         my $claims = Koha::Checkouts::ReturnClaims->search(
2425            {
2426                itemnumber => $item->id,
2427                resolution => undef,
2428            }
2429         );
2430
2431         if ( $claims->count ) {
2432             $messages->{ReturnClaims} = $claims;
2433         }
2434     }
2435
2436     # Check for bundle status
2437     if ( $item->in_bundle ) {
2438         my $host = $item->bundle_host;
2439         $messages->{InBundle} = $host;
2440     }
2441
2442     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2443     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2444
2445     if ( $doreturn and $issue ) {
2446         my $checkin = Koha::Old::Checkouts->find($issue->id);
2447
2448         Koha::Plugins->call('after_circ_action', {
2449             action  => 'checkin',
2450             payload => {
2451                 checkout=> $checkin
2452             }
2453         });
2454
2455         Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
2456             {
2457                 biblio_ids => [ $item->biblionumber ]
2458             }
2459         ) if C4::Context->preference('RealTimeHoldsQueue');
2460     }
2461
2462     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2463 }
2464
2465 =head2 MarkIssueReturned
2466
2467   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2468
2469 Unconditionally marks an issue as being returned by
2470 moving the C<issues> row to C<old_issues> and
2471 setting C<returndate> to the current date.
2472
2473 if C<$returndate> is specified (in iso format), it is used as the date
2474 of the return.
2475
2476 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2477 the old_issue is immediately anonymised
2478
2479 Ideally, this function would be internal to C<C4::Circulation>,
2480 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2481 and offline_circ/process_koc.pl.
2482
2483 The last optional parameter allos passing skip_record_index to the item store call.
2484
2485 =cut
2486
2487 sub MarkIssueReturned {
2488     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2489
2490     # Retrieve the issue
2491     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2492
2493     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2494
2495     my $issue_id = $issue->issue_id;
2496
2497     my $schema = Koha::Database->schema;
2498
2499     # FIXME Improve the return value and handle it from callers
2500     $schema->txn_do(sub {
2501
2502         my $patron = Koha::Patrons->find( $borrowernumber );
2503
2504         # Update the returndate value
2505         if ( $returndate ) {
2506             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2507         }
2508         else {
2509             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2510         }
2511
2512         # Create the old_issues entry
2513         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2514
2515         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2516         if ( $privacy && $privacy == 2) {
2517             $old_checkout->anonymize;
2518         }
2519
2520         # And finally delete the issue
2521         $issue->delete;
2522
2523         $issue->item->onloan(undef)->store(
2524             {   log_action        => 0,
2525                 skip_record_index => $params->{skip_record_index},
2526                 skip_holds_queue  => $params->{skip_holds_queue}
2527             }
2528         );
2529
2530         if ( C4::Context->preference('StoreLastBorrower') ) {
2531             my $item = Koha::Items->find( $itemnumber );
2532             $item->last_returned_by( $patron );
2533         }
2534
2535         # Remove any OVERDUES related debarment if the borrower has no overdues
2536         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2537           && $patron->debarred
2538           && !$patron->has_overdues
2539           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2540         ) {
2541             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2542         }
2543
2544     });
2545
2546     return $issue_id;
2547 }
2548
2549 =head2 _debar_user_on_return
2550
2551     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2552
2553 C<$borrower> borrower hashref
2554
2555 C<$item> item hashref
2556
2557 C<$datedue> date due DateTime object
2558
2559 C<$returndate> DateTime object representing the return time
2560
2561 Internal function, called only by AddReturn that calculates and updates
2562  the user fine days, and debars them if necessary.
2563
2564 Should only be called for overdue returns
2565
2566 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2567 to ease testing.
2568
2569 =cut
2570
2571 sub _calculate_new_debar_dt {
2572     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2573
2574     my $branchcode = _GetCircControlBranch( $item, $borrower );
2575     my $circcontrol = C4::Context->preference('CircControl');
2576     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2577         {   categorycode => $borrower->{categorycode},
2578             itemtype     => $item->{itype},
2579             branchcode   => $branchcode,
2580             rules => [
2581                 'finedays',
2582                 'lengthunit',
2583                 'firstremind',
2584                 'maxsuspensiondays',
2585                 'suspension_chargeperiod',
2586             ]
2587         }
2588     );
2589     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2590     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2591     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2592
2593     return unless $finedays;
2594
2595     # finedays is in days, so hourly loans must multiply by 24
2596     # thus 1 hour late equals 1 day suspension * finedays rate
2597     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2598
2599     # grace period is measured in the same units as the loan
2600     my $grace =
2601       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2602
2603     my $deltadays = DateTime::Duration->new(
2604         days => $chargeable_units
2605     );
2606
2607     if ( $deltadays->subtract($grace)->is_positive() ) {
2608         my $suspension_days = $deltadays * $finedays;
2609
2610         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2611             # No need to / 1 and do not consider / 0
2612             $suspension_days = DateTime::Duration->new(
2613                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2614             );
2615         }
2616
2617         # If the max suspension days is < than the suspension days
2618         # the suspension days is limited to this maximum period.
2619         my $max_sd = $issuing_rule->{maxsuspensiondays};
2620         if ( defined $max_sd && $max_sd ne '' ) {
2621             $max_sd = DateTime::Duration->new( days => $max_sd );
2622             $suspension_days = $max_sd
2623               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2624         }
2625
2626         my ( $has_been_extended );
2627         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2628             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2629             if ( $debarment ) {
2630                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2631                 $has_been_extended = 1;
2632             }
2633         }
2634
2635         my $new_debar_dt;
2636         # Use the calendar or not to calculate the debarment date
2637         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2638             my $calendar = Koha::Calendar->new(
2639                 branchcode => $branchcode,
2640                 days_mode  => 'Calendar'
2641             );
2642             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2643         }
2644         else {
2645             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2646         }
2647         return $new_debar_dt;
2648     }
2649     return;
2650 }
2651
2652 sub _debar_user_on_return {
2653     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2654
2655     $return_date //= dt_from_string();
2656
2657     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2658
2659     return unless $new_debar_dt;
2660
2661     Koha::Patron::Debarments::AddUniqueDebarment({
2662         borrowernumber => $borrower->{borrowernumber},
2663         expiration     => $new_debar_dt->ymd(),
2664         type           => 'SUSPENSION',
2665     });
2666     # if borrower was already debarred but does not get an extra debarment
2667     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2668     my ($new_debarment_str, $is_a_reminder);
2669     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2670         $is_a_reminder = 1;
2671         $new_debarment_str = $borrower->{debarred};
2672     } else {
2673         $new_debarment_str = $new_debar_dt->ymd();
2674     }
2675     # FIXME Should return a DateTime object
2676     return $new_debarment_str, $is_a_reminder;
2677 }
2678
2679 =head2 _FixOverduesOnReturn
2680
2681    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2682
2683 C<$borrowernumber> borrowernumber
2684
2685 C<$itemnumber> itemnumber
2686
2687 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2688
2689 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2690
2691 Internal function
2692
2693 =cut
2694
2695 sub _FixOverduesOnReturn {
2696     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2697     unless( $borrowernumber ) {
2698         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2699         return;
2700     }
2701     unless( $item ) {
2702         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2703         return;
2704     }
2705     unless( $status ) {
2706         warn "_FixOverduesOnReturn() not supplied valid status";
2707         return;
2708     }
2709
2710     my $schema = Koha::Database->schema;
2711
2712     my $result = $schema->txn_do(
2713         sub {
2714             # check for overdue fine
2715             my $accountlines = Koha::Account::Lines->search(
2716                 {
2717                     borrowernumber  => $borrowernumber,
2718                     itemnumber      => $item,
2719                     debit_type_code => 'OVERDUE',
2720                     status          => 'UNRETURNED'
2721                 }
2722             );
2723             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2724
2725             my $accountline = $accountlines->next;
2726             my $payments = $accountline->credits;
2727
2728             my $amountoutstanding = $accountline->amountoutstanding;
2729             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2730                 $accountline->delete;
2731                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2732             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2733                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2734                 my $credit = $account->add_credit(
2735                     {
2736                         amount     => $amountoutstanding,
2737                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2738                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2739                         interface  => C4::Context->interface,
2740                         type       => 'FORGIVEN',
2741                         item_id    => $item
2742                     }
2743                 );
2744
2745                 $credit->apply({ debits => [ $accountline ] });
2746
2747                 if (C4::Context->preference("FinesLog")) {
2748                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2749                 }
2750             }
2751
2752             $accountline->status($status);
2753             return $accountline->store();
2754         }
2755     );
2756
2757     return $result;
2758 }
2759
2760 =head2 _GetCircControlBranch
2761
2762    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2763
2764 Internal function :
2765
2766 Return the library code to be used to determine which circulation
2767 policy applies to a transaction.  Looks up the CircControl and
2768 HomeOrHoldingBranch system preferences.
2769
2770 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2771
2772 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2773
2774 =cut
2775
2776 sub _GetCircControlBranch {
2777     my ($item, $borrower) = @_;
2778     my $circcontrol = C4::Context->preference('CircControl');
2779     my $branch;
2780
2781     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2782         $branch= C4::Context->userenv->{'branch'};
2783     } elsif ($circcontrol eq 'PatronLibrary') {
2784         $branch=$borrower->{branchcode};
2785     } else {
2786         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2787         $branch = $item->{$branchfield};
2788         # default to item home branch if holdingbranch is used
2789         # and is not defined
2790         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2791             $branch = $item->{homebranch};
2792         }
2793     }
2794     return $branch;
2795 }
2796
2797 =head2 GetUpcomingDueIssues
2798
2799   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2800
2801 =cut
2802
2803 sub GetUpcomingDueIssues {
2804     my $params = shift;
2805
2806     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2807     my $dbh = C4::Context->dbh;
2808     my $statement;
2809     $statement = q{
2810         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2811         FROM issues
2812         LEFT JOIN items USING (itemnumber)
2813         LEFT JOIN branches ON branches.branchcode =
2814     };
2815     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2816     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2817     my @bind_parameters = ( $params->{'days_in_advance'} );
2818
2819     my $sth = $dbh->prepare( $statement );
2820     $sth->execute( @bind_parameters );
2821     my $upcoming_dues = $sth->fetchall_arrayref({});
2822
2823     return $upcoming_dues;
2824 }
2825
2826 =head2 CanBookBeRenewed
2827
2828   ($ok,$error,$info) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2829
2830 Find out whether a borrowed item may be renewed.
2831
2832 C<$borrowernumber> is the borrower number of the patron who currently
2833 has the item on loan.
2834
2835 C<$itemnumber> is the number of the item to renew.
2836
2837 C<$override_limit>, if supplied with a true value, causes
2838 the limit on the number of times that the loan can be renewed
2839 (as controlled by the item type) to be ignored. Overriding also allows
2840 to renew sooner than "No renewal before" and to manually renew loans
2841 that are automatically renewed.
2842
2843 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2844 item must currently be on loan to the specified borrower; renewals
2845 must be allowed for the item's type; and the borrower must not have
2846 already renewed the loan.
2847     $error will contain the reason the renewal can not proceed
2848     $info will contain a hash of additional info
2849       currently 'soonest_renew_date' if error is 'too soon'
2850
2851 =cut
2852
2853 sub CanBookBeRenewed {
2854     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2855
2856     my $auto_renew = "no";
2857     my $soonest;
2858
2859     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2860     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2861     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2862     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2863
2864     my $patron = $issue->patron or return;
2865
2866     # override_limit will override anything else except on_reserve
2867     unless ( $override_limit ){
2868         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2869         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2870             {
2871                 categorycode => $patron->categorycode,
2872                 itemtype     => $item->effective_itemtype,
2873                 branchcode   => $branchcode,
2874                 rules => [
2875                     'renewalsallowed',
2876                     'lengthunit',
2877                     'unseen_renewals_allowed'
2878                 ]
2879             }
2880         );
2881
2882         return ( 0, "too_many" )
2883           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals_count;
2884
2885         return ( 0, "too_unseen" )
2886           if C4::Context->preference('UnseenRenewals') &&
2887             looks_like_number($issuing_rule->{unseen_renewals_allowed}) &&
2888             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
2889
2890         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2891         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2892         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2893         my $restricted  = $patron->is_debarred;
2894         my $hasoverdues = $patron->has_overdues;
2895
2896         if ( $restricted and $restrictionblockrenewing ) {
2897             return ( 0, 'restriction');
2898         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2899             return ( 0, 'overdue');
2900         }
2901
2902         ( $auto_renew, $soonest ) = _CanBookBeAutoRenewed({
2903             patron     => $patron,
2904             item       => $item,
2905             branchcode => $branchcode,
2906             issue      => $issue
2907         });
2908         return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'auto_too_soon' && $cron;
2909         # cron wants 'too_soon' over 'on_reserve' for performance and to avoid
2910         # extra notices being sent. Cron also implies no override
2911         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_account_expired';
2912         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_late';
2913         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_much_oweing';
2914     }
2915
2916     if ( C4::Context->preference('UseRecalls') ) {
2917         my $recall = undef;
2918         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2919         if ( defined $recall ) {
2920             if ( $recall->item_level ) {
2921                 # item-level recall. check if this item is the recalled item, otherwise renewal will be allowed
2922                 return ( 0, 'recalled' ) if ( $recall->item_id == $item->itemnumber );
2923             } else {
2924                 # biblio-level recall, so only disallow renewal if the biblio-level recall has been fulfilled by a different item
2925                 return ( 0, 'recalled' ) unless ( $recall->waiting );
2926             }
2927         }
2928     }
2929
2930     my $fillable_holds = Koha::Holds->search(
2931         {
2932             biblionumber => $item->biblionumber,
2933             non_priority => 0,
2934             found        => undef,
2935             reservedate  => { '<=' => \'NOW()' },
2936             suspend      => 0,
2937         },
2938         { prefetch => 'patron' }
2939     );
2940     if ( $fillable_holds->count ) {
2941         if ( C4::Context->preference('AllowRenewalIfOtherItemsAvailable') ) {
2942             my @possible_holds = $fillable_holds->as_list;
2943
2944             # Get all other items that could possibly fill reserves
2945             # FIXME We could join reserves (or more tables) here to eliminate some checks later
2946             my @other_items = Koha::Items->search({
2947                 biblionumber => $item->biblionumber,
2948                 onloan       => undef,
2949                 notforloan   => 0,
2950                 -not         => { itemnumber => $itemnumber } })->as_list;
2951
2952             return ( 0, "on_reserve" ) if @possible_holds && (scalar @other_items < scalar @possible_holds);
2953
2954             my %matched_items;
2955             foreach my $possible_hold (@possible_holds) {
2956                 my $fillable = 0;
2957                 my $patron_with_reserve = Koha::Patrons->find($possible_hold->borrowernumber);
2958                 my $items_any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $item->biblionumber, patron => $patron_with_reserve });
2959
2960                 # FIXME: We are not checking whether the item we are renewing can fill the hold
2961
2962                 foreach my $other_item (@other_items) {
2963                   next if defined $matched_items{$other_item->itemnumber};
2964                   next if IsItemOnHoldAndFound( $other_item->itemnumber );
2965                   next unless IsAvailableForItemLevelRequest($other_item, $patron_with_reserve, undef, $items_any_available);
2966                   next unless CanItemBeReserved($patron_with_reserve,$other_item,undef,{ignore_hold_counts=>1})->{status} eq 'OK';
2967                   # NOTE: At checkin we call 'CheckReserves' which checks hold 'policy'
2968                   # CanItemBeReserved checks 'rules' and 'policies' which means
2969                   # items will fill holds at checkin that are rejected here
2970                   $fillable = 1;
2971                   $matched_items{$other_item->itemnumber} = 1;
2972                   last;
2973                 }
2974                 return ( 0, "on_reserve" ) unless $fillable;
2975             }
2976
2977         } else {
2978             my ($status, $matched_reserve, $possible_reserves) = CheckReserves($itemnumber);
2979             return ( 0, "on_reserve" ) if $status;
2980         }
2981     }
2982
2983     return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2984     $soonest = GetSoonestRenewDate($borrowernumber, $itemnumber);
2985     if ( $soonest > dt_from_string() ){
2986         return (0, "too_soon", { soonest_renew_date => $soonest } ) unless $override_limit;
2987     }
2988
2989     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
2990
2991     return ( 1, undef );
2992 }
2993
2994 =head2 AddRenewal
2995
2996   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate], [$seen]);
2997
2998 Renews a loan.
2999
3000 C<$borrowernumber> is the borrower number of the patron who currently
3001 has the item.
3002
3003 C<$itemnumber> is the number of the item to renew.
3004
3005 C<$branch> is the library where the renewal took place (if any).
3006            The library that controls the circ policies for the renewal is retrieved from the issues record.
3007
3008 C<$datedue> can be a DateTime object used to set the due date.
3009
3010 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
3011 this parameter is not supplied, lastreneweddate is set to the current date.
3012
3013 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
3014 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
3015 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
3016 syspref)
3017
3018 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
3019 from the book's item type.
3020
3021 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
3022 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
3023 fallback to a true value
3024
3025 =cut
3026
3027 sub AddRenewal {
3028     my $borrowernumber  = shift;
3029     my $itemnumber      = shift or return;
3030     my $branch          = shift;
3031     my $datedue         = shift;
3032     my $lastreneweddate = shift || dt_from_string();
3033     my $skipfinecalc    = shift;
3034     my $seen            = shift;
3035
3036     # Fallback on a 'seen' renewal
3037     $seen = defined $seen && $seen == 0 ? 0 : 1;
3038
3039     my $item_object   = Koha::Items->find($itemnumber) or return;
3040     my $biblio = $item_object->biblio;
3041     my $issue  = $item_object->checkout;
3042     my $item_unblessed = $item_object->unblessed;
3043
3044     my $dbh = C4::Context->dbh;
3045
3046     return unless $issue;
3047
3048     $borrowernumber ||= $issue->borrowernumber;
3049
3050     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3051         $datedue = dt_from_string($datedue, 'sql');
3052     }
3053
3054     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3055     my $patron_unblessed = $patron->unblessed;
3056
3057     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3058
3059     my $schema = Koha::Database->schema;
3060     $schema->txn_do(sub{
3061
3062         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3063             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3064         }
3065         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3066
3067         # If the due date wasn't specified, calculate it by adding the
3068         # book's loan length to today's date or the current due date
3069         # based on the value of the RenewalPeriodBase syspref.
3070         my $itemtype = $item_object->effective_itemtype;
3071         unless ($datedue) {
3072
3073             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3074                                             dt_from_string( $issue->date_due, 'sql' ) :
3075                                             dt_from_string();
3076             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3077         }
3078
3079         my $fees = Koha::Charges::Fees->new(
3080             {
3081                 patron    => $patron,
3082                 library   => $circ_library,
3083                 item      => $item_object,
3084                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3085                 to_date   => dt_from_string($datedue),
3086             }
3087         );
3088
3089         # Increment the unseen renewals, if appropriate
3090         # We only do so if the syspref is enabled and
3091         # a maximum value has been set in the circ rules
3092         my $unseen_renewals = $issue->unseen_renewals;
3093         if (C4::Context->preference('UnseenRenewals')) {
3094             my $rule = Koha::CirculationRules->get_effective_rule(
3095                 {   categorycode => $patron->categorycode,
3096                     itemtype     => $item_object->effective_itemtype,
3097                     branchcode   => $circ_library->branchcode,
3098                     rule_name    => 'unseen_renewals_allowed'
3099                 }
3100             );
3101             if (!$seen && $rule && looks_like_number($rule->rule_value)) {
3102                 $unseen_renewals++;
3103             } else {
3104                 # If the renewal is seen, unseen should revert to 0
3105                 $unseen_renewals = 0;
3106             }
3107         }
3108
3109         # Update the issues record to have the new due date, and a new count
3110         # of how many times it has been renewed.
3111         my $renews = ( $issue->renewals_count || 0 ) + 1;
3112         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals_count = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3113
3114         eval{
3115             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3116         };
3117         if( $sth->err ){
3118             Koha::Exceptions::Checkout::FailedRenewal->throw(
3119                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3120             );
3121         }
3122
3123         # Update the renewal count on the item, and tell zebra to reindex
3124         $renews = ( $item_object->renewals || 0 ) + 1;
3125         $item_object->renewals($renews);
3126         $item_object->onloan($datedue);
3127         $item_object->store({ log_action => 0 });
3128
3129         # Charge a new rental fee, if applicable
3130         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3131         if ( $charge > 0 ) {
3132             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3133         }
3134
3135         # Charge a new accumulate rental fee, if applicable
3136         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3137         if ( $itemtype_object ) {
3138             my $accumulate_charge = $fees->accumulate_rentalcharge();
3139             if ( $accumulate_charge > 0 ) {
3140                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3141             }
3142             $charge += $accumulate_charge;
3143         }
3144
3145         # Send a renewal slip according to checkout alert preferencei
3146         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3147             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3148             my %conditions        = (
3149                 branchcode   => $branch,
3150                 categorycode => $patron->categorycode,
3151                 item_type    => $itemtype,
3152                 notification => 'CHECKOUT',
3153             );
3154             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3155                 SendCirculationAlert(
3156                     {
3157                         type     => 'RENEWAL',
3158                         item     => $item_unblessed,
3159                         borrower => $patron->unblessed,
3160                         branch   => $branch,
3161                     }
3162                 );
3163             }
3164         }
3165
3166         # Remove any OVERDUES related debarment if the borrower has no overdues
3167         if ( $patron
3168           && $patron->is_debarred
3169           && ! $patron->has_overdues
3170           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3171         ) {
3172             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3173         }
3174
3175         # Add renewal record
3176         my $renewal = Koha::Checkouts::Renewal->new(
3177             {
3178                 checkout_id => $issue->issue_id,
3179                 renewer_id  => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3180                 seen        => $seen,
3181                 interface   => C4::Context->interface
3182             }
3183         )->store();
3184
3185         # Add the renewal to stats
3186         C4::Stats::UpdateStats(
3187             {
3188                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3189                 type           => 'renew',
3190                 amount         => $charge,
3191                 itemnumber     => $itemnumber,
3192                 itemtype       => $itemtype,
3193                 location       => $item_object->location,
3194                 borrowernumber => $borrowernumber,
3195                 ccode          => $item_object->ccode,
3196                 categorycode   => $patron->categorycode,
3197             }
3198         );
3199
3200         #Log the renewal
3201         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3202
3203         Koha::Plugins->call('after_circ_action', {
3204             action  => 'renewal',
3205             payload => {
3206                 checkout  => $issue->get_from_storage
3207             }
3208         });
3209     });
3210
3211     return $datedue;
3212 }
3213
3214 sub GetRenewCount {
3215     # check renewal status
3216     my ( $bornum, $itemno ) = @_;
3217     my $dbh           = C4::Context->dbh;
3218     my $renewcount    = 0;
3219     my $unseencount    = 0;
3220     my $renewsallowed = 0;
3221     my $unseenallowed = 0;
3222     my $renewsleft    = 0;
3223     my $unseenleft    = 0;
3224
3225     my $patron = Koha::Patrons->find( $bornum );
3226     my $item   = Koha::Items->find($itemno);
3227
3228     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3229
3230     # Look in the issues table for this item, lent to this borrower,
3231     # and not yet returned.
3232
3233     # FIXME - I think this function could be redone to use only one SQL call.
3234     my $sth = $dbh->prepare(
3235         "select * from issues
3236                                 where (borrowernumber = ?)
3237                                 and (itemnumber = ?)"
3238     );
3239     $sth->execute( $bornum, $itemno );
3240     my $data = $sth->fetchrow_hashref;
3241     $renewcount = $data->{'renewals_count'} if $data->{'renewals_count'};
3242     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3243     # $item and $borrower should be calculated
3244     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3245
3246     my $rules = Koha::CirculationRules->get_effective_rules(
3247         {
3248             categorycode => $patron->categorycode,
3249             itemtype     => $item->effective_itemtype,
3250             branchcode   => $branchcode,
3251             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3252         }
3253     );
3254     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3255     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3256         $rules->{unseen_renewals_allowed} :
3257         0;
3258     $renewsleft    = $renewsallowed - $renewcount;
3259     $unseenleft    = $unseenallowed - $unseencount;
3260     if($renewsleft < 0){ $renewsleft = 0; }
3261     if($unseenleft < 0){ $unseenleft = 0; }
3262     return (
3263         $renewcount,
3264         $renewsallowed,
3265         $renewsleft,
3266         $unseencount,
3267         $unseenallowed,
3268         $unseenleft
3269     );
3270 }
3271
3272 =head2 GetSoonestRenewDate
3273
3274   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3275
3276 Find out the soonest possible renew date of a borrowed item.
3277
3278 C<$borrowernumber> is the borrower number of the patron who currently
3279 has the item on loan.
3280
3281 C<$itemnumber> is the number of the item to renew.
3282
3283 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3284 renew date, based on the value "No renewal before" of the applicable
3285 issuing rule. Returns the current date if the item can already be
3286 renewed, and returns undefined if the borrower, loan, or item
3287 cannot be found.
3288
3289 =cut
3290
3291 sub GetSoonestRenewDate {
3292     my ( $borrowernumber, $itemnumber ) = @_;
3293
3294     my $dbh = C4::Context->dbh;
3295
3296     my $item      = Koha::Items->find($itemnumber)      or return;
3297     my $itemissue = $item->checkout or return;
3298
3299     $borrowernumber ||= $itemissue->borrowernumber;
3300     my $patron = Koha::Patrons->find( $borrowernumber )
3301       or return;
3302
3303     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3304     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3305         {   categorycode => $patron->categorycode,
3306             itemtype     => $item->effective_itemtype,
3307             branchcode   => $branchcode,
3308             rules => [
3309                 'norenewalbefore',
3310                 'lengthunit',
3311             ]
3312         }
3313     );
3314
3315     my $now = dt_from_string;
3316
3317     if ( defined $issuing_rule->{norenewalbefore}
3318         and $issuing_rule->{norenewalbefore} ne "" )
3319     {
3320         my $soonestrenewal =
3321           dt_from_string( $itemissue->date_due )->subtract(
3322             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3323
3324         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3325             and $issuing_rule->{lengthunit} eq 'days' )
3326         {
3327             $soonestrenewal->truncate( to => 'day' );
3328         }
3329         return $soonestrenewal if $now < $soonestrenewal;
3330     } elsif ( $itemissue->auto_renew && $patron->autorenew_checkouts ) {
3331         # Checkouts with auto-renewing fall back to due date
3332         my $soonestrenewal = dt_from_string( $itemissue->date_due );
3333         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3334             and $issuing_rule->{lengthunit} eq 'days' )
3335         {
3336             $soonestrenewal->truncate( to => 'day' );
3337         }
3338         return $soonestrenewal;
3339     }
3340     return $now;
3341 }
3342
3343 =head2 GetLatestAutoRenewDate
3344
3345   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3346
3347 Find out the latest possible auto renew date of a borrowed item.
3348
3349 C<$borrowernumber> is the borrower number of the patron who currently
3350 has the item on loan.
3351
3352 C<$itemnumber> is the number of the item to renew.
3353
3354 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3355 auto renew date, based on the value "No auto renewal after" and the "No auto
3356 renewal after (hard limit) of the applicable issuing rule.
3357 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3358 or item cannot be found.
3359
3360 =cut
3361
3362 sub GetLatestAutoRenewDate {
3363     my ( $borrowernumber, $itemnumber ) = @_;
3364
3365     my $dbh = C4::Context->dbh;
3366
3367     my $item      = Koha::Items->find($itemnumber)  or return;
3368     my $itemissue = $item->checkout                 or return;
3369
3370     $borrowernumber ||= $itemissue->borrowernumber;
3371     my $patron = Koha::Patrons->find( $borrowernumber )
3372       or return;
3373
3374     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3375     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3376         {
3377             categorycode => $patron->categorycode,
3378             itemtype     => $item->effective_itemtype,
3379             branchcode   => $branchcode,
3380             rules => [
3381                 'no_auto_renewal_after',
3382                 'no_auto_renewal_after_hard_limit',
3383                 'lengthunit',
3384             ]
3385         }
3386     );
3387
3388     return unless $circulation_rules;
3389     return
3390       if ( not $circulation_rules->{no_auto_renewal_after}
3391             or $circulation_rules->{no_auto_renewal_after} eq '' )
3392       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3393              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3394
3395     my $maximum_renewal_date;
3396     if ( $circulation_rules->{no_auto_renewal_after} ) {
3397         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3398         $maximum_renewal_date->add(
3399             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3400         );
3401     }
3402
3403     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3404         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3405         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3406     }
3407     return $maximum_renewal_date;
3408 }
3409
3410
3411 =head2 GetIssuingCharges
3412
3413   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3414
3415 Calculate how much it would cost for a given patron to borrow a given
3416 item, including any applicable discounts.
3417
3418 C<$itemnumber> is the item number of item the patron wishes to borrow.
3419
3420 C<$borrowernumber> is the patron's borrower number.
3421
3422 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3423 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3424 if it's a video).
3425
3426 =cut
3427
3428 sub GetIssuingCharges {
3429
3430     # calculate charges due
3431     my ( $itemnumber, $borrowernumber ) = @_;
3432     my $charge = 0;
3433     my $dbh    = C4::Context->dbh;
3434     my $item_type;
3435
3436     # Get the book's item type and rental charge (via its biblioitem).
3437     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3438         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3439     $charge_query .= (C4::Context->preference('item-level_itypes'))
3440         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3441         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3442
3443     $charge_query .= ' WHERE items.itemnumber =?';
3444
3445     my $sth = $dbh->prepare($charge_query);
3446     $sth->execute($itemnumber);
3447     if ( my $item_data = $sth->fetchrow_hashref ) {
3448         $item_type = $item_data->{itemtype};
3449         $charge    = $item_data->{rentalcharge};
3450         if ($charge) {
3451             # FIXME This should follow CircControl
3452             my $branch = C4::Context::mybranch();
3453             my $patron = Koha::Patrons->find( $borrowernumber );
3454             my $discount = Koha::CirculationRules->get_effective_rule({
3455                 categorycode => $patron->categorycode,
3456                 branchcode   => $branch,
3457                 itemtype     => $item_type,
3458                 rule_name    => 'rentaldiscount'
3459             });
3460             if ($discount) {
3461                 $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3462             }
3463             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3464         }
3465     }
3466
3467     return ( $charge, $item_type );
3468 }
3469
3470 =head2 AddIssuingCharge
3471
3472   &AddIssuingCharge( $checkout, $charge, $type )
3473
3474 =cut
3475
3476 sub AddIssuingCharge {
3477     my ( $checkout, $charge, $type ) = @_;
3478
3479     # FIXME What if checkout does not exist?
3480
3481     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3482     my $accountline = $account->add_debit(
3483         {
3484             amount      => $charge,
3485             note        => undef,
3486             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3487             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3488             interface   => C4::Context->interface,
3489             type        => $type,
3490             item_id     => $checkout->itemnumber,
3491             issue_id    => $checkout->issue_id,
3492         }
3493     );
3494 }
3495
3496 =head2 GetTransfersFromTo
3497
3498   @results = GetTransfersFromTo($frombranch,$tobranch);
3499
3500 Returns the list of pending transfers between $from and $to branch
3501
3502 =cut
3503
3504 sub GetTransfersFromTo {
3505     my ( $frombranch, $tobranch ) = @_;
3506     return unless ( $frombranch && $tobranch );
3507     my $dbh   = C4::Context->dbh;
3508     my $query = "
3509         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3510         FROM   branchtransfers
3511         WHERE  frombranch=?
3512           AND  tobranch=?
3513           AND datecancelled IS NULL
3514           AND datesent IS NOT NULL
3515           AND datearrived IS NULL
3516     ";
3517     my $sth = $dbh->prepare($query);
3518     $sth->execute( $frombranch, $tobranch );
3519     my @gettransfers;
3520
3521     while ( my $data = $sth->fetchrow_hashref ) {
3522         push @gettransfers, $data;
3523     }
3524     return (@gettransfers);
3525 }
3526
3527 =head2 SendCirculationAlert
3528
3529 Send out a C<check-in> or C<checkout> alert using the messaging system.
3530
3531 B<Parameters>:
3532
3533 =over 4
3534
3535 =item type
3536
3537 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3538
3539 =item item
3540
3541 Hashref of information about the item being checked in or out.
3542
3543 =item borrower
3544
3545 Hashref of information about the borrower of the item.
3546
3547 =item branch
3548
3549 The branchcode from where the checkout or check-in took place.
3550
3551 =back
3552
3553 B<Example>:
3554
3555     SendCirculationAlert({
3556         type     => 'CHECKOUT',
3557         item     => $item,
3558         borrower => $borrower,
3559         branch   => $branch,
3560     });
3561
3562 =cut
3563
3564 sub SendCirculationAlert {
3565     my ($opts) = @_;
3566     my ($type, $item, $borrower, $branch, $issue) =
3567         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch}, $opts->{issue});
3568     my %message_name = (
3569         CHECKIN  => 'Item_Check_in',
3570         CHECKOUT => 'Item_Checkout',
3571         RENEWAL  => 'Item_Checkout',
3572     );
3573     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3574         borrowernumber => $borrower->{borrowernumber},
3575         message_name   => $message_name{$type},
3576     });
3577
3578
3579     my $tables = {
3580         items => $item->{itemnumber},
3581         biblio      => $item->{biblionumber},
3582         biblioitems => $item->{biblionumber},
3583         borrowers   => $borrower,
3584         branches    => $branch,
3585     };
3586
3587     # TODO: Currently, we need to pass an issue_id as identifier for old_issues, but still an itemnumber for issues.
3588     # See C4::Letters:: _parseletter_sth
3589     if( $type eq 'CHECKIN' ){
3590         $tables->{old_issues} = $issue->issue_id;
3591     } else {
3592         $tables->{issues} = $item->{itemnumber};
3593     }
3594
3595     my $schema = Koha::Database->new->schema;
3596     my @transports = keys %{ $borrower_preferences->{transports} };
3597
3598     # From the MySQL doc:
3599     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3600     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3601     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3602     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3603
3604     for my $mtt (@transports) {
3605         my $letter =  C4::Letters::GetPreparedLetter (
3606             module => 'circulation',
3607             letter_code => $type,
3608             branchcode => $branch,
3609             message_transport_type => $mtt,
3610             lang => $borrower->{lang},
3611             tables => $tables,
3612         ) or next;
3613
3614         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3615         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3616         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3617         unless ( $message ) {
3618             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3619             C4::Message->enqueue($letter, $borrower, $mtt);
3620         } else {
3621             $message->append($letter);
3622             $message->update;
3623         }
3624         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3625     }
3626
3627     return;
3628 }
3629
3630 =head2 updateWrongTransfer
3631
3632   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3633
3634 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3635
3636 =cut
3637
3638 sub updateWrongTransfer {
3639         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3640
3641     # first step: cancel the original transfer
3642     my $item = Koha::Items->find($itemNumber);
3643     my $transfer = $item->get_transfer;
3644     $transfer->set({ datecancelled => dt_from_string, cancellation_reason => 'WrongTransfer' })->store();
3645
3646     # second step: create a new transfer to the right location
3647     my $new_transfer = $item->request_transfer(
3648         {
3649             to            => $transfer->to_library,
3650             reason        => $transfer->reason,
3651             comment       => $transfer->comments,
3652             ignore_limits => 1,
3653             enqueue       => 1
3654         }
3655     );
3656
3657     return $new_transfer;
3658 }
3659
3660 =head2 CalcDateDue
3661
3662 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3663
3664 this function calculates the due date given the start date and configured circulation rules,
3665 checking against the holidays calendar as per the daysmode circulation rule.
3666 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3667 C<$itemtype>  = itemtype code of item in question
3668 C<$branch>  = location whose calendar to use
3669 C<$borrower> = Borrower object
3670 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3671
3672 =cut
3673
3674 sub CalcDateDue {
3675     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3676
3677     $isrenewal ||= 0;
3678
3679     # loanlength now a href
3680     my $loanlength =
3681             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3682
3683     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} and $loanlength->{renewalperiod} ne q{} )
3684             ? qq{renewalperiod}
3685             : qq{issuelength};
3686
3687     my $datedue;
3688     if ( $startdate ) {
3689         if (ref $startdate ne 'DateTime' ) {
3690             $datedue = dt_from_string($datedue);
3691         } else {
3692             $datedue = $startdate->clone;
3693         }
3694     } else {
3695         $datedue = dt_from_string()->truncate( to => 'minute' );
3696     }
3697
3698
3699     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3700         {
3701             categorycode => $borrower->{categorycode},
3702             itemtype     => $itemtype,
3703             branchcode   => $branch,
3704         }
3705     );
3706
3707     # calculate the datedue as normal
3708     if ( $daysmode eq 'Days' )
3709     {    # ignoring calendar
3710         if ( $loanlength->{lengthunit} eq 'hours' ) {
3711             $datedue->add( hours => $loanlength->{$length_key} );
3712         } else {    # days
3713             $datedue->add( days => $loanlength->{$length_key} );
3714             $datedue->set_hour(23);
3715             $datedue->set_minute(59);
3716         }
3717     } else {
3718         my $dur;
3719         if ($loanlength->{lengthunit} eq 'hours') {
3720             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3721         }
3722         else { # days
3723             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3724         }
3725         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3726         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3727         if ($loanlength->{lengthunit} eq 'days') {
3728             $datedue->set_hour(23);
3729             $datedue->set_minute(59);
3730         }
3731     }
3732
3733     # if Hard Due Dates are used, retrieve them and apply as necessary
3734     my ( $hardduedate, $hardduedatecompare ) =
3735       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3736     if ($hardduedate) {    # hardduedates are currently dates
3737         $hardduedate->truncate( to => 'minute' );
3738         $hardduedate->set_hour(23);
3739         $hardduedate->set_minute(59);
3740         my $cmp = DateTime->compare( $hardduedate, $datedue );
3741
3742 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3743 # if the calculated date is before the 'after' Hard Due Date (floor), override
3744 # if the hard due date is set to 'exactly', overrride
3745         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3746             $datedue = $hardduedate->clone;
3747         }
3748
3749         # in all other cases, keep the date due as it is
3750
3751     }
3752
3753     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3754     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3755         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3756         if( $expiry_dt ) { #skip empty expiry date..
3757             $expiry_dt->set( hour => 23, minute => 59);
3758             my $d1= $datedue->clone->set_time_zone('floating');
3759             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3760                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3761             }
3762         }
3763         if ( $daysmode ne 'Days' ) {
3764           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3765           if ( $calendar->is_holiday($datedue) ) {
3766               # Don't return on a closed day
3767               $datedue = $calendar->prev_open_days( $datedue, 1 );
3768           }
3769         }
3770     }
3771
3772     return $datedue;
3773 }
3774
3775
3776 sub CheckValidBarcode{
3777 my ($barcode) = @_;
3778 my $dbh = C4::Context->dbh;
3779 my $query=qq|SELECT count(*)
3780              FROM items
3781              WHERE barcode=?
3782             |;
3783 my $sth = $dbh->prepare($query);
3784 $sth->execute($barcode);
3785 my $exist=$sth->fetchrow ;
3786 return $exist;
3787 }
3788
3789 =head2 IsBranchTransferAllowed
3790
3791   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3792
3793 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3794
3795 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3796 Koha::Item->can_be_transferred.
3797
3798 =cut
3799
3800 sub IsBranchTransferAllowed {
3801         my ( $toBranch, $fromBranch, $code ) = @_;
3802
3803         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3804
3805         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3806         my $dbh = C4::Context->dbh;
3807
3808         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3809         $sth->execute( $toBranch, $fromBranch, $code );
3810         my $limit = $sth->fetchrow_hashref();
3811
3812         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3813         if ( $limit->{'limitId'} ) {
3814                 return 0;
3815         } else {
3816                 return 1;
3817         }
3818 }
3819
3820 =head2 CreateBranchTransferLimit
3821
3822   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3823
3824 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3825
3826 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3827
3828 =cut
3829
3830 sub CreateBranchTransferLimit {
3831    my ( $toBranch, $fromBranch, $code ) = @_;
3832    return unless defined($toBranch) && defined($fromBranch);
3833    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3834
3835    my $dbh = C4::Context->dbh;
3836
3837    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3838    return $sth->execute( $code, $toBranch, $fromBranch );
3839 }
3840
3841 =head2 DeleteBranchTransferLimits
3842
3843     my $result = DeleteBranchTransferLimits($frombranch);
3844
3845 Deletes all the library transfer limits for one library.  Returns the
3846 number of limits deleted, 0e0 if no limits were deleted, or undef if
3847 no arguments are supplied.
3848
3849 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3850     fromBranch => $fromBranch
3851     })->delete.
3852
3853 =cut
3854
3855 sub DeleteBranchTransferLimits {
3856     my $branch = shift;
3857     return unless defined $branch;
3858     my $dbh    = C4::Context->dbh;
3859     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3860     return $sth->execute($branch);
3861 }
3862
3863 sub ReturnLostItem{
3864     my ( $borrowernumber, $itemnum ) = @_;
3865     MarkIssueReturned( $borrowernumber, $itemnum );
3866 }
3867
3868 =head2 LostItem
3869
3870   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3871
3872 The final optional parameter, C<$params>, expected to contain
3873 'skip_record_index' key, which relayed down to Koha::Item/store,
3874 there it prevents calling of ModZebra index_records,
3875 which takes most of the time in batch adds/deletes: index_records better
3876 to be called later in C<additem.pl> after the whole loop.
3877
3878 $params:
3879     skip_record_index => 1|0
3880
3881 =cut
3882
3883 sub LostItem{
3884     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3885
3886     unless ( $mark_lost_from ) {
3887         # Temporary check to avoid regressions
3888         die q|LostItem called without $mark_lost_from, check the API.|;
3889     }
3890
3891     my $mark_returned;
3892     if ( $force_mark_returned ) {
3893         $mark_returned = 1;
3894     } else {
3895         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3896         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3897     }
3898
3899     my $dbh = C4::Context->dbh();
3900     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3901                            FROM issues
3902                            JOIN items USING (itemnumber)
3903                            JOIN biblio USING (biblionumber)
3904                            WHERE issues.itemnumber=?");
3905     $sth->execute($itemnumber);
3906     my $issues=$sth->fetchrow_hashref();
3907
3908     # If a borrower lost the item, add a replacement cost to the their record
3909     if ( my $borrowernumber = $issues->{borrowernumber} ){
3910         my $patron = Koha::Patrons->find( $borrowernumber );
3911
3912         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3913         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3914
3915         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3916             C4::Accounts::chargelostitem(
3917                 $borrowernumber,
3918                 $itemnumber,
3919                 $issues->{'replacementprice'},
3920                 sprintf( "%s %s %s",
3921                     $issues->{'title'}          || q{},
3922                     $issues->{'barcode'}        || q{},
3923                     $issues->{'itemcallnumber'} || q{},
3924                 ),
3925             );
3926             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3927             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3928         }
3929
3930         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy,$params) if $mark_returned;
3931     }
3932
3933     # When an item is marked as lost, we should automatically cancel its outstanding transfers.
3934     my $item = Koha::Items->find($itemnumber);
3935     my $transfers = $item->get_transfers;
3936     while (my $transfer = $transfers->next) {
3937         $transfer->cancel({ reason => 'ItemLost', force => 1 });
3938     }
3939 }
3940
3941 sub GetOfflineOperations {
3942     my $dbh = C4::Context->dbh;
3943     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3944     $sth->execute(C4::Context->userenv->{'branch'});
3945     my $results = $sth->fetchall_arrayref({});
3946     return $results;
3947 }
3948
3949 sub GetOfflineOperation {
3950     my $operationid = shift;
3951     return unless $operationid;
3952     my $dbh = C4::Context->dbh;
3953     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3954     $sth->execute( $operationid );
3955     return $sth->fetchrow_hashref;
3956 }
3957
3958 sub AddOfflineOperation {
3959     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3960     my $dbh = C4::Context->dbh;
3961     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3962     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3963     return "Added.";
3964 }
3965
3966 sub DeleteOfflineOperation {
3967     my $dbh = C4::Context->dbh;
3968     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3969     $sth->execute( shift );
3970     return "Deleted.";
3971 }
3972
3973 sub ProcessOfflineOperation {
3974     my $operation = shift;
3975
3976     my $report;
3977     if ( $operation->{action} eq 'return' ) {
3978         $report = ProcessOfflineReturn( $operation );
3979     } elsif ( $operation->{action} eq 'issue' ) {
3980         $report = ProcessOfflineIssue( $operation );
3981     } elsif ( $operation->{action} eq 'payment' ) {
3982         $report = ProcessOfflinePayment( $operation );
3983     }
3984
3985     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3986
3987     return $report;
3988 }
3989
3990 sub ProcessOfflineReturn {
3991     my $operation = shift;
3992
3993     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3994
3995     if ( $item ) {
3996         my $itemnumber = $item->itemnumber;
3997         my $issue = $item->checkout;
3998         if ( $issue ) {
3999             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
4000             ModDateLastSeen( $itemnumber, $leave_item_lost );
4001             MarkIssueReturned(
4002                 $issue->borrowernumber,
4003                 $itemnumber,
4004                 $operation->{timestamp},
4005             );
4006             $item->renewals_count(0);
4007             $item->onloan(undef);
4008             $item->store({ log_action => 0 });
4009             return "Success.";
4010         } else {
4011             return "Item not issued.";
4012         }
4013     } else {
4014         return "Item not found.";
4015     }
4016 }
4017
4018 sub ProcessOfflineIssue {
4019     my $operation = shift;
4020
4021     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4022
4023     if ( $patron ) {
4024         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4025         unless ($item) {
4026             return "Barcode not found.";
4027         }
4028         my $itemnumber = $item->itemnumber;
4029         my $issue = $item->checkout;
4030
4031         if ( $issue and ( $issue->borrowernumber ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4032             MarkIssueReturned(
4033                 $issue->borrowernumber,
4034                 $itemnumber,
4035                 $operation->{timestamp},
4036             );
4037         }
4038         AddIssue(
4039             $patron->unblessed,
4040             $operation->{'barcode'},
4041             undef,
4042             undef,
4043             $operation->{timestamp},
4044             undef,
4045         );
4046         return "Success.";
4047     } else {
4048         return "Borrower not found.";
4049     }
4050 }
4051
4052 sub ProcessOfflinePayment {
4053     my $operation = shift;
4054
4055     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4056
4057     $patron->account->pay(
4058         {
4059             amount     => $operation->{amount},
4060             library_id => $operation->{branchcode},
4061             interface  => 'koc'
4062         }
4063     );
4064
4065     return "Success.";
4066 }
4067
4068 =head2 TransferSlip
4069
4070   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4071
4072   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4073
4074 =cut
4075
4076 sub TransferSlip {
4077     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4078
4079     my $item =
4080       $itemnumber
4081       ? Koha::Items->find($itemnumber)
4082       : Koha::Items->find( { barcode => $barcode } );
4083
4084     $item or return;
4085
4086     return C4::Letters::GetPreparedLetter (
4087         module => 'circulation',
4088         letter_code => 'TRANSFERSLIP',
4089         branchcode => $branch,
4090         tables => {
4091             'branches'    => $to_branch,
4092             'biblio'      => $item->biblionumber,
4093             'items'       => $item->unblessed,
4094         },
4095     );
4096 }
4097
4098 =head2 CheckIfIssuedToPatron
4099
4100   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4101
4102   Return 1 if any record item is issued to patron, otherwise return 0
4103
4104 =cut
4105
4106 sub CheckIfIssuedToPatron {
4107     my ($borrowernumber, $biblionumber) = @_;
4108
4109     my $dbh = C4::Context->dbh;
4110     my $query = q|
4111         SELECT COUNT(*) FROM issues
4112         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4113         WHERE items.biblionumber = ?
4114         AND issues.borrowernumber = ?
4115     |;
4116     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4117     return 1 if $is_issued;
4118     return;
4119 }
4120
4121 =head2 IsItemIssued
4122
4123   IsItemIssued( $itemnumber )
4124
4125   Return 1 if the item is on loan, otherwise return 0
4126
4127 =cut
4128
4129 sub IsItemIssued {
4130     my $itemnumber = shift;
4131     my $dbh = C4::Context->dbh;
4132     my $sth = $dbh->prepare(q{
4133         SELECT COUNT(*)
4134         FROM issues
4135         WHERE itemnumber = ?
4136     });
4137     $sth->execute($itemnumber);
4138     return $sth->fetchrow;
4139 }
4140
4141 =head2 GetAgeRestriction
4142
4143   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4144   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4145
4146   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4147   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4148
4149 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4150 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4151 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4152          Negative days mean the borrower has gone past the age restriction age.
4153
4154 =cut
4155
4156 sub GetAgeRestriction {
4157     my ($record_restrictions, $borrower) = @_;
4158     my $markers = C4::Context->preference('AgeRestrictionMarker');
4159
4160     return unless $record_restrictions;
4161     # Split $record_restrictions to something like FSK 16 or PEGI 6
4162     my @values = split ' ', uc($record_restrictions);
4163     return unless @values;
4164
4165     # Search first occurrence of one of the markers
4166     my @markers = split /\|/, uc($markers);
4167     return unless @markers;
4168
4169     my $index            = 0;
4170     my $restriction_year = 0;
4171     for my $value (@values) {
4172         $index++;
4173         for my $marker (@markers) {
4174             $marker =~ s/^\s+//;    #remove leading spaces
4175             $marker =~ s/\s+$//;    #remove trailing spaces
4176             if ( $marker eq $value ) {
4177                 if ( $index <= $#values ) {
4178                     $restriction_year += $values[$index];
4179                 }
4180                 last;
4181             }
4182             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4183
4184                 # Perhaps it is something like "K16" (as in Finland)
4185                 $restriction_year += $1;
4186                 last;
4187             }
4188         }
4189         last if ( $restriction_year > 0 );
4190     }
4191
4192     #Check if the borrower is age restricted for this material and for how long.
4193     if ($restriction_year && $borrower) {
4194         if ( $borrower->{'dateofbirth'} ) {
4195             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4196             $alloweddate[0] += $restriction_year;
4197
4198             #Prevent runime eror on leap year (invalid date)
4199             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4200                 $alloweddate[2] = 28;
4201             }
4202
4203             #Get how many days the borrower has to reach the age restriction
4204             my @Today = split /-/, dt_from_string()->ymd();
4205             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4206             #Negative days means the borrower went past the age restriction age
4207             return ($restriction_year, $daysToAgeRestriction);
4208         }
4209     }
4210
4211     return ($restriction_year);
4212 }
4213
4214
4215 =head2 GetPendingOnSiteCheckouts
4216
4217 =cut
4218
4219 sub GetPendingOnSiteCheckouts {
4220     my $dbh = C4::Context->dbh;
4221     return $dbh->selectall_arrayref(q|
4222         SELECT
4223           items.barcode,
4224           items.biblionumber,
4225           items.itemnumber,
4226           items.itemnotes,
4227           items.itemcallnumber,
4228           items.location,
4229           issues.date_due,
4230           issues.branchcode,
4231           issues.date_due < NOW() AS is_overdue,
4232           biblio.author,
4233           biblio.title,
4234           borrowers.firstname,
4235           borrowers.surname,
4236           borrowers.cardnumber,
4237           borrowers.borrowernumber
4238         FROM items
4239         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4240         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4241         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4242         WHERE issues.onsite_checkout = 1
4243     |, { Slice => {} } );
4244 }
4245
4246 sub GetTopIssues {
4247     my ($params) = @_;
4248
4249     my ($count, $branch, $itemtype, $ccode, $newness)
4250         = @$params{qw(count branch itemtype ccode newness)};
4251
4252     my $dbh = C4::Context->dbh;
4253     my $query = q{
4254         SELECT * FROM (
4255         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4256           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4257           i.ccode, SUM(i.issues) AS count
4258         FROM biblio b
4259         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4260         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4261     };
4262
4263     my (@where_strs, @where_args);
4264
4265     if ($branch) {
4266         push @where_strs, 'i.homebranch = ?';
4267         push @where_args, $branch;
4268     }
4269     if ($itemtype) {
4270         if (C4::Context->preference('item-level_itypes')){
4271             push @where_strs, 'i.itype = ?';
4272             push @where_args, $itemtype;
4273         } else {
4274             push @where_strs, 'bi.itemtype = ?';
4275             push @where_args, $itemtype;
4276         }
4277     }
4278     if ($ccode) {
4279         push @where_strs, 'i.ccode = ?';
4280         push @where_args, $ccode;
4281     }
4282     if ($newness) {
4283         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4284         push @where_args, $newness;
4285     }
4286
4287     if (@where_strs) {
4288         $query .= 'WHERE ' . join(' AND ', @where_strs);
4289     }
4290
4291     $query .= q{
4292         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4293           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4294           i.ccode
4295         ORDER BY count DESC
4296     };
4297
4298     $query .= q{ ) xxx WHERE count > 0 };
4299     $count = int($count);
4300     if ($count > 0) {
4301         $query .= "LIMIT $count";
4302     }
4303
4304     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4305
4306     return @$rows;
4307 }
4308
4309 =head2 Internal methods
4310
4311 =cut
4312
4313 sub _CalculateAndUpdateFine {
4314     my ($params) = @_;
4315
4316     my $borrower    = $params->{borrower};
4317     my $item        = $params->{item};
4318     my $issue       = $params->{issue};
4319     my $return_date = $params->{return_date};
4320
4321     unless ($borrower) { carp "No borrower passed in!" && return; }
4322     unless ($item)     { carp "No item passed in!"     && return; }
4323     unless ($issue)    { carp "No issue passed in!"    && return; }
4324
4325     my $datedue = dt_from_string( $issue->date_due );
4326
4327     # we only need to calculate and change the fines if we want to do that on return
4328     # Should be on for hourly loans
4329     my $control = C4::Context->preference('CircControl');
4330     my $control_branchcode =
4331         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4332       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4333       :                                     $issue->branchcode;
4334
4335     my $date_returned = $return_date ? $return_date : dt_from_string();
4336
4337     my ( $amount, $unitcounttotal, $unitcount  ) =
4338       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4339
4340     if ( C4::Context->preference('finesMode') eq 'production' ) {
4341         if ( $amount > 0 ) {
4342             C4::Overdues::UpdateFine({
4343                 issue_id       => $issue->issue_id,
4344                 itemnumber     => $issue->itemnumber,
4345                 borrowernumber => $issue->borrowernumber,
4346                 amount         => $amount,
4347                 due            => $datedue,
4348             });
4349         }
4350         elsif ($return_date) {
4351
4352             # Backdated returns may have fines that shouldn't exist,
4353             # so in this case, we need to drop those fines to 0
4354
4355             C4::Overdues::UpdateFine({
4356                 issue_id       => $issue->issue_id,
4357                 itemnumber     => $issue->itemnumber,
4358                 borrowernumber => $issue->borrowernumber,
4359                 amount         => 0,
4360                 due            => $datedue,
4361             });
4362         }
4363     }
4364 }
4365
4366 sub _CanBookBeAutoRenewed {
4367     my ( $params ) = @_;
4368     my $patron = $params->{patron};
4369     my $item = $params->{item};
4370     my $branchcode = $params->{branchcode};
4371     my $issue = $params->{issue};
4372
4373     return "no" unless $issue->auto_renew && $patron->autorenew_checkouts;
4374
4375     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
4376         {
4377             categorycode => $patron->categorycode,
4378             itemtype     => $item->effective_itemtype,
4379             branchcode   => $branchcode,
4380             rules => [
4381                 'no_auto_renewal_after',
4382                 'no_auto_renewal_after_hard_limit',
4383                 'lengthunit',
4384                 'norenewalbefore',
4385             ]
4386         }
4387     );
4388
4389     if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
4390         return 'auto_account_expired';
4391     }
4392
4393     if ( defined $issuing_rule->{no_auto_renewal_after}
4394             and $issuing_rule->{no_auto_renewal_after} ne "" ) {
4395         # Get issue_date and add no_auto_renewal_after
4396         # If this is greater than today, it's too late for renewal.
4397         my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
4398         $maximum_renewal_date->add(
4399             $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
4400         );
4401         my $now = dt_from_string;
4402         if ( $now >= $maximum_renewal_date ) {
4403             return "auto_too_late";
4404         }
4405     }
4406     if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
4407                   and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
4408         # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
4409         if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
4410             return "auto_too_late";
4411         }
4412     }
4413
4414     if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
4415         my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
4416         my $amountoutstanding =
4417           C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
4418           ? $patron->account->balance
4419           : $patron->account->outstanding_debits->total_outstanding;
4420         if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
4421             return "auto_too_much_oweing";
4422         }
4423     }
4424
4425     my $soonest = GetSoonestRenewDate($patron->id, $item->id);
4426     if ( $soonest > dt_from_string() )
4427     {
4428         return ( "auto_too_soon", $soonest );
4429     }
4430
4431     return "ok";
4432 }
4433
4434 sub _item_denied_renewal {
4435     my ($params) = @_;
4436
4437     my $item = $params->{item};
4438     return unless $item;
4439
4440     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4441     return unless $denyingrules;
4442     foreach my $field (keys %$denyingrules) {
4443         my $val = $item->$field;
4444         if( !defined $val) {
4445             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4446                 return 1;
4447             }
4448         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4449            # If the results matches the values in the syspref
4450            # We return true if match found
4451             return 1;
4452         }
4453     }
4454     return 0;
4455 }
4456
4457 1;
4458
4459 __END__
4460
4461 =head1 AUTHOR
4462
4463 Koha Development Team <http://koha-community.org/>
4464
4465 =cut