C4/Auth.pm

   1 package C4::Auth;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22 use Carp qw/croak/;
  23
  24 use Digest::MD5 qw(md5_base64);
  25 use JSON qw/encode_json/;
  26 use URI::Escape;
  27 use CGI::Session;
  28
  29 require Exporter;
  30 use C4::Context;
  31 use C4::Templates;    # to get the template
  32 use C4::Languages;
  33 use C4::Search::History;
  34 use Koha;
  35 use Koha::Caches;
  36 use Koha::AuthUtils qw(get_script_name hash_password);
  37 use Koha::Checkouts;
  38 use Koha::DateUtils qw(dt_from_string);
  39 use Koha::Library::Groups;
  40 use Koha::Libraries;
  41 use Koha::Cash::Registers;
  42 use Koha::Desks;
  43 use Koha::Patrons;
  44 use Koha::Patron::Consents;
  45 use POSIX qw/strftime/;
  46 use List::MoreUtils qw/ any /;
  47 use Encode qw( encode is_utf8);
  48 use C4::Auth_with_shibboleth;
  49 use Net::CIDR;
  50 use C4::Log qw/logaction/;
  51
  52 # use utf8;
  53 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug $ldap $cas $caslogout);
  54
  55 BEGIN {
  56     sub psgi_env { any { /^psgi\./ } keys %ENV }
  57
  58     sub safe_exit {
  59         if   (psgi_env) { die 'psgi:exit' }
  60         else            { exit }
  61     }
  62
  63     C4::Context->set_remote_address;
  64
  65     $debug     = $ENV{DEBUG};
  66     @ISA       = qw(Exporter);
  67     @EXPORT    = qw(&checkauth &get_template_and_user &haspermission &get_user_subpermissions);
  68     @EXPORT_OK = qw(&check_api_auth &get_session &check_cookie_auth &checkpw &checkpw_internal &checkpw_hash
  69       &get_all_subpermissions &get_user_subpermissions track_login_daily &in_iprange
  70     );
  71     %EXPORT_TAGS = ( EditPermissions => [qw(get_all_subpermissions get_user_subpermissions)] );
  72     $ldap      = C4::Context->config('useldapserver') || 0;
  73     $cas       = C4::Context->preference('casAuthentication');
  74     $caslogout = C4::Context->preference('casLogout');
  75     require C4::Auth_with_cas;    # no import
  76
  77     if ($ldap) {
  78         require C4::Auth_with_ldap;
  79         import C4::Auth_with_ldap qw(checkpw_ldap);
  80     }
  81     if ($cas) {
  82         import C4::Auth_with_cas qw(check_api_auth_cas checkpw_cas login_cas logout_cas login_cas_url logout_if_required);
  83     }
  84
  85 }
  86
  87 =head1 NAME
  88
  89 C4::Auth - Authenticates Koha users
  90
  91 =head1 SYNOPSIS
  92
  93   use CGI qw ( -utf8 );
  94   use C4::Auth;
  95   use C4::Output;
  96
  97   my $query = CGI->new;
  98
  99   my ($template, $borrowernumber, $cookie)
 100     = get_template_and_user(
 101         {
 102             template_name   => "opac-main.tt",
 103             query           => $query,
 104       type            => "opac",
 105       authnotrequired => 0,
 106       flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 107   }
 108     );
 109
 110   output_html_with_http_headers $query, $cookie, $template->output;
 111
 112 =head1 DESCRIPTION
 113
 114 The main function of this module is to provide
 115 authentification. However the get_template_and_user function has
 116 been provided so that a users login information is passed along
 117 automatically. This gets loaded into the template.
 118
 119 =head1 FUNCTIONS
 120
 121 =head2 get_template_and_user
 122
 123  my ($template, $borrowernumber, $cookie)
 124      = get_template_and_user(
 125        {
 126          template_name   => "opac-main.tt",
 127          query           => $query,
 128          type            => "opac",
 129          authnotrequired => 0,
 130          flagsrequired   => { catalogue => '*', tools => 'import_patrons' },
 131        }
 132      );
 133
 134 This call passes the C<query>, C<flagsrequired> and C<authnotrequired>
 135 to C<&checkauth> (in this module) to perform authentification.
 136 See C<&checkauth> for an explanation of these parameters.
 137
 138 The C<template_name> is then used to find the correct template for
 139 the page. The authenticated users details are loaded onto the
 140 template in the logged_in_user variable (which is a Koha::Patron object). Also the
 141 C<sessionID> is passed to the template. This can be used in templates
 142 if cookies are disabled. It needs to be put as and input to every
 143 authenticated page.
 144
 145 More information on the C<gettemplate> sub can be found in the
 146 Output.pm module.
 147
 148 =cut
 149
 150 sub get_template_and_user {
 151
 152     my $in = shift;
 153     my ( $user, $cookie, $sessionID, $flags );
 154
 155     # Get shibboleth login attribute
 156     my $shib = C4::Context->config('useshibboleth') && shib_ok();
 157     my $shib_login = $shib ? get_login_shib() : undef;
 158
 159     C4::Context->interface( $in->{type} );
 160
 161     $in->{'authnotrequired'} ||= 0;
 162
 163     # the following call includes a bad template check; might croak
 164     my $template = C4::Templates::gettemplate(
 165         $in->{'template_name'},
 166         $in->{'type'},
 167         $in->{'query'},
 168     );
 169
 170     if ( $in->{'template_name'} !~ m/maintenance/ ) {
 171         ( $user, $cookie, $sessionID, $flags ) = checkauth(
 172             $in->{'query'},
 173             $in->{'authnotrequired'},
 174             $in->{'flagsrequired'},
 175             $in->{'type'},
 176             undef,
 177             $in->{template_name},
 178         );
 179     }
 180
 181     # If we enforce GDPR and the user did not consent, redirect
 182     # Exceptions for consent page itself and SCI/SCO system
 183     if( $in->{type} eq 'opac' && $user &&
 184         $in->{'template_name'} !~ /^(opac-patron-consent|sc[io]\/)/ &&
 185         C4::Context->preference('GDPR_Policy') eq 'Enforced' )
 186     {
 187         my $consent = Koha::Patron::Consents->search({
 188             borrowernumber => getborrowernumber($user),
 189             type => 'GDPR_PROCESSING',
 190             given_on => { '!=', undef },
 191         })->next;
 192         if( !$consent ) {
 193             print $in->{query}->redirect(-uri => '/cgi-bin/koha/opac-patron-consent.pl', -cookie => $cookie);
 194             safe_exit;
 195         }
 196     }
 197
 198     if ( $in->{type} eq 'opac' && $user ) {
 199         my $kick_out;
 200
 201         if (
 202 # If the user logged in is the SCO user and they try to go out of the SCO module,
 203 # log the user out removing the CGISESSID cookie
 204             $in->{template_name} !~ m|sco/| && $in->{template_name} !~ m|errors/errorpage.tt|
 205             && C4::Context->preference('AutoSelfCheckID')
 206             && $user eq C4::Context->preference('AutoSelfCheckID')
 207           )
 208         {
 209             $kick_out = 1;
 210         }
 211         elsif (
 212 # If the user logged in is the SCI user and they try to go out of the SCI module,
 213 # kick them out unless it is SCO with a valid permission
 214 # or they are a superlibrarian
 215                $in->{template_name} !~ m|sci/|
 216             && haspermission( $user, { self_check => 'self_checkin_module' } )
 217             && !(
 218                 $in->{template_name} =~ m|sco/| && haspermission(
 219                     $user, { self_check => 'self_checkout_module' }
 220                 )
 221             )
 222             && $flags && $flags->{superlibrarian} != 1
 223           )
 224         {
 225             $kick_out = 1;
 226         }
 227
 228         if ($kick_out) {
 229             $template = C4::Templates::gettemplate( 'opac-auth.tt', 'opac',
 230                 $in->{query} );
 231             $cookie = $in->{query}->cookie(
 232                 -name     => 'CGISESSID',
 233                 -value    => '',
 234                 -expires  => '',
 235                 -HttpOnly => 1,
 236                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 237             );
 238
 239             $template->param(
 240                 loginprompt => 1,
 241                 script_name => get_script_name(),
 242             );
 243
 244             print $in->{query}->header(
 245                 {
 246                     type              => 'text/html',
 247                     charset           => 'utf-8',
 248                     cookie            => $cookie,
 249                     'X-Frame-Options' => 'SAMEORIGIN'
 250                 }
 251               ),
 252               $template->output;
 253             safe_exit;
 254         }
 255     }
 256
 257     my $borrowernumber;
 258     if ($user) {
 259
 260         # It's possible for $user to be the borrowernumber if they don't have a
 261         # userid defined (and are logging in through some other method, such
 262         # as SSL certs against an email address)
 263         my $patron;
 264         $borrowernumber = getborrowernumber($user) if defined($user);
 265         if ( !defined($borrowernumber) && defined($user) ) {
 266             $patron = Koha::Patrons->find( $user );
 267             if ($patron) {
 268                 $borrowernumber = $user;
 269
 270                 # A bit of a hack, but I don't know there's a nicer way
 271                 # to do it.
 272                 $user = $patron->firstname . ' ' . $patron->surname;
 273             }
 274         } else {
 275             $patron = Koha::Patrons->find( $borrowernumber );
 276             # FIXME What to do if $patron does not exist?
 277         }
 278
 279         # user info
 280         $template->param( loggedinusername   => $user ); # OBSOLETE - Do not reuse this in template, use logged_in_user.userid instead
 281         $template->param( loggedinusernumber => $borrowernumber ); # FIXME Should be replaced with logged_in_user.borrowernumber
 282         $template->param( logged_in_user     => $patron );
 283         $template->param( sessionID          => $sessionID );
 284
 285         if ( $in->{'type'} eq 'opac' ) {
 286             require Koha::Virtualshelves;
 287             my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 288                 {
 289                     borrowernumber => $borrowernumber,
 290                     category       => 1,
 291                 }
 292             );
 293             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 294                 {
 295                     category       => 2,
 296                 }
 297             );
 298             $template->param(
 299                 some_private_shelves => $some_private_shelves,
 300                 some_public_shelves  => $some_public_shelves,
 301             );
 302         }
 303
 304         my $all_perms = get_all_subpermissions();
 305
 306         my @flagroots = qw(circulate catalogue parameters borrowers permissions reserveforothers borrow
 307           editcatalogue updatecharges tools editauthorities serials reports acquisition clubs problem_reports);
 308
 309         # We are going to use the $flags returned by checkauth
 310         # to create the template's parameters that will indicate
 311         # which menus the user can access.
 312         if ( $flags && $flags->{superlibrarian} == 1 ) {
 313             $template->param( CAN_user_circulate        => 1 );
 314             $template->param( CAN_user_catalogue        => 1 );
 315             $template->param( CAN_user_parameters       => 1 );
 316             $template->param( CAN_user_borrowers        => 1 );
 317             $template->param( CAN_user_permissions      => 1 );
 318             $template->param( CAN_user_reserveforothers => 1 );
 319             $template->param( CAN_user_editcatalogue    => 1 );
 320             $template->param( CAN_user_updatecharges    => 1 );
 321             $template->param( CAN_user_acquisition      => 1 );
 322             $template->param( CAN_user_suggestions      => 1 );
 323             $template->param( CAN_user_tools            => 1 );
 324             $template->param( CAN_user_editauthorities  => 1 );
 325             $template->param( CAN_user_serials          => 1 );
 326             $template->param( CAN_user_reports          => 1 );
 327             $template->param( CAN_user_staffaccess      => 1 );
 328             $template->param( CAN_user_coursereserves   => 1 );
 329             $template->param( CAN_user_plugins          => 1 );
 330             $template->param( CAN_user_lists            => 1 );
 331             $template->param( CAN_user_clubs            => 1 );
 332             $template->param( CAN_user_ill              => 1 );
 333             $template->param( CAN_user_stockrotation    => 1 );
 334             $template->param( CAN_user_cash_management  => 1 );
 335             $template->param( CAN_user_problem_reports  => 1 );
 336
 337             foreach my $module ( keys %$all_perms ) {
 338                 foreach my $subperm ( keys %{ $all_perms->{$module} } ) {
 339                     $template->param( "CAN_user_${module}_${subperm}" => 1 );
 340                 }
 341             }
 342         }
 343
 344         if ($flags) {
 345             foreach my $module ( keys %$all_perms ) {
 346                 if ( defined($flags->{$module}) && $flags->{$module} == 1 ) {
 347                     foreach my $subperm ( keys %{ $all_perms->{$module} } ) {
 348                         $template->param( "CAN_user_${module}_${subperm}" => 1 );
 349                     }
 350                 } elsif ( ref( $flags->{$module} ) ) {
 351                     foreach my $subperm ( keys %{ $flags->{$module} } ) {
 352                         $template->param( "CAN_user_${module}_${subperm}" => 1 );
 353                     }
 354                 }
 355             }
 356         }
 357
 358         if ($flags) {
 359             foreach my $module ( keys %$flags ) {
 360                 if ( $flags->{$module} == 1 or ref( $flags->{$module} ) ) {
 361                     $template->param( "CAN_user_$module" => 1 );
 362                 }
 363             }
 364         }
 365
 366         # Logged-in opac search history
 367         # If the requested template is an opac one and opac search history is enabled
 368         if ( $in->{type} eq 'opac' && C4::Context->preference('EnableOpacSearchHistory') ) {
 369             my $dbh   = C4::Context->dbh;
 370             my $query = "SELECT COUNT(*) FROM search_history WHERE userid=?";
 371             my $sth   = $dbh->prepare($query);
 372             $sth->execute($borrowernumber);
 373
 374             # If at least one search has already been performed
 375             if ( $sth->fetchrow_array > 0 ) {
 376
 377                 # We show the link in opac
 378                 $template->param( EnableOpacSearchHistory => 1 );
 379             }
 380             if (C4::Context->preference('LoadSearchHistoryToTheFirstLoggedUser'))
 381             {
 382                 # And if there are searches performed when the user was not logged in,
 383                 # we add them to the logged-in search history
 384                 my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 385                 if (@recentSearches) {
 386                     my $dbh   = C4::Context->dbh;
 387                     my $query = q{
 388                         INSERT INTO search_history(userid, sessionid, query_desc, query_cgi, type,  total, time )
 389                         VALUES (?, ?, ?, ?, ?, ?, ?)
 390                     };
 391                     my $sth = $dbh->prepare($query);
 392                     $sth->execute( $borrowernumber,
 393                         $in->{query}->cookie("CGISESSID"),
 394                         $_->{query_desc},
 395                         $_->{query_cgi},
 396                         $_->{type} || 'biblio',
 397                         $_->{total},
 398                         $_->{time},
 399                     ) foreach @recentSearches;
 400
 401                     # clear out the search history from the session now that
 402                     # we've saved it to the database
 403                  }
 404               }
 405               C4::Search::History::set_to_session( { cgi => $in->{'query'}, search_history => [] } );
 406
 407         } elsif ( $in->{type} eq 'intranet' and C4::Context->preference('EnableSearchHistory') ) {
 408             $template->param( EnableSearchHistory => 1 );
 409         }
 410     }
 411     else {    # if this is an anonymous session, setup to display public lists...
 412
 413         # If shibboleth is enabled, and we're in an anonymous session, we should allow
 414         # the user to attempt login via shibboleth.
 415         if ($shib) {
 416             $template->param( shibbolethAuthentication => $shib,
 417                 shibbolethLoginUrl => login_shib_url( $in->{'query'} ),
 418             );
 419
 420             # If shibboleth is enabled and we have a shibboleth login attribute,
 421             # but we are in an anonymous session, then we clearly have an invalid
 422             # shibboleth koha account.
 423             if ($shib_login) {
 424                 $template->param( invalidShibLogin => '1' );
 425             }
 426         }
 427
 428         $template->param( sessionID => $sessionID );
 429
 430         if ( $in->{'type'} eq 'opac' ){
 431             require Koha::Virtualshelves;
 432             my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 433                 {
 434                     category       => 2,
 435                 }
 436             );
 437             $template->param(
 438                 some_public_shelves  => $some_public_shelves,
 439             );
 440         }
 441     }
 442
 443     # Sysprefs disabled via URL param
 444     # Note that value must be defined in order to override via ENV
 445     foreach my $syspref (
 446         qw(
 447             OPACUserCSS
 448             OPACUserJS
 449             IntranetUserCSS
 450             IntranetUserJS
 451             OpacAdditionalStylesheet
 452             opaclayoutstylesheet
 453             intranetcolorstylesheet
 454             intranetstylesheet
 455         )
 456       )
 457     {
 458         $ENV{"OVERRIDE_SYSPREF_$syspref"} = q{}
 459           if $in->{'query'}->param("DISABLE_SYSPREF_$syspref");
 460     }
 461
 462     # Anonymous opac search history
 463     # If opac search history is enabled and at least one search has already been performed
 464     if ( C4::Context->preference('EnableOpacSearchHistory') ) {
 465         my @recentSearches = C4::Search::History::get_from_session( { cgi => $in->{'query'} } );
 466         if (@recentSearches) {
 467             $template->param( EnableOpacSearchHistory => 1 );
 468         }
 469     }
 470
 471     if ( C4::Context->preference('dateformat') ) {
 472         $template->param( dateformat => C4::Context->preference('dateformat') );
 473     }
 474
 475     $template->param(auth_forwarded_hash => scalar $in->{'query'}->param('auth_forwarded_hash'));
 476
 477     # these template parameters are set the same regardless of $in->{'type'}
 478
 479     my $minPasswordLength = C4::Context->preference('minPasswordLength');
 480     $minPasswordLength = 3 if not $minPasswordLength or $minPasswordLength < 3;
 481     $template->param(
 482         "BiblioDefaultView" . C4::Context->preference("BiblioDefaultView") => 1,
 483         EnhancedMessagingPreferences                                       => C4::Context->preference('EnhancedMessagingPreferences'),
 484         GoogleJackets                                                      => C4::Context->preference("GoogleJackets"),
 485         OpenLibraryCovers                                                  => C4::Context->preference("OpenLibraryCovers"),
 486         KohaAdminEmailAddress                                              => "" . C4::Context->preference("KohaAdminEmailAddress"),
 487         LoginFirstname  => ( C4::Context->userenv ? C4::Context->userenv->{"firstname"} : "Bel" ),
 488         LoginSurname    => C4::Context->userenv ? C4::Context->userenv->{"surname"}      : "Inconnu",
 489         emailaddress    => C4::Context->userenv ? C4::Context->userenv->{"emailaddress"} : undef,
 490         TagsEnabled     => C4::Context->preference("TagsEnabled"),
 491         hide_marc       => C4::Context->preference("hide_marc"),
 492         item_level_itypes  => C4::Context->preference('item-level_itypes'),
 493         patronimages       => C4::Context->preference("patronimages"),
 494         singleBranchMode   => ( Koha::Libraries->search->count == 1 ),
 495         XSLTDetailsDisplay => C4::Context->preference("XSLTDetailsDisplay"),
 496         XSLTResultsDisplay => C4::Context->preference("XSLTResultsDisplay"),
 497         noItemTypeImages   => C4::Context->preference("noItemTypeImages"),
 498         marcflavour        => C4::Context->preference("marcflavour"),
 499         OPACBaseURL        => C4::Context->preference('OPACBaseURL'),
 500         minPasswordLength  => $minPasswordLength,
 501     );
 502     if ( $in->{'type'} eq "intranet" ) {
 503         $template->param(
 504             AmazonCoverImages                                                          => C4::Context->preference("AmazonCoverImages"),
 505             AutoLocation                                                               => C4::Context->preference("AutoLocation"),
 506             "BiblioDefaultView" . C4::Context->preference("IntranetBiblioDefaultView") => 1,
 507             PatronAutoComplete                                                       => C4::Context->preference("PatronAutoComplete"),
 508             FRBRizeEditions                                                            => C4::Context->preference("FRBRizeEditions"),
 509             IndependentBranches                                                        => C4::Context->preference("IndependentBranches"),
 510             IntranetNav                                                                => C4::Context->preference("IntranetNav"),
 511             IntranetmainUserblock                                                      => C4::Context->preference("IntranetmainUserblock"),
 512             LibraryName                                                                => C4::Context->preference("LibraryName"),
 513             advancedMARCEditor                                                         => C4::Context->preference("advancedMARCEditor"),
 514             canreservefromotherbranches                                                => C4::Context->preference('canreservefromotherbranches'),
 515             intranetcolorstylesheet                                                    => C4::Context->preference("intranetcolorstylesheet"),
 516             IntranetFavicon                                                            => C4::Context->preference("IntranetFavicon"),
 517             intranetreadinghistory                                                     => C4::Context->preference("intranetreadinghistory"),
 518             intranetstylesheet                                                         => C4::Context->preference("intranetstylesheet"),
 519             IntranetUserCSS                                                            => C4::Context->preference("IntranetUserCSS"),
 520             IntranetUserJS                                                             => C4::Context->preference("IntranetUserJS"),
 521             suggestion                                                                 => C4::Context->preference("suggestion"),
 522             virtualshelves                                                             => C4::Context->preference("virtualshelves"),
 523             StaffSerialIssueDisplayCount                                               => C4::Context->preference("StaffSerialIssueDisplayCount"),
 524             EasyAnalyticalRecords                                                      => C4::Context->preference('EasyAnalyticalRecords'),
 525             LocalCoverImages                                                           => C4::Context->preference('LocalCoverImages'),
 526             OPACLocalCoverImages                                                       => C4::Context->preference('OPACLocalCoverImages'),
 527             AllowMultipleCovers                                                        => C4::Context->preference('AllowMultipleCovers'),
 528             EnableBorrowerFiles                                                        => C4::Context->preference('EnableBorrowerFiles'),
 529             UseCourseReserves                                                          => C4::Context->preference("UseCourseReserves"),
 530             useDischarge                                                               => C4::Context->preference('useDischarge'),
 531             pending_checkout_notes                                                     => scalar Koha::Checkouts->search({ noteseen => 0 }),
 532         );
 533     }
 534     else {
 535         warn "template type should be OPAC, here it is=[" . $in->{'type'} . "]" unless ( $in->{'type'} eq 'opac' );
 536
 537         #TODO : replace LibraryName syspref with 'system name', and remove this html processing
 538         my $LibraryNameTitle = C4::Context->preference("LibraryName");
 539         $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
 540         $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
 541
 542         # clean up the busc param in the session
 543         # if the page is not opac-detail and not the "add to list" page
 544         # and not the "edit comments" page
 545         if ( C4::Context->preference("OpacBrowseResults")
 546             && $in->{'template_name'} =~ /opac-(.+)\.(?:tt|tmpl)$/ ) {
 547             my $pagename = $1;
 548             unless ( $pagename =~ /^(?:MARC|ISBD)?detail$/
 549                 or $pagename =~ /^addbybiblionumber$/
 550                 or $pagename =~ /^review$/ ) {
 551                 my $sessionSearch = get_session( $sessionID || $in->{'query'}->cookie("CGISESSID") );
 552                 $sessionSearch->clear( ["busc"] ) if ( $sessionSearch->param("busc") );
 553             }
 554         }
 555
 556         # variables passed from CGI: opac_css_override and opac_search_limits.
 557         my $opac_search_limit   = $ENV{'OPAC_SEARCH_LIMIT'};
 558         my $opac_limit_override = $ENV{'OPAC_LIMIT_OVERRIDE'};
 559         my $opac_name           = '';
 560         if (
 561             ( $opac_limit_override && $opac_search_limit && $opac_search_limit =~ /branch:([\w-]+)/ ) ||
 562             ( $in->{'query'}->param('limit') && $in->{'query'}->param('limit') =~ /branch:([\w-]+)/ ) ||
 563             ( $in->{'query'}->param('multibranchlimit') && $in->{'query'}->param('multibranchlimit') =~ /multibranchlimit-(\w+)/ )
 564           ) {
 565             $opac_name = $1;    # opac_search_limit is a branch, so we use it.
 566         } elsif ( $in->{'query'}->param('multibranchlimit') ) {
 567             $opac_name = $in->{'query'}->param('multibranchlimit');
 568         } elsif ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv && C4::Context->userenv->{'branch'} ) {
 569             $opac_name = C4::Context->userenv->{'branch'};
 570         }
 571
 572         my @search_groups = Koha::Library::Groups->get_search_groups({ interface => 'opac' });
 573         $template->param(
 574             AnonSuggestions                       => "" . C4::Context->preference("AnonSuggestions"),
 575             LibrarySearchGroups                   => \@search_groups,
 576             opac_name                             => $opac_name,
 577             LibraryName                           => "" . C4::Context->preference("LibraryName"),
 578             LibraryNameTitle                      => "" . $LibraryNameTitle,
 579             OPACAmazonCoverImages                 => C4::Context->preference("OPACAmazonCoverImages"),
 580             OPACFRBRizeEditions                   => C4::Context->preference("OPACFRBRizeEditions"),
 581             OpacHighlightedWords                  => C4::Context->preference("OpacHighlightedWords"),
 582             OPACShelfBrowser                      => "" . C4::Context->preference("OPACShelfBrowser"),
 583             OPACURLOpenInNewWindow                => "" . C4::Context->preference("OPACURLOpenInNewWindow"),
 584             OPACUserCSS                           => "" . C4::Context->preference("OPACUserCSS"),
 585             OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
 586             opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
 587             opac_search_limit                     => $opac_search_limit,
 588             opac_limit_override                   => $opac_limit_override,
 589             OpacBrowser                           => C4::Context->preference("OpacBrowser"),
 590             OpacCloud                             => C4::Context->preference("OpacCloud"),
 591             OpacKohaUrl                           => C4::Context->preference("OpacKohaUrl"),
 592             OpacNav                               => "" . C4::Context->preference("OpacNav"),
 593             OpacNavBottom                         => "" . C4::Context->preference("OpacNavBottom"),
 594             OpacPasswordChange                    => C4::Context->preference("OpacPasswordChange"),
 595             OPACPatronDetails                     => C4::Context->preference("OPACPatronDetails"),
 596             OPACPrivacy                           => C4::Context->preference("OPACPrivacy"),
 597             OPACFinesTab                          => C4::Context->preference("OPACFinesTab"),
 598             OpacTopissue                          => C4::Context->preference("OpacTopissue"),
 599             RequestOnOpac                         => C4::Context->preference("RequestOnOpac"),
 600             'Version'                             => C4::Context->preference('Version'),
 601             hidelostitems                         => C4::Context->preference("hidelostitems"),
 602             mylibraryfirst                        => ( C4::Context->preference("SearchMyLibraryFirst") && C4::Context->userenv ) ? C4::Context->userenv->{'branch'} : '',
 603             opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
 604             OpacFavicon                           => C4::Context->preference("OpacFavicon"),
 605             opaclanguagesdisplay                  => "" . C4::Context->preference("opaclanguagesdisplay"),
 606             opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
 607             OPACUserJS                            => C4::Context->preference("OPACUserJS"),
 608             opacuserlogin                         => "" . C4::Context->preference("opacuserlogin"),
 609             OpenLibrarySearch                     => C4::Context->preference("OpenLibrarySearch"),
 610             ShowReviewer                          => C4::Context->preference("ShowReviewer"),
 611             ShowReviewerPhoto                     => C4::Context->preference("ShowReviewerPhoto"),
 612             suggestion                            => "" . C4::Context->preference("suggestion"),
 613             virtualshelves                        => "" . C4::Context->preference("virtualshelves"),
 614             OPACSerialIssueDisplayCount           => C4::Context->preference("OPACSerialIssueDisplayCount"),
 615             OPACXSLTDetailsDisplay                => C4::Context->preference("OPACXSLTDetailsDisplay"),
 616             OPACXSLTResultsDisplay                => C4::Context->preference("OPACXSLTResultsDisplay"),
 617             SyndeticsClientCode                   => C4::Context->preference("SyndeticsClientCode"),
 618             SyndeticsEnabled                      => C4::Context->preference("SyndeticsEnabled"),
 619             SyndeticsCoverImages                  => C4::Context->preference("SyndeticsCoverImages"),
 620             SyndeticsTOC                          => C4::Context->preference("SyndeticsTOC"),
 621             SyndeticsSummary                      => C4::Context->preference("SyndeticsSummary"),
 622             SyndeticsEditions                     => C4::Context->preference("SyndeticsEditions"),
 623             SyndeticsExcerpt                      => C4::Context->preference("SyndeticsExcerpt"),
 624             SyndeticsReviews                      => C4::Context->preference("SyndeticsReviews"),
 625             SyndeticsAuthorNotes                  => C4::Context->preference("SyndeticsAuthorNotes"),
 626             SyndeticsAwards                       => C4::Context->preference("SyndeticsAwards"),
 627             SyndeticsSeries                       => C4::Context->preference("SyndeticsSeries"),
 628             SyndeticsCoverImageSize               => C4::Context->preference("SyndeticsCoverImageSize"),
 629             OPACLocalCoverImages                  => C4::Context->preference("OPACLocalCoverImages"),
 630             PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
 631             PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
 632             useDischarge                 => C4::Context->preference('useDischarge'),
 633         );
 634
 635         $template->param( OpacPublic => '1' ) if ( $user || C4::Context->preference("OpacPublic") );
 636     }
 637
 638     # Check if we were asked using parameters to force a specific language
 639     if ( defined $in->{'query'}->param('language') ) {
 640
 641         # Extract the language, let C4::Languages::getlanguage choose
 642         # what to do
 643         my $language = C4::Languages::getlanguage( $in->{'query'} );
 644         my $languagecookie = C4::Templates::getlanguagecookie( $in->{'query'}, $language );
 645         if ( ref $cookie eq 'ARRAY' ) {
 646             push @{$cookie}, $languagecookie;
 647         } else {
 648             $cookie = [ $cookie, $languagecookie ];
 649         }
 650     }
 651
 652     return ( $template, $borrowernumber, $cookie, $flags );
 653 }
 654
 655 =head2 checkauth
 656
 657   ($userid, $cookie, $sessionID) = &checkauth($query, $noauth, $flagsrequired, $type);
 658
 659 Verifies that the user is authorized to run this script.  If
 660 the user is authorized, a (userid, cookie, session-id, flags)
 661 quadruple is returned.  If the user is not authorized but does
 662 not have the required privilege (see $flagsrequired below), it
 663 displays an error page and exits.  Otherwise, it displays the
 664 login page and exits.
 665
 666 Note that C<&checkauth> will return if and only if the user
 667 is authorized, so it should be called early on, before any
 668 unfinished operations (e.g., if you've opened a file, then
 669 C<&checkauth> won't close it for you).
 670
 671 C<$query> is the CGI object for the script calling C<&checkauth>.
 672
 673 The C<$noauth> argument is optional. If it is set, then no
 674 authorization is required for the script.
 675
 676 C<&checkauth> fetches user and session information from C<$query> and
 677 ensures that the user is authorized to run scripts that require
 678 authorization.
 679
 680 The C<$flagsrequired> argument specifies the required privileges
 681 the user must have if the username and password are correct.
 682 It should be specified as a reference-to-hash; keys in the hash
 683 should be the "flags" for the user, as specified in the Members
 684 intranet module. Any key specified must correspond to a "flag"
 685 in the userflags table. E.g., { circulate => 1 } would specify
 686 that the user must have the "circulate" privilege in order to
 687 proceed. To make sure that access control is correct, the
 688 C<$flagsrequired> parameter must be specified correctly.
 689
 690 Koha also has a concept of sub-permissions, also known as
 691 granular permissions.  This makes the value of each key
 692 in the C<flagsrequired> hash take on an additional
 693 meaning, i.e.,
 694
 695  1
 696
 697 The user must have access to all subfunctions of the module
 698 specified by the hash key.
 699
 700  *
 701
 702 The user must have access to at least one subfunction of the module
 703 specified by the hash key.
 704
 705  specific permission, e.g., 'export_catalog'
 706
 707 The user must have access to the specific subfunction list, which
 708 must correspond to a row in the permissions table.
 709
 710 The C<$type> argument specifies whether the template should be
 711 retrieved from the opac or intranet directory tree.  "opac" is
 712 assumed if it is not specified; however, if C<$type> is specified,
 713 "intranet" is assumed if it is not "opac".
 714
 715 If C<$query> does not have a valid session ID associated with it
 716 (i.e., the user has not logged in) or if the session has expired,
 717 C<&checkauth> presents the user with a login page (from the point of
 718 view of the original script, C<&checkauth> does not return). Once the
 719 user has authenticated, C<&checkauth> restarts the original script
 720 (this time, C<&checkauth> returns).
 721
 722 The login page is provided using a HTML::Template, which is set in the
 723 systempreferences table or at the top of this file. The variable C<$type>
 724 selects which template to use, either the opac or the intranet
 725 authentification template.
 726
 727 C<&checkauth> returns a user ID, a cookie, and a session ID. The
 728 cookie should be sent back to the browser; it verifies that the user
 729 has authenticated.
 730
 731 =cut
 732
 733 sub _version_check {
 734     my $type  = shift;
 735     my $query = shift;
 736     my $version;
 737
 738     # If version syspref is unavailable, it means Koha is being installed,
 739     # and so we must redirect to OPAC maintenance page or to the WebInstaller
 740     # also, if OpacMaintenance is ON, OPAC should redirect to maintenance
 741     if ( C4::Context->preference('OpacMaintenance') && $type eq 'opac' ) {
 742         warn "OPAC Install required, redirecting to maintenance";
 743         print $query->redirect("/cgi-bin/koha/maintenance.pl");
 744         safe_exit;
 745     }
 746     unless ( $version = C4::Context->preference('Version') ) {    # assignment, not comparison
 747         if ( $type ne 'opac' ) {
 748             warn "Install required, redirecting to Installer";
 749             print $query->redirect("/cgi-bin/koha/installer/install.pl");
 750         } else {
 751             warn "OPAC Install required, redirecting to maintenance";
 752             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 753         }
 754         safe_exit;
 755     }
 756
 757     # check that database and koha version are the same
 758     # there is no DB version, it's a fresh install,
 759     # go to web installer
 760     # there is a DB version, compare it to the code version
 761     my $kohaversion = Koha::version();
 762
 763     # remove the 3 last . to have a Perl number
 764     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
 765     $debug and print STDERR "kohaversion : $kohaversion\n";
 766     if ( $version < $kohaversion ) {
 767         my $warning = "Database update needed, redirecting to %s. Database is $version and Koha is $kohaversion";
 768         if ( $type ne 'opac' ) {
 769             warn sprintf( $warning, 'Installer' );
 770             print $query->redirect("/cgi-bin/koha/installer/install.pl?step=1&op=updatestructure");
 771         } else {
 772             warn sprintf( "OPAC: " . $warning, 'maintenance' );
 773             print $query->redirect("/cgi-bin/koha/maintenance.pl");
 774         }
 775         safe_exit;
 776     }
 777 }
 778
 779 sub _session_log {
 780     (@_) or return 0;
 781     open my $fh, '>>', "/tmp/sessionlog" or warn "ERROR: Cannot append to /tmp/sessionlog";
 782     printf $fh join( "\n", @_ );
 783     close $fh;
 784 }
 785
 786 sub _timeout_syspref {
 787     my $default_timeout = 600;
 788     my $timeout = C4::Context->preference('timeout') || $default_timeout;
 789
 790     # value in days, convert in seconds
 791     if ( $timeout =~ /^(\d+)[dD]$/ ) {
 792         $timeout = $1 * 86400;
 793     }
 794     # value in hours, convert in seconds
 795     elsif ( $timeout =~ /^(\d+)[hH]$/ ) {
 796         $timeout = $1 * 3600;
 797     }
 798     elsif ( $timeout !~ m/^\d+$/ ) {
 799         warn "The value of the system preference 'timeout' is not correct, defaulting to $default_timeout";
 800         $timeout = $default_timeout;
 801     }
 802
 803     return $timeout;
 804 }
 805
 806 sub checkauth {
 807     my $query = shift;
 808     $debug and warn "Checking Auth";
 809
 810     # Get shibboleth login attribute
 811     my $shib = C4::Context->config('useshibboleth') && shib_ok();
 812     my $shib_login = $shib ? get_login_shib() : undef;
 813
 814     # $authnotrequired will be set for scripts which will run without authentication
 815     my $authnotrequired = shift;
 816     my $flagsrequired   = shift;
 817     my $type            = shift;
 818     my $emailaddress    = shift;
 819     my $template_name   = shift;
 820     $type = 'opac' unless $type;
 821
 822     unless ( C4::Context->preference("OpacPublic") ) {
 823         my @allowed_scripts_for_private_opac = qw(
 824           opac-memberentry.tt
 825           opac-registration-email-sent.tt
 826           opac-registration-confirmation.tt
 827           opac-memberentry-update-submitted.tt
 828           opac-password-recovery.tt
 829         );
 830         $authnotrequired = 0 unless grep { $_ eq $template_name }
 831           @allowed_scripts_for_private_opac;
 832     }
 833
 834     my $dbh     = C4::Context->dbh;
 835     my $timeout = _timeout_syspref();
 836
 837     _version_check( $type, $query );
 838
 839     # state variables
 840     my $loggedin = 0;
 841     my %info;
 842     my ( $userid, $cookie, $sessionID, $flags );
 843     my $logout = $query->param('logout.x');
 844
 845     my $anon_search_history;
 846     my $cas_ticket = '';
 847     # This parameter is the name of the CAS server we want to authenticate against,
 848     # when using authentication against multiple CAS servers, as configured in Auth_cas_servers.yaml
 849     my $casparam = $query->param('cas');
 850     my $q_userid = $query->param('userid') // '';
 851
 852     my $session;
 853
 854     # Basic authentication is incompatible with the use of Shibboleth,
 855     # as Shibboleth may return REMOTE_USER as a Shibboleth attribute,
 856     # and it may not be the attribute we want to use to match the koha login.
 857     #
 858     # Also, do not consider an empty REMOTE_USER.
 859     #
 860     # Finally, after those tests, we can assume (although if it would be better with
 861     # a syspref) that if we get a REMOTE_USER, that's from basic authentication,
 862     # and we can affect it to $userid.
 863     if ( !$shib and defined( $ENV{'REMOTE_USER'} ) and $ENV{'REMOTE_USER'} ne '' and $userid = $ENV{'REMOTE_USER'} ) {
 864
 865         # Using Basic Authentication, no cookies required
 866         $cookie = $query->cookie(
 867             -name     => 'CGISESSID',
 868             -value    => '',
 869             -expires  => '',
 870             -HttpOnly => 1,
 871             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 872         );
 873         $loggedin = 1;
 874     }
 875     elsif ( $emailaddress) {
 876         # the Google OpenID Connect passes an email address
 877     }
 878     elsif ( $sessionID = $query->cookie("CGISESSID") )
 879     {    # assignment, not comparison
 880         $session = get_session($sessionID);
 881         C4::Context->_new_userenv($sessionID);
 882         my ( $ip, $lasttime, $sessiontype );
 883         my $s_userid = '';
 884         if ($session) {
 885             $s_userid = $session->param('id') // '';
 886             C4::Context->set_userenv(
 887                 $session->param('number'),       $s_userid,
 888                 $session->param('cardnumber'),   $session->param('firstname'),
 889                 $session->param('surname'),      $session->param('branch'),
 890                 $session->param('branchname'),   $session->param('flags'),
 891                 $session->param('emailaddress'), $session->param('shibboleth'),
 892                 $session->param('desk_id'),      $session->param('desk_name'),
 893                 $session->param('register_id'),  $session->param('register_name')
 894             );
 895             C4::Context::set_shelves_userenv( 'bar', $session->param('barshelves') );
 896             C4::Context::set_shelves_userenv( 'pub', $session->param('pubshelves') );
 897             C4::Context::set_shelves_userenv( 'tot', $session->param('totshelves') );
 898             $debug and printf STDERR "AUTH_SESSION: (%s)\t%s %s - %s\n", map { $session->param($_) } qw(cardnumber firstname surname branch);
 899             $ip          = $session->param('ip');
 900             $lasttime    = $session->param('lasttime');
 901             $userid      = $s_userid;
 902             $sessiontype = $session->param('sessiontype') || '';
 903         }
 904         if ( ( $query->param('koha_login_context') && ( $q_userid ne $s_userid ) )
 905             || ( $cas && $query->param('ticket') && !C4::Context->userenv->{'id'} )
 906             || ( $shib && $shib_login && !$logout && !C4::Context->userenv->{'id'} )
 907         ) {
 908
 909             #if a user enters an id ne to the id in the current session, we need to log them in...
 910             #first we need to clear the anonymous session...
 911             $debug and warn "query id = $q_userid but session id = $s_userid";
 912             $anon_search_history = $session->param('search_history');
 913             $session->delete();
 914             $session->flush;
 915             C4::Context->_unset_userenv($sessionID);
 916             $sessionID = undef;
 917             $userid    = undef;
 918         }
 919         elsif ($logout) {
 920
 921             # voluntary logout the user
 922             # check wether the user was using their shibboleth session or a local one
 923             my $shibSuccess = C4::Context->userenv->{'shibboleth'};
 924             $session->delete();
 925             $session->flush;
 926             C4::Context->_unset_userenv($sessionID);
 927
 928             #_session_log(sprintf "%20s from %16s logged out at %30s (manually).\n", $userid,$ip,(strftime "%c",localtime));
 929             $sessionID = undef;
 930             $userid    = undef;
 931
 932             if ($cas and $caslogout) {
 933                 logout_cas($query, $type);
 934             }
 935
 936             # If we are in a shibboleth session (shibboleth is enabled, a shibboleth match attribute is set and matches koha matchpoint)
 937             if ( $shib and $shib_login and $shibSuccess) {
 938                 logout_shib($query);
 939             }
 940         }
 941         elsif ( !$lasttime || ( $lasttime < time() - $timeout ) ) {
 942
 943             # timed logout
 944             $info{'timed_out'} = 1;
 945             if ($session) {
 946                 $session->delete();
 947                 $session->flush;
 948             }
 949             C4::Context->_unset_userenv($sessionID);
 950
 951             #_session_log(sprintf "%20s from %16s logged out at %30s (inactivity).\n", $userid,$ip,(strftime "%c",localtime));
 952             $userid    = undef;
 953             $sessionID = undef;
 954         }
 955         elsif ( C4::Context->preference('SessionRestrictionByIP') && $ip ne $ENV{'REMOTE_ADDR'} ) {
 956
 957             # Different ip than originally logged in from
 958             $info{'oldip'}        = $ip;
 959             $info{'newip'}        = $ENV{'REMOTE_ADDR'};
 960             $info{'different_ip'} = 1;
 961             $session->delete();
 962             $session->flush;
 963             C4::Context->_unset_userenv($sessionID);
 964
 965             #_session_log(sprintf "%20s from %16s logged out at %30s (ip changed to %16s).\n", $userid,$ip,(strftime "%c",localtime), $info{'newip'});
 966             $sessionID = undef;
 967             $userid    = undef;
 968         }
 969         else {
 970             $cookie = $query->cookie(
 971                 -name     => 'CGISESSID',
 972                 -value    => $session->id,
 973                 -HttpOnly => 1,
 974                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
 975             );
 976             $session->param( 'lasttime', time() );
 977             unless ( $sessiontype && $sessiontype eq 'anon' ) {    #if this is an anonymous session, we want to update the session, but not behave as if they are logged in...
 978                 $flags = haspermission( $userid, $flagsrequired );
 979                 if ($flags) {
 980                     $loggedin = 1;
 981                 } else {
 982                     $info{'nopermission'} = 1;
 983                 }
 984             }
 985         }
 986     }
 987     unless ( $userid || $sessionID ) {
 988         #we initiate a session prior to checking for a username to allow for anonymous sessions...
 989         my $session = get_session("") or die "Auth ERROR: Cannot get_session()";
 990
 991         # Save anonymous search history in new session so it can be retrieved
 992         # by get_template_and_user to store it in user's search history after
 993         # a successful login.
 994         if ($anon_search_history) {
 995             $session->param( 'search_history', $anon_search_history );
 996         }
 997
 998         $sessionID = $session->id;
 999         C4::Context->_new_userenv($sessionID);
1000         $cookie = $query->cookie(
1001             -name     => 'CGISESSID',
1002             -value    => $session->id,
1003             -HttpOnly => 1,
1004             -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1005         );
1006         my $pki_field = C4::Context->preference('AllowPKIAuth');
1007         if ( !defined($pki_field) ) {
1008             print STDERR "ERROR: Missing system preference AllowPKIAuth.\n";
1009             $pki_field = 'None';
1010         }
1011         if ( ( $cas && $query->param('ticket') )
1012             || $q_userid
1013             || ( $shib && $shib_login )
1014             || $pki_field ne 'None'
1015             || $emailaddress )
1016         {
1017             my $password    = $query->param('password');
1018             my $shibSuccess = 0;
1019             my ( $return, $cardnumber );
1020
1021             # If shib is enabled and we have a shib login, does the login match a valid koha user
1022             if ( $shib && $shib_login ) {
1023                 my $retuserid;
1024
1025                 # Do not pass password here, else shib will not be checked in checkpw.
1026                 ( $return, $cardnumber, $retuserid ) = checkpw( $dbh, $q_userid, undef, $query );
1027                 $userid      = $retuserid;
1028                 $shibSuccess = $return;
1029                 $info{'invalidShibLogin'} = 1 unless ($return);
1030             }
1031
1032             # If shib login and match were successful, skip further login methods
1033             unless ($shibSuccess) {
1034                 if ( $cas && $query->param('ticket') ) {
1035                     my $retuserid;
1036                     ( $return, $cardnumber, $retuserid, $cas_ticket ) =
1037                       checkpw( $dbh, $userid, $password, $query, $type );
1038                     $userid = $retuserid;
1039                     $info{'invalidCasLogin'} = 1 unless ($return);
1040                 }
1041
1042                 elsif ( $emailaddress ) {
1043                     my $value = $emailaddress;
1044
1045                     # If we're looking up the email, there's a chance that the person
1046                     # doesn't have a userid. So if there is none, we pass along the
1047                     # borrower number, and the bits of code that need to know the user
1048                     # ID will have to be smart enough to handle that.
1049                     my $patrons = Koha::Patrons->search({ email => $value });
1050                     if ($patrons->count) {
1051
1052                         # First the userid, then the borrowernum
1053                         my $patron = $patrons->next;
1054                         $value = $patron->userid || $patron->borrowernumber;
1055                     } else {
1056                         undef $value;
1057                     }
1058                     $return = $value ? 1 : 0;
1059                     $userid = $value;
1060                 }
1061
1062                 elsif (
1063                     ( $pki_field eq 'Common Name' && $ENV{'SSL_CLIENT_S_DN_CN'} )
1064                     || ( $pki_field eq 'emailAddress'
1065                         && $ENV{'SSL_CLIENT_S_DN_Email'} )
1066                   )
1067                 {
1068                     my $value;
1069                     if ( $pki_field eq 'Common Name' ) {
1070                         $value = $ENV{'SSL_CLIENT_S_DN_CN'};
1071                     }
1072                     elsif ( $pki_field eq 'emailAddress' ) {
1073                         $value = $ENV{'SSL_CLIENT_S_DN_Email'};
1074
1075                         # If we're looking up the email, there's a chance that the person
1076                         # doesn't have a userid. So if there is none, we pass along the
1077                         # borrower number, and the bits of code that need to know the user
1078                         # ID will have to be smart enough to handle that.
1079                         my $patrons = Koha::Patrons->search({ email => $value });
1080                         if ($patrons->count) {
1081
1082                             # First the userid, then the borrowernum
1083                             my $patron = $patrons->next;
1084                             $value = $patron->userid || $patron->borrowernumber;
1085                         } else {
1086                             undef $value;
1087                         }
1088                     }
1089
1090                     $return = $value ? 1 : 0;
1091                     $userid = $value;
1092
1093                 }
1094                 else {
1095                     my $retuserid;
1096                     my $request_method = $query->request_method();
1097                     if ($request_method eq 'POST'){
1098                         ( $return, $cardnumber, $retuserid, $cas_ticket ) =
1099                           checkpw( $dbh, $q_userid, $password, $query, $type );
1100                         $userid = $retuserid if ($retuserid);
1101                         $info{'invalid_username_or_password'} = 1 unless ($return);
1102                     }
1103                 }
1104             }
1105
1106             # If shib configured and shibOnly enabled, we should ignore anything other than a shibboleth type login.
1107             if (
1108                    $shib
1109                 && !$shibSuccess
1110                 && (
1111                     (
1112                         ( $type eq 'opac' )
1113                         && C4::Context->preference('OPACShibOnly')
1114                     )
1115                     || ( ( $type ne 'opac' )
1116                         && C4::Context->preference('staffShibOnly') )
1117                 )
1118               )
1119             {
1120                 $return = 0;
1121             }
1122
1123             # $return: 1 = valid user
1124             if ($return) {
1125
1126                 #_session_log(sprintf "%20s from %16s logged in  at %30s.\n", $userid,$ENV{'REMOTE_ADDR'},(strftime '%c', localtime));
1127                 if ( $flags = haspermission( $userid, $flagsrequired ) ) {
1128                     $loggedin = 1;
1129                 }
1130                 else {
1131                     $info{'nopermission'} = 1;
1132                     C4::Context->_unset_userenv($sessionID);
1133                 }
1134                 my ( $borrowernumber, $firstname, $surname, $userflags,
1135                     $branchcode, $branchname, $emailaddress, $desk_id,
1136                     $desk_name, $register_id, $register_name );
1137
1138                 if ( $return == 1 ) {
1139                     my $select = "
1140                     SELECT borrowernumber, firstname, surname, flags, borrowers.branchcode,
1141                     branches.branchname    as branchname, email
1142                     FROM borrowers
1143                     LEFT JOIN branches on borrowers.branchcode=branches.branchcode
1144                     ";
1145                     my $sth = $dbh->prepare("$select where userid=?");
1146                     $sth->execute($userid);
1147                     unless ( $sth->rows ) {
1148                         $debug and print STDERR "AUTH_1: no rows for userid='$userid'\n";
1149                         $sth = $dbh->prepare("$select where cardnumber=?");
1150                         $sth->execute($cardnumber);
1151
1152                         unless ( $sth->rows ) {
1153                             $debug and print STDERR "AUTH_2a: no rows for cardnumber='$cardnumber'\n";
1154                             $sth->execute($userid);
1155                             unless ( $sth->rows ) {
1156                                 $debug and print STDERR "AUTH_2b: no rows for userid='$userid' AS cardnumber\n";
1157                             }
1158                         }
1159                     }
1160                     if ( $sth->rows ) {
1161                         ( $borrowernumber, $firstname, $surname, $userflags,
1162                             $branchcode, $branchname, $emailaddress ) = $sth->fetchrow;
1163                         $debug and print STDERR "AUTH_3 results: " .
1164                           "$cardnumber,$borrowernumber,$userid,$firstname,$surname,$userflags,$branchcode,$emailaddress\n";
1165                     } else {
1166                         print STDERR "AUTH_3: no results for userid='$userid', cardnumber='$cardnumber'.\n";
1167                     }
1168
1169                     # launch a sequence to check if we have a ip for the branch, i
1170                     # if we have one we replace the branchcode of the userenv by the branch bound in the ip.
1171
1172                     my $ip = $ENV{'REMOTE_ADDR'};
1173
1174                     # if they specify at login, use that
1175                     if ( $query->param('branch') ) {
1176                         $branchcode = $query->param('branch');
1177                         my $library = Koha::Libraries->find($branchcode);
1178                         $branchname = $library? $library->branchname: '';
1179                     }
1180                     if ( $query->param('desk_id') ) {
1181                         $desk_id = $query->param('desk_id');
1182                         my $desk = Koha::Desks->find($desk_id);
1183                         $desk_name = $desk ? $desk->desk_name : '';
1184                     }
1185                     if ( C4::Context->preference('UseCashRegisters') ) {
1186                         my $register =
1187                           $query->param('register_id')
1188                           ? Koha::Cash::Registers->find($query->param('register_id'))
1189                           : Koha::Cash::Registers->search(
1190                             { branch => $branchcode, branch_default => 1 },
1191                             { rows   => 1 } )->single;
1192                         $register_id   = $register->id   if ($register);
1193                         $register_name = $register->name if ($register);
1194                     }
1195                     my $branches = { map { $_->branchcode => $_->unblessed } Koha::Libraries->search };
1196                     if ( $type ne 'opac' and C4::Context->preference('AutoLocation') ) {
1197
1198                         # we have to check they are coming from the right ip range
1199                         my $domain = $branches->{$branchcode}->{'branchip'};
1200                         $domain =~ s|\.\*||g;
1201                         if ( $ip !~ /^$domain/ ) {
1202                             $loggedin = 0;
1203                             $cookie = $query->cookie(
1204                                 -name     => 'CGISESSID',
1205                                 -value    => '',
1206                                 -HttpOnly => 1,
1207                                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1208                             );
1209                             $info{'wrongip'} = 1;
1210                         }
1211                     }
1212
1213                     foreach my $br ( keys %$branches ) {
1214
1215                         #     now we work with the treatment of ip
1216                         my $domain = $branches->{$br}->{'branchip'};
1217                         if ( $domain && $ip =~ /^$domain/ ) {
1218                             $branchcode = $branches->{$br}->{'branchcode'};
1219
1220                             # new op dev : add the branchname to the cookie
1221                             $branchname    = $branches->{$br}->{'branchname'};
1222                         }
1223                     }
1224                     $session->param( 'number',       $borrowernumber );
1225                     $session->param( 'id',           $userid );
1226                     $session->param( 'cardnumber',   $cardnumber );
1227                     $session->param( 'firstname',    $firstname );
1228                     $session->param( 'surname',      $surname );
1229                     $session->param( 'branch',       $branchcode );
1230                     $session->param( 'branchname',   $branchname );
1231                     $session->param( 'desk_id',      $desk_id);
1232                     $session->param( 'desk_name',     $desk_name);
1233                     $session->param( 'flags',        $userflags );
1234                     $session->param( 'emailaddress', $emailaddress );
1235                     $session->param( 'ip',           $session->remote_addr() );
1236                     $session->param( 'lasttime',     time() );
1237                     $session->param( 'interface',    $type);
1238                     $session->param( 'shibboleth',   $shibSuccess );
1239                     $session->param( 'register_id',  $register_id );
1240                     $session->param( 'register_name',  $register_name );
1241                     $debug and printf STDERR "AUTH_4: (%s)\t%s %s - %s\n", map { $session->param($_) } qw(cardnumber firstname surname branch);
1242                 }
1243                 $session->param('cas_ticket', $cas_ticket) if $cas_ticket;
1244                 C4::Context->set_userenv(
1245                     $session->param('number'),       $session->param('id'),
1246                     $session->param('cardnumber'),   $session->param('firstname'),
1247                     $session->param('surname'),      $session->param('branch'),
1248                     $session->param('branchname'),   $session->param('flags'),
1249                     $session->param('emailaddress'), $session->param('shibboleth'),
1250                     $session->param('desk_id'),      $session->param('desk_name'),
1251                     $session->param('register_id'),  $session->param('register_name')
1252                 );
1253
1254             }
1255             # $return: 0 = invalid user
1256             # reset to anonymous session
1257             else {
1258                 $debug and warn "Login failed, resetting anonymous session...";
1259                 if ($userid) {
1260                     $info{'invalid_username_or_password'} = 1;
1261                     C4::Context->_unset_userenv($sessionID);
1262                 }
1263                 $session->param( 'lasttime', time() );
1264                 $session->param( 'ip',       $session->remote_addr() );
1265                 $session->param( 'sessiontype', 'anon' );
1266                 $session->param( 'interface', $type);
1267             }
1268         }    # END if ( $q_userid
1269         elsif ( $type eq "opac" ) {
1270
1271             # if we are here this is an anonymous session; add public lists to it and a few other items...
1272             # anonymous sessions are created only for the OPAC
1273             $debug and warn "Initiating an anonymous session...";
1274
1275             # setting a couple of other session vars...
1276             $session->param( 'ip',          $session->remote_addr() );
1277             $session->param( 'lasttime',    time() );
1278             $session->param( 'sessiontype', 'anon' );
1279             $session->param( 'interface', $type);
1280         }
1281     }    # END unless ($userid)
1282
1283     # finished authentification, now respond
1284     if ( $loggedin || $authnotrequired )
1285     {
1286         # successful login
1287         unless ($cookie) {
1288             $cookie = $query->cookie(
1289                 -name     => 'CGISESSID',
1290                 -value    => '',
1291                 -HttpOnly => 1,
1292                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1293             );
1294         }
1295
1296         track_login_daily( $userid );
1297
1298         # In case, that this request was a login attempt, we want to prevent that users can repost the opac login
1299         # request. We therefore redirect the user to the requested page again without the login parameters.
1300         # See Post/Redirect/Get (PRG) design pattern: https://en.wikipedia.org/wiki/Post/Redirect/Get
1301         if ( $type eq "opac" && $query->param('koha_login_context') && $query->param('koha_login_context') ne 'sco' && $query->param('password') && $query->param('userid') ) {
1302             my $uri = URI->new($query->url(-relative=>1, -query_string=>1));
1303             $uri->query_param_delete('userid');
1304             $uri->query_param_delete('password');
1305             $uri->query_param_delete('koha_login_context');
1306             print $query->redirect(-uri => $uri->as_string, -cookie => $cookie, -status=>'303 See other');
1307             exit;
1308         }
1309
1310         return ( $userid, $cookie, $sessionID, $flags );
1311     }
1312
1313     #
1314     #
1315     # AUTH rejected, show the login/password template, after checking the DB.
1316     #
1317     #
1318
1319     # get the inputs from the incoming query
1320     my @inputs = ();
1321     foreach my $name ( param $query) {
1322         (next) if ( $name eq 'userid' || $name eq 'password' || $name eq 'ticket' );
1323         my @value = $query->multi_param($name);
1324         push @inputs, { name => $name, value => $_ } for @value;
1325     }
1326
1327     my $patron = Koha::Patrons->find({ userid => $q_userid }); # Not necessary logged in!
1328
1329     my $LibraryNameTitle = C4::Context->preference("LibraryName");
1330     $LibraryNameTitle =~ s/<(?:\/?)(?:br|p)\s*(?:\/?)>/ /sgi;
1331     $LibraryNameTitle =~ s/<(?:[^<>'"]|'(?:[^']*)'|"(?:[^"]*)")*>//sg;
1332
1333     my $auth_template_name = ( $type eq 'opac' ) ? 'opac-auth.tt' : 'auth.tt';
1334     my $template = C4::Templates::gettemplate( $auth_template_name, $type, $query );
1335     $template->param(
1336         login                                 => 1,
1337         INPUTS                                => \@inputs,
1338         script_name                           => get_script_name(),
1339         casAuthentication                     => C4::Context->preference("casAuthentication"),
1340         shibbolethAuthentication              => $shib,
1341         SessionRestrictionByIP                => C4::Context->preference("SessionRestrictionByIP"),
1342         suggestion                            => C4::Context->preference("suggestion"),
1343         virtualshelves                        => C4::Context->preference("virtualshelves"),
1344         LibraryName                           => "" . C4::Context->preference("LibraryName"),
1345         LibraryNameTitle                      => "" . $LibraryNameTitle,
1346         opacuserlogin                         => C4::Context->preference("opacuserlogin"),
1347         OpacNav                               => C4::Context->preference("OpacNav"),
1348         OpacNavBottom                         => C4::Context->preference("OpacNavBottom"),
1349         OpacFavicon                           => C4::Context->preference("OpacFavicon"),
1350         opacreadinghistory                    => C4::Context->preference("opacreadinghistory"),
1351         opaclanguagesdisplay                  => C4::Context->preference("opaclanguagesdisplay"),
1352         OPACUserJS                            => C4::Context->preference("OPACUserJS"),
1353         opacbookbag                           => "" . C4::Context->preference("opacbookbag"),
1354         OpacCloud                             => C4::Context->preference("OpacCloud"),
1355         OpacTopissue                          => C4::Context->preference("OpacTopissue"),
1356         OpacAuthorities                       => C4::Context->preference("OpacAuthorities"),
1357         OpacBrowser                           => C4::Context->preference("OpacBrowser"),
1358         TagsEnabled                           => C4::Context->preference("TagsEnabled"),
1359         OPACUserCSS                           => C4::Context->preference("OPACUserCSS"),
1360         intranetcolorstylesheet               => C4::Context->preference("intranetcolorstylesheet"),
1361         intranetstylesheet                    => C4::Context->preference("intranetstylesheet"),
1362         IntranetNav                           => C4::Context->preference("IntranetNav"),
1363         IntranetFavicon                       => C4::Context->preference("IntranetFavicon"),
1364         IntranetUserCSS                       => C4::Context->preference("IntranetUserCSS"),
1365         IntranetUserJS                        => C4::Context->preference("IntranetUserJS"),
1366         IndependentBranches                   => C4::Context->preference("IndependentBranches"),
1367         AutoLocation                          => C4::Context->preference("AutoLocation"),
1368         wrongip                               => $info{'wrongip'},
1369         PatronSelfRegistration                => C4::Context->preference("PatronSelfRegistration"),
1370         PatronSelfRegistrationDefaultCategory => C4::Context->preference("PatronSelfRegistrationDefaultCategory"),
1371         opac_css_override                     => $ENV{'OPAC_CSS_OVERRIDE'},
1372         too_many_login_attempts               => ( $patron and $patron->account_locked )
1373     );
1374
1375     $template->param( SCO_login => 1 ) if ( $query->param('sco_user_login') );
1376     $template->param( SCI_login => 1 ) if ( $query->param('sci_user_login') );
1377     $template->param( OpacPublic => C4::Context->preference("OpacPublic") );
1378     $template->param( loginprompt => 1 ) unless $info{'nopermission'};
1379
1380     if ( $type eq 'opac' ) {
1381         require Koha::Virtualshelves;
1382         my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
1383             {
1384                 category       => 2,
1385             }
1386         );
1387         $template->param(
1388             some_public_shelves  => $some_public_shelves,
1389         );
1390     }
1391
1392     if ($cas) {
1393
1394         # Is authentication against multiple CAS servers enabled?
1395         if ( C4::Auth_with_cas::multipleAuth && !$casparam ) {
1396             my $casservers = C4::Auth_with_cas::getMultipleAuth();
1397             my @tmplservers;
1398             foreach my $key ( keys %$casservers ) {
1399                 push @tmplservers, { name => $key, value => login_cas_url( $query, $key, $type ) . "?cas=$key" };
1400             }
1401             $template->param(
1402                 casServersLoop => \@tmplservers
1403             );
1404         } else {
1405             $template->param(
1406                 casServerUrl => login_cas_url($query, undef, $type),
1407             );
1408         }
1409
1410         $template->param(
1411             invalidCasLogin => $info{'invalidCasLogin'}
1412         );
1413     }
1414
1415     if ($shib) {
1416         #If shibOnly is enabled just go ahead and redirect directly
1417         if ( (($type eq 'opac') && C4::Context->preference('OPACShibOnly')) || (($type ne 'opac') && C4::Context->preference('staffShibOnly')) ) {
1418             my $redirect_url = login_shib_url( $query );
1419             print $query->redirect( -uri => "$redirect_url", -status => 303 );
1420             safe_exit;
1421         }
1422
1423         $template->param(
1424             shibbolethAuthentication => $shib,
1425             shibbolethLoginUrl       => login_shib_url($query),
1426         );
1427     }
1428
1429     if (C4::Context->preference('GoogleOpenIDConnect')) {
1430         if ($query->param("OpenIDConnectFailed")) {
1431             my $reason = $query->param('OpenIDConnectFailed');
1432             $template->param(invalidGoogleOpenIDConnectLogin => $reason);
1433         }
1434     }
1435
1436     $template->param(
1437         LibraryName => C4::Context->preference("LibraryName"),
1438     );
1439     $template->param(%info);
1440
1441     #    $cookie = $query->cookie(CGISESSID => $session->id
1442     #   );
1443     print $query->header(
1444         {   type              => 'text/html',
1445             charset           => 'utf-8',
1446             cookie            => $cookie,
1447             'X-Frame-Options' => 'SAMEORIGIN'
1448         }
1449       ),
1450       $template->output;
1451     safe_exit;
1452 }
1453
1454 =head2 check_api_auth
1455
1456   ($status, $cookie, $sessionId) = check_api_auth($query, $userflags);
1457
1458 Given a CGI query containing the parameters 'userid' and 'password' and/or a session
1459 cookie, determine if the user has the privileges specified by C<$userflags>.
1460
1461 C<check_api_auth> is is meant for authenticating users of web services, and
1462 consequently will always return and will not attempt to redirect the user
1463 agent.
1464
1465 If a valid session cookie is already present, check_api_auth will return a status
1466 of "ok", the cookie, and the Koha session ID.
1467
1468 If no session cookie is present, check_api_auth will check the 'userid' and 'password
1469 parameters and create a session cookie and Koha session if the supplied credentials
1470 are OK.
1471
1472 Possible return values in C<$status> are:
1473
1474 =over
1475
1476 =item "ok" -- user authenticated; C<$cookie> and C<$sessionid> have valid values.
1477
1478 =item "failed" -- credentials are not correct; C<$cookie> and C<$sessionid> are undef
1479
1480 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1481
1482 =item "expired -- session cookie has expired; API user should resubmit userid and password
1483
1484 =back
1485
1486 =cut
1487
1488 sub check_api_auth {
1489
1490     my $query         = shift;
1491     my $flagsrequired = shift;
1492     my $dbh     = C4::Context->dbh;
1493     my $timeout = _timeout_syspref();
1494
1495     unless ( C4::Context->preference('Version') ) {
1496
1497         # database has not been installed yet
1498         return ( "maintenance", undef, undef );
1499     }
1500     my $kohaversion = Koha::version();
1501     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1502     if ( C4::Context->preference('Version') < $kohaversion ) {
1503
1504         # database in need of version update; assume that
1505         # no API should be called while databsae is in
1506         # this condition.
1507         return ( "maintenance", undef, undef );
1508     }
1509
1510     # FIXME -- most of what follows is a copy-and-paste
1511     # of code from checkauth.  There is an obvious need
1512     # for refactoring to separate the various parts of
1513     # the authentication code, but as of 2007-11-19 this
1514     # is deferred so as to not introduce bugs into the
1515     # regular authentication code for Koha 3.0.
1516
1517     # see if we have a valid session cookie already
1518     # however, if a userid parameter is present (i.e., from
1519     # a form submission, assume that any current cookie
1520     # is to be ignored
1521     my $sessionID = undef;
1522     unless ( $query->param('userid') ) {
1523         $sessionID = $query->cookie("CGISESSID");
1524     }
1525     if ( $sessionID && not( $cas && $query->param('PT') ) ) {
1526         my $session = get_session($sessionID);
1527         C4::Context->_new_userenv($sessionID);
1528         if ($session) {
1529             C4::Context->interface($session->param('interface'));
1530             C4::Context->set_userenv(
1531                 $session->param('number'),       $session->param('id'),
1532                 $session->param('cardnumber'),   $session->param('firstname'),
1533                 $session->param('surname'),      $session->param('branch'),
1534                 $session->param('branchname'),   $session->param('flags'),
1535                 $session->param('emailaddress'), $session->param('shibboleth'),
1536                 $session->param('desk_id'),      $session->param('desk_name'),
1537                 $session->param('register_id'),  $session->param('register_name')
1538             );
1539
1540             my $ip       = $session->param('ip');
1541             my $lasttime = $session->param('lasttime');
1542             my $userid   = $session->param('id');
1543             if ( $lasttime < time() - $timeout ) {
1544
1545                 # time out
1546                 $session->delete();
1547                 $session->flush;
1548                 C4::Context->_unset_userenv($sessionID);
1549                 $userid    = undef;
1550                 $sessionID = undef;
1551                 return ( "expired", undef, undef );
1552             } elsif ( C4::Context->preference('SessionRestrictionByIP') && $ip ne $ENV{'REMOTE_ADDR'} ) {
1553
1554                 # IP address changed
1555                 $session->delete();
1556                 $session->flush;
1557                 C4::Context->_unset_userenv($sessionID);
1558                 $userid    = undef;
1559                 $sessionID = undef;
1560                 return ( "expired", undef, undef );
1561             } else {
1562                 my $cookie = $query->cookie(
1563                     -name     => 'CGISESSID',
1564                     -value    => $session->id,
1565                     -HttpOnly => 1,
1566                     -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1567                 );
1568                 $session->param( 'lasttime', time() );
1569                 my $flags = haspermission( $userid, $flagsrequired );
1570                 if ($flags) {
1571                     return ( "ok", $cookie, $sessionID );
1572                 } else {
1573                     $session->delete();
1574                     $session->flush;
1575                     C4::Context->_unset_userenv($sessionID);
1576                     $userid    = undef;
1577                     $sessionID = undef;
1578                     return ( "failed", undef, undef );
1579                 }
1580             }
1581         } else {
1582             return ( "expired", undef, undef );
1583         }
1584     } else {
1585
1586         # new login
1587         my $userid   = $query->param('userid');
1588         my $password = $query->param('password');
1589         my ( $return, $cardnumber, $cas_ticket );
1590
1591         # Proxy CAS auth
1592         if ( $cas && $query->param('PT') ) {
1593             my $retuserid;
1594             $debug and print STDERR "## check_api_auth - checking CAS\n";
1595
1596             # In case of a CAS authentication, we use the ticket instead of the password
1597             my $PT = $query->param('PT');
1598             ( $return, $cardnumber, $userid, $cas_ticket ) = check_api_auth_cas( $dbh, $PT, $query );    # EXTERNAL AUTH
1599         } else {
1600
1601             # User / password auth
1602             unless ( $userid and $password ) {
1603
1604                 # caller did something wrong, fail the authenticateion
1605                 return ( "failed", undef, undef );
1606             }
1607             my $newuserid;
1608             ( $return, $cardnumber, $newuserid, $cas_ticket ) = checkpw( $dbh, $userid, $password, $query );
1609         }
1610
1611         if ( $return and haspermission( $userid, $flagsrequired ) ) {
1612             my $session = get_session("");
1613             return ( "failed", undef, undef ) unless $session;
1614
1615             my $sessionID = $session->id;
1616             C4::Context->_new_userenv($sessionID);
1617             my $cookie = $query->cookie(
1618                 -name     => 'CGISESSID',
1619                 -value    => $sessionID,
1620                 -HttpOnly => 1,
1621                 -secure => ( C4::Context->https_enabled() ? 1 : 0 ),
1622             );
1623             if ( $return == 1 ) {
1624                 my (
1625                     $borrowernumber, $firstname,  $surname,
1626                     $userflags,      $branchcode, $branchname,
1627                     $emailaddress
1628                 );
1629                 my $sth =
1630                   $dbh->prepare(
1631 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where userid=?"
1632                   );
1633                 $sth->execute($userid);
1634                 (
1635                     $borrowernumber, $firstname,  $surname,
1636                     $userflags,      $branchcode, $branchname,
1637                     $emailaddress
1638                 ) = $sth->fetchrow if ( $sth->rows );
1639
1640                 unless ( $sth->rows ) {
1641                     my $sth = $dbh->prepare(
1642 "select borrowernumber, firstname, surname, flags, borrowers.branchcode, branches.branchname as branchname, email from borrowers left join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
1643                     );
1644                     $sth->execute($cardnumber);
1645                     (
1646                         $borrowernumber, $firstname,  $surname,
1647                         $userflags,      $branchcode, $branchname,
1648                         $emailaddress
1649                     ) = $sth->fetchrow if ( $sth->rows );
1650
1651                     unless ( $sth->rows ) {
1652                         $sth->execute($userid);
1653                         (
1654                             $borrowernumber, $firstname,  $surname,       $userflags,
1655                             $branchcode,     $branchname, $emailaddress
1656                         ) = $sth->fetchrow if ( $sth->rows );
1657                     }
1658                 }
1659
1660                 my $ip = $ENV{'REMOTE_ADDR'};
1661
1662                 # if they specify at login, use that
1663                 if ( $query->param('branch') ) {
1664                     $branchcode = $query->param('branch');
1665                     my $library = Koha::Libraries->find($branchcode);
1666                     $branchname = $library? $library->branchname: '';
1667                 }
1668                 my $branches = { map { $_->branchcode => $_->unblessed } Koha::Libraries->search };
1669                 foreach my $br ( keys %$branches ) {
1670
1671                     #     now we work with the treatment of ip
1672                     my $domain = $branches->{$br}->{'branchip'};
1673                     if ( $domain && $ip =~ /^$domain/ ) {
1674                         $branchcode = $branches->{$br}->{'branchcode'};
1675
1676                         # new op dev : add the branchname to the cookie
1677                         $branchname    = $branches->{$br}->{'branchname'};
1678                     }
1679                 }
1680                 $session->param( 'number',       $borrowernumber );
1681                 $session->param( 'id',           $userid );
1682                 $session->param( 'cardnumber',   $cardnumber );
1683                 $session->param( 'firstname',    $firstname );
1684                 $session->param( 'surname',      $surname );
1685                 $session->param( 'branch',       $branchcode );
1686                 $session->param( 'branchname',   $branchname );
1687                 $session->param( 'flags',        $userflags );
1688                 $session->param( 'emailaddress', $emailaddress );
1689                 $session->param( 'ip',           $session->remote_addr() );
1690                 $session->param( 'lasttime',     time() );
1691                 $session->param( 'interface',    'api'  );
1692             }
1693             $session->param( 'cas_ticket', $cas_ticket);
1694             C4::Context->set_userenv(
1695                 $session->param('number'),       $session->param('id'),
1696                 $session->param('cardnumber'),   $session->param('firstname'),
1697                 $session->param('surname'),      $session->param('branch'),
1698                 $session->param('branchname'),   $session->param('flags'),
1699                 $session->param('emailaddress'), $session->param('shibboleth'),
1700                 $session->param('desk_id'),      $session->param('desk_name'),
1701                 $session->param('register_id'),  $session->param('register_name')
1702             );
1703             return ( "ok", $cookie, $sessionID );
1704         } else {
1705             return ( "failed", undef, undef );
1706         }
1707     }
1708 }
1709
1710 =head2 check_cookie_auth
1711
1712   ($status, $sessionId) = check_api_auth($cookie, $userflags);
1713
1714 Given a CGISESSID cookie set during a previous login to Koha, determine
1715 if the user has the privileges specified by C<$userflags>. C<$userflags>
1716 is passed unaltered into C<haspermission> and as such accepts all options
1717 avaiable to that routine with the one caveat that C<check_api_auth> will
1718 also allow 'undef' to be passed and in such a case the permissions check
1719 will be skipped altogether.
1720
1721 C<check_cookie_auth> is meant for authenticating special services
1722 such as tools/upload-file.pl that are invoked by other pages that
1723 have been authenticated in the usual way.
1724
1725 Possible return values in C<$status> are:
1726
1727 =over
1728
1729 =item "ok" -- user authenticated; C<$sessionID> have valid values.
1730
1731 =item "failed" -- credentials are not correct; C<$sessionid> are undef
1732
1733 =item "maintenance" -- DB is in maintenance mode; no login possible at the moment
1734
1735 =item "expired -- session cookie has expired; API user should resubmit userid and password
1736
1737 =back
1738
1739 =cut
1740
1741 sub check_cookie_auth {
1742     my $cookie        = shift;
1743     my $flagsrequired = shift;
1744     my $params        = shift;
1745
1746     my $remote_addr = $params->{remote_addr} || $ENV{REMOTE_ADDR};
1747     my $dbh     = C4::Context->dbh;
1748     my $timeout = _timeout_syspref();
1749
1750     unless ( C4::Context->preference('Version') ) {
1751
1752         # database has not been installed yet
1753         return ( "maintenance", undef );
1754     }
1755     my $kohaversion = Koha::version();
1756     $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
1757     if ( C4::Context->preference('Version') < $kohaversion ) {
1758
1759         # database in need of version update; assume that
1760         # no API should be called while databsae is in
1761         # this condition.
1762         return ( "maintenance", undef );
1763     }
1764
1765     # FIXME -- most of what follows is a copy-and-paste
1766     # of code from checkauth.  There is an obvious need
1767     # for refactoring to separate the various parts of
1768     # the authentication code, but as of 2007-11-23 this
1769     # is deferred so as to not introduce bugs into the
1770     # regular authentication code for Koha 3.0.
1771
1772     # see if we have a valid session cookie already
1773     # however, if a userid parameter is present (i.e., from
1774     # a form submission, assume that any current cookie
1775     # is to be ignored
1776     unless ( defined $cookie and $cookie ) {
1777         return ( "failed", undef );
1778     }
1779     my $sessionID = $cookie;
1780     my $session   = get_session($sessionID);
1781     C4::Context->_new_userenv($sessionID);
1782     if ($session) {
1783         C4::Context->interface($session->param('interface'));
1784         C4::Context->set_userenv(
1785             $session->param('number'),       $session->param('id'),
1786             $session->param('cardnumber'),   $session->param('firstname'),
1787             $session->param('surname'),      $session->param('branch'),
1788             $session->param('branchname'),   $session->param('flags'),
1789             $session->param('emailaddress'), $session->param('shibboleth'),
1790             $session->param('desk_id'),      $session->param('desk_name'),
1791             $session->param('register_id'),  $session->param('register_name')
1792         );
1793
1794         my $ip       = $session->param('ip');
1795         my $lasttime = $session->param('lasttime');
1796         my $userid   = $session->param('id');
1797         if ( $lasttime < time() - $timeout ) {
1798
1799             # time out
1800             $session->delete();
1801             $session->flush;
1802             C4::Context->_unset_userenv($sessionID);
1803             $userid    = undef;
1804             $sessionID = undef;
1805             return ("expired", undef);
1806         } elsif ( C4::Context->preference('SessionRestrictionByIP') && $ip ne $remote_addr ) {
1807
1808             # IP address changed
1809             $session->delete();
1810             $session->flush;
1811             C4::Context->_unset_userenv($sessionID);
1812             $userid    = undef;
1813             $sessionID = undef;
1814             return ( "expired", undef );
1815         } else {
1816             $session->param( 'lasttime', time() );
1817             my $flags = defined($flagsrequired) ? haspermission( $userid, $flagsrequired ) : 1;
1818             if ($flags) {
1819                 return ( "ok", $sessionID );
1820             } else {
1821                 $session->delete();
1822                 $session->flush;
1823                 C4::Context->_unset_userenv($sessionID);
1824                 $userid    = undef;
1825                 $sessionID = undef;
1826                 return ( "failed", undef );
1827             }
1828         }
1829     } else {
1830         return ( "expired", undef );
1831     }
1832 }
1833
1834 =head2 get_session
1835
1836   use CGI::Session;
1837   my $session = get_session($sessionID);
1838
1839 Given a session ID, retrieve the CGI::Session object used to store
1840 the session's state.  The session object can be used to store
1841 data that needs to be accessed by different scripts during a
1842 user's session.
1843
1844 If the C<$sessionID> parameter is an empty string, a new session
1845 will be created.
1846
1847 =cut
1848
1849 sub _get_session_params {
1850     my $storage_method = C4::Context->preference('SessionStorage');
1851     if ( $storage_method eq 'mysql' ) {
1852         my $dbh = C4::Context->dbh;
1853         return { dsn => "driver:MySQL;id:md5", dsn_args => { Handle => $dbh } };
1854     }
1855     elsif ( $storage_method eq 'Pg' ) {
1856         my $dbh = C4::Context->dbh;
1857         return { dsn => "driver:PostgreSQL;id:md5", dsn_args => { Handle => $dbh } };
1858     }
1859     elsif ( $storage_method eq 'memcached' && Koha::Caches->get_instance->memcached_cache ) {
1860         my $memcached = Koha::Caches->get_instance()->memcached_cache;
1861         return { dsn => "driver:memcached;id:md5", dsn_args => { Memcached => $memcached } };
1862     }
1863     else {
1864         # catch all defaults to tmp should work on all systems
1865         my $dir = C4::Context::temporary_directory;
1866         my $instance = C4::Context->config( 'database' ); #actually for packages not exactly the instance name, but generally safer to leave it as it is
1867         return { dsn => "driver:File;id:md5", dsn_args => { Directory => "$dir/cgisess_$instance" } };
1868     }
1869 }
1870
1871 sub get_session {
1872     my $sessionID      = shift;
1873     my $params = _get_session_params();
1874     return CGI::Session->new( $params->{dsn}, $sessionID, $params->{dsn_args} );
1875 }
1876
1877
1878 # FIXME no_set_userenv may be replaced with force_branchcode_for_userenv
1879 # (or something similar)
1880 # Currently it's only passed from C4::SIP::ILS::Patron::check_password, but
1881 # not having a userenv defined could cause a crash.
1882 sub checkpw {
1883     my ( $dbh, $userid, $password, $query, $type, $no_set_userenv ) = @_;
1884     $type = 'opac' unless $type;
1885
1886     # Get shibboleth login attribute
1887     my $shib = C4::Context->config('useshibboleth') && shib_ok();
1888     my $shib_login = $shib ? get_login_shib() : undef;
1889
1890     my @return;
1891     my $patron;
1892     if ( defined $userid ){
1893         $patron = Koha::Patrons->find({ userid => $userid });
1894         $patron = Koha::Patrons->find({ cardnumber => $userid }) unless $patron;
1895     }
1896     my $check_internal_as_fallback = 0;
1897     my $passwd_ok = 0;
1898     # Note: checkpw_* routines returns:
1899     # 1 if auth is ok
1900     # 0 if auth is nok
1901     # -1 if user bind failed (LDAP only)
1902
1903     if ( $patron and $patron->account_locked ) {
1904         # Nothing to check, account is locked
1905     } elsif ($ldap && defined($password)) {
1906         $debug and print STDERR "## checkpw - checking LDAP\n";
1907         my ( $retval, $retcard, $retuserid ) = checkpw_ldap(@_);    # EXTERNAL AUTH
1908         if ( $retval == 1 ) {
1909             @return = ( $retval, $retcard, $retuserid );
1910             $passwd_ok = 1;
1911         }
1912         $check_internal_as_fallback = 1 if $retval == 0;
1913
1914     } elsif ( $cas && $query && $query->param('ticket') ) {
1915         $debug and print STDERR "## checkpw - checking CAS\n";
1916
1917         # In case of a CAS authentication, we use the ticket instead of the password
1918         my $ticket = $query->param('ticket');
1919         $query->delete('ticket');                                   # remove ticket to come back to original URL
1920         my ( $retval, $retcard, $retuserid, $cas_ticket ) = checkpw_cas( $dbh, $ticket, $query, $type );    # EXTERNAL AUTH
1921         if ( $retval ) {
1922             @return = ( $retval, $retcard, $retuserid, $cas_ticket );
1923         } else {
1924             @return = (0);
1925         }
1926         $passwd_ok = $retval;
1927     }
1928
1929     # If we are in a shibboleth session (shibboleth is enabled, and a shibboleth match attribute is present)
1930     # Check for password to asertain whether we want to be testing against shibboleth or another method this
1931     # time around.
1932     elsif ( $shib && $shib_login && !$password ) {
1933
1934         $debug and print STDERR "## checkpw - checking Shibboleth\n";
1935
1936         # In case of a Shibboleth authentication, we expect a shibboleth user attribute
1937         # (defined under shibboleth mapping in koha-conf.xml) to contain the login of the
1938         # shibboleth-authenticated user
1939
1940         # Then, we check if it matches a valid koha user
1941         if ($shib_login) {
1942             my ( $retval, $retcard, $retuserid ) = C4::Auth_with_shibboleth::checkpw_shib($shib_login);    # EXTERNAL AUTH
1943             if ( $retval ) {
1944                 @return = ( $retval, $retcard, $retuserid );
1945             }
1946             $passwd_ok = $retval;
1947         }
1948     } else {
1949         $check_internal_as_fallback = 1;
1950     }
1951
1952     # INTERNAL AUTH
1953     if ( $check_internal_as_fallback ) {
1954         @return = checkpw_internal( $dbh, $userid, $password, $no_set_userenv);
1955         $passwd_ok = 1 if $return[0] > 0; # 1 or 2
1956     }
1957
1958     if( $patron ) {
1959         if ( $passwd_ok ) {
1960             $patron->update({ login_attempts => 0 });
1961         } elsif( !$patron->account_locked ) {
1962             $patron->update({ login_attempts => $patron->login_attempts + 1 });
1963         }
1964     }
1965
1966     # Optionally log success or failure
1967     if( $patron && $passwd_ok && C4::Context->preference('AuthSuccessLog') ) {
1968         logaction( 'AUTH', 'SUCCESS', $patron->id, "Valid password for $userid", $type );
1969     } elsif( !$passwd_ok && C4::Context->preference('AuthFailureLog') ) {
1970         logaction( 'AUTH', 'FAILURE', $patron ? $patron->id : 0, "Wrong password for $userid", $type );
1971     }
1972
1973     return @return;
1974 }
1975
1976 sub checkpw_internal {
1977     my ( $dbh, $userid, $password, $no_set_userenv ) = @_;
1978
1979     $password = Encode::encode( 'UTF-8', $password )
1980       if Encode::is_utf8($password);
1981
1982     my $sth =
1983       $dbh->prepare(
1984         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where userid=?"
1985       );
1986     $sth->execute($userid);
1987     if ( $sth->rows ) {
1988         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
1989             $surname, $branchcode, $branchname, $flags )
1990           = $sth->fetchrow;
1991
1992         if ( checkpw_hash( $password, $stored_hash ) ) {
1993
1994             C4::Context->set_userenv( "$borrowernumber", $userid, $cardnumber,
1995                 $firstname, $surname, $branchcode, $branchname, $flags ) unless $no_set_userenv;
1996             return 1, $cardnumber, $userid;
1997         }
1998     }
1999     $sth =
2000       $dbh->prepare(
2001         "select password,cardnumber,borrowernumber,userid,firstname,surname,borrowers.branchcode,branches.branchname,flags from borrowers join branches on borrowers.branchcode=branches.branchcode where cardnumber=?"
2002       );
2003     $sth->execute($userid);
2004     if ( $sth->rows ) {
2005         my ( $stored_hash, $cardnumber, $borrowernumber, $userid, $firstname,
2006             $surname, $branchcode, $branchname, $flags )
2007           = $sth->fetchrow;
2008
2009         if ( checkpw_hash( $password, $stored_hash ) ) {
2010
2011             C4::Context->set_userenv( $borrowernumber, $userid, $cardnumber,
2012                 $firstname, $surname, $branchcode, $branchname, $flags ) unless $no_set_userenv;
2013             return 1, $cardnumber, $userid;
2014         }
2015     }
2016     return 0;
2017 }
2018
2019 sub checkpw_hash {
2020     my ( $password, $stored_hash ) = @_;
2021
2022     return if $stored_hash eq '!';
2023
2024     # check what encryption algorithm was implemented: Bcrypt - if the hash starts with '$2' it is Bcrypt else md5
2025     my $hash;
2026     if ( substr( $stored_hash, 0, 2 ) eq '$2' ) {
2027         $hash = hash_password( $password, $stored_hash );
2028     } else {
2029         $hash = md5_base64($password);
2030     }
2031     return $hash eq $stored_hash;
2032 }
2033
2034 =head2 getuserflags
2035
2036     my $authflags = getuserflags($flags, $userid, [$dbh]);
2037
2038 Translates integer flags into permissions strings hash.
2039
2040 C<$flags> is the integer userflags value ( borrowers.userflags )
2041 C<$userid> is the members.userid, used for building subpermissions
2042 C<$authflags> is a hashref of permissions
2043
2044 =cut
2045
2046 sub getuserflags {
2047     my $flags  = shift;
2048     my $userid = shift;
2049     my $dbh    = @_ ? shift : C4::Context->dbh;
2050     my $userflags;
2051     {
2052         # I don't want to do this, but if someone logs in as the database
2053         # user, it would be preferable not to spam them to death with
2054         # numeric warnings. So, we make $flags numeric.
2055         no warnings 'numeric';
2056         $flags += 0;
2057     }
2058     my $sth = $dbh->prepare("SELECT bit, flag, defaulton FROM userflags");
2059     $sth->execute;
2060
2061     while ( my ( $bit, $flag, $defaulton ) = $sth->fetchrow ) {
2062         if ( ( $flags & ( 2**$bit ) ) || $defaulton ) {
2063             $userflags->{$flag} = 1;
2064         }
2065         else {
2066             $userflags->{$flag} = 0;
2067         }
2068     }
2069
2070     # get subpermissions and merge with top-level permissions
2071     my $user_subperms = get_user_subpermissions($userid);
2072     foreach my $module ( keys %$user_subperms ) {
2073         next if $userflags->{$module} == 1;    # user already has permission for everything in this module
2074         $userflags->{$module} = $user_subperms->{$module};
2075     }
2076
2077     return $userflags;
2078 }
2079
2080 =head2 get_user_subpermissions
2081
2082   $user_perm_hashref = get_user_subpermissions($userid);
2083
2084 Given the userid (note, not the borrowernumber) of a staff user,
2085 return a hashref of hashrefs of the specific subpermissions
2086 accorded to the user.  An example return is
2087
2088  {
2089     tools => {
2090         export_catalog => 1,
2091         import_patrons => 1,
2092     }
2093  }
2094
2095 The top-level hash-key is a module or function code from
2096 userflags.flag, while the second-level key is a code
2097 from permissions.
2098
2099 The results of this function do not give a complete picture
2100 of the functions that a staff user can access; it is also
2101 necessary to check borrowers.flags.
2102
2103 =cut
2104
2105 sub get_user_subpermissions {
2106     my $userid = shift;
2107
2108     my $dbh = C4::Context->dbh;
2109     my $sth = $dbh->prepare( "SELECT flag, user_permissions.code
2110                              FROM user_permissions
2111                              JOIN permissions USING (module_bit, code)
2112                              JOIN userflags ON (module_bit = bit)
2113                              JOIN borrowers USING (borrowernumber)
2114                              WHERE userid = ?" );
2115     $sth->execute($userid);
2116
2117     my $user_perms = {};
2118     while ( my $perm = $sth->fetchrow_hashref ) {
2119         $user_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
2120     }
2121     return $user_perms;
2122 }
2123
2124 =head2 get_all_subpermissions
2125
2126   my $perm_hashref = get_all_subpermissions();
2127
2128 Returns a hashref of hashrefs defining all specific
2129 permissions currently defined.  The return value
2130 has the same structure as that of C<get_user_subpermissions>,
2131 except that the innermost hash value is the description
2132 of the subpermission.
2133
2134 =cut
2135
2136 sub get_all_subpermissions {
2137     my $dbh = C4::Context->dbh;
2138     my $sth = $dbh->prepare( "SELECT flag, code
2139                              FROM permissions
2140                              JOIN userflags ON (module_bit = bit)" );
2141     $sth->execute();
2142
2143     my $all_perms = {};
2144     while ( my $perm = $sth->fetchrow_hashref ) {
2145         $all_perms->{ $perm->{'flag'} }->{ $perm->{'code'} } = 1;
2146     }
2147     return $all_perms;
2148 }
2149
2150 =head2 haspermission
2151
2152   $flagsrequired = '*';                                 # Any permission at all
2153   $flagsrequired = 'a_flag';                            # a_flag must be satisfied (all subpermissions)
2154   $flagsrequired = [ 'a_flag', 'b_flag' ];              # a_flag OR b_flag must be satisfied
2155   $flagsrequired = { 'a_flag => 1, 'b_flag' => 1 };     # a_flag AND b_flag must be satisfied
2156   $flagsrequired = { 'a_flag' => 'sub_a' };             # sub_a of a_flag must be satisfied
2157   $flagsrequired = { 'a_flag' => [ 'sub_a, 'sub_b' ] }; # sub_a OR sub_b of a_flag must be satisfied
2158
2159   $flags = ($userid, $flagsrequired);
2160
2161 C<$userid> the userid of the member
2162 C<$flags> is a query structure similar to that used by SQL::Abstract that
2163 denotes the combination of flags required. It is a required parameter.
2164
2165 The main logic of this method is that things in arrays are OR'ed, and things
2166 in hashes are AND'ed. The `*` character can be used, at any depth, to denote `ANY`
2167
2168 Returns member's flags or 0 if a permission is not met.
2169
2170 =cut
2171
2172 sub _dispatch {
2173     my ($required, $flags) = @_;
2174
2175     my $ref = ref($required);
2176     if ($ref eq '') {
2177         if ($required eq '*') {
2178             return 0 unless ( $flags or ref( $flags ) );
2179         } else {
2180             return 0 unless ( $flags and (!ref( $flags ) || $flags->{$required} ));
2181         }
2182     } elsif ($ref eq 'HASH') {
2183         foreach my $key (keys %{$required}) {
2184             next if $flags == 1;
2185             my $require = $required->{$key};
2186             my $rflags  = $flags->{$key};
2187             return 0 unless _dispatch($require, $rflags);
2188         }
2189     } elsif ($ref eq 'ARRAY') {
2190         my $satisfied = 0;
2191         foreach my $require ( @{$required} ) {
2192             my $rflags =
2193               ( ref($flags) && !ref($require) && ( $require ne '*' ) )
2194               ? $flags->{$require}
2195               : $flags;
2196             $satisfied++ if _dispatch( $require, $rflags );
2197         }
2198         return 0 unless $satisfied;
2199     } else {
2200         croak "Unexpected structure found: $ref";
2201     }
2202
2203     return $flags;
2204 };
2205
2206 sub haspermission {
2207     my ( $userid, $flagsrequired ) = @_;
2208
2209     #Koha::Exceptions::WrongParameter->throw('$flagsrequired should not be undef')
2210     #  unless defined($flagsrequired);
2211
2212     my $sth = C4::Context->dbh->prepare("SELECT flags FROM borrowers WHERE userid=?");
2213     $sth->execute($userid);
2214     my $row = $sth->fetchrow();
2215     my $flags = getuserflags( $row, $userid );
2216
2217     return $flags unless defined($flagsrequired);
2218     return $flags if $flags->{superlibrarian};
2219     return _dispatch($flagsrequired, $flags);
2220
2221     #FIXME - This fcn should return the failed permission so a suitable error msg can be delivered.
2222 }
2223
2224 =head2 in_iprange
2225
2226   $flags = ($iprange);
2227
2228 C<$iprange> A space separated string describing an IP range. Can include single IPs or ranges
2229
2230 Returns 1 if the remote address is in the provided iprange, or 0 otherwise.
2231
2232 =cut
2233
2234 sub in_iprange {
2235     my ($iprange) = @_;
2236     my $result = 1;
2237     my @allowedipranges = $iprange ? split(' ', $iprange) : ();
2238     if (scalar @allowedipranges > 0) {
2239         my @rangelist;
2240         eval { @rangelist = Net::CIDR::range2cidr(@allowedipranges); }; return 0 if $@;
2241         eval { $result = Net::CIDR::cidrlookup($ENV{'REMOTE_ADDR'}, @rangelist) } || ( $ENV{DEBUG} && warn 'cidrlookup failed for ' . join(' ',@rangelist) );
2242      }
2243      return $result ? 1 : 0;
2244 }
2245
2246 sub getborrowernumber {
2247     my ($userid) = @_;
2248     my $userenv = C4::Context->userenv;
2249     if ( defined($userenv) && ref($userenv) eq 'HASH' && $userenv->{number} ) {
2250         return $userenv->{number};
2251     }
2252     my $dbh = C4::Context->dbh;
2253     for my $field ( 'userid', 'cardnumber' ) {
2254         my $sth =
2255           $dbh->prepare("select borrowernumber from borrowers where $field=?");
2256         $sth->execute($userid);
2257         if ( $sth->rows ) {
2258             my ($bnumber) = $sth->fetchrow;
2259             return $bnumber;
2260         }
2261     }
2262     return 0;
2263 }
2264
2265 =head2 track_login_daily
2266
2267     track_login_daily( $userid );
2268
2269 Wraps the call to $patron->track_login, the method used to update borrowers.lastseen. We only call track_login once a day.
2270
2271 =cut
2272
2273 sub track_login_daily {
2274     my $userid = shift;
2275     return if !$userid || !C4::Context->preference('TrackLastPatronActivity');
2276
2277     my $cache     = Koha::Caches->get_instance();
2278     my $cache_key = "track_login_" . $userid;
2279     my $cached    = $cache->get_from_cache($cache_key);
2280     my $today = dt_from_string()->ymd;
2281     return if $cached && $cached eq $today;
2282
2283     my $patron = Koha::Patrons->find({ userid => $userid });
2284     return unless $patron;
2285     $patron->track_login;
2286     $cache->set_in_cache( $cache_key, $today );
2287 }
2288
2289 END { }    # module clean-up code here (global destructor)
2290 1;
2291 __END__
2292
2293 =head1 SEE ALSO
2294
2295 CGI(3)
2296
2297 C4::Output(3)
2298
2299 Crypt::Eksblowfish::Bcrypt(3)
2300
2301 Digest::MD5(3)
2302
2303 =cut