C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use YAML::XS;
  25 use Encode;
  26
  27 use C4::Context;
  28 use C4::Stats qw( UpdateStats );
  29 use C4::Reserves qw( CheckReserves CanItemBeReserved MoveReserve ModReserve ModReserveMinusPriority RevertWaitingStatus IsItemOnHoldAndFound IsAvailableForItemLevelRequest ItemsAnyAvailableAndNotRestricted );
  30 use C4::Biblio qw( UpdateTotalIssues );
  31 use C4::Items qw( ModItemTransfer ModDateLastSeen CartToShelf );
  32 use C4::Accounts;
  33 use C4::ItemCirculationAlertPreference;
  34 use C4::Message;
  35 use C4::Log qw( logaction ); # logaction
  36 use C4::Overdues;
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits qw( CheckDigits );
  39
  40 use Data::Dumper qw( Dumper );
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils qw( dt_from_string );
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::Illrequests;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments qw( DelUniqueDebarment GetDebarments AddUniqueDebarment );
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Account::Lines;
  55 use Koha::Holds;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Config::SysPref;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Koha::SearchEngine::Indexer;
  63 use Koha::Exceptions::Checkout;
  64 use Koha::Plugins;
  65 use Koha::Recalls;
  66 use Carp qw( carp );
  67 use List::MoreUtils qw( any );
  68 use Scalar::Util qw( looks_like_number );
  69 use Date::Calc qw( Date_to_Days );
  70 our (@ISA, @EXPORT_OK);
  71 BEGIN {
  72
  73     require Exporter;
  74     @ISA = qw(Exporter);
  75
  76     # FIXME subs that should probably be elsewhere
  77     push @EXPORT_OK, qw(
  78       barcodedecode
  79       LostItem
  80       ReturnLostItem
  81       GetPendingOnSiteCheckouts
  82
  83       CanBookBeIssued
  84       checkHighHolds
  85       CanBookBeRenewed
  86       AddIssue
  87       GetLoanLength
  88       GetHardDueDate
  89       AddRenewal
  90       GetRenewCount
  91       GetSoonestRenewDate
  92       GetLatestAutoRenewDate
  93       GetIssuingCharges
  94       AddIssuingCharge
  95       GetBranchBorrowerCircRule
  96       GetBranchItemRule
  97       GetBiblioIssues
  98       GetOpenIssue
  99       GetUpcomingDueIssues
 100       CheckIfIssuedToPatron
 101       IsItemIssued
 102       GetAgeRestriction
 103       GetTopIssues
 104
 105       AddReturn
 106       MarkIssueReturned
 107
 108       transferbook
 109       TooMany
 110       GetTransfers
 111       GetTransfersFromTo
 112       updateWrongTransfer
 113       CalcDateDue
 114       CheckValidBarcode
 115       IsBranchTransferAllowed
 116       CreateBranchTransferLimit
 117       DeleteBranchTransferLimits
 118       TransferSlip
 119
 120       GetOfflineOperations
 121       GetOfflineOperation
 122       AddOfflineOperation
 123       DeleteOfflineOperation
 124       ProcessOfflineOperation
 125       ProcessOfflinePayment
 126     );
 127     push @EXPORT_OK, '_GetCircControlBranch';    # This is wrong!
 128 }
 129
 130 =head1 NAME
 131
 132 C4::Circulation - Koha circulation module
 133
 134 =head1 SYNOPSIS
 135
 136 use C4::Circulation;
 137
 138 =head1 DESCRIPTION
 139
 140 The functions in this module deal with circulation, issues, and
 141 returns, as well as general information about the library.
 142 Also deals with inventory.
 143
 144 =head1 FUNCTIONS
 145
 146 =head2 barcodedecode
 147
 148   $str = &barcodedecode($barcode, [$filter]);
 149
 150 Generic filter function for barcode string.
 151 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 152 Will do some manipulation of the barcode for systems that deliver a barcode
 153 to circulation.pl that differs from the barcode stored for the item.
 154 For proper functioning of this filter, calling the function on the
 155 correct barcode string (items.barcode) should return an unaltered barcode.
 156 Barcode is going to be automatically trimmed of leading/trailing whitespaces.
 157
 158 The optional $filter argument is to allow for testing or explicit
 159 behavior that ignores the System Pref.  Valid values are the same as the
 160 System Pref options.
 161
 162 =cut
 163
 164 # FIXME -- the &decode fcn below should be wrapped into this one.
 165 # FIXME -- these plugins should be moved out of Circulation.pm
 166 #
 167 sub barcodedecode {
 168     my ($barcode, $filter) = @_;
 169
 170     return unless defined $barcode;
 171
 172     my $branch = C4::Context::mybranch();
 173     $barcode =~ s/^\s+|\s+$//g;
 174     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 175     Koha::Plugins->call('item_barcode_transform',  \$barcode );
 176     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 177         if ($filter eq 'whitespace') {
 178                 $barcode =~ s/\s//g;
 179         } elsif ($filter eq 'cuecat') {
 180                 chomp($barcode);
 181             my @fields = split( /\./, $barcode );
 182             my @results = map( C4::Circulation::_decode($_), @fields[ 1 .. $#fields ] );
 183             ($#results == 2) and return $results[2];
 184         } elsif ($filter eq 'T-prefix') {
 185                 if ($barcode =~ /^[Tt](\d)/) {
 186                         (defined($1) and $1 eq '0') and return $barcode;
 187             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 188                 }
 189         return sprintf("T%07d", $barcode);
 190         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 191         # Why drop the nonzero digit after the T?
 192         # Why pass non-digits (or empty string) to "T%07d"?
 193         } elsif ($filter eq 'libsuite8') {
 194                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 195                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 196                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 197                         }else{
 198                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 199                         }
 200                 }
 201     } elsif ($filter eq 'EAN13') {
 202         my $ean = CheckDigits('ean');
 203         if ( $ean->is_valid($barcode) ) {
 204             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 205             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 206         } else {
 207             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 208         }
 209         }
 210     return $barcode;    # return barcode, modified or not
 211 }
 212
 213 =head2 _decode
 214
 215   $str = &_decode($chunk);
 216
 217 Decodes a segment of a string emitted by a CueCat barcode scanner and
 218 returns it.
 219
 220 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 221 or Javascript based decoding on the client side.
 222
 223 =cut
 224
 225 sub _decode {
 226     my ($encoded) = @_;
 227     my $seq =
 228       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 229     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 230     my $l = ( $#s + 1 ) % 4;
 231     if ($l) {
 232         if ( $l == 1 ) {
 233             # warn "Error: Cuecat decode parsing failed!";
 234             return;
 235         }
 236         $l = 4 - $l;
 237         $#s += $l;
 238     }
 239     my $r = '';
 240     while ( $#s >= 0 ) {
 241         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 242         $r .=
 243             chr( ( $n >> 16 ) ^ 67 )
 244          .chr( ( $n >> 8 & 255 ) ^ 67 )
 245          .chr( ( $n & 255 ) ^ 67 );
 246         @s = @s[ 4 .. $#s ];
 247     }
 248     $r = substr( $r, 0, length($r) - $l );
 249     return $r;
 250 }
 251
 252 =head2 transferbook
 253
 254   ($dotransfer, $messages, $iteminformation) = &transferbook({
 255                                                    from_branch => $frombranch
 256                                                    to_branch => $tobranch,
 257                                                    barcode => $barcode,
 258                                                    ignore_reserves => $ignore_reserves,
 259                                                    trigger => $trigger
 260                                                 });
 261
 262 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 263
 264 C<$fbr> is the code for the branch initiating the transfer.
 265 C<$tbr> is the code for the branch to which the item should be transferred.
 266
 267 C<$barcode> is the barcode of the item to be transferred.
 268
 269 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 270 Otherwise, if an item is reserved, the transfer fails.
 271
 272 C<$trigger> is the enum value for what triggered the transfer.
 273
 274 Returns three values:
 275
 276 =over
 277
 278 =item $dotransfer
 279
 280 is true if the transfer was successful.
 281
 282 =item $messages
 283
 284 is a reference-to-hash which may have any of the following keys:
 285
 286 =over
 287
 288 =item C<BadBarcode>
 289
 290 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 291
 292 =item C<DestinationEqualsHolding>
 293
 294 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 295
 296 =item C<WasReturned>
 297
 298 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 299
 300 =item C<ResFound>
 301
 302 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 303
 304 =item C<WasTransferred>
 305
 306 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 307
 308 =item C<RecallPlacedAtHoldingBranch>
 309
 310 A recall for this item was found, and the transfer has already been completed as the item's branch matches the recall's pickup branch.
 311
 312 =item C<RecallFound>
 313
 314 A recall for this item was found, and the item needs to be transferred to the recall's pickup branch.
 315
 316 =back
 317
 318 =back
 319
 320 =cut
 321
 322 sub transferbook {
 323     my $params = shift;
 324     my $tbr      = $params->{to_branch};
 325     my $fbr      = $params->{from_branch};
 326     my $ignoreRs = $params->{ignore_reserves};
 327     my $barcode  = $params->{barcode};
 328     my $trigger  = $params->{trigger};
 329     my $messages;
 330     my $dotransfer      = 1;
 331     my $item = Koha::Items->find( { barcode => $barcode } );
 332
 333     Koha::Exceptions::MissingParameter->throw(
 334         "Missing mandatory parameter: from_branch")
 335       unless $fbr;
 336
 337     Koha::Exceptions::MissingParameter->throw(
 338         "Missing mandatory parameter: to_branch")
 339       unless $tbr;
 340
 341     # bad barcode..
 342     unless ( $item ) {
 343         $messages->{'BadBarcode'} = $barcode;
 344         $dotransfer = 0;
 345         return ( $dotransfer, $messages );
 346     }
 347
 348     my $itemnumber = $item->itemnumber;
 349     # get branches of book...
 350     my $hbr = $item->homebranch;
 351
 352     # if using Branch Transfer Limits
 353     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 354         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 355         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 356             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 357                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 358                 $dotransfer = 0;
 359             }
 360         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 361             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 362             $dotransfer = 0;
 363         }
 364     }
 365
 366     # can't transfer book if is already there....
 367     if ( $fbr eq $tbr ) {
 368         $messages->{'DestinationEqualsHolding'} = 1;
 369         $dotransfer = 0;
 370     }
 371
 372     # check if it is still issued to someone, return it...
 373     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 374     if ( $issue ) {
 375         AddReturn( $barcode, $fbr );
 376         $messages->{'WasReturned'} = $issue->borrowernumber;
 377     }
 378
 379     # find reserves.....
 380     # That'll save a database query.
 381     my ( $resfound, $resrec, undef ) =
 382       CheckReserves( $itemnumber );
 383     if ( $resfound ) {
 384         $resrec->{'ResFound'} = $resfound;
 385         $messages->{'ResFound'} = $resrec;
 386         $dotransfer = 0 unless $ignoreRs;
 387     }
 388
 389     # find recall
 390     if ( C4::Context->preference('UseRecalls') ) {
 391         my $recall = Koha::Recalls->find({ item_id => $itemnumber, status => 'in_transit' });
 392         if ( defined $recall ) {
 393             # do a transfer if the recall branch is different to the item holding branch
 394             if ( $recall->pickup_library_id eq $fbr ) {
 395                 $dotransfer = 0;
 396                 $messages->{'RecallPlacedAtHoldingBranch'} = 1;
 397             } else {
 398                 $dotransfer = 1;
 399                 $messages->{'RecallFound'} = $recall;
 400             }
 401         }
 402     }
 403
 404     #actually do the transfer....
 405     if ($dotransfer) {
 406         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 407
 408         # don't need to update MARC anymore, we do it in batch now
 409         $messages->{'WasTransfered'} = $tbr;
 410
 411     }
 412     ModDateLastSeen( $itemnumber );
 413     return ( $dotransfer, $messages );
 414 }
 415
 416
 417 sub TooMany {
 418     my $borrower        = shift;
 419     my $item_object = shift;
 420     my $params = shift;
 421     my $onsite_checkout = $params->{onsite_checkout} || 0;
 422     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 423     my $cat_borrower    = $borrower->{'categorycode'};
 424     my $dbh             = C4::Context->dbh;
 425     # Get which branchcode we need
 426     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 427     my $type = $item_object->effective_itemtype;
 428
 429     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 430     $type_object = Koha::ItemTypes->find( $type );
 431     $parent_type = $type_object->parent_type if $type_object;
 432     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 433     # Find any children if we are a parent_type;
 434
 435     # given branch, patron category, and item type, determine
 436     # applicable issuing rule
 437
 438     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 439         {
 440             categorycode => $cat_borrower,
 441             itemtype     => $parent_type,
 442             branchcode   => $branch,
 443             rule_name    => 'maxissueqty',
 444         }
 445     ) if $parent_type;
 446     # If the parent rule is for default type we discount it
 447     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 448
 449     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 450         {
 451             categorycode => $cat_borrower,
 452             itemtype     => $type,
 453             branchcode   => $branch,
 454             rule_name    => 'maxissueqty',
 455         }
 456     );
 457
 458     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 459         {
 460             categorycode => $cat_borrower,
 461             itemtype     => $type,
 462             branchcode   => $branch,
 463             rule_name    => 'maxonsiteissueqty',
 464         }
 465     );
 466
 467
 468     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 469     # if a rule is found and has a loan limit set, count
 470     # how many loans the patron already has that meet that
 471     # rule
 472     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 473
 474         my $checkouts;
 475         if ( $maxissueqty_rule->branchcode ) {
 476             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 477                 $checkouts = $patron->checkouts->search(
 478                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 479             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 480                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 481             } else {
 482                 $checkouts = $patron->checkouts->search(
 483                     { 'item.homebranch' => $maxissueqty_rule->branchcode } );
 484             }
 485         } else {
 486             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 487         }
 488         $checkouts = $checkouts->search(undef, { prefetch => 'item' });
 489
 490         my $sum_checkouts;
 491         my $rule_itemtype = $maxissueqty_rule->itemtype;
 492
 493         my @types;
 494         unless ( $rule_itemtype ) {
 495             # matching rule has the default item type, so count only
 496             # those existing loans that don't fall under a more
 497             # specific rule
 498             @types = Koha::CirculationRules->search(
 499                 {
 500                     branchcode => $maxissueqty_rule->branchcode,
 501                     categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 502                     itemtype  => { '!=' => undef },
 503                     rule_name => 'maxissueqty'
 504                 }
 505             )->get_column('itemtype');
 506         } else {
 507             if ( $parent_maxissueqty_rule ) {
 508                 # if we have a parent item type then we count loans of the
 509                 # specific item type or its siblings or parent
 510                 my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 511                 @types = $children->get_column('itemtype');
 512                 push @types, $parent_type;
 513             } elsif ( $child_types ) {
 514                 # If we are a parent type, we need to count all child types and our own type
 515                 @types = $child_types->get_column('itemtype');
 516                 push @types, $type; # And don't forget to count our own types
 517             } else {
 518                 # Otherwise only count the specific itemtype
 519                 push @types, $type;
 520             }
 521         }
 522
 523         while ( my $c = $checkouts->next ) {
 524             my $itemtype = $c->item->effective_itemtype;
 525
 526             unless ( $rule_itemtype ) {
 527                 next if grep {$_ eq $itemtype} @types;
 528             } else {
 529                 next unless grep {$_ eq $itemtype} @types;
 530             }
 531
 532             $sum_checkouts->{total}++;
 533             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 534             $sum_checkouts->{itemtype}->{$itemtype}++;
 535         }
 536
 537         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 538         my $checkout_count = $sum_checkouts->{total} || 0;
 539         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 540
 541         my $checkout_rules = {
 542             checkout_count               => $checkout_count,
 543             onsite_checkout_count        => $onsite_checkout_count,
 544             onsite_checkout              => $onsite_checkout,
 545             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 546             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 547             switch_onsite_checkout       => $switch_onsite_checkout,
 548         };
 549         # If parent rules exists
 550         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 551             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 552             my $qty_over = _check_max_qty($checkout_rules);
 553             return $qty_over if defined $qty_over;
 554
 555             # If the parent rule is less than or equal to the child, we only need check the parent
 556             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 557                 $checkout_rules->{checkout_count} = $checkout_count_type;
 558                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 559                 my $qty_over = _check_max_qty($checkout_rules);
 560                 return $qty_over if defined $qty_over;
 561             }
 562         } else {
 563             my $qty_over = _check_max_qty($checkout_rules);
 564             return $qty_over if defined $qty_over;
 565         }
 566     }
 567
 568     # Now count total loans against the limit for the branch
 569     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 570     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 571         my $checkouts;
 572         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 573             $checkouts = $patron->checkouts->search(
 574                 { 'me.branchcode' => $branch} );
 575         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 576             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 577         } else {
 578             $checkouts = $patron->checkouts->search(
 579                 { 'item.homebranch' => $branch},
 580                 { prefetch          => 'item' } );
 581         }
 582
 583         my $checkout_count = $checkouts->count;
 584         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 585         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 586         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 587
 588         my $qty_over = _check_max_qty(
 589             {
 590                 checkout_count               => $checkout_count,
 591                 onsite_checkout_count        => $onsite_checkout_count,
 592                 onsite_checkout              => $onsite_checkout,
 593                 max_checkouts_allowed        => $max_checkouts_allowed,
 594                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 595                 switch_onsite_checkout       => $switch_onsite_checkout
 596             }
 597         );
 598         return $qty_over if defined $qty_over;
 599     }
 600
 601     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 602         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 603     }
 604
 605     # OK, the patron can issue !!!
 606     return;
 607 }
 608
 609 sub _check_max_qty {
 610     my $params                       = shift;
 611     my $checkout_count               = $params->{checkout_count};
 612     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 613     my $onsite_checkout              = $params->{onsite_checkout};
 614     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 615     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 616     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 617
 618     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 619         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 620         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 621             return {
 622                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 623                 count       => $onsite_checkout_count,
 624                 max_allowed => $max_onsite_checkouts_allowed,
 625             };
 626         }
 627     }
 628     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 629         if ( $max_checkouts_allowed eq '' ) { return; }
 630         my $delta = $switch_onsite_checkout ? 1 : 0;
 631         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 632             return {
 633                 reason      => 'TOO_MANY_CHECKOUTS',
 634                 count       => $checkout_count,
 635                 max_allowed => $max_checkouts_allowed,
 636             };
 637         }
 638     }
 639     elsif ( not $onsite_checkout ) {
 640         if ( $max_checkouts_allowed eq '' ) { return; }
 641         if (
 642             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 643         {
 644             return {
 645                 reason      => 'TOO_MANY_CHECKOUTS',
 646                 count       => $checkout_count - $onsite_checkout_count,
 647                 max_allowed => $max_checkouts_allowed,
 648             };
 649         }
 650     }
 651
 652     return;
 653 }
 654
 655 =head2 CanBookBeIssued
 656
 657   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 658                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 659
 660 Check if a book can be issued.
 661
 662 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 663
 664 IMPORTANT: The assumption by users of this routine is that causes blocking
 665 the issue are keyed by uppercase labels and other returned
 666 data is keyed in lower case!
 667
 668 =over 4
 669
 670 =item C<$patron> is a Koha::Patron
 671
 672 =item C<$barcode> is the bar code of the book being issued.
 673
 674 =item C<$duedates> is a DateTime object.
 675
 676 =item C<$inprocess> boolean switch
 677
 678 =item C<$ignore_reserves> boolean switch
 679
 680 =item C<$params> Hashref of additional parameters
 681
 682 Available keys:
 683     override_high_holds - Ignore high holds
 684     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 685
 686 =back
 687
 688 Returns :
 689
 690 =over 4
 691
 692 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 693 Possible values are :
 694
 695 =back
 696
 697 =head3 INVALID_DATE
 698
 699 sticky due date is invalid
 700
 701 =head3 GNA
 702
 703 borrower gone with no address
 704
 705 =head3 CARD_LOST
 706
 707 borrower declared it's card lost
 708
 709 =head3 DEBARRED
 710
 711 borrower debarred
 712
 713 =head3 UNKNOWN_BARCODE
 714
 715 barcode unknown
 716
 717 =head3 NOT_FOR_LOAN
 718
 719 item is not for loan
 720
 721 =head3 WTHDRAWN
 722
 723 item withdrawn.
 724
 725 =head3 RESTRICTED
 726
 727 item is restricted (set by ??)
 728
 729 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 730 could be prevented, but ones that can be overriden by the operator.
 731
 732 Possible values are :
 733
 734 =head3 DEBT
 735
 736 borrower has debts.
 737
 738 =head3 RENEW_ISSUE
 739
 740 renewing, not issuing
 741
 742 =head3 ISSUED_TO_ANOTHER
 743
 744 issued to someone else.
 745
 746 =head3 RESERVED
 747
 748 reserved for someone else.
 749
 750 =head3 TRANSFERRED
 751
 752 reserved and being transferred for someone else.
 753
 754 =head3 INVALID_DATE
 755
 756 sticky due date is invalid or due date in the past
 757
 758 =head3 TOO_MANY
 759
 760 if the borrower borrows to much things
 761
 762 =head3 RECALLED
 763
 764 recalled by someone else
 765
 766 =cut
 767
 768 sub CanBookBeIssued {
 769     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 770     my %needsconfirmation;    # filled with problems that needs confirmations
 771     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 772     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 773     my %messages;             # filled with information messages that should be displayed.
 774
 775     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 776     my $override_high_holds = $params->{override_high_holds} || 0;
 777
 778     my $item_object = Koha::Items->find({barcode => $barcode });
 779
 780     # MANDATORY CHECKS - unless item exists, nothing else matters
 781     unless ( $item_object ) {
 782         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 783     }
 784     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 785
 786     my $item_unblessed = $item_object->unblessed; # Transition...
 787     my $issue = $item_object->checkout;
 788     my $biblio = $item_object->biblio;
 789
 790     my $biblioitem = $biblio->biblioitem;
 791     my $effective_itemtype = $item_object->effective_itemtype;
 792     my $dbh             = C4::Context->dbh;
 793     my $patron_unblessed = $patron->unblessed;
 794
 795     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 796
 797     my $now = dt_from_string();
 798     $duedate ||= CalcDateDue( $now, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 799     if (DateTime->compare($duedate,$now) == -1 ) { # duedate cannot be before now
 800          $needsconfirmation{INVALID_DATE} = $duedate;
 801     }
 802
 803     my $fees = Koha::Charges::Fees->new(
 804         {
 805             patron    => $patron,
 806             library   => $circ_library,
 807             item      => $item_object,
 808             to_date   => $duedate,
 809         }
 810     );
 811
 812     #
 813     # BORROWER STATUS
 814     #
 815     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 816         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 817         C4::Stats::UpdateStats({
 818                      branch => C4::Context->userenv->{'branch'},
 819                      type => 'localuse',
 820                      itemnumber => $item_object->itemnumber,
 821                      itemtype => $effective_itemtype,
 822                      borrowernumber => $patron->borrowernumber,
 823                      ccode => $item_object->ccode}
 824                     );
 825         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 826         return( { STATS => 1 }, {});
 827     }
 828
 829     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 830         $issuingimpossible{GNA} = 1;
 831     }
 832
 833     if ( $patron->lost && $patron->lost == 1 ) {
 834         $issuingimpossible{CARD_LOST} = 1;
 835     }
 836     if ( $patron->is_debarred ) {
 837         $issuingimpossible{DEBARRED} = 1;
 838     }
 839
 840     if ( $patron->is_expired ) {
 841         $issuingimpossible{EXPIRED} = 1;
 842     }
 843
 844     #
 845     # BORROWER STATUS
 846     #
 847
 848     # DEBTS
 849     my $account = $patron->account;
 850     my $balance = $account->balance;
 851     my $non_issues_charges = $account->non_issues_charges;
 852     my $other_charges = $balance - $non_issues_charges;
 853
 854     my $amountlimit = C4::Context->preference("noissuescharge");
 855     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 856     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 857
 858     # Check the debt of this patrons guarantees
 859     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 860     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 861     if ( defined $no_issues_charge_guarantees ) {
 862         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships->as_list;
 863         my $guarantees_non_issues_charges = 0;
 864         foreach my $g ( @guarantees ) {
 865             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 866         }
 867
 868         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 869             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 870         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 871             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 872         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 873             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 874         }
 875     }
 876
 877     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 878     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 879     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 880     if ( defined $no_issues_charge_guarantors ) {
 881         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 882
 883         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 884             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 885         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 886             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 887         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 888             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 889         }
 890     }
 891
 892     if ( C4::Context->preference("IssuingInProcess") ) {
 893         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 894             $issuingimpossible{DEBT} = $non_issues_charges;
 895         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 896             $needsconfirmation{DEBT} = $non_issues_charges;
 897         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 898             $needsconfirmation{DEBT} = $non_issues_charges;
 899         }
 900     }
 901     else {
 902         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 903             $needsconfirmation{DEBT} = $non_issues_charges;
 904         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 905             $issuingimpossible{DEBT} = $non_issues_charges;
 906         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 907             $needsconfirmation{DEBT} = $non_issues_charges;
 908         }
 909     }
 910
 911     if ($balance > 0 && $other_charges > 0) {
 912         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 913     }
 914
 915     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 916     $patron_unblessed = $patron->unblessed;
 917
 918     if ( my $debarred_date = $patron->is_debarred ) {
 919          # patron has accrued fine days or has a restriction. $count is a date
 920         if ($debarred_date eq '9999-12-31') {
 921             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 922         }
 923         else {
 924             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 925         }
 926     } elsif ( my $num_overdues = $patron->has_overdues ) {
 927         ## patron has outstanding overdue loans
 928         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 929             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 930         }
 931         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 932             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 933         }
 934     }
 935
 936     # Additional Materials Check
 937     if ( C4::Context->preference("CircConfirmItemParts")
 938         && $item_object->materials )
 939     {
 940         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 941     }
 942
 943     #
 944     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 945     #
 946     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 947
 948         # Already issued to current borrower.
 949         # If it is an on-site checkout if it can be switched to a normal checkout
 950         # or ask whether the loan should be renewed
 951
 952         if ( $issue->onsite_checkout
 953                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 954             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 955         } else {
 956             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 957                 $patron->borrowernumber,
 958                 $item_object->itemnumber,
 959             );
 960             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 961                 if ( $renewerror eq 'onsite_checkout' ) {
 962                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 963                 }
 964                 else {
 965                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 966                 }
 967             }
 968             else {
 969                 $needsconfirmation{RENEW_ISSUE} = 1;
 970             }
 971         }
 972     }
 973     elsif ( $issue ) {
 974
 975         # issued to someone else
 976
 977         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 978
 979         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 980
 981         unless ( $can_be_returned ) {
 982             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 983             $issuingimpossible{branch_to_return} = $message;
 984         } else {
 985             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 986                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 987             } else {
 988             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 989             $needsconfirmation{issued_firstname} = $patron->firstname;
 990             $needsconfirmation{issued_surname} = $patron->surname;
 991             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 992             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 993             }
 994         }
 995     }
 996
 997     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 998     #
 999     my $switch_onsite_checkout = (
1000           C4::Context->preference('SwitchOnSiteCheckouts')
1001       and $issue
1002       and $issue->onsite_checkout
1003       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
1004     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
1005     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
1006     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
1007         if ( $toomany->{max_allowed} == 0 ) {
1008             $needsconfirmation{PATRON_CANT} = 1;
1009         }
1010         if ( C4::Context->preference("AllowTooManyOverride") ) {
1011             $needsconfirmation{TOO_MANY} = $toomany->{reason};
1012             $needsconfirmation{current_loan_count} = $toomany->{count};
1013             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
1014         } else {
1015             $issuingimpossible{TOO_MANY} = $toomany->{reason};
1016             $issuingimpossible{current_loan_count} = $toomany->{count};
1017             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
1018         }
1019     }
1020
1021     #
1022     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1023     #
1024     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1025     my $wants_check = $patron->wants_check_for_previous_checkout;
1026     $needsconfirmation{PREVISSUE} = 1
1027         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1028
1029     #
1030     # ITEM CHECKING
1031     #
1032     if ( $item_object->notforloan )
1033     {
1034         if(!C4::Context->preference("AllowNotForLoanOverride")){
1035             $issuingimpossible{NOT_FOR_LOAN} = 1;
1036             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1037         }else{
1038             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1039             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1040         }
1041     }
1042     else {
1043         # we have to check itemtypes.notforloan also
1044         if (C4::Context->preference('item-level_itypes')){
1045             # this should probably be a subroutine
1046             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1047             $sth->execute($effective_itemtype);
1048             my $notforloan=$sth->fetchrow_hashref();
1049             if ($notforloan->{'notforloan'}) {
1050                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1051                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1052                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1053                 } else {
1054                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1055                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1056                 }
1057             }
1058         }
1059         else {
1060             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1061             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1062                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1063                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1064                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1065                 } else {
1066                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1067                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1068                 }
1069             }
1070         }
1071     }
1072     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1073     {
1074         $issuingimpossible{WTHDRAWN} = 1;
1075     }
1076     if (   $item_object->restricted
1077         && $item_object->restricted == 1 )
1078     {
1079         $issuingimpossible{RESTRICTED} = 1;
1080     }
1081     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1082         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1083         my $code = $av->count ? $av->next->lib : '';
1084         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1085         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1086     }
1087     if ( C4::Context->preference("IndependentBranches") ) {
1088         my $userenv = C4::Context->userenv;
1089         unless ( C4::Context->IsSuperLibrarian() ) {
1090             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1091             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1092                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1093                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1094             }
1095             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1096               if ( $patron->branchcode ne $userenv->{branch} );
1097         }
1098     }
1099
1100     #
1101     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1102     #
1103     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1104     if ($rentalConfirmation) {
1105         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1106
1107         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1108         if ($itemtype_object) {
1109             my $accumulate_charge = $fees->accumulate_rentalcharge();
1110             if ( $accumulate_charge > 0 ) {
1111                 $rentalCharge += $accumulate_charge;
1112             }
1113         }
1114
1115         if ( $rentalCharge > 0 ) {
1116             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1117         }
1118     }
1119
1120     my $recall;
1121     # CHECK IF ITEM HAS BEEN RECALLED BY ANOTHER PATRON
1122     # Only bother doing this if UseRecalls is enabled and the item is recallable
1123     # Don't look at recalls that are in transit
1124     if ( C4::Context->preference('UseRecalls') and $item_object->can_be_waiting_recall ) {
1125         my @recalls = $biblio->recalls({},{ order_by => { -asc => 'created_date' } })->filter_by_current->as_list;
1126
1127         foreach my $r ( @recalls ) {
1128             if ( $r->item_id and
1129                 $r->item_id == $item_object->itemnumber and
1130                 $r->patron_id == $patron->borrowernumber and
1131                 ( $r->waiting or $r->requested ) ) {
1132                 $messages{RECALLED} = $r->id;
1133                 $recall = $r;
1134                 # this item is recalled by or already waiting for this borrower and the recall can be fulfilled
1135                 last;
1136             }
1137             elsif ( $r->item_id and
1138                 $r->item_id == $item_object->itemnumber and
1139                 $r->in_transit ) {
1140                 # recalled item is in transit
1141                 $issuingimpossible{RECALLED_INTRANSIT} = $r->pickup_library_id;
1142             }
1143             elsif ( $r->item_level and
1144                 $r->item_id == $item_object->itemnumber and
1145                 $r->patron_id != $patron->borrowernumber and
1146                 !$r->in_transit ) {
1147                 # this specific item has been recalled by a different patron
1148                 $needsconfirmation{RECALLED} = $r;
1149                 $recall = $r;
1150                 last;
1151             }
1152             elsif ( !$r->item_level and
1153                 $r->patron_id != $patron->borrowernumber and
1154                 !$r->in_transit ) {
1155                 # a different patron has placed a biblio-level recall and this item is eligible to fill it
1156                 $needsconfirmation{RECALLED} = $r;
1157                 $recall = $r;
1158                 last;
1159             }
1160         }
1161     }
1162
1163     unless ( $ignore_reserves and defined $recall ) {
1164         # See if the item is on reserve.
1165         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1166         if ($restype) {
1167             my $resbor = $res->{'borrowernumber'};
1168             if ( $resbor ne $patron->borrowernumber ) {
1169                 my $patron = Koha::Patrons->find( $resbor );
1170                 if ( $restype eq "Waiting" )
1171                 {
1172                     # The item is on reserve and waiting, but has been
1173                     # reserved by some other patron.
1174                     $needsconfirmation{RESERVE_WAITING} = 1;
1175                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1176                     $needsconfirmation{'ressurname'} = $patron->surname;
1177                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1178                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1179                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1180                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1181                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1182                 }
1183                 elsif ( $restype eq "Reserved" ) {
1184                     # The item is on reserve for someone else.
1185                     $needsconfirmation{RESERVED} = 1;
1186                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1187                     $needsconfirmation{'ressurname'} = $patron->surname;
1188                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1189                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1190                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1191                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1192                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1193                 }
1194                 elsif ( $restype eq "Transferred" ) {
1195                     # The item is determined hold being transferred for someone else.
1196                     $needsconfirmation{TRANSFERRED} = 1;
1197                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1198                     $needsconfirmation{'ressurname'} = $patron->surname;
1199                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1200                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1201                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1202                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1203                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1204                 }
1205                 elsif ( $restype eq "Processing" ) {
1206                     # The item is determined hold being processed for someone else.
1207                     $needsconfirmation{PROCESSING} = 1;
1208                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1209                     $needsconfirmation{'ressurname'} = $patron->surname;
1210                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1211                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1212                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1213                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1214                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1215                 }
1216             }
1217         }
1218     }
1219
1220     ## CHECK AGE RESTRICTION
1221     my $agerestriction  = $biblioitem->agerestriction;
1222     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1223     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1224         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1225             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1226         }
1227         else {
1228             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1229         }
1230     }
1231
1232     ## check for high holds decreasing loan period
1233     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1234         my $check = checkHighHolds( $item_object, $patron );
1235
1236         if ( $check->{exceeded} ) {
1237             my $highholds = {
1238                 num_holds  => $check->{outstanding},
1239                 duration   => $check->{duration},
1240                 returndate => $check->{due_date},
1241             };
1242             if ($override_high_holds) {
1243                 $alerts{HIGHHOLDS} = $highholds;
1244             }
1245             else {
1246                 $needsconfirmation{HIGHHOLDS} = $highholds;
1247             }
1248         }
1249     }
1250
1251     if (
1252         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1253         # don't do the multiple loans per bib check if we've
1254         # already determined that we've got a loan on the same item
1255         !$issuingimpossible{NO_MORE_RENEWALS} &&
1256         !$needsconfirmation{RENEW_ISSUE}
1257     ) {
1258         # Check if borrower has already issued an item from the same biblio
1259         # Only if it's not a subscription
1260         my $biblionumber = $item_object->biblionumber;
1261         require C4::Serials;
1262         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1263         unless ($is_a_subscription) {
1264             # FIXME Should be $patron->checkouts($args);
1265             my $checkouts = Koha::Checkouts->search(
1266                 {
1267                     borrowernumber => $patron->borrowernumber,
1268                     biblionumber   => $biblionumber,
1269                 },
1270                 {
1271                     join => 'item',
1272                 }
1273             );
1274             # if we get here, we don't already have a loan on this item,
1275             # so if there are any loans on this bib, ask for confirmation
1276             if ( $checkouts->count ) {
1277                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1278             }
1279         }
1280     }
1281
1282     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1283 }
1284
1285 =head2 CanBookBeReturned
1286
1287   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1288
1289 Check whether the item can be returned to the provided branch
1290
1291 =over 4
1292
1293 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1294
1295 =item C<$branch> is the branchcode where the return is taking place
1296
1297 =back
1298
1299 Returns:
1300
1301 =over 4
1302
1303 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1304
1305 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1306
1307 =back
1308
1309 =cut
1310
1311 sub CanBookBeReturned {
1312   my ($item, $branch) = @_;
1313   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1314
1315   # assume return is allowed to start
1316   my $allowed = 1;
1317   my $message;
1318
1319   # identify all cases where return is forbidden
1320   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1321      $allowed = 0;
1322      $message = $item->{'homebranch'};
1323   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1324      $allowed = 0;
1325      $message = $item->{'holdingbranch'};
1326   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1327      $allowed = 0;
1328      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1329   }
1330
1331   return ($allowed, $message);
1332 }
1333
1334 =head2 CheckHighHolds
1335
1336     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1337     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1338     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1339
1340 =cut
1341
1342 sub checkHighHolds {
1343     my ( $item, $patron ) = @_;
1344     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
1345
1346     my $return_data = {
1347         exceeded    => 0,
1348         outstanding => 0,
1349         duration    => 0,
1350         due_date    => undef,
1351     };
1352
1353     my $holds = Koha::Holds->search( { biblionumber => $item->biblionumber } );
1354
1355     if ( $holds->count() ) {
1356         $return_data->{outstanding} = $holds->count();
1357
1358         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1359         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1360         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1361
1362         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1363
1364         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1365
1366             # static means just more than a given number of holds on the record
1367
1368             # If the number of holds is less than the threshold, we can stop here
1369             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1370                 return $return_data;
1371             }
1372         }
1373         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1374
1375             # dynamic means X more than the number of holdable items on the record
1376
1377             # let's get the items
1378             my @items = $holds->next()->biblio()->items()->as_list;
1379
1380             # Remove any items with status defined to be ignored even if the would not make item unholdable
1381             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1382                 @items = grep { !$_->$status } @items;
1383             }
1384
1385             # Remove any items that are not holdable for this patron
1386             @items = grep { CanItemBeReserved( $patron , $_, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1387
1388             my $items_count = scalar @items;
1389
1390             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1391
1392             # If the number of holds is less than the count of items we have
1393             # plus the number of holds allowed above that count, we can stop here
1394             if ( $holds->count() <= $threshold ) {
1395                 return $return_data;
1396             }
1397         }
1398
1399         my $issuedate = dt_from_string();
1400
1401         my $itype = $item->effective_itemtype;
1402         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1403             {
1404                 categorycode => $patron->categorycode,
1405                 itemtype     => $itype,
1406                 branchcode   => $branchcode,
1407             }
1408         );
1409         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1410
1411         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $patron->unblessed );
1412
1413         my $rule = Koha::CirculationRules->get_effective_rule_value(
1414             {
1415                 categorycode => $patron->categorycode,
1416                 itemtype     => $item->effective_itemtype,
1417                 branchcode   => $branchcode,
1418                 rule_name    => 'decreaseloanholds',
1419             }
1420         );
1421
1422         my $duration;
1423         if ( defined($rule) && $rule ne '' ){
1424             # overrides decreaseLoanHighHoldsDuration syspref
1425             $duration = $rule;
1426         } else {
1427             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1428         }
1429         my $reduced_datedue = $calendar->addDuration( $issuedate, $duration );
1430         $reduced_datedue->set_hour($orig_due->hour);
1431         $reduced_datedue->set_minute($orig_due->minute);
1432         $reduced_datedue->truncate( to => 'minute' );
1433
1434         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1435             $return_data->{exceeded} = 1;
1436             $return_data->{duration} = $duration;
1437             $return_data->{due_date} = $reduced_datedue;
1438         }
1439     }
1440
1441     return $return_data;
1442 }
1443
1444 =head2 AddIssue
1445
1446   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1447
1448 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1449
1450 =over 4
1451
1452 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1453
1454 =item C<$barcode> is the barcode of the item being issued.
1455
1456 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1457 Calculated if empty.
1458
1459 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1460
1461 =item C<$issuedate> is a DateTime object for the date to issue the item (optional).
1462 Defaults to today.
1463
1464 AddIssue does the following things :
1465
1466   - step 01: check that there is a borrowernumber & a barcode provided
1467   - check for RENEWAL (book issued & being issued to the same patron)
1468       - renewal YES = Calculate Charge & renew
1469       - renewal NO  =
1470           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1471           * RESERVE PLACED ?
1472               - fill reserve if reserve to this patron
1473               - cancel reserve or not, otherwise
1474           * RECALL PLACED ?
1475               - fill recall if recall to this patron
1476               - cancel recall or not
1477               - revert recall's waiting status or not
1478           * TRANSFERT PENDING ?
1479               - complete the transfert
1480           * ISSUE THE BOOK
1481
1482 =back
1483
1484 =cut
1485
1486 sub AddIssue {
1487     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1488
1489     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1490     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1491     my $auto_renew = $params && $params->{auto_renew};
1492     my $cancel_recall = $params && $params->{cancel_recall};
1493     my $recall_id = $params && $params->{recall_id};
1494     my $dbh          = C4::Context->dbh;
1495     my $barcodecheck = CheckValidBarcode($barcode);
1496
1497     my $issue;
1498
1499     if ( $datedue && ref $datedue ne 'DateTime' ) {
1500         $datedue = dt_from_string($datedue);
1501     }
1502
1503     # $issuedate defaults to today.
1504     if ( !defined $issuedate ) {
1505         $issuedate = dt_from_string();
1506     }
1507     else {
1508         if ( ref $issuedate ne 'DateTime' ) {
1509             $issuedate = dt_from_string($issuedate);
1510
1511         }
1512     }
1513
1514     # Stop here if the patron or barcode doesn't exist
1515     if ( $borrower && $barcode && $barcodecheck ) {
1516         # find which item we issue
1517         my $item_object = Koha::Items->find({ barcode => $barcode })
1518           or return;    # if we don't get an Item, abort.
1519         my $item_unblessed = $item_object->unblessed;
1520
1521         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1522
1523         # get actual issuing if there is one
1524         my $actualissue = $item_object->checkout;
1525
1526         # check if we just renew the issue.
1527         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1528                 and not $switch_onsite_checkout ) {
1529             $datedue = AddRenewal(
1530                 $borrower->{'borrowernumber'},
1531                 $item_object->itemnumber,
1532                 $branchcode,
1533                 $datedue,
1534                 $issuedate,    # here interpreted as the renewal date
1535             );
1536         }
1537         else {
1538             unless ($datedue) {
1539                 my $itype = $item_object->effective_itemtype;
1540                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1541
1542             }
1543
1544             # Check if we need to use an exact due date set by the ILL module
1545             if ( C4::Context->preference('ILLModule') ) {
1546                 # Check if there is an ILL connected with the biblio of the item we are issuing
1547                 my $ill_request = Koha::Illrequests->search({
1548                     biblio_id => $item_object->biblionumber,
1549                     borrowernumber => $borrower->{'borrowernumber'},
1550                     completed => undef,
1551                     due_date => { '!=', undef },
1552                 })->next;
1553
1554                 if ( $ill_request and length( $ill_request->due_date ) > 0 ) {
1555                     my $ill_dt = dt_from_string( $ill_request->due_date );
1556                     $ill_dt->set_hour(23);
1557                     $ill_dt->set_minute(59);
1558                     $datedue = $ill_dt;
1559                 }
1560             }
1561
1562             $datedue->truncate( to => 'minute' );
1563
1564             my $patron = Koha::Patrons->find( $borrower );
1565             my $library = Koha::Libraries->find( $branchcode );
1566             my $fees = Koha::Charges::Fees->new(
1567                 {
1568                     patron    => $patron,
1569                     library   => $library,
1570                     item      => $item_object,
1571                     to_date   => $datedue,
1572                 }
1573             );
1574
1575             # it's NOT a renewal
1576             if ( $actualissue and not $switch_onsite_checkout ) {
1577                 # This book is currently on loan, but not to the person
1578                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1579                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1580                 return unless $allowed;
1581                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1582                 # AddReturn certainly has side-effects, like onloan => undef
1583                 $item_object->discard_changes;
1584             }
1585
1586             if ( C4::Context->preference('UseRecalls') ) {
1587                 Koha::Recalls->move_recall(
1588                     {
1589                         action         => $cancel_recall,
1590                         recall_id      => $recall_id,
1591                         item           => $item_object,
1592                         borrowernumber => $borrower->{borrowernumber},
1593                     }
1594                 );
1595             }
1596
1597             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1598
1599             # Starting process for transfer job (checking transfert and validate it if we have one)
1600             if ( my $transfer = $item_object->get_transfer ) {
1601                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1602                 $transfer->set(
1603                     {
1604                         datearrived => dt_from_string,
1605                         tobranch    => C4::Context->userenv->{branch},
1606                         comments    => 'Forced branchtransfer'
1607                     }
1608                 )->store;
1609                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1610                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1611                     if ( $hold ) { # Is this really needed?
1612                         $hold->set( { found => undef } )->store;
1613                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1614                     }
1615                 }
1616             }
1617
1618             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1619             unless ($auto_renew) {
1620                 my $rule = Koha::CirculationRules->get_effective_rule_value(
1621                     {
1622                         categorycode => $borrower->{categorycode},
1623                         itemtype     => $item_object->effective_itemtype,
1624                         branchcode   => $branchcode,
1625                         rule_name    => 'auto_renew'
1626                     }
1627                 );
1628
1629                 $auto_renew = $rule if defined $rule && $rule ne '';
1630             }
1631
1632             my $issue_attributes = {
1633                 borrowernumber  => $borrower->{'borrowernumber'},
1634                 issuedate       => $issuedate,
1635                 date_due        => $datedue,
1636                 branchcode      => C4::Context->userenv->{'branch'},
1637                 onsite_checkout => $onsite_checkout,
1638                 auto_renew      => $auto_renew ? 1 : 0,
1639             };
1640
1641             # Get ID of logged in user.  if called from a batch job,
1642             # no user session exists and C4::Context->userenv() returns
1643             # the scalar '0'. Only do this if the syspref says so
1644             if ( C4::Context->preference('RecordStaffUserOnCheckout') ) {
1645                 my $userenv = C4::Context->userenv();
1646                 my $usernumber = (ref($userenv) eq 'HASH') ? $userenv->{'number'} : undef;
1647                 if ($usernumber) {
1648                     $issue_attributes->{issuer_id} = $usernumber;
1649                 }
1650             }
1651
1652             # In the case that the borrower has an on-site checkout
1653             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1654             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1655             if ($issue) {
1656                 $issue->set($issue_attributes)->store;
1657             }
1658             else {
1659                 $issue = Koha::Checkout->new(
1660                     {
1661                         itemnumber => $item_object->itemnumber,
1662                         %$issue_attributes,
1663                     }
1664                 )->store;
1665             }
1666             $issue->discard_changes;
1667             C4::Auth::track_login_daily( $borrower->{userid} );
1668             if ( $item_object->location && $item_object->location eq 'CART'
1669                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1670             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1671                 CartToShelf( $item_object->itemnumber );
1672             }
1673
1674             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1675                 UpdateTotalIssues( $item_object->biblionumber, 1, undef, { skip_holds_queue => 1 } );
1676             }
1677
1678             # Record if item was lost
1679             my $was_lost = $item_object->itemlost;
1680
1681             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1682             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1683             $item_object->itemlost(0);
1684             $item_object->onloan($datedue->ymd());
1685             $item_object->datelastborrowed( dt_from_string()->ymd() );
1686             $item_object->datelastseen( dt_from_string()->ymd() );
1687             $item_object->store( { log_action => 0, skip_holds_queue => 1 } );
1688
1689             # If the item was lost, it has now been found, charge the overdue if necessary
1690             if ($was_lost) {
1691                 if ( $item_object->{_charge} ) {
1692                     $actualissue //= Koha::Old::Checkouts->search(
1693                         { itemnumber => $item_unblessed->{itemnumber} },
1694                         {
1695                             order_by => { '-desc' => 'returndate' },
1696                             rows     => 1
1697                         }
1698                     )->single;
1699                     unless ( exists( $borrower->{branchcode} ) ) {
1700                         my $patron = $actualissue->patron;
1701                         $borrower = $patron->unblessed;
1702                     }
1703                     _CalculateAndUpdateFine(
1704                         {
1705                             issue       => $actualissue,
1706                             item        => $item_unblessed,
1707                             borrower    => $borrower,
1708                             return_date => $issuedate
1709                         }
1710                     );
1711                     _FixOverduesOnReturn( $borrower->{borrowernumber},
1712                         $item_object->itemnumber, undef, 'RENEWED' );
1713                 }
1714             }
1715
1716             # If it costs to borrow this book, charge it to the patron's account.
1717             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1718             if ( $charge && $charge > 0 ) {
1719                 AddIssuingCharge( $issue, $charge, 'RENT' );
1720             }
1721
1722             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1723             if ( $itemtype_object ) {
1724                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1725                 if ( $accumulate_charge > 0 ) {
1726                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1727                     $charge += $accumulate_charge;
1728                     $item_unblessed->{charge} = $charge;
1729                 }
1730             }
1731
1732             # Record the fact that this book was issued.
1733             C4::Stats::UpdateStats(
1734                 {
1735                     branch => C4::Context->userenv->{'branch'},
1736                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1737                     amount         => $charge,
1738                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1739                     itemnumber     => $item_object->itemnumber,
1740                     itemtype       => $item_object->effective_itemtype,
1741                     location       => $item_object->location,
1742                     borrowernumber => $borrower->{'borrowernumber'},
1743                     ccode          => $item_object->ccode,
1744                 }
1745             );
1746
1747             # Send a checkout slip.
1748             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1749             my %conditions        = (
1750                 branchcode   => $branchcode,
1751                 categorycode => $borrower->{categorycode},
1752                 item_type    => $item_object->effective_itemtype,
1753                 notification => 'CHECKOUT',
1754             );
1755             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1756                 SendCirculationAlert(
1757                     {
1758                         type     => 'CHECKOUT',
1759                         item     => $item_object->unblessed,
1760                         borrower => $borrower,
1761                         branch   => $branchcode,
1762                     }
1763                 );
1764             }
1765             logaction(
1766                 "CIRCULATION", "ISSUE",
1767                 $borrower->{'borrowernumber'},
1768                 $item_object->itemnumber,
1769             ) if C4::Context->preference("IssueLog");
1770
1771             Koha::Plugins->call('after_circ_action', {
1772                 action  => 'checkout',
1773                 payload => {
1774                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1775                     checkout => $issue->get_from_storage
1776                 }
1777             });
1778
1779             Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
1780                 {
1781                     biblio_ids => [ $item_object->biblionumber ]
1782                 }
1783             ) if C4::Context->preference('RealTimeHoldsQueue');
1784         }
1785     }
1786     return $issue;
1787 }
1788
1789 =head2 GetLoanLength
1790
1791   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1792
1793 Get loan length for an itemtype, a borrower type and a branch
1794
1795 =cut
1796
1797 sub GetLoanLength {
1798     my ( $categorycode, $itemtype, $branchcode ) = @_;
1799
1800     # Initialize default values
1801     my $rules = {
1802         issuelength   => 0,
1803         renewalperiod => 0,
1804         lengthunit    => 'days',
1805     };
1806
1807     my $found = Koha::CirculationRules->get_effective_rules( {
1808         branchcode => $branchcode,
1809         categorycode => $categorycode,
1810         itemtype => $itemtype,
1811         rules => [
1812             'issuelength',
1813             'renewalperiod',
1814             'lengthunit'
1815         ],
1816     } );
1817
1818     # Search for rules!
1819     foreach my $rule_name (keys %$found) {
1820         $rules->{$rule_name} = $found->{$rule_name};
1821     }
1822
1823     return $rules;
1824 }
1825
1826
1827 =head2 GetHardDueDate
1828
1829   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1830
1831 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1832
1833 =cut
1834
1835 sub GetHardDueDate {
1836     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1837
1838     my $rules = Koha::CirculationRules->get_effective_rules(
1839         {
1840             categorycode => $borrowertype,
1841             itemtype     => $itemtype,
1842             branchcode   => $branchcode,
1843             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1844         }
1845     );
1846
1847     if ( defined( $rules->{hardduedate} ) ) {
1848         if ( $rules->{hardduedate} ) {
1849             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1850         }
1851         else {
1852             return ( undef, undef );
1853         }
1854     }
1855 }
1856
1857 =head2 GetBranchBorrowerCircRule
1858
1859   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1860
1861 Retrieves circulation rule attributes that apply to the given
1862 branch and patron category, regardless of item type.
1863 The return value is a hashref containing the following key:
1864
1865 patron_maxissueqty - maximum number of loans that a
1866 patron of the given category can have at the given
1867 branch.  If the value is undef, no limit.
1868
1869 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1870 patron of the given category can have at the given
1871 branch.  If the value is undef, no limit.
1872
1873 This will check for different branch/category combinations in the following order:
1874 branch and category
1875 branch only
1876 category only
1877 default branch and category
1878
1879 If no rule has been found in the database, it will default to
1880 the buillt in rule:
1881
1882 patron_maxissueqty - undef
1883 patron_maxonsiteissueqty - undef
1884
1885 C<$branchcode> and C<$categorycode> should contain the
1886 literal branch code and patron category code, respectively - no
1887 wildcards.
1888
1889 =cut
1890
1891 sub GetBranchBorrowerCircRule {
1892     my ( $branchcode, $categorycode ) = @_;
1893
1894     # Initialize default values
1895     my $rules = {
1896         patron_maxissueqty       => undef,
1897         patron_maxonsiteissueqty => undef,
1898     };
1899
1900     # Search for rules!
1901     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1902         my $rule = Koha::CirculationRules->get_effective_rule(
1903             {
1904                 categorycode => $categorycode,
1905                 itemtype     => undef,
1906                 branchcode   => $branchcode,
1907                 rule_name    => $rule_name,
1908             }
1909         );
1910
1911         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1912     }
1913
1914     return $rules;
1915 }
1916
1917 =head2 GetBranchItemRule
1918
1919   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1920
1921 Retrieves circulation rule attributes that apply to the given
1922 branch and item type, regardless of patron category.
1923
1924 The return value is a hashref containing the following keys:
1925
1926 holdallowed => Hold policy for this branch and itemtype. Possible values:
1927   not_allowed:           No holds allowed.
1928   from_home_library:     Holds allowed only by patrons that have the same homebranch as the item.
1929   from_any_library:      Holds allowed from any patron.
1930   from_local_hold_group: Holds allowed from libraries in hold group
1931
1932 returnbranch => branch to which to return item.  Possible values:
1933   noreturn: do not return, let item remain where checked in (floating collections)
1934   homebranch: return to item's home branch
1935   holdingbranch: return to issuer branch
1936
1937 This searches branchitemrules in the following order:
1938
1939   * Same branchcode and itemtype
1940   * Same branchcode, itemtype '*'
1941   * branchcode '*', same itemtype
1942   * branchcode and itemtype '*'
1943
1944 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1945
1946 =cut
1947
1948 sub GetBranchItemRule {
1949     my ( $branchcode, $itemtype ) = @_;
1950
1951     # Search for rules!
1952     my $rules = Koha::CirculationRules->get_effective_rules({
1953         branchcode => $branchcode,
1954         itemtype => $itemtype,
1955         rules => ['holdallowed', 'hold_fulfillment_policy', 'returnbranch']
1956     });
1957
1958     # built-in default circulation rule
1959     $rules->{holdallowed} //= 'from_any_library';
1960     $rules->{hold_fulfillment_policy} //= 'any';
1961     $rules->{returnbranch} //= 'homebranch';
1962
1963     return $rules;
1964 }
1965
1966 =head2 AddReturn
1967
1968   ($doreturn, $messages, $iteminformation, $borrower) =
1969       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1970
1971 Returns a book.
1972
1973 =over 4
1974
1975 =item C<$barcode> is the bar code of the book being returned.
1976
1977 =item C<$branch> is the code of the branch where the book is being returned.
1978
1979 =item C<$exemptfine> indicates that overdue charges for the item will be
1980 removed. Optional.
1981
1982 =item C<$return_date> allows the default return date to be overridden
1983 by the given return date. Optional.
1984
1985 =back
1986
1987 C<&AddReturn> returns a list of four items:
1988
1989 C<$doreturn> is true iff the return succeeded.
1990
1991 C<$messages> is a reference-to-hash giving feedback on the operation.
1992 The keys of the hash are:
1993
1994 =over 4
1995
1996 =item C<BadBarcode>
1997
1998 No item with this barcode exists. The value is C<$barcode>.
1999
2000 =item C<NotIssued>
2001
2002 The book is not currently on loan. The value is C<$barcode>.
2003
2004 =item C<withdrawn>
2005
2006 This book has been withdrawn/cancelled. The value should be ignored.
2007
2008 =item C<Wrongbranch>
2009
2010 This book has was returned to the wrong branch.  The value is a hashref
2011 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
2012 contain the branchcode of the incorrect and correct return library, respectively.
2013
2014 =item C<ResFound>
2015
2016 The item was reserved. The value is a reference-to-hash whose keys are
2017 fields from the reserves table of the Koha database, and
2018 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
2019 either C<Waiting>, C<Reserved>, or 0.
2020
2021 =item C<WasReturned>
2022
2023 Value 1 if return is successful.
2024
2025 =item C<NeedsTransfer>
2026
2027 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
2028
2029 =item C<RecallFound>
2030
2031 This item can fill a recall. The recall object is returned. If the recall pickup branch differs from
2032 the branch this item is being returned at, C<RecallNeedsTransfer> is also returned which contains this
2033 branchcode.
2034
2035 =item C<TransferredRecall>
2036
2037 This item has been transferred to this branch to fill a recall. The recall object is returned.
2038
2039 =back
2040
2041 C<$iteminformation> is a reference-to-hash, giving information about the
2042 returned item from the issues table.
2043
2044 C<$borrower> is a reference-to-hash, giving information about the
2045 patron who last borrowed the book.
2046
2047 =cut
2048
2049 sub AddReturn {
2050     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
2051
2052     if ($branch and not Koha::Libraries->find($branch)) {
2053         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
2054         undef $branch;
2055     }
2056     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
2057     my $return_date_specified = !!$return_date;
2058     $return_date //= dt_from_string();
2059     my $messages;
2060     my $patron;
2061     my $doreturn       = 1;
2062     my $validTransfer = 1;
2063     my $stat_type = 'return';
2064
2065     # get information on item
2066     my $item = Koha::Items->find({ barcode => $barcode });
2067     unless ($item) {
2068         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
2069     }
2070
2071     my $itemnumber = $item->itemnumber;
2072     my $itemtype = $item->effective_itemtype;
2073
2074     my $issue  = $item->checkout;
2075     if ( $issue ) {
2076         $patron = $issue->patron
2077             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
2078                 . Dumper($issue->unblessed) . "\n";
2079     } else {
2080         $messages->{'NotIssued'} = $barcode;
2081         $item->onloan(undef)->store( { skip_record_index => 1, skip_holds_queue => 1 } ) if defined $item->onloan;
2082
2083         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
2084         $doreturn = 0;
2085         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
2086         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
2087         if (C4::Context->preference("RecordLocalUseOnReturn")) {
2088            $messages->{'LocalUse'} = 1;
2089            $stat_type = 'localuse';
2090         }
2091     }
2092
2093         # full item data, but no borrowernumber or checkout info (no issue)
2094     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
2095         # get the proper branch to which to return the item
2096     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
2097         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
2098     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
2099
2100     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
2101     my $patron_unblessed = $patron ? $patron->unblessed : {};
2102
2103     my $update_loc_rules = Koha::Config::SysPrefs->find('UpdateItemLocationOnCheckin')->get_yaml_pref_hash();
2104     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
2105     if ($update_loc_rules) {
2106         if (defined $update_loc_rules->{_ALL_}) {
2107             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
2108             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
2109             if (
2110                 ( defined $item->location && $item->location ne $update_loc_rules->{_ALL_}) ||
2111                 (!defined $item->location && $update_loc_rules->{_ALL_} ne "")
2112                ) {
2113                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
2114                 $item->location($update_loc_rules->{_ALL_})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1});
2115             }
2116         }
2117         else {
2118             foreach my $key ( keys %$update_loc_rules ) {
2119                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
2120                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
2121                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
2122                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
2123                     $item->location($update_loc_rules->{$key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1});
2124                     last;
2125                 }
2126             }
2127         }
2128     }
2129
2130     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2131     if ($yaml) {
2132         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2133         my $rules;
2134         eval { $rules = YAML::XS::Load(Encode::encode_utf8($yaml)); };
2135         if ($@) {
2136             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2137         }
2138         else {
2139             foreach my $key ( keys %$rules ) {
2140                 if ( $item->notforloan eq $key ) {
2141                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2142                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2143                     last;
2144                 }
2145             }
2146         }
2147     }
2148
2149     # check if the return is allowed at this branch
2150     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2151     unless ($returnallowed){
2152         $messages->{'Wrongbranch'} = {
2153             Wrongbranch => $branch,
2154             Rightbranch => $message
2155         };
2156         $doreturn = 0;
2157         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2158         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2159         return ( $doreturn, $messages, $issue, $patron_unblessed);
2160     }
2161
2162     if ( $item->withdrawn ) { # book has been cancelled
2163         $messages->{'withdrawn'} = 1;
2164         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
2165     }
2166
2167     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2168         $doreturn = 0;
2169     }
2170
2171     # case of a return of document (deal with issues and holdingbranch)
2172     if ($doreturn) {
2173         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2174         $patron or warn "AddReturn without current borrower";
2175
2176         if ($patron) {
2177             eval {
2178                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1, skip_holds_queue => 1} );
2179             };
2180             unless ( $@ ) {
2181                 if (
2182                     (
2183                         C4::Context->preference('CalculateFinesOnReturn')
2184                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2185                     )
2186                     && !$item->itemlost
2187                   )
2188                 {
2189                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2190                 }
2191             } else {
2192                 carp "The checkin for the following issue failed, Please go to the about page and check all messages on the 'System information' to see if there are configuration / data issues ($@)" . Dumper( $issue->unblessed );
2193
2194                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2195                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2196
2197                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2198             }
2199
2200             # FIXME is the "= 1" right?  This could be the borrower hash.
2201             $messages->{'WasReturned'} = 1;
2202
2203         } else {
2204             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1, skip_holds_queue => 1 });
2205         }
2206     }
2207
2208     # the holdingbranch is updated if the document is returned to another location.
2209     # this is always done regardless of whether the item was on loan or not
2210     if ($item->holdingbranch ne $branch) {
2211         $item->holdingbranch($branch)->store({ log_action => 0, skip_record_index => 1, skip_holds_queue => 1 });
2212     }
2213
2214     my $item_was_lost = $item->itemlost;
2215     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2216     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1, skip_holds_queue => 1 } ); # will unset itemlost if needed
2217
2218     # fix up the accounts.....
2219     if ($item_was_lost) {
2220         $messages->{'WasLost'} = 1;
2221         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2222             my @object_messages = @{ $updated_item->object_messages };
2223             for my $message (@object_messages) {
2224                 $messages->{'LostItemFeeRefunded'} = 1
2225                   if $message->message eq 'lost_refunded';
2226                 $messages->{'LostItemFeeRestored'} = 1
2227                   if $message->message eq 'lost_restored';
2228
2229                 if ( $message->message eq 'lost_charge' ) {
2230                     $issue //= Koha::Old::Checkouts->search(
2231                         { itemnumber => $item->itemnumber },
2232                         { order_by   => { '-desc' => 'returndate' }, rows => 1 }
2233                     )->single;
2234                     unless ( exists( $patron_unblessed->{branchcode} ) ) {
2235                         my $patron = $issue->patron;
2236                         $patron_unblessed = $patron->unblessed;
2237                     }
2238                     _CalculateAndUpdateFine(
2239                         {
2240                             issue       => $issue,
2241                             item        => $item->unblessed,
2242                             borrower    => $patron_unblessed,
2243                             return_date => $return_date
2244                         }
2245                     );
2246                     _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2247                         $item->itemnumber, undef, 'RETURNED' );
2248                     $messages->{'LostItemFeeCharged'} = 1;
2249                 }
2250             }
2251         }
2252     }
2253
2254     # check if we have a transfer for this document
2255     my $transfer = $item->get_transfer;
2256
2257     # if we have a transfer to complete, we update the line of transfers with the datearrived
2258     if ($transfer) {
2259         $validTransfer = 0;
2260         if ( $transfer->in_transit ) {
2261             if ( $transfer->tobranch eq $branch ) {
2262                 $transfer->receive;
2263                 $messages->{'TransferArrived'} = $transfer->frombranch;
2264                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2265                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2266             }
2267             else {
2268                 $messages->{'WrongTransfer'}     = $transfer->tobranch;
2269                 $messages->{'WrongTransferItem'} = $item->itemnumber;
2270                 $messages->{'TransferTrigger'}   = $transfer->reason;
2271             }
2272         }
2273         else {
2274             if ( $transfer->tobranch eq $branch ) {
2275                 $transfer->receive;
2276                 $messages->{'TransferArrived'} = $transfer->frombranch;
2277                 # validTransfer=1 allows us returning the item back if the reserve is cancelled
2278                 $validTransfer = 1 if $transfer->reason eq 'Reserve';
2279             }
2280             else {
2281                 $messages->{'WasTransfered'}   = $transfer->tobranch;
2282                 $messages->{'TransferTrigger'} = $transfer->reason;
2283             }
2284         }
2285     }
2286
2287     # fix up the overdues in accounts...
2288     if ($borrowernumber) {
2289         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2290         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2291
2292         if ( $issue and $issue->is_overdue($return_date) ) {
2293         # fix fine days
2294             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2295             if ($reminder){
2296                 $messages->{'PrevDebarred'} = $debardate;
2297             } else {
2298                 $messages->{'Debarred'} = $debardate if $debardate;
2299             }
2300         # there's no overdue on the item but borrower had been previously debarred
2301         } elsif ( $issue->date_due and $patron->debarred ) {
2302              if ( $patron->debarred eq "9999-12-31") {
2303                 $messages->{'ForeverDebarred'} = $patron->debarred;
2304              } else {
2305                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2306                   $borrower_debar_dt->truncate(to => 'day');
2307                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2308                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2309                       $messages->{'PrevDebarred'} = $patron->debarred;
2310                   }
2311              }
2312         }
2313     }
2314
2315     # find recalls...
2316     if ( C4::Context->preference('UseRecalls') ) {
2317         # check if this item is recallable first, which includes checking if UseRecalls syspref is enabled
2318         my $recall = undef;
2319         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2320         if ( defined $recall ) {
2321             $messages->{RecallFound} = $recall;
2322             if ( $recall->pickup_library_id ne $branch ) {
2323                 $messages->{RecallNeedsTransfer} = $branch;
2324             }
2325         }
2326     }
2327
2328     # find reserves.....
2329     # launch the Checkreserves routine to find any holds
2330     my ($resfound, $resrec);
2331     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2332     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2333     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2334     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2335         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2336         $resfound = 'Reserved';
2337         $resrec = $hold->unblessed;
2338     }
2339     if ($resfound) {
2340           $resrec->{'ResFound'} = $resfound;
2341         $messages->{'ResFound'} = $resrec;
2342     }
2343
2344     # Record the fact that this book was returned.
2345     C4::Stats::UpdateStats({
2346         branch         => $branch,
2347         type           => $stat_type,
2348         itemnumber     => $itemnumber,
2349         itemtype       => $itemtype,
2350         location       => $item->location,
2351         borrowernumber => $borrowernumber,
2352         ccode          => $item->ccode,
2353     });
2354
2355     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2356     if ( $patron ) {
2357         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2358         my %conditions = (
2359             branchcode   => $branch,
2360             categorycode => $patron->categorycode,
2361             item_type    => $itemtype,
2362             notification => 'CHECKIN',
2363         );
2364         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2365             SendCirculationAlert({
2366                 type     => 'CHECKIN',
2367                 item     => $item->unblessed,
2368                 borrower => $patron->unblessed,
2369                 branch   => $branch,
2370                 issue    => $issue
2371             });
2372         }
2373
2374         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2375             if C4::Context->preference("ReturnLog");
2376         }
2377
2378     # Check if this item belongs to a biblio record that is attached to an
2379     # ILL request, if it is we need to update the ILL request's status
2380     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2381         my $request = Koha::Illrequests->find(
2382             { biblio_id => $item->biblio->biblionumber }
2383         );
2384         $request->status('RET') if $request;
2385     }
2386
2387     if ( C4::Context->preference('UseRecalls') ) {
2388         # all recalls that have triggered a transfer will have an allocated itemnumber
2389         my $transfer_recall = Koha::Recalls->find({ item_id => $item->itemnumber, status => 'in_transit' });
2390         if ( $transfer_recall and $transfer_recall->pickup_library_id eq $branch ) {
2391             $messages->{TransferredRecall} = $transfer_recall;
2392         }
2393     }
2394
2395     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2396     if ( $validTransfer && !C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber )
2397         && ( $doreturn or $messages->{'NotIssued'} )
2398         and !$resfound
2399         and ( $branch ne $returnbranch )
2400         and not $messages->{'WrongTransfer'}
2401         and not $messages->{'WasTransfered'}
2402         and not $messages->{TransferredRecall}
2403         and not $messages->{RecallNeedsTransfer} )
2404     {
2405         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2406         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2407             (C4::Context->preference("UseBranchTransferLimits") and
2408              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2409            )) {
2410             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2411             $messages->{'WasTransfered'} = $returnbranch;
2412             $messages->{'TransferTrigger'} = $transfer_trigger;
2413         } else {
2414             $messages->{'NeedsTransfer'} = $returnbranch;
2415             $messages->{'TransferTrigger'} = $transfer_trigger;
2416         }
2417     }
2418
2419     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2420         my $claims = Koha::Checkouts::ReturnClaims->search(
2421            {
2422                itemnumber => $item->id,
2423                resolution => undef,
2424            }
2425         );
2426
2427         if ( $claims->count ) {
2428             $messages->{ReturnClaims} = $claims;
2429         }
2430     }
2431
2432     # Check for bundle status
2433     if ( $item->in_bundle ) {
2434         my $host = $item->bundle_host;
2435         $messages->{InBundle} = $host;
2436     }
2437
2438     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2439     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2440
2441     if ( $doreturn and $issue ) {
2442         my $checkin = Koha::Old::Checkouts->find($issue->id);
2443
2444         Koha::Plugins->call('after_circ_action', {
2445             action  => 'checkin',
2446             payload => {
2447                 checkout=> $checkin
2448             }
2449         });
2450
2451         Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
2452             {
2453                 biblio_ids => [ $item->biblionumber ]
2454             }
2455         ) if C4::Context->preference('RealTimeHoldsQueue');
2456     }
2457
2458     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2459 }
2460
2461 =head2 MarkIssueReturned
2462
2463   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2464
2465 Unconditionally marks an issue as being returned by
2466 moving the C<issues> row to C<old_issues> and
2467 setting C<returndate> to the current date.
2468
2469 if C<$returndate> is specified (in iso format), it is used as the date
2470 of the return.
2471
2472 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2473 the old_issue is immediately anonymised
2474
2475 Ideally, this function would be internal to C<C4::Circulation>,
2476 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2477 and offline_circ/process_koc.pl.
2478
2479 The last optional parameter allos passing skip_record_index to the item store call.
2480
2481 =cut
2482
2483 sub MarkIssueReturned {
2484     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2485
2486     # Retrieve the issue
2487     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2488
2489     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2490
2491     my $issue_id = $issue->issue_id;
2492
2493     my $schema = Koha::Database->schema;
2494
2495     # FIXME Improve the return value and handle it from callers
2496     $schema->txn_do(sub {
2497
2498         my $patron = Koha::Patrons->find( $borrowernumber );
2499
2500         # Update the returndate value
2501         if ( $returndate ) {
2502             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2503         }
2504         else {
2505             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2506         }
2507
2508         # Create the old_issues entry
2509         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2510
2511         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2512         if ( $privacy && $privacy == 2) {
2513             $old_checkout->anonymize;
2514         }
2515
2516         # And finally delete the issue
2517         $issue->delete;
2518
2519         $issue->item->onloan(undef)->store(
2520             {   log_action        => 0,
2521                 skip_record_index => $params->{skip_record_index},
2522                 skip_holds_queue  => $params->{skip_holds_queue}
2523             }
2524         );
2525
2526         if ( C4::Context->preference('StoreLastBorrower') ) {
2527             my $item = Koha::Items->find( $itemnumber );
2528             $item->last_returned_by( $patron );
2529         }
2530
2531         # Remove any OVERDUES related debarment if the borrower has no overdues
2532         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2533           && $patron->debarred
2534           && !$patron->has_overdues
2535           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2536         ) {
2537             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2538         }
2539
2540     });
2541
2542     return $issue_id;
2543 }
2544
2545 =head2 _debar_user_on_return
2546
2547     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2548
2549 C<$borrower> borrower hashref
2550
2551 C<$item> item hashref
2552
2553 C<$datedue> date due DateTime object
2554
2555 C<$returndate> DateTime object representing the return time
2556
2557 Internal function, called only by AddReturn that calculates and updates
2558  the user fine days, and debars them if necessary.
2559
2560 Should only be called for overdue returns
2561
2562 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2563 to ease testing.
2564
2565 =cut
2566
2567 sub _calculate_new_debar_dt {
2568     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2569
2570     my $branchcode = _GetCircControlBranch( $item, $borrower );
2571     my $circcontrol = C4::Context->preference('CircControl');
2572     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2573         {   categorycode => $borrower->{categorycode},
2574             itemtype     => $item->{itype},
2575             branchcode   => $branchcode,
2576             rules => [
2577                 'finedays',
2578                 'lengthunit',
2579                 'firstremind',
2580                 'maxsuspensiondays',
2581                 'suspension_chargeperiod',
2582             ]
2583         }
2584     );
2585     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2586     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2587     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2588
2589     return unless $finedays;
2590
2591     # finedays is in days, so hourly loans must multiply by 24
2592     # thus 1 hour late equals 1 day suspension * finedays rate
2593     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2594
2595     # grace period is measured in the same units as the loan
2596     my $grace =
2597       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2598
2599     my $deltadays = DateTime::Duration->new(
2600         days => $chargeable_units
2601     );
2602
2603     if ( $deltadays->subtract($grace)->is_positive() ) {
2604         my $suspension_days = $deltadays * $finedays;
2605
2606         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2607             # No need to / 1 and do not consider / 0
2608             $suspension_days = DateTime::Duration->new(
2609                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2610             );
2611         }
2612
2613         # If the max suspension days is < than the suspension days
2614         # the suspension days is limited to this maximum period.
2615         my $max_sd = $issuing_rule->{maxsuspensiondays};
2616         if ( defined $max_sd && $max_sd ne '' ) {
2617             $max_sd = DateTime::Duration->new( days => $max_sd );
2618             $suspension_days = $max_sd
2619               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2620         }
2621
2622         my ( $has_been_extended );
2623         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2624             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2625             if ( $debarment ) {
2626                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2627                 $has_been_extended = 1;
2628             }
2629         }
2630
2631         my $new_debar_dt;
2632         # Use the calendar or not to calculate the debarment date
2633         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2634             my $calendar = Koha::Calendar->new(
2635                 branchcode => $branchcode,
2636                 days_mode  => 'Calendar'
2637             );
2638             $new_debar_dt = $calendar->addDuration( $return_date, $suspension_days );
2639         }
2640         else {
2641             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2642         }
2643         return $new_debar_dt;
2644     }
2645     return;
2646 }
2647
2648 sub _debar_user_on_return {
2649     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2650
2651     $return_date //= dt_from_string();
2652
2653     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2654
2655     return unless $new_debar_dt;
2656
2657     Koha::Patron::Debarments::AddUniqueDebarment({
2658         borrowernumber => $borrower->{borrowernumber},
2659         expiration     => $new_debar_dt->ymd(),
2660         type           => 'SUSPENSION',
2661     });
2662     # if borrower was already debarred but does not get an extra debarment
2663     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2664     my ($new_debarment_str, $is_a_reminder);
2665     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2666         $is_a_reminder = 1;
2667         $new_debarment_str = $borrower->{debarred};
2668     } else {
2669         $new_debarment_str = $new_debar_dt->ymd();
2670     }
2671     # FIXME Should return a DateTime object
2672     return $new_debarment_str, $is_a_reminder;
2673 }
2674
2675 =head2 _FixOverduesOnReturn
2676
2677    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2678
2679 C<$borrowernumber> borrowernumber
2680
2681 C<$itemnumber> itemnumber
2682
2683 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2684
2685 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2686
2687 Internal function
2688
2689 =cut
2690
2691 sub _FixOverduesOnReturn {
2692     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2693     unless( $borrowernumber ) {
2694         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2695         return;
2696     }
2697     unless( $item ) {
2698         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2699         return;
2700     }
2701     unless( $status ) {
2702         warn "_FixOverduesOnReturn() not supplied valid status";
2703         return;
2704     }
2705
2706     my $schema = Koha::Database->schema;
2707
2708     my $result = $schema->txn_do(
2709         sub {
2710             # check for overdue fine
2711             my $accountlines = Koha::Account::Lines->search(
2712                 {
2713                     borrowernumber  => $borrowernumber,
2714                     itemnumber      => $item,
2715                     debit_type_code => 'OVERDUE',
2716                     status          => 'UNRETURNED'
2717                 }
2718             );
2719             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2720
2721             my $accountline = $accountlines->next;
2722             my $payments = $accountline->credits;
2723
2724             my $amountoutstanding = $accountline->amountoutstanding;
2725             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2726                 $accountline->delete;
2727                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2728             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2729                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2730                 my $credit = $account->add_credit(
2731                     {
2732                         amount     => $amountoutstanding,
2733                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2734                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2735                         interface  => C4::Context->interface,
2736                         type       => 'FORGIVEN',
2737                         item_id    => $item
2738                     }
2739                 );
2740
2741                 $credit->apply({ debits => [ $accountline ] });
2742
2743                 if (C4::Context->preference("FinesLog")) {
2744                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2745                 }
2746             }
2747
2748             $accountline->status($status);
2749             return $accountline->store();
2750         }
2751     );
2752
2753     return $result;
2754 }
2755
2756 =head2 _GetCircControlBranch
2757
2758    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2759
2760 Internal function :
2761
2762 Return the library code to be used to determine which circulation
2763 policy applies to a transaction.  Looks up the CircControl and
2764 HomeOrHoldingBranch system preferences.
2765
2766 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2767
2768 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2769
2770 =cut
2771
2772 sub _GetCircControlBranch {
2773     my ($item, $borrower) = @_;
2774     my $circcontrol = C4::Context->preference('CircControl');
2775     my $branch;
2776
2777     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2778         $branch= C4::Context->userenv->{'branch'};
2779     } elsif ($circcontrol eq 'PatronLibrary') {
2780         $branch=$borrower->{branchcode};
2781     } else {
2782         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2783         $branch = $item->{$branchfield};
2784         # default to item home branch if holdingbranch is used
2785         # and is not defined
2786         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2787             $branch = $item->{homebranch};
2788         }
2789     }
2790     return $branch;
2791 }
2792
2793 =head2 GetOpenIssue
2794
2795   $issue = GetOpenIssue( $itemnumber );
2796
2797 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2798
2799 C<$itemnumber> is the item's itemnumber
2800
2801 Returns a hashref
2802
2803 =cut
2804
2805 sub GetOpenIssue {
2806   my ( $itemnumber ) = @_;
2807   return unless $itemnumber;
2808   my $dbh = C4::Context->dbh;
2809   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2810   $sth->execute( $itemnumber );
2811   return $sth->fetchrow_hashref();
2812
2813 }
2814
2815 =head2 GetUpcomingDueIssues
2816
2817   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2818
2819 =cut
2820
2821 sub GetUpcomingDueIssues {
2822     my $params = shift;
2823
2824     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2825     my $dbh = C4::Context->dbh;
2826     my $statement;
2827     $statement = q{
2828         SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2829         FROM issues
2830         LEFT JOIN items USING (itemnumber)
2831         LEFT JOIN branches ON branches.branchcode =
2832     };
2833     $statement .= $params->{'owning_library'} ? " items.homebranch " : " issues.branchcode ";
2834     $statement .= " WHERE returndate is NULL AND TO_DAYS( date_due )-TO_DAYS( NOW() ) BETWEEN 0 AND ?";
2835     my @bind_parameters = ( $params->{'days_in_advance'} );
2836
2837     my $sth = $dbh->prepare( $statement );
2838     $sth->execute( @bind_parameters );
2839     my $upcoming_dues = $sth->fetchall_arrayref({});
2840
2841     return $upcoming_dues;
2842 }
2843
2844 =head2 CanBookBeRenewed
2845
2846   ($ok,$error,$info) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2847
2848 Find out whether a borrowed item may be renewed.
2849
2850 C<$borrowernumber> is the borrower number of the patron who currently
2851 has the item on loan.
2852
2853 C<$itemnumber> is the number of the item to renew.
2854
2855 C<$override_limit>, if supplied with a true value, causes
2856 the limit on the number of times that the loan can be renewed
2857 (as controlled by the item type) to be ignored. Overriding also allows
2858 to renew sooner than "No renewal before" and to manually renew loans
2859 that are automatically renewed.
2860
2861 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2862 item must currently be on loan to the specified borrower; renewals
2863 must be allowed for the item's type; and the borrower must not have
2864 already renewed the loan.
2865     $error will contain the reason the renewal can not proceed
2866     $info will contain a hash of additional info
2867       currently 'soonest_renew_date' if error is 'too soon'
2868
2869 =cut
2870
2871 sub CanBookBeRenewed {
2872     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2873
2874     my $auto_renew = "no";
2875     my $soonest;
2876
2877     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2878     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2879     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2880     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2881
2882     my $patron = $issue->patron or return;
2883
2884     # override_limit will override anything else except on_reserve
2885     unless ( $override_limit ){
2886         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2887         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2888             {
2889                 categorycode => $patron->categorycode,
2890                 itemtype     => $item->effective_itemtype,
2891                 branchcode   => $branchcode,
2892                 rules => [
2893                     'renewalsallowed',
2894                     'lengthunit',
2895                     'unseen_renewals_allowed'
2896                 ]
2897             }
2898         );
2899
2900         return ( 0, "too_many" )
2901           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals_count;
2902
2903         return ( 0, "too_unseen" )
2904           if C4::Context->preference('UnseenRenewals') &&
2905             looks_like_number($issuing_rule->{unseen_renewals_allowed}) &&
2906             $issuing_rule->{unseen_renewals_allowed} <= $issue->unseen_renewals;
2907
2908         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2909         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2910         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2911         my $restricted  = $patron->is_debarred;
2912         my $hasoverdues = $patron->has_overdues;
2913
2914         if ( $restricted and $restrictionblockrenewing ) {
2915             return ( 0, 'restriction');
2916         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2917             return ( 0, 'overdue');
2918         }
2919
2920         ( $auto_renew, $soonest ) = _CanBookBeAutoRenewed({
2921             patron     => $patron,
2922             item       => $item,
2923             branchcode => $branchcode,
2924             issue      => $issue
2925         });
2926         return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'auto_too_soon' && $cron;
2927         # cron wants 'too_soon' over 'on_reserve' for performance and to avoid
2928         # extra notices being sent. Cron also implies no override
2929         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_account_expired';
2930         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_late';
2931         return ( 0, $auto_renew  ) if $auto_renew =~ 'auto_too_much_oweing';
2932     }
2933
2934     if ( C4::Context->preference('UseRecalls') ) {
2935         my $recall = undef;
2936         $recall = $item->check_recalls if $item->can_be_waiting_recall;
2937         if ( defined $recall ) {
2938             if ( $recall->item_level ) {
2939                 # item-level recall. check if this item is the recalled item, otherwise renewal will be allowed
2940                 return ( 0, 'recalled' ) if ( $recall->item_id == $item->itemnumber );
2941             } else {
2942                 # biblio-level recall, so only disallow renewal if the biblio-level recall has been fulfilled by a different item
2943                 return ( 0, 'recalled' ) unless ( $recall->waiting );
2944             }
2945         }
2946     }
2947
2948     # Note: possible_reserves will contain all title level holds on this bib and item level
2949     # holds on the checked out item
2950     my ( $resfound, $resrec, $possible_reserves ) = C4::Reserves::CheckReserves($itemnumber);
2951
2952     # If next hold is non priority, then check if any hold with priority (non_priority = 0) exists for the same biblionumber.
2953     if ( $resfound && $resrec->{non_priority} ) {
2954         $resfound = Koha::Holds->search(
2955             { biblionumber => $resrec->{biblionumber}, non_priority => 0 } )
2956           ->count > 0;
2957     }
2958
2959
2960
2961     # This item can fill one or more unfilled reserve, can those unfilled reserves
2962     # all be filled by other available items?
2963     if ( $resfound
2964         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2965     {
2966         my $item_holds = Koha::Holds->search( { itemnumber => $itemnumber, found => undef } )->count();
2967         if ($item_holds) {
2968             # There is an item level hold on this item, no other item can fill the hold
2969             $resfound = 1;
2970         }
2971         else {
2972
2973             # Get all other items that could possibly fill reserves
2974             # FIXME We could join reserves (or more tables) here to eliminate some checks later
2975             my $items = Koha::Items->search({
2976                 biblionumber => $resrec->{biblionumber},
2977                 onloan       => undef,
2978                 notforloan   => 0,
2979                 -not         => { itemnumber => $itemnumber }
2980             });
2981             my $item_count = $items->count();
2982
2983             # Get all other reserves that could have been filled by this item
2984             my @borrowernumbers = map { $_->{borrowernumber} } @$possible_reserves;
2985             # Note: fetching the patrons in this manner means that a patron with 2 holds will
2986             # not block renewal if one reserve can be satisfied i.e. each patron is checked once
2987             my $patrons = Koha::Patrons->search({
2988                 borrowernumber => { -in => \@borrowernumbers }
2989             });
2990             my $patron_count = $patrons->count();
2991
2992             return ( 0, "on_reserve" ) if ($patron_count > $item_count);
2993             # We cannot possibly fill all reserves if we don't have enough items
2994
2995             # If we can fill each hold that has been found with the available items on the record
2996             # then the patron can renew. If we cannot, they cannot renew.
2997             # FIXME This code does not check whether the item we are renewing can fill
2998             # any of the existing reserves.
2999             my $reservable = 0;
3000             my %matched_items;
3001             my $seen = 0;
3002             PATRON: while ( my $patron = $patrons->next ) {
3003                 # If there is a reserve that cannot be filled we are done
3004                 return ( 0, "on_reserve" ) if ( $seen > $reservable );
3005                 my $items_any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $item->biblionumber, patron => $patron });
3006                 while ( my $other_item = $items->next ) {
3007                     next if defined $matched_items{$other_item->itemnumber};
3008                     next if IsItemOnHoldAndFound( $other_item->itemnumber );
3009                     next unless IsAvailableForItemLevelRequest($other_item, $patron, undef, $items_any_available);
3010                     next unless CanItemBeReserved($patron,$other_item,undef,{ignore_hold_counts=>1})->{status} eq 'OK';
3011                     # NOTE: At checkin we call 'CheckReserves' which checks hold 'policy'
3012                     # CanItemBeReserved checks 'rules' and 'policies' which means
3013                     # items will fill holds at checkin that are rejected here
3014                     $reservable++;
3015                     if ($reservable >= $patron_count) {
3016                         $resfound = 0;
3017                         last PATRON;
3018                     }
3019                     $matched_items{$other_item->itemnumber} = 1;
3020                     last;
3021                 }
3022                 $items->reset;
3023                 $seen++;
3024             }
3025         }
3026     }
3027
3028     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
3029     return ( 0, $auto_renew, { soonest_renew_date => $soonest } ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
3030     $soonest = GetSoonestRenewDate($borrowernumber, $itemnumber);
3031     if ( $soonest > dt_from_string() ){
3032         return (0, "too_soon", { soonest_renew_date => $soonest } ) unless $override_limit;
3033     }
3034
3035     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
3036
3037     return ( 1, undef );
3038 }
3039
3040 =head2 AddRenewal
3041
3042   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate], [$seen]);
3043
3044 Renews a loan.
3045
3046 C<$borrowernumber> is the borrower number of the patron who currently
3047 has the item.
3048
3049 C<$itemnumber> is the number of the item to renew.
3050
3051 C<$branch> is the library where the renewal took place (if any).
3052            The library that controls the circ policies for the renewal is retrieved from the issues record.
3053
3054 C<$datedue> can be a DateTime object used to set the due date.
3055
3056 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
3057 this parameter is not supplied, lastreneweddate is set to the current date.
3058
3059 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
3060 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
3061 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
3062 syspref)
3063
3064 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
3065 from the book's item type.
3066
3067 C<$seen> is a boolean flag indicating if the item was seen or not during the renewal. This
3068 informs the incrementing of the unseen_renewals column. If this flag is not supplied, we
3069 fallback to a true value
3070
3071 =cut
3072
3073 sub AddRenewal {
3074     my $borrowernumber  = shift;
3075     my $itemnumber      = shift or return;
3076     my $branch          = shift;
3077     my $datedue         = shift;
3078     my $lastreneweddate = shift || dt_from_string();
3079     my $skipfinecalc    = shift;
3080     my $seen            = shift;
3081
3082     # Fallback on a 'seen' renewal
3083     $seen = defined $seen && $seen == 0 ? 0 : 1;
3084
3085     my $item_object   = Koha::Items->find($itemnumber) or return;
3086     my $biblio = $item_object->biblio;
3087     my $issue  = $item_object->checkout;
3088     my $item_unblessed = $item_object->unblessed;
3089
3090     my $dbh = C4::Context->dbh;
3091
3092     return unless $issue;
3093
3094     $borrowernumber ||= $issue->borrowernumber;
3095
3096     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
3097         carp 'Invalid date passed to AddRenewal.';
3098         return;
3099     }
3100
3101     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3102     my $patron_unblessed = $patron->unblessed;
3103
3104     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3105
3106     my $schema = Koha::Database->schema;
3107     $schema->txn_do(sub{
3108
3109         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3110             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3111         }
3112         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3113
3114         # If the due date wasn't specified, calculate it by adding the
3115         # book's loan length to today's date or the current due date
3116         # based on the value of the RenewalPeriodBase syspref.
3117         my $itemtype = $item_object->effective_itemtype;
3118         unless ($datedue) {
3119
3120             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3121                                             dt_from_string( $issue->date_due, 'sql' ) :
3122                                             dt_from_string();
3123             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3124         }
3125
3126         my $fees = Koha::Charges::Fees->new(
3127             {
3128                 patron    => $patron,
3129                 library   => $circ_library,
3130                 item      => $item_object,
3131                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3132                 to_date   => dt_from_string($datedue),
3133             }
3134         );
3135
3136         # Increment the unseen renewals, if appropriate
3137         # We only do so if the syspref is enabled and
3138         # a maximum value has been set in the circ rules
3139         my $unseen_renewals = $issue->unseen_renewals;
3140         if (C4::Context->preference('UnseenRenewals')) {
3141             my $rule = Koha::CirculationRules->get_effective_rule(
3142                 {   categorycode => $patron->categorycode,
3143                     itemtype     => $item_object->effective_itemtype,
3144                     branchcode   => $circ_library->branchcode,
3145                     rule_name    => 'unseen_renewals_allowed'
3146                 }
3147             );
3148             if (!$seen && $rule && looks_like_number($rule->rule_value)) {
3149                 $unseen_renewals++;
3150             } else {
3151                 # If the renewal is seen, unseen should revert to 0
3152                 $unseen_renewals = 0;
3153             }
3154         }
3155
3156         # Update the issues record to have the new due date, and a new count
3157         # of how many times it has been renewed.
3158         my $renews = ( $issue->renewals_count || 0 ) + 1;
3159         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals_count = ?, unseen_renewals = ?, lastreneweddate = ? WHERE issue_id = ?");
3160
3161         eval{
3162             $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $unseen_renewals, $lastreneweddate, $issue->issue_id );
3163         };
3164         if( $sth->err ){
3165             Koha::Exceptions::Checkout::FailedRenewal->throw(
3166                 error => 'Update of issue# ' . $issue->issue_id . ' failed with error: ' . $sth->errstr
3167             );
3168         }
3169
3170         # Update the renewal count on the item, and tell zebra to reindex
3171         $renews = ( $item_object->renewals || 0 ) + 1;
3172         $item_object->renewals($renews);
3173         $item_object->onloan($datedue);
3174         $item_object->store({ log_action => 0 });
3175
3176         # Charge a new rental fee, if applicable
3177         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3178         if ( $charge > 0 ) {
3179             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3180         }
3181
3182         # Charge a new accumulate rental fee, if applicable
3183         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3184         if ( $itemtype_object ) {
3185             my $accumulate_charge = $fees->accumulate_rentalcharge();
3186             if ( $accumulate_charge > 0 ) {
3187                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3188             }
3189             $charge += $accumulate_charge;
3190         }
3191
3192         # Send a renewal slip according to checkout alert preferencei
3193         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3194             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3195             my %conditions        = (
3196                 branchcode   => $branch,
3197                 categorycode => $patron->categorycode,
3198                 item_type    => $itemtype,
3199                 notification => 'CHECKOUT',
3200             );
3201             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3202                 SendCirculationAlert(
3203                     {
3204                         type     => 'RENEWAL',
3205                         item     => $item_unblessed,
3206                         borrower => $patron->unblessed,
3207                         branch   => $branch,
3208                     }
3209                 );
3210             }
3211         }
3212
3213         # Remove any OVERDUES related debarment if the borrower has no overdues
3214         if ( $patron
3215           && $patron->is_debarred
3216           && ! $patron->has_overdues
3217           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3218         ) {
3219             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3220         }
3221
3222         # Add renewal record
3223         my $renewal = Koha::Checkouts::Renewal->new(
3224             {
3225                 checkout_id => $issue->issue_id,
3226                 renewer_id  => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3227                 seen        => $seen,
3228                 interface   => C4::Context->interface
3229             }
3230         )->store();
3231
3232         # Add the renewal to stats
3233         C4::Stats::UpdateStats(
3234             {
3235                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3236                 type           => 'renew',
3237                 amount         => $charge,
3238                 itemnumber     => $itemnumber,
3239                 itemtype       => $itemtype,
3240                 location       => $item_object->location,
3241                 borrowernumber => $borrowernumber,
3242                 ccode          => $item_object->ccode,
3243             }
3244         );
3245
3246         #Log the renewal
3247         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3248
3249         Koha::Plugins->call('after_circ_action', {
3250             action  => 'renewal',
3251             payload => {
3252                 checkout  => $issue->get_from_storage
3253             }
3254         });
3255     });
3256
3257     return $datedue;
3258 }
3259
3260 sub GetRenewCount {
3261     # check renewal status
3262     my ( $bornum, $itemno ) = @_;
3263     my $dbh           = C4::Context->dbh;
3264     my $renewcount    = 0;
3265     my $unseencount    = 0;
3266     my $renewsallowed = 0;
3267     my $unseenallowed = 0;
3268     my $renewsleft    = 0;
3269     my $unseenleft    = 0;
3270
3271     my $patron = Koha::Patrons->find( $bornum );
3272     my $item   = Koha::Items->find($itemno);
3273
3274     return (0, 0, 0, 0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3275
3276     # Look in the issues table for this item, lent to this borrower,
3277     # and not yet returned.
3278
3279     # FIXME - I think this function could be redone to use only one SQL call.
3280     my $sth = $dbh->prepare(
3281         "select * from issues
3282                                 where (borrowernumber = ?)
3283                                 and (itemnumber = ?)"
3284     );
3285     $sth->execute( $bornum, $itemno );
3286     my $data = $sth->fetchrow_hashref;
3287     $renewcount = $data->{'renewals_count'} if $data->{'renewals_count'};
3288     $unseencount = $data->{'unseen_renewals'} if $data->{'unseen_renewals'};
3289     # $item and $borrower should be calculated
3290     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3291
3292     my $rules = Koha::CirculationRules->get_effective_rules(
3293         {
3294             categorycode => $patron->categorycode,
3295             itemtype     => $item->effective_itemtype,
3296             branchcode   => $branchcode,
3297             rules        => [ 'renewalsallowed', 'unseen_renewals_allowed' ]
3298         }
3299     );
3300     $renewsallowed = $rules ? $rules->{renewalsallowed} : 0;
3301     $unseenallowed = $rules->{unseen_renewals_allowed} ?
3302         $rules->{unseen_renewals_allowed} :
3303         0;
3304     $renewsleft    = $renewsallowed - $renewcount;
3305     $unseenleft    = $unseenallowed - $unseencount;
3306     if($renewsleft < 0){ $renewsleft = 0; }
3307     if($unseenleft < 0){ $unseenleft = 0; }
3308     return (
3309         $renewcount,
3310         $renewsallowed,
3311         $renewsleft,
3312         $unseencount,
3313         $unseenallowed,
3314         $unseenleft
3315     );
3316 }
3317
3318 =head2 GetSoonestRenewDate
3319
3320   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3321
3322 Find out the soonest possible renew date of a borrowed item.
3323
3324 C<$borrowernumber> is the borrower number of the patron who currently
3325 has the item on loan.
3326
3327 C<$itemnumber> is the number of the item to renew.
3328
3329 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3330 renew date, based on the value "No renewal before" of the applicable
3331 issuing rule. Returns the current date if the item can already be
3332 renewed, and returns undefined if the borrower, loan, or item
3333 cannot be found.
3334
3335 =cut
3336
3337 sub GetSoonestRenewDate {
3338     my ( $borrowernumber, $itemnumber ) = @_;
3339
3340     my $dbh = C4::Context->dbh;
3341
3342     my $item      = Koha::Items->find($itemnumber)      or return;
3343     my $itemissue = $item->checkout or return;
3344
3345     $borrowernumber ||= $itemissue->borrowernumber;
3346     my $patron = Koha::Patrons->find( $borrowernumber )
3347       or return;
3348
3349     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3350     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3351         {   categorycode => $patron->categorycode,
3352             itemtype     => $item->effective_itemtype,
3353             branchcode   => $branchcode,
3354             rules => [
3355                 'norenewalbefore',
3356                 'lengthunit',
3357             ]
3358         }
3359     );
3360
3361     my $now = dt_from_string;
3362
3363     if ( defined $issuing_rule->{norenewalbefore}
3364         and $issuing_rule->{norenewalbefore} ne "" )
3365     {
3366         my $soonestrenewal =
3367           dt_from_string( $itemissue->date_due )->subtract(
3368             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3369
3370         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3371             and $issuing_rule->{lengthunit} eq 'days' )
3372         {
3373             $soonestrenewal->truncate( to => 'day' );
3374         }
3375         return $soonestrenewal if $now < $soonestrenewal;
3376     } elsif ( $itemissue->auto_renew && $patron->autorenew_checkouts ) {
3377         # Checkouts with auto-renewing fall back to due date
3378         my $soonestrenewal = dt_from_string( $itemissue->date_due );
3379         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3380             and $issuing_rule->{lengthunit} eq 'days' )
3381         {
3382             $soonestrenewal->truncate( to => 'day' );
3383         }
3384         return $soonestrenewal;
3385     }
3386     return $now;
3387 }
3388
3389 =head2 GetLatestAutoRenewDate
3390
3391   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3392
3393 Find out the latest possible auto renew date of a borrowed item.
3394
3395 C<$borrowernumber> is the borrower number of the patron who currently
3396 has the item on loan.
3397
3398 C<$itemnumber> is the number of the item to renew.
3399
3400 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3401 auto renew date, based on the value "No auto renewal after" and the "No auto
3402 renewal after (hard limit) of the applicable issuing rule.
3403 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3404 or item cannot be found.
3405
3406 =cut
3407
3408 sub GetLatestAutoRenewDate {
3409     my ( $borrowernumber, $itemnumber ) = @_;
3410
3411     my $dbh = C4::Context->dbh;
3412
3413     my $item      = Koha::Items->find($itemnumber)  or return;
3414     my $itemissue = $item->checkout                 or return;
3415
3416     $borrowernumber ||= $itemissue->borrowernumber;
3417     my $patron = Koha::Patrons->find( $borrowernumber )
3418       or return;
3419
3420     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3421     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3422         {
3423             categorycode => $patron->categorycode,
3424             itemtype     => $item->effective_itemtype,
3425             branchcode   => $branchcode,
3426             rules => [
3427                 'no_auto_renewal_after',
3428                 'no_auto_renewal_after_hard_limit',
3429                 'lengthunit',
3430             ]
3431         }
3432     );
3433
3434     return unless $circulation_rules;
3435     return
3436       if ( not $circulation_rules->{no_auto_renewal_after}
3437             or $circulation_rules->{no_auto_renewal_after} eq '' )
3438       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3439              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3440
3441     my $maximum_renewal_date;
3442     if ( $circulation_rules->{no_auto_renewal_after} ) {
3443         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3444         $maximum_renewal_date->add(
3445             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3446         );
3447     }
3448
3449     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3450         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3451         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3452     }
3453     return $maximum_renewal_date;
3454 }
3455
3456
3457 =head2 GetIssuingCharges
3458
3459   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3460
3461 Calculate how much it would cost for a given patron to borrow a given
3462 item, including any applicable discounts.
3463
3464 C<$itemnumber> is the item number of item the patron wishes to borrow.
3465
3466 C<$borrowernumber> is the patron's borrower number.
3467
3468 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3469 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3470 if it's a video).
3471
3472 =cut
3473
3474 sub GetIssuingCharges {
3475
3476     # calculate charges due
3477     my ( $itemnumber, $borrowernumber ) = @_;
3478     my $charge = 0;
3479     my $dbh    = C4::Context->dbh;
3480     my $item_type;
3481
3482     # Get the book's item type and rental charge (via its biblioitem).
3483     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3484         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3485     $charge_query .= (C4::Context->preference('item-level_itypes'))
3486         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3487         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3488
3489     $charge_query .= ' WHERE items.itemnumber =?';
3490
3491     my $sth = $dbh->prepare($charge_query);
3492     $sth->execute($itemnumber);
3493     if ( my $item_data = $sth->fetchrow_hashref ) {
3494         $item_type = $item_data->{itemtype};
3495         $charge    = $item_data->{rentalcharge};
3496         if ($charge) {
3497             # FIXME This should follow CircControl
3498             my $branch = C4::Context::mybranch();
3499             my $patron = Koha::Patrons->find( $borrowernumber );
3500             my $discount = Koha::CirculationRules->get_effective_rule({
3501                 categorycode => $patron->categorycode,
3502                 branchcode   => $branch,
3503                 itemtype     => $item_type,
3504                 rule_name    => 'rentaldiscount'
3505             });
3506             if ($discount) {
3507                 $charge = ( $charge * ( 100 - $discount->rule_value ) ) / 100;
3508             }
3509             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3510         }
3511     }
3512
3513     return ( $charge, $item_type );
3514 }
3515
3516 =head2 AddIssuingCharge
3517
3518   &AddIssuingCharge( $checkout, $charge, $type )
3519
3520 =cut
3521
3522 sub AddIssuingCharge {
3523     my ( $checkout, $charge, $type ) = @_;
3524
3525     # FIXME What if checkout does not exist?
3526
3527     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3528     my $accountline = $account->add_debit(
3529         {
3530             amount      => $charge,
3531             note        => undef,
3532             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3533             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3534             interface   => C4::Context->interface,
3535             type        => $type,
3536             item_id     => $checkout->itemnumber,
3537             issue_id    => $checkout->issue_id,
3538         }
3539     );
3540 }
3541
3542 =head2 GetTransfers
3543
3544   GetTransfers($itemnumber);
3545
3546 =cut
3547
3548 sub GetTransfers {
3549     my ($itemnumber) = @_;
3550
3551     my $dbh = C4::Context->dbh;
3552
3553     my $query = '
3554         SELECT datesent,
3555                frombranch,
3556                tobranch,
3557                branchtransfer_id,
3558                daterequested,
3559                reason
3560         FROM branchtransfers
3561         WHERE itemnumber = ?
3562           AND datearrived IS NULL
3563           AND datecancelled IS NULL
3564         ';
3565     my $sth = $dbh->prepare($query);
3566     $sth->execute($itemnumber);
3567     my @row = $sth->fetchrow_array();
3568     return @row;
3569 }
3570
3571 =head2 GetTransfersFromTo
3572
3573   @results = GetTransfersFromTo($frombranch,$tobranch);
3574
3575 Returns the list of pending transfers between $from and $to branch
3576
3577 =cut
3578
3579 sub GetTransfersFromTo {
3580     my ( $frombranch, $tobranch ) = @_;
3581     return unless ( $frombranch && $tobranch );
3582     my $dbh   = C4::Context->dbh;
3583     my $query = "
3584         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3585         FROM   branchtransfers
3586         WHERE  frombranch=?
3587           AND  tobranch=?
3588           AND datecancelled IS NULL
3589           AND datesent IS NOT NULL
3590           AND datearrived IS NULL
3591     ";
3592     my $sth = $dbh->prepare($query);
3593     $sth->execute( $frombranch, $tobranch );
3594     my @gettransfers;
3595
3596     while ( my $data = $sth->fetchrow_hashref ) {
3597         push @gettransfers, $data;
3598     }
3599     return (@gettransfers);
3600 }
3601
3602 =head2 SendCirculationAlert
3603
3604 Send out a C<check-in> or C<checkout> alert using the messaging system.
3605
3606 B<Parameters>:
3607
3608 =over 4
3609
3610 =item type
3611
3612 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3613
3614 =item item
3615
3616 Hashref of information about the item being checked in or out.
3617
3618 =item borrower
3619
3620 Hashref of information about the borrower of the item.
3621
3622 =item branch
3623
3624 The branchcode from where the checkout or check-in took place.
3625
3626 =back
3627
3628 B<Example>:
3629
3630     SendCirculationAlert({
3631         type     => 'CHECKOUT',
3632         item     => $item,
3633         borrower => $borrower,
3634         branch   => $branch,
3635     });
3636
3637 =cut
3638
3639 sub SendCirculationAlert {
3640     my ($opts) = @_;
3641     my ($type, $item, $borrower, $branch, $issue) =
3642         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch}, $opts->{issue});
3643     my %message_name = (
3644         CHECKIN  => 'Item_Check_in',
3645         CHECKOUT => 'Item_Checkout',
3646         RENEWAL  => 'Item_Checkout',
3647     );
3648     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3649         borrowernumber => $borrower->{borrowernumber},
3650         message_name   => $message_name{$type},
3651     });
3652
3653
3654     my $tables = {
3655         items => $item->{itemnumber},
3656         biblio      => $item->{biblionumber},
3657         biblioitems => $item->{biblionumber},
3658         borrowers   => $borrower,
3659         branches    => $branch,
3660     };
3661
3662     # TODO: Currently, we need to pass an issue_id as identifier for old_issues, but still an itemnumber for issues.
3663     # See C4::Letters:: _parseletter_sth
3664     if( $type eq 'CHECKIN' ){
3665         $tables->{old_issues} = $issue->issue_id;
3666     } else {
3667         $tables->{issues} = $item->{itemnumber};
3668     }
3669
3670     my $schema = Koha::Database->new->schema;
3671     my @transports = keys %{ $borrower_preferences->{transports} };
3672
3673     # From the MySQL doc:
3674     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3675     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3676     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3677     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3678
3679     for my $mtt (@transports) {
3680         my $letter =  C4::Letters::GetPreparedLetter (
3681             module => 'circulation',
3682             letter_code => $type,
3683             branchcode => $branch,
3684             message_transport_type => $mtt,
3685             lang => $borrower->{lang},
3686             tables => $tables,
3687         ) or next;
3688
3689         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3690         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3691         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3692         unless ( $message ) {
3693             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3694             C4::Message->enqueue($letter, $borrower, $mtt);
3695         } else {
3696             $message->append($letter);
3697             $message->update;
3698         }
3699         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3700     }
3701
3702     return;
3703 }
3704
3705 =head2 updateWrongTransfer
3706
3707   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3708
3709 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3710
3711 =cut
3712
3713 sub updateWrongTransfer {
3714         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3715
3716     # first step: cancel the original transfer
3717     my $item = Koha::Items->find($itemNumber);
3718     my $transfer = $item->get_transfer;
3719     $transfer->set({ datecancelled => dt_from_string, cancellation_reason => 'WrongTransfer' })->store();
3720
3721     # second step: create a new transfer to the right location
3722     my $new_transfer = $item->request_transfer(
3723         {
3724             to            => $transfer->to_library,
3725             reason        => $transfer->reason,
3726             comment       => $transfer->comments,
3727             ignore_limits => 1,
3728             enqueue       => 1
3729         }
3730     );
3731
3732     return $new_transfer;
3733 }
3734
3735 =head2 CalcDateDue
3736
3737 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3738
3739 this function calculates the due date given the start date and configured circulation rules,
3740 checking against the holidays calendar as per the daysmode circulation rule.
3741 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3742 C<$itemtype>  = itemtype code of item in question
3743 C<$branch>  = location whose calendar to use
3744 C<$borrower> = Borrower object
3745 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3746
3747 =cut
3748
3749 sub CalcDateDue {
3750     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3751
3752     $isrenewal ||= 0;
3753
3754     # loanlength now a href
3755     my $loanlength =
3756             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3757
3758     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} and $loanlength->{renewalperiod} ne q{} )
3759             ? qq{renewalperiod}
3760             : qq{issuelength};
3761
3762     my $datedue;
3763     if ( $startdate ) {
3764         if (ref $startdate ne 'DateTime' ) {
3765             $datedue = dt_from_string($datedue);
3766         } else {
3767             $datedue = $startdate->clone;
3768         }
3769     } else {
3770         $datedue = dt_from_string()->truncate( to => 'minute' );
3771     }
3772
3773
3774     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3775         {
3776             categorycode => $borrower->{categorycode},
3777             itemtype     => $itemtype,
3778             branchcode   => $branch,
3779         }
3780     );
3781
3782     # calculate the datedue as normal
3783     if ( $daysmode eq 'Days' )
3784     {    # ignoring calendar
3785         if ( $loanlength->{lengthunit} eq 'hours' ) {
3786             $datedue->add( hours => $loanlength->{$length_key} );
3787         } else {    # days
3788             $datedue->add( days => $loanlength->{$length_key} );
3789             $datedue->set_hour(23);
3790             $datedue->set_minute(59);
3791         }
3792     } else {
3793         my $dur;
3794         if ($loanlength->{lengthunit} eq 'hours') {
3795             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3796         }
3797         else { # days
3798             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3799         }
3800         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3801         $datedue = $calendar->addDuration( $datedue, $dur, $loanlength->{lengthunit} );
3802         if ($loanlength->{lengthunit} eq 'days') {
3803             $datedue->set_hour(23);
3804             $datedue->set_minute(59);
3805         }
3806     }
3807
3808     # if Hard Due Dates are used, retrieve them and apply as necessary
3809     my ( $hardduedate, $hardduedatecompare ) =
3810       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3811     if ($hardduedate) {    # hardduedates are currently dates
3812         $hardduedate->truncate( to => 'minute' );
3813         $hardduedate->set_hour(23);
3814         $hardduedate->set_minute(59);
3815         my $cmp = DateTime->compare( $hardduedate, $datedue );
3816
3817 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3818 # if the calculated date is before the 'after' Hard Due Date (floor), override
3819 # if the hard due date is set to 'exactly', overrride
3820         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3821             $datedue = $hardduedate->clone;
3822         }
3823
3824         # in all other cases, keep the date due as it is
3825
3826     }
3827
3828     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3829     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3830         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3831         if( $expiry_dt ) { #skip empty expiry date..
3832             $expiry_dt->set( hour => 23, minute => 59);
3833             my $d1= $datedue->clone->set_time_zone('floating');
3834             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3835                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3836             }
3837         }
3838         if ( $daysmode ne 'Days' ) {
3839           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3840           if ( $calendar->is_holiday($datedue) ) {
3841               # Don't return on a closed day
3842               $datedue = $calendar->prev_open_days( $datedue, 1 );
3843           }
3844         }
3845     }
3846
3847     return $datedue;
3848 }
3849
3850
3851 sub CheckValidBarcode{
3852 my ($barcode) = @_;
3853 my $dbh = C4::Context->dbh;
3854 my $query=qq|SELECT count(*)
3855              FROM items
3856              WHERE barcode=?
3857             |;
3858 my $sth = $dbh->prepare($query);
3859 $sth->execute($barcode);
3860 my $exist=$sth->fetchrow ;
3861 return $exist;
3862 }
3863
3864 =head2 IsBranchTransferAllowed
3865
3866   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3867
3868 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3869
3870 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3871 Koha::Item->can_be_transferred.
3872
3873 =cut
3874
3875 sub IsBranchTransferAllowed {
3876         my ( $toBranch, $fromBranch, $code ) = @_;
3877
3878         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3879
3880         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3881         my $dbh = C4::Context->dbh;
3882
3883         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3884         $sth->execute( $toBranch, $fromBranch, $code );
3885         my $limit = $sth->fetchrow_hashref();
3886
3887         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3888         if ( $limit->{'limitId'} ) {
3889                 return 0;
3890         } else {
3891                 return 1;
3892         }
3893 }
3894
3895 =head2 CreateBranchTransferLimit
3896
3897   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3898
3899 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3900
3901 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3902
3903 =cut
3904
3905 sub CreateBranchTransferLimit {
3906    my ( $toBranch, $fromBranch, $code ) = @_;
3907    return unless defined($toBranch) && defined($fromBranch);
3908    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3909
3910    my $dbh = C4::Context->dbh;
3911
3912    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3913    return $sth->execute( $code, $toBranch, $fromBranch );
3914 }
3915
3916 =head2 DeleteBranchTransferLimits
3917
3918     my $result = DeleteBranchTransferLimits($frombranch);
3919
3920 Deletes all the library transfer limits for one library.  Returns the
3921 number of limits deleted, 0e0 if no limits were deleted, or undef if
3922 no arguments are supplied.
3923
3924 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3925     fromBranch => $fromBranch
3926     })->delete.
3927
3928 =cut
3929
3930 sub DeleteBranchTransferLimits {
3931     my $branch = shift;
3932     return unless defined $branch;
3933     my $dbh    = C4::Context->dbh;
3934     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3935     return $sth->execute($branch);
3936 }
3937
3938 sub ReturnLostItem{
3939     my ( $borrowernumber, $itemnum ) = @_;
3940     MarkIssueReturned( $borrowernumber, $itemnum );
3941 }
3942
3943 =head2 LostItem
3944
3945   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3946
3947 The final optional parameter, C<$params>, expected to contain
3948 'skip_record_index' key, which relayed down to Koha::Item/store,
3949 there it prevents calling of ModZebra index_records,
3950 which takes most of the time in batch adds/deletes: index_records better
3951 to be called later in C<additem.pl> after the whole loop.
3952
3953 $params:
3954     skip_record_index => 1|0
3955
3956 =cut
3957
3958 sub LostItem{
3959     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3960
3961     unless ( $mark_lost_from ) {
3962         # Temporary check to avoid regressions
3963         die q|LostItem called without $mark_lost_from, check the API.|;
3964     }
3965
3966     my $mark_returned;
3967     if ( $force_mark_returned ) {
3968         $mark_returned = 1;
3969     } else {
3970         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3971         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3972     }
3973
3974     my $dbh = C4::Context->dbh();
3975     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3976                            FROM issues
3977                            JOIN items USING (itemnumber)
3978                            JOIN biblio USING (biblionumber)
3979                            WHERE issues.itemnumber=?");
3980     $sth->execute($itemnumber);
3981     my $issues=$sth->fetchrow_hashref();
3982
3983     # If a borrower lost the item, add a replacement cost to the their record
3984     if ( my $borrowernumber = $issues->{borrowernumber} ){
3985         my $patron = Koha::Patrons->find( $borrowernumber );
3986
3987         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3988         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3989
3990         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3991             C4::Accounts::chargelostitem(
3992                 $borrowernumber,
3993                 $itemnumber,
3994                 $issues->{'replacementprice'},
3995                 sprintf( "%s %s %s",
3996                     $issues->{'title'}          || q{},
3997                     $issues->{'barcode'}        || q{},
3998                     $issues->{'itemcallnumber'} || q{},
3999                 ),
4000             );
4001             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
4002             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
4003         }
4004
4005         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy,$params) if $mark_returned;
4006     }
4007
4008     # When an item is marked as lost, we should automatically cancel its outstanding transfers.
4009     my $item = Koha::Items->find($itemnumber);
4010     my $transfers = $item->get_transfers;
4011     while (my $transfer = $transfers->next) {
4012         $transfer->cancel({ reason => 'ItemLost', force => 1 });
4013     }
4014 }
4015
4016 sub GetOfflineOperations {
4017     my $dbh = C4::Context->dbh;
4018     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
4019     $sth->execute(C4::Context->userenv->{'branch'});
4020     my $results = $sth->fetchall_arrayref({});
4021     return $results;
4022 }
4023
4024 sub GetOfflineOperation {
4025     my $operationid = shift;
4026     return unless $operationid;
4027     my $dbh = C4::Context->dbh;
4028     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
4029     $sth->execute( $operationid );
4030     return $sth->fetchrow_hashref;
4031 }
4032
4033 sub AddOfflineOperation {
4034     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
4035     my $dbh = C4::Context->dbh;
4036     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
4037     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
4038     return "Added.";
4039 }
4040
4041 sub DeleteOfflineOperation {
4042     my $dbh = C4::Context->dbh;
4043     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
4044     $sth->execute( shift );
4045     return "Deleted.";
4046 }
4047
4048 sub ProcessOfflineOperation {
4049     my $operation = shift;
4050
4051     my $report;
4052     if ( $operation->{action} eq 'return' ) {
4053         $report = ProcessOfflineReturn( $operation );
4054     } elsif ( $operation->{action} eq 'issue' ) {
4055         $report = ProcessOfflineIssue( $operation );
4056     } elsif ( $operation->{action} eq 'payment' ) {
4057         $report = ProcessOfflinePayment( $operation );
4058     }
4059
4060     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
4061
4062     return $report;
4063 }
4064
4065 sub ProcessOfflineReturn {
4066     my $operation = shift;
4067
4068     my $item = Koha::Items->find({barcode => $operation->{barcode}});
4069
4070     if ( $item ) {
4071         my $itemnumber = $item->itemnumber;
4072         my $issue = GetOpenIssue( $itemnumber );
4073         if ( $issue ) {
4074             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
4075             ModDateLastSeen( $itemnumber, $leave_item_lost );
4076             MarkIssueReturned(
4077                 $issue->{borrowernumber},
4078                 $itemnumber,
4079                 $operation->{timestamp},
4080             );
4081             $item->renewals_count(0);
4082             $item->onloan(undef);
4083             $item->store({ log_action => 0 });
4084             return "Success.";
4085         } else {
4086             return "Item not issued.";
4087         }
4088     } else {
4089         return "Item not found.";
4090     }
4091 }
4092
4093 sub ProcessOfflineIssue {
4094     my $operation = shift;
4095
4096     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
4097
4098     if ( $patron ) {
4099         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
4100         unless ($item) {
4101             return "Barcode not found.";
4102         }
4103         my $itemnumber = $item->itemnumber;
4104         my $issue = GetOpenIssue( $itemnumber );
4105
4106         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
4107             MarkIssueReturned(
4108                 $issue->{borrowernumber},
4109                 $itemnumber,
4110                 $operation->{timestamp},
4111             );
4112         }
4113         AddIssue(
4114             $patron->unblessed,
4115             $operation->{'barcode'},
4116             undef,
4117             undef,
4118             $operation->{timestamp},
4119             undef,
4120         );
4121         return "Success.";
4122     } else {
4123         return "Borrower not found.";
4124     }
4125 }
4126
4127 sub ProcessOfflinePayment {
4128     my $operation = shift;
4129
4130     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4131
4132     $patron->account->pay(
4133         {
4134             amount     => $operation->{amount},
4135             library_id => $operation->{branchcode},
4136             interface  => 'koc'
4137         }
4138     );
4139
4140     return "Success.";
4141 }
4142
4143 =head2 TransferSlip
4144
4145   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4146
4147   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4148
4149 =cut
4150
4151 sub TransferSlip {
4152     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4153
4154     my $item =
4155       $itemnumber
4156       ? Koha::Items->find($itemnumber)
4157       : Koha::Items->find( { barcode => $barcode } );
4158
4159     $item or return;
4160
4161     return C4::Letters::GetPreparedLetter (
4162         module => 'circulation',
4163         letter_code => 'TRANSFERSLIP',
4164         branchcode => $branch,
4165         tables => {
4166             'branches'    => $to_branch,
4167             'biblio'      => $item->biblionumber,
4168             'items'       => $item->unblessed,
4169         },
4170     );
4171 }
4172
4173 =head2 CheckIfIssuedToPatron
4174
4175   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4176
4177   Return 1 if any record item is issued to patron, otherwise return 0
4178
4179 =cut
4180
4181 sub CheckIfIssuedToPatron {
4182     my ($borrowernumber, $biblionumber) = @_;
4183
4184     my $dbh = C4::Context->dbh;
4185     my $query = q|
4186         SELECT COUNT(*) FROM issues
4187         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4188         WHERE items.biblionumber = ?
4189         AND issues.borrowernumber = ?
4190     |;
4191     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4192     return 1 if $is_issued;
4193     return;
4194 }
4195
4196 =head2 IsItemIssued
4197
4198   IsItemIssued( $itemnumber )
4199
4200   Return 1 if the item is on loan, otherwise return 0
4201
4202 =cut
4203
4204 sub IsItemIssued {
4205     my $itemnumber = shift;
4206     my $dbh = C4::Context->dbh;
4207     my $sth = $dbh->prepare(q{
4208         SELECT COUNT(*)
4209         FROM issues
4210         WHERE itemnumber = ?
4211     });
4212     $sth->execute($itemnumber);
4213     return $sth->fetchrow;
4214 }
4215
4216 =head2 GetAgeRestriction
4217
4218   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4219   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4220
4221   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4222   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4223
4224 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4225 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4226 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4227          Negative days mean the borrower has gone past the age restriction age.
4228
4229 =cut
4230
4231 sub GetAgeRestriction {
4232     my ($record_restrictions, $borrower) = @_;
4233     my $markers = C4::Context->preference('AgeRestrictionMarker');
4234
4235     return unless $record_restrictions;
4236     # Split $record_restrictions to something like FSK 16 or PEGI 6
4237     my @values = split ' ', uc($record_restrictions);
4238     return unless @values;
4239
4240     # Search first occurrence of one of the markers
4241     my @markers = split /\|/, uc($markers);
4242     return unless @markers;
4243
4244     my $index            = 0;
4245     my $restriction_year = 0;
4246     for my $value (@values) {
4247         $index++;
4248         for my $marker (@markers) {
4249             $marker =~ s/^\s+//;    #remove leading spaces
4250             $marker =~ s/\s+$//;    #remove trailing spaces
4251             if ( $marker eq $value ) {
4252                 if ( $index <= $#values ) {
4253                     $restriction_year += $values[$index];
4254                 }
4255                 last;
4256             }
4257             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4258
4259                 # Perhaps it is something like "K16" (as in Finland)
4260                 $restriction_year += $1;
4261                 last;
4262             }
4263         }
4264         last if ( $restriction_year > 0 );
4265     }
4266
4267     #Check if the borrower is age restricted for this material and for how long.
4268     if ($restriction_year && $borrower) {
4269         if ( $borrower->{'dateofbirth'} ) {
4270             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4271             $alloweddate[0] += $restriction_year;
4272
4273             #Prevent runime eror on leap year (invalid date)
4274             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4275                 $alloweddate[2] = 28;
4276             }
4277
4278             #Get how many days the borrower has to reach the age restriction
4279             my @Today = split /-/, dt_from_string()->ymd();
4280             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4281             #Negative days means the borrower went past the age restriction age
4282             return ($restriction_year, $daysToAgeRestriction);
4283         }
4284     }
4285
4286     return ($restriction_year);
4287 }
4288
4289
4290 =head2 GetPendingOnSiteCheckouts
4291
4292 =cut
4293
4294 sub GetPendingOnSiteCheckouts {
4295     my $dbh = C4::Context->dbh;
4296     return $dbh->selectall_arrayref(q|
4297         SELECT
4298           items.barcode,
4299           items.biblionumber,
4300           items.itemnumber,
4301           items.itemnotes,
4302           items.itemcallnumber,
4303           items.location,
4304           issues.date_due,
4305           issues.branchcode,
4306           issues.date_due < NOW() AS is_overdue,
4307           biblio.author,
4308           biblio.title,
4309           borrowers.firstname,
4310           borrowers.surname,
4311           borrowers.cardnumber,
4312           borrowers.borrowernumber
4313         FROM items
4314         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4315         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4316         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4317         WHERE issues.onsite_checkout = 1
4318     |, { Slice => {} } );
4319 }
4320
4321 sub GetTopIssues {
4322     my ($params) = @_;
4323
4324     my ($count, $branch, $itemtype, $ccode, $newness)
4325         = @$params{qw(count branch itemtype ccode newness)};
4326
4327     my $dbh = C4::Context->dbh;
4328     my $query = q{
4329         SELECT * FROM (
4330         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4331           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4332           i.ccode, SUM(i.issues) AS count
4333         FROM biblio b
4334         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4335         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4336     };
4337
4338     my (@where_strs, @where_args);
4339
4340     if ($branch) {
4341         push @where_strs, 'i.homebranch = ?';
4342         push @where_args, $branch;
4343     }
4344     if ($itemtype) {
4345         if (C4::Context->preference('item-level_itypes')){
4346             push @where_strs, 'i.itype = ?';
4347             push @where_args, $itemtype;
4348         } else {
4349             push @where_strs, 'bi.itemtype = ?';
4350             push @where_args, $itemtype;
4351         }
4352     }
4353     if ($ccode) {
4354         push @where_strs, 'i.ccode = ?';
4355         push @where_args, $ccode;
4356     }
4357     if ($newness) {
4358         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4359         push @where_args, $newness;
4360     }
4361
4362     if (@where_strs) {
4363         $query .= 'WHERE ' . join(' AND ', @where_strs);
4364     }
4365
4366     $query .= q{
4367         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4368           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4369           i.ccode
4370         ORDER BY count DESC
4371     };
4372
4373     $query .= q{ ) xxx WHERE count > 0 };
4374     $count = int($count);
4375     if ($count > 0) {
4376         $query .= "LIMIT $count";
4377     }
4378
4379     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4380
4381     return @$rows;
4382 }
4383
4384 =head2 Internal methods
4385
4386 =cut
4387
4388 sub _CalculateAndUpdateFine {
4389     my ($params) = @_;
4390
4391     my $borrower    = $params->{borrower};
4392     my $item        = $params->{item};
4393     my $issue       = $params->{issue};
4394     my $return_date = $params->{return_date};
4395
4396     unless ($borrower) { carp "No borrower passed in!" && return; }
4397     unless ($item)     { carp "No item passed in!"     && return; }
4398     unless ($issue)    { carp "No issue passed in!"    && return; }
4399
4400     my $datedue = dt_from_string( $issue->date_due );
4401
4402     # we only need to calculate and change the fines if we want to do that on return
4403     # Should be on for hourly loans
4404     my $control = C4::Context->preference('CircControl');
4405     my $control_branchcode =
4406         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4407       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4408       :                                     $issue->branchcode;
4409
4410     my $date_returned = $return_date ? $return_date : dt_from_string();
4411
4412     my ( $amount, $unitcounttotal, $unitcount  ) =
4413       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4414
4415     if ( C4::Context->preference('finesMode') eq 'production' ) {
4416         if ( $amount > 0 ) {
4417             C4::Overdues::UpdateFine({
4418                 issue_id       => $issue->issue_id,
4419                 itemnumber     => $issue->itemnumber,
4420                 borrowernumber => $issue->borrowernumber,
4421                 amount         => $amount,
4422                 due            => $datedue,
4423             });
4424         }
4425         elsif ($return_date) {
4426
4427             # Backdated returns may have fines that shouldn't exist,
4428             # so in this case, we need to drop those fines to 0
4429
4430             C4::Overdues::UpdateFine({
4431                 issue_id       => $issue->issue_id,
4432                 itemnumber     => $issue->itemnumber,
4433                 borrowernumber => $issue->borrowernumber,
4434                 amount         => 0,
4435                 due            => $datedue,
4436             });
4437         }
4438     }
4439 }
4440
4441 sub _CanBookBeAutoRenewed {
4442     my ( $params ) = @_;
4443     my $patron = $params->{patron};
4444     my $item = $params->{item};
4445     my $branchcode = $params->{branchcode};
4446     my $issue = $params->{issue};
4447
4448     return "no" unless $issue->auto_renew && $patron->autorenew_checkouts;
4449
4450     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
4451         {
4452             categorycode => $patron->categorycode,
4453             itemtype     => $item->effective_itemtype,
4454             branchcode   => $branchcode,
4455             rules => [
4456                 'no_auto_renewal_after',
4457                 'no_auto_renewal_after_hard_limit',
4458                 'lengthunit',
4459                 'norenewalbefore',
4460             ]
4461         }
4462     );
4463
4464     if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
4465         return 'auto_account_expired';
4466     }
4467
4468     if ( defined $issuing_rule->{no_auto_renewal_after}
4469             and $issuing_rule->{no_auto_renewal_after} ne "" ) {
4470         # Get issue_date and add no_auto_renewal_after
4471         # If this is greater than today, it's too late for renewal.
4472         my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
4473         $maximum_renewal_date->add(
4474             $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
4475         );
4476         my $now = dt_from_string;
4477         if ( $now >= $maximum_renewal_date ) {
4478             return "auto_too_late";
4479         }
4480     }
4481     if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
4482                   and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
4483         # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
4484         if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
4485             return "auto_too_late";
4486         }
4487     }
4488
4489     if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
4490         my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
4491         my $amountoutstanding =
4492           C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
4493           ? $patron->account->balance
4494           : $patron->account->outstanding_debits->total_outstanding;
4495         if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
4496             return "auto_too_much_oweing";
4497         }
4498     }
4499
4500     my $soonest = GetSoonestRenewDate($patron->id, $item->id);
4501     if ( $soonest > dt_from_string() )
4502     {
4503         return ( "auto_too_soon", $soonest );
4504     }
4505
4506     return "ok";
4507 }
4508
4509 sub _item_denied_renewal {
4510     my ($params) = @_;
4511
4512     my $item = $params->{item};
4513     return unless $item;
4514
4515     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4516     return unless $denyingrules;
4517     foreach my $field (keys %$denyingrules) {
4518         my $val = $item->$field;
4519         if( !defined $val) {
4520             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4521                 return 1;
4522             }
4523         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4524            # If the results matches the values in the syspref
4525            # We return true if match found
4526             return 1;
4527         }
4528     }
4529     return 0;
4530 }
4531
4532 1;
4533
4534 __END__
4535
4536 =head1 AUTHOR
4537
4538 Koha Development Team <http://koha-community.org/>
4539
4540 =cut