koha-dev.rot13.org Git - srvgit/blob - C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use Carp;
  22
  23 use C4::Context;
  24 use C4::Members::Messaging;
  25 use C4::Auth qw(checkpw_internal);
  26 use Koha::Patrons;
  27 use Koha::AuthUtils qw(hash_password);
  28 use List::MoreUtils qw( any );
  29 use Net::LDAP;
  30 use Net::LDAP::Filter;
  31
  32 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  33
  34 BEGIN {
  35         require Exporter;
  36         @ISA    = qw(Exporter);
  37         @EXPORT = qw( checkpw_ldap );
  38 }
  39
  40 # Redefine checkpw_ldap:
  41 # connect to LDAP (named or anonymous)
  42 # ~ retrieves $userid from KOHA_CONF mapping
  43 # ~ then compares $password with userPassword
  44 # ~ then gets the LDAP entry
  45 # ~ and calls the memberadd if necessary
  46
  47 sub ldapserver_error {
  48         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  49 }
  50
  51 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  52 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  53 # since Bug 28278 we need to skip id in <ldapserver id="ldapserver"> which generates additional hash level
  54 if ( exists $ldap->{ldapserver} ) {
  55     $ldap = $ldap->{ldapserver}         or die ldapserver_error('id="ldapserver"');
  56 }
  57 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  58 my $base      = $ldap->{base}           or die ldapserver_error('base');
  59 $ldapname     = $ldap->{user}           ;
  60 $ldappassword = $ldap->{pass}           ;
  61 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  62 my @mapkeys = keys %mapping;
  63 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  64 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  65 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  66
  67 my %categorycode_conversions;
  68 my $default_categorycode;
  69 if(defined $ldap->{categorycode_mapping}) {
  70     $default_categorycode = $ldap->{categorycode_mapping}->{default};
  71     foreach my $cat (@{$ldap->{categorycode_mapping}->{categorycode}}) {
  72         $categorycode_conversions{$cat->{value}} = $cat->{content};
  73     }
  74 }
  75
  76 my %config = (
  77     anonymous => defined ($ldap->{anonymous_bind}) ? $ldap->{anonymous_bind} : 1,
  78     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  79        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  80 );
  81
  82 sub description {
  83         my $result = shift or return;
  84         return "LDAP error #" . $result->code
  85                         . ": " . $result->error_name . "\n"
  86                         . "# " . $result->error_text . "\n";
  87 }
  88
  89 sub search_method {
  90     my $db     = shift or return;
  91     my $userid = shift or return;
  92         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  93         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  94         my $search = $db->search(
  95                   base => $base,
  96                 filter => $filter,
  97                 # attrs => ['*'],
  98     );
  99     die "LDAP search failed to return object : " . $search->error if $search->code;
 100
 101         my $count = $search->count;
 102         if ($search->code > 0) {
 103                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
 104                 return 0;
 105         }
 106     if ($count == 0) {
 107         warn sprintf("LDAP Auth rejected : search with filter '%s' returns no hit\n", $filter->as_string);
 108         return 0;
 109     }
 110     return $search;
 111 }
 112
 113 sub checkpw_ldap {
 114     my ($dbh, $userid, $password) = @_;
 115     my @hosts = split(',', $prefhost);
 116     my $db = Net::LDAP->new(\@hosts);
 117     unless ( $db ) {
 118         warn "LDAP connexion failed";
 119         return 0;
 120     }
 121
 122         #$debug and $db->debug(5);
 123     my $userldapentry;
 124
 125     # first, LDAP authentication
 126     if ( $ldap->{auth_by_bind} ) {
 127         my $principal_name;
 128         if ( $config{anonymous} ) {
 129
 130             # Perform an anonymous bind
 131             my $res = $db->bind;
 132             if ( $res->code ) {
 133                 warn "Anonymous LDAP bind failed: " . description($res);
 134                 return 0;
 135             }
 136
 137             # Perform a LDAP search for the given username
 138             my $search = search_method( $db, $userid )
 139               or return 0;    # warnings are in the sub
 140             $userldapentry = $search->shift_entry;
 141             $principal_name = $userldapentry->dn;
 142         }
 143         else {
 144             $principal_name = $ldap->{principal_name};
 145             if ( $principal_name and $principal_name =~ /\%/ ) {
 146                 $principal_name = sprintf( $principal_name, $userid );
 147             }
 148             else {
 149                 $principal_name = $userid;
 150             }
 151         }
 152
 153         # Perform a LDAP bind for the given username using the matched DN
 154         my $res = $db->bind( $principal_name, password => $password );
 155         if ( $res->code ) {
 156             if ( $config{anonymous} ) {
 157                 # With anonymous_bind approach we can be sure we have found the correct user
 158                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 159                 # or password changed). We should not fall back to local accounts in this case.
 160                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 161                 return -1;
 162             } else {
 163                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 164                 # at all, and thus we should fall back to local logins to restore previous behaviour
 165                 # see bug 12831
 166                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 167                 return 0;
 168             }
 169         }
 170         if ( !defined($userldapentry)
 171             && ( $config{update} or $config{replicate} ) )
 172         {
 173             my $search = search_method( $db, $userid ) or return 0;
 174             $userldapentry = $search->shift_entry;
 175         }
 176     } else {
 177         my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 178                 if ($res->code) {               # connection refused
 179                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 180                         return 0;
 181                 }
 182         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 183         # Handle multiple branches. Same login exists several times in different branches.
 184         my $bind_ok = 0;
 185         while (my $entry = $search->shift_entry) {
 186             my $user_ldap_bind_ret = $db->bind($entry->dn, password => $password);
 187             unless ($user_ldap_bind_ret->code) {
 188                 $userldapentry = $entry;
 189                 $bind_ok = 1;
 190                 last;
 191             }
 192         }
 193
 194         unless ($bind_ok) {
 195             warn "LDAP Auth rejected : invalid password for user '$userid'.";
 196             return -1;
 197         }
 198
 199
 200     }
 201
 202     # To get here, LDAP has accepted our user's login attempt.
 203     # But we still have work to do.  See perldoc below for detailed breakdown.
 204
 205     my (%borrower);
 206         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 207
 208     if (( $borrowernumber and $config{update}   ) or
 209         (!$borrowernumber and $config{replicate})   ) {
 210         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 211         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 212     }
 213
 214     if ($borrowernumber) {
 215         if ($config{update}) { # A1, B1
 216             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 217             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 218         } else { # C1, D1
 219             # maybe update just the password?
 220                 return(1, $cardnumber, $local_userid);
 221         }
 222     } elsif ($config{replicate}) { # A2, C2
 223         my @columns = Koha::Patrons->columns;
 224         my $patron = Koha::Patron->new(
 225             {
 226                 map { exists( $borrower{$_} ) ? ( $_ => $borrower{$_} ) : () } @columns
 227             }
 228         )->store;
 229         die "Insert of new patron failed" unless $patron;
 230         $borrowernumber = $patron->borrowernumber;
 231         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 232    } else {
 233         return 0;   # B2, D2
 234     }
 235     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 236         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 237         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 238         while ( my $attribute_type = $attribute_types->next ) {
 239             my $code = $attribute_type->code;
 240             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 241                 next;
 242             }
 243             my $patron = Koha::Patrons->find($borrowernumber);
 244             if ( $patron ) { # Should not be needed, but we are in C4::Auth LDAP...
 245                 eval {
 246                     my $attribute = Koha::Patron::Attribute->new({code => $code, attribute => $borrower{$code}});
 247                     $patron->extended_attributes([$attribute->unblessed]);
 248                 };
 249                 if ($@) { # FIXME Test if Koha::Exceptions::Patron::Attribute::NonRepeatable
 250                     warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 251                 }
 252             }
 253         }
 254     }
 255     return(1, $cardnumber, $userid);
 256 }
 257
 258 # Pass LDAP entry object and local cardnumber (userid).
 259 # Returns borrower hash.
 260 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 261 # Ensure that mandatory fields are correctly filled!
 262 #
 263 sub ldap_entry_2_hash {
 264         my $userldapentry = shift;
 265         my %borrower = ( cardnumber => shift );
 266         my %memberhash;
 267         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 268         if ($debug) {
 269                 foreach (keys %$userldapentry) {
 270                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 271                 }
 272         }
 273         my $x = $userldapentry->{attrs} or return;
 274         foreach (keys %$x) {
 275                 $memberhash{$_} = join ' ', @{$x->{$_}};
 276                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 277         }
 278         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 279                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 280         foreach my $key (keys %mapping) {
 281                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 282                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 283                 unless (defined $data) {
 284             $data = $mapping{$key}->{content} || undef;
 285                 }
 286         $borrower{$key} = $data;
 287         }
 288         $borrower{initials} = $memberhash{initials} ||
 289                 ( substr($borrower{'firstname'},0,1)
 290                 . substr($borrower{ 'surname' },0,1)
 291                 . " ");
 292
 293     # categorycode conversions
 294     if(defined $categorycode_conversions{$borrower{categorycode}}) {
 295         $borrower{categorycode} = $categorycode_conversions{$borrower{categorycode}};
 296     }
 297     elsif($default_categorycode) {
 298         $borrower{categorycode} = $default_categorycode;
 299     }
 300
 301         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 302         my $dbh = C4::Context->dbh;
 303         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 304         $sth->execute( uc($borrower{'categorycode'}) );
 305         unless ( my $row = $sth->fetchrow_hashref ) {
 306                 my $default = $mapping{'categorycode'}->{content};
 307                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 308                 $borrower{'categorycode'} = $default
 309         }
 310
 311         return %borrower;
 312 }
 313
 314 sub exists_local {
 315         my $arg = shift;
 316         my $dbh = C4::Context->dbh;
 317         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 318
 319         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 320         $sth->execute($arg);
 321         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 322         ($sth->rows == 1) and return $sth->fetchrow;
 323
 324         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 325         $sth->execute($arg);
 326         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 327         ($sth->rows == 1) and return $sth->fetchrow;
 328         return 0;
 329 }
 330
 331 # This function performs a password update, given the userid, borrowerid,
 332 # and digested password. It will verify that things are correct and return the
 333 # borrowers cardnumber. The idea is that it is used to keep the local
 334 # passwords in sync with the LDAP passwords.
 335 #
 336 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 337 #
 338 # Note: if the LDAP config has the update_password tag set to a false value,
 339 # then this will not update the password, it will simply return the cardnumber.
 340 sub _do_changepassword {
 341     my ($userid, $borrowerid, $password) = @_;
 342
 343     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 344
 345         # We don't store the password in the database
 346         my $sth = C4::Context->dbh->prepare(
 347             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 348         $sth->execute($borrowerid);
 349         die "Unable to access borrowernumber "
 350             . "with userid=$userid, "
 351             . "borrowernumber=$borrowerid"
 352           if !$sth->rows;
 353         my ($cardnum) = $sth->fetchrow;
 354         $sth = C4::Context->dbh->prepare(
 355             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 356         $sth->execute($borrowerid);
 357         return $cardnum;
 358     }
 359
 360     my $digest = hash_password($password);
 361     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 362     Koha::Patrons->find($borrowerid)->set_password({ password => $password, skip_validation => 1 });
 363
 364     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 365     return $cardnum if $ok;
 366
 367     warn "Password mismatch after update to borrowernumber=$borrowerid";
 368     return;
 369 }
 370
 371 sub update_local {
 372     my $userid     = shift or croak "No userid";
 373     my $password   = shift or croak "No password";
 374     my $borrowerid = shift or croak "No borrowerid";
 375     my $borrower   = shift or croak "No borrower record";
 376
 377     # skip extended patron attributes in 'borrowers' attribute update
 378     my @keys = keys %$borrower;
 379     if (C4::Context->preference('ExtendedPatronAttributes')) {
 380         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 381         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 382         while ( my $attribute_type = $attribute_types->next ) {
 383            my $code = $attribute_type->code;
 384            @keys = grep { $_ ne $code } @keys;
 385            $debug and printf STDERR "ignoring extended patron attribute '%s' in update_local()\n", $code;
 386         }
 387     }
 388
 389     my $dbh = C4::Context->dbh;
 390     my $query = "UPDATE  borrowers\nSET     " .
 391         join(',', map {"$_=?"} @keys) .
 392         "\nWHERE   borrowernumber=? ";
 393     my $sth = $dbh->prepare($query);
 394     if ($debug) {
 395         print STDERR $query, "\n",
 396             join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 397         print STDERR "\nuserid = $userid\n";
 398     }
 399     $sth->execute(
 400         ((map {$borrower->{$_}} @keys), $borrowerid)
 401     );
 402
 403     # MODIFY PASSWORD/LOGIN if password was mapped
 404     _do_changepassword($userid, $borrowerid, $password) if exists( $borrower->{'password'} );
 405 }
 406
 407 1;
 408 __END__
 409
 410 =head1 NAME
 411
 412 C4::Auth - Authenticates Koha users
 413
 414 =head1 SYNOPSIS
 415
 416   use C4::Auth_with_ldap;
 417
 418 =head1 LDAP Configuration
 419
 420     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 421         working LDAP servers.
 422         To use it :
 423            * Modify ldapserver element in KOHA_CONF
 424            * Establish field mapping in <mapping> element.
 425
 426         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 427         the username would match the "uid" field, and the password should match the "userpassword" field.
 428
 429         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 430         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 431
 432         mysql> show COLUMNS from borrowers;
 433                 +---------------------+--------------+------+-----+---------+----------------+
 434                 | Field               | Type         | Null | Key | Default | Extra          |
 435                 +---------------------+--------------+------+-----+---------+----------------+
 436                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 437                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 438                 | surname             | mediumtext   | NO   |     | NULL    |                |
 439                 | firstname           | text         | YES  |     | NULL    |                |
 440                 | title               | mediumtext   | YES  |     | NULL    |                |
 441                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 442                 | initials            | text         | YES  |     | NULL    |                |
 443                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 444                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 445                 | address             | mediumtext   | NO   |     | NULL    |                |
 446                 | address2            | text         | YES  |     | NULL    |                |
 447                 | city                | mediumtext   | NO   |     | NULL    |                |
 448                 | state               | mediumtext   | YES  |     | NULL    |                |
 449                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 450                 | country             | text         | YES  |     | NULL    |                |
 451                 | email               | mediumtext   | YES  |     | NULL    |                |
 452                 | phone               | text         | YES  |     | NULL    |                |
 453                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 454                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 455                 | emailpro            | text         | YES  |     | NULL    |                |
 456                 | phonepro            | text         | YES  |     | NULL    |                |
 457                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 458                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 459                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 460                 | B_address2          | text         | YES  |     | NULL    |                |
 461                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 462                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 463                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 464                 | B_country           | text         | YES  |     | NULL    |                |
 465                 | B_email             | text         | YES  |     | NULL    |                |
 466                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 467                 | dateofbirth         | date         | YES  |     | NULL    |                |
 468                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 469                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 470                 | dateenrolled        | date         | YES  |     | NULL    |                |
 471                 | dateexpiry          | date         | YES  |     | NULL    |                |
 472                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 473                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 474                 | debarred            | date         | YES  |     | NULL    |                |
 475                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 476                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 477                 | contactfirstname    | text         | YES  |     | NULL    |                |
 478                 | contacttitle        | text         | YES  |     | NULL    |                |
 479                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 480                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 481                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 482                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 483                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 484                 | password            | varchar(30)  | YES  |     | NULL    |                |
 485                 | flags               | int(11)      | YES  |     | NULL    |                |
 486                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 487                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 488                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 489                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 490                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 491                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 492                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 493                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 494                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 495                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 496                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 497                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 498                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 499                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 500                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 501                 | privacy             | int(11)      | NO   |     | 1       |                |
 502                 +---------------------+--------------+------+-----+---------+----------------+
 503                 66 rows in set (0.00 sec)
 504                 Where Null="NO", the field is required.
 505
 506 =head1 KOHA_CONF and field mapping
 507
 508 Example XML stanza for LDAP configuration in KOHA_CONF.
 509
 510  <config>
 511   ...
 512   <useldapserver>1</useldapserver>
 513   <!-- LDAP SERVER (optional) -->
 514   <ldapserver id="ldapserver">
 515     <hostname>localhost</hostname>
 516     <base>dc=metavore,dc=com</base>
 517     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 518     <pass>metavore</pass>          <!-- password, if not anonymous -->
 519     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 520     <update>1</update>             <!-- update existing users in Koha database -->
 521     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 522                                         password comparison, e.g., to use Active Directory -->
 523     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 524                                             an anonymous bind, even when auth_by_bind is on -->
 525     <principal_name>%s@my_domain.com</principal_name>
 526                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 527                                         Not used with anonymous_bind. -->
 528     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 529                                               synced to the local database -->
 530     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 531       <firstname    is="givenname"      ></firstname>
 532       <surname      is="sn"             ></surname>
 533       <address      is="postaladdress"  ></address>
 534       <city         is="l"              >Athens, OH</city>
 535       <zipcode      is="postalcode"     ></zipcode>
 536       <branchcode   is="branch"         >MAIN</branchcode>
 537       <userid       is="uid"            ></userid>
 538       <password     is="userpassword"   ></password>
 539       <email        is="mail"           ></email>
 540       <categorycode is="employeetype"   >PT</categorycode>
 541       <phone        is="telephonenumber"></phone>
 542     </mapping>
 543   </ldapserver>
 544  </config>
 545
 546 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 547 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 548 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 549 patron).
 550
 551 =head1 CONFIGURATION
 552
 553 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 554 your configuration and the presence of a matching Koha user in your local DB:
 555
 556                          LOCAL_USER
 557  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 558    A1      1       1        1      OK : We're updating them anyway.
 559    A2      1       1        0      OK : We're adding them anyway.
 560    B1      1       0        1      OK : We update them.
 561    B2      1       0        0     FAIL: We cannot add new user.
 562    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 563    C2      0       1        0      OK : We add the new user.
 564    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 565    D2      0       0        0     FAIL: We cannot add new user.
 566
 567 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 568 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 569 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 570
 571 If you choose NOT to update local users, the borrowers table will not be affected at all.
 572 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 573 the local table never contained the LDAP values.
 574
 575 =head2 auth_by_bind
 576
 577 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 578
 579 =head2 principal_name
 580
 581 Provides an optional sprintf-style format for manipulating the userid before the bind.
 582 Even though the userPrincipalName is one intended target, any uniquely identifying
 583 attribute that the server allows to be used for binding could be used.
 584
 585 Currently, principal_name only operates when auth_by_bind is enabled.
 586
 587 =head2 update_password
 588
 589 If this tag is left out or set to a true value, then the user's LDAP password
 590 will be stored (hashed) in the local Koha database. If you don't want this
 591 to happen, then set the value of this to '0'. Note that if passwords are not
 592 stored locally, and the connection to the LDAP system fails, then the users
 593 will not be able to log in at all.
 594
 595 =head2 Active Directory
 596
 597 The auth_by_bind and principal_name settings are recommended for Active Directory.
 598
 599 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 600 we would typically under openldap.  Instead of:
 601
 602     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 603
 604 We might get:
 605
 606     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 607
 608 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 609 in Koha userids.  But the userPrincipalName should be consistent, something like:
 610
 611     userPrincipalName: barnes.7@my_company.com
 612
 613 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 614 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 615 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 616 like this:
 617     <principal_name>%s@core.my_company.com</principal_name>
 618
 619 The user of the previous example, barnes.7, would then attempt to bind as:
 620     barnes.7@core.my_company.com
 621
 622 =head1 SEE ALSO
 623
 624 CGI(3)
 625
 626 Net::LDAP()
 627
 628 XML::Simple()
 629
 630 Digest::MD5(3)
 631
 632 sprintf()
 633
 634 =cut
 635
 636 # For reference, here's an important difference in the data structure we rely on.
 637 # ========================================
 638 # Using attrs instead of {asn}->attributes
 639 # ========================================
 640 #
 641 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 642 #       LDAP key: ->{             cn}->{           sss} = sss
 643 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 644 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 645 #
 646 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 647 #       LDAP key: ->{      givenname}->{Steve} = Steve
 648 #